threads - Perl のインタプリタベースのスレッド
このドキュメントは threads バージョン 1.67 を記述しています。
use threads ('yield',
'stack_size' => 64*4096,
'exit' => 'threads_only',
'stringify');
sub start_thread {
my @args = @_;
print('Thread started: ', join(' ', @args), "\n");
}
my $thr = threads->create('start_thread', 'argument');
$thr->join();
threads->create(sub { print("I am a thread\n"); })->join();
my $thr2 = async { foreach (@files) { ... } };
$thr2->join();
if (my $err = $thr2->error()) {
warn("Thread error: $err\n");
}
# Invoke thread in list context (implicit) so it can return a list
my ($thr) = threads->create(sub { return (qw/a b c/); });
# or specify list context explicitly
my $thr = threads->create({'context' => 'list'},
sub { return (qw/a b c/); });
my @results = $thr->join();
$thr->detach();
# Get a thread's object
$thr = threads->self();
$thr = threads->object($tid);
# Get a thread's ID
$tid = threads->tid();
$tid = $thr->tid();
$tid = "$thr";
# Give other threads a chance to run
threads->yield();
yield();
# Lists of non-detached threads
my @threads = threads->list();
my $thread_count = threads->list();
my @running = threads->list(threads::running);
my @joinable = threads->list(threads::joinable);
# Test thread objects
if ($thr1 == $thr2) {
...
}
# Manage thread stack size
$stack_size = threads->get_stack_size();
$old_size = threads->set_stack_size(32*4096);
# Create a thread with a specific context and stack size
my $thr = threads->create({ 'context' => 'list',
'stack_size' => 32*4096,
'exit' => 'thread_only' },
\&foo);
# Get thread's context
my $wantarray = $thr->wantarray();
# Check thread's state
if ($thr->is_running()) {
sleep(1);
}
if ($thr->is_joinable()) {
$thr->join();
}
# Send a signal to a thread
$thr->kill('SIGUSR1');
# Exit a thread
threads->exit();
Perl 5.6 はインタプリタスレッドと呼ばれるものを導入しました。 インタプリタスレッドは、スレッド毎に新たに Perl インタプリタを 生成することによって、また、デフォルトではいかなるデータや状態も スレッド間で共有しないことによって、5005スレッド (Perl 5.005 におけるスレッドモデル)とは区別されます。
Perl 5.8 より前では、これは Perl を組み込むする人々にとってのみ、
そして Windows で fork() をエミュレートするためにのみ利用可能でした。
threads API は、古い Thread.pm API におおまかに基づいています。 変数はスレッド間で共有されず、全ての変数はデフォルトで スレッドローカルなものであることに注意しておくことが非常に重要です。 共有変数を利用するには、threads::shared を使わなければなりません。
use threads;
use threads::shared;
また、スクリプト内ではできるだけ早いうちに use threads して
スレッドを利用可能にしておくべきだし、
eval "", do, require, use の内部では
スレッド操作ができないことに注意してください。
特に threads::shared を使って変数を共有しようとするならば、
use threads::shared の前に use threads しなければなりません。
(逆にしてしまうと threads は警告を発します。)
これは指定されたエントリポイント関数の実行を開始し、引数として
ARGS リストが与えられる新しいスレッドを作ります。
対応するスレッドオブジェクトか、スレッド作成に失敗した場合は
undef を返します。
FUNCTION は関数名、無名サブルーチン、コードリファレンスのいずれかです。
my $thr = threads->create('func_name', ...);
# or
my $thr = threads->create(sub { ... }, ...);
# or
my $thr = threads->create(\&func, ...);
->new() メソッドは ->create() のエイリアスです。
join()対応するスレッドが実行を終了するのを待ちます。
そのスレッドが終了した時、->join() は
エントリポイント関数の戻り値を返します。
->join() のコンテキスト (無効、スカラ、リストのいずれか) は、
スレッド生成時に決定されます。
# Create thread in list context (implicit)
my ($thr1) = threads->create(sub {
my @results = qw(a b c);
return (@results);
});
# or (explicit)
my $thr1 = threads->create({'context' => 'list'},
sub {
my @results = qw(a b c);
return (@results);
});
# Retrieve list results from thread
my @res1 = $thr1->join();
# Create thread in scalar context (implicit)
my $thr2 = threads->create(sub {
my $result = 42;
return ($result);
});
# Retrieve scalar result from thread
my $res2 = $thr2->join();
# Create a thread in void context (explicit)
my $thr3 = threads->create({'void' => 1},
sub { print("Hello, world\n"); });
# Join the thread in void context (i.e., no return value)
$thr3->join();
さらなる詳細については スレッドのコンテキスト を参照してください。
全てのスレッドが join されるか detach される前にプログラムが終了した場合、 警告が発生します。
既に join しているスレッドに対して ->join() や ->detach() を
行うと、エラーが発生します。
detach()スレッドを join 不可能にし、最終的な返り値を捨てるようにします。 プログラムが終了するとき、まだ実行中の detach されたスレッドは暗黙に 終了します。
いずれかのスレッドが join か detach されずにプログラムが終了すると、警告が 出ます。
既に detach されたスレッドに ->join() や ->detach() を
呼び出すと、エラーが発生します。
detach()スレッドが自分自身を detach するためのクラスメソッドです。
self()スレッドが自身の threads オブジェクトを取得するためのクラスメソッドです。
tid()スレッドの ID を返します。 スレッド ID はユニークな整数であり、プログラムの始まりとなる メインスレッドの値は 0 で、 新しいスレッドが生成されるたびに値を 1 増やしていきます。
tid()スレッドが自身の ID を得るためのクラスメソッドです。
use threads 宣言に stringify インポートオプションを追加すると、
文字列や文字列コンテキスト (例えばハッシュのキーとして) で
スレッドオブジェクトを使おうとすると、その ID が値として使われます:
use threads qw(stringify);
my $thr = threads->create(...);
print("Thread $thr started...\n"); # Prints out: Thread 1 started...
object($tid)指定されたスレッドに関連するアクティブな threads オブジェクトを返します。
もし TID で指定されたスレッドがない場合、join や detach されている場合、
TID が指定されていない場合、指定された TID が undef の
場合、メソッドは undef を返します。
yield()このスレッドが他のスレッドに CPU 時間を譲ってもいいということを OS に 示唆します。 実際に起こることは、基になっているスレッド実装に大きく依存しています。
コード内では、use threads qw(yield) してから、単に yield() を
使えます。
list()引数なしで (または threads::all を使って) リストコンテキストの場合、
join されておらず、detach されていない全ての threads オブジェクトの
リストを返します。
スカラコンテキストでは、上述のものの数を返します。
引数が 真 の (または threads::running を使った) 場合、
join されておらず、detach されていない、まだ実行中の
threads オブジェクトのリストを返します。
引数が 偽 の (または threads::joinable を使った) 場合、
join されておらず、detach されていない、実行が終了した
(つまり ->join() が ブロック されない) threads オブジェクトの
リストを返します。
equal($thr2)2 つのスレッドオブジェクトが同じスレッドかどうかをテストします。 これはより自然な形にオーバーロードされます:
if ($thr1 == $thr2) {
print("Threads are the same\n");
}
# or
if ($thr1 != $thr2) {
print("Threads differ\n");
}
(スレッドの比較はスレッド ID を基にします。)
async はその直後に続くブロックを実行するスレッドを生成します。
このブロックは無名サブルーチンとして扱われるので、閉じ大括弧の後に
セミコロンをつけなければなりません。
threads->create() 同様、async は
threads オブジェクトを返します。
error()スレッドは 無効 コンテキストで実行されます。
このメソッドは、スレッドが 普通に 終了した場合は undef を返します。
さもなければ、スレッドの実行状態に関連づけられた $@ の値を
無効 コンテキストで返します。
_handle()この プライベート メソッドは、スレッドオブジェクトに関連づけられた
内部スレッド構造体のメモリ位置を返します。
Win32 では、これは CreateThread から返される HANDLE 値へのポインタ
(つまり HANDLE *) です; その他のプラットフォームでは、
pthread_create 呼び出しで使われる pthread_t 構造体へのポインタ
(つまり pthread_t *) です。
このメソッドは、一般的な Perl スレッドプログラミングには無用です。 このメソッドの目的は、その他の (XS ベースの) スレッドモジュールが、 Perl スレッドと関連づけられている基礎となるスレッド構造体へのアクセスおよび おそらくは操作を可能にすることです。
_handle()スレッドが自身の handle を得るためのクラスメソッドです。
The usual method for terminating a thread is to return() from the entry point function with the appropriate return value(s). (TBT)
exit()もし必要なら、スレッドはいつでも threads->exit() を
呼び出すことで終了させることが出来ます。
これにより、スレッドはスカラコンテキストでは undef を返し、
リストコンテキストでは空リストを返します。
main スレッドから呼び出されると、exit(0) と同様に振る舞います。
スレッドから呼び出されると、threads->exit() と同様に振る舞います
(つまり、status 終了コードは無視されます)。
main スレッドから呼び出されると、exit(status) と同様に振る舞います。
die()スレッドでの die() の呼び出しは、スレッドの異常終了を意味します。
まずスレッドでの $SIG{__DIE__} ハンドラが呼び出され、
それからスレッドは die() 呼び出しに渡された引数による警告メッセージと
共に終了します。
Calling exit() inside a thread causes the whole
application to terminate. Because of this, the use of exit() inside
threaded code, or in modules that might be used in threaded applications, is
strongly discouraged.
(TBT)
もし本当に exit() が必要なら、以下を使うことを考えてください:
threads->exit() if threads->can('exit'); # Thread friendly
exit(status);
This globally overrides the default behavior of calling exit() inside a
thread, and effectively causes such calls to behave the same as
threads->exit(). In other words, with this setting, calling exit()
causes only the thread to terminate.
(TBT)
Because of its global effect, this setting should not be used inside modules or the like. (TBT)
The main thread is unaffected by this setting. (TBT)
This overrides the default behavior of exit() inside the newly created
thread only.
(TBT)
This can be used to change the exit thread only behavior for a thread after
it has been created. With a true argument, exit() will cause only the
thread to exit. With a false argument, exit() will terminate the
application.
(TBT)
The main thread is unaffected by this call. (TBT)
Class method for use inside a thread to change its own behavior for exit().
(TBT)
The main thread is unaffected by this call. (TBT)
以下の真偽値メソッドはスレッドの 状態 を決定するのに便利です。
is_running()スレッドがまだ実行されている(つまり、そのエントリポイント関数がまだ完了または 終了していない)なら真を返します。
is_joinable()スレッドが実行を完了していて、detach も join もされていないなら真を返します。
言い換えると、このスレッドは join する準備が出来ていて、
$thr->join() の呼び出しは ブロック されません。
is_detached()スレッドが detach されたなら真を返します。
is_detached()スレッドが detach されているかどうかを決定できるようにするための クラスメソッド。
As with subroutines, the type of value returned from a thread's entry point
function may be determined by the thread's context: list, scalar or void.
The thread's context is determined at thread creation. This is necessary so
that the context is available to the entry point function via
wantarray(). The thread may then specify a value of
the appropriate type to be returned from ->join().
(TBT)
Because thread creation and thread joining may occur in different contexts, it
may be desirable to state the context explicitly to the thread's entry point
function. This may be done by calling ->create() with a hash reference
as the first argument:
(TBT)
my $thr = threads->create({'context' => 'list'}, \&foo);
...
my @results = $thr->join();
In the above, the threads object is returned to the parent thread in scalar
context, and the thread's entry point function foo will be called in list
(array) context such that the parent thread can receive a list (array) from
the ->join() call. ('array' is synonymous with 'list'.)
(TBT)
Similarly, if you need the threads object, but your thread will not be returning a value (i.e., void context), you would do the following: (TBT)
my $thr = threads->create({'context' => 'void'}, \&foo);
...
$thr->join();
The context type may also be used as the key in the hash reference followed by a true value: (TBT)
threads->create({'scalar' => 1}, \&foo);
...
my ($thr) = threads->list();
my $result = $thr->join();
明示的に宣言されない場合、スレッドのコンテキストは ->create()
呼び出しのコンテキストになります:
# Create thread in list context
my ($thr) = threads->create(...);
# Create thread in scalar context
my $thr = threads->create(...);
# Create thread in void context
threads->create(...);
wantarray()これは wantarray() と同じ方法でスレッドの コンテキストを返します。
wantarray()現在のスレッドのコンテキストを返すクラスメソッドです。 現在のスレッドのエントリポイント関数の内側で wantarray() を実行するのと同じ値を返します。
The default per-thread stack size for different platforms varies significantly, and is almost always far more than is needed for most applications. On Win32, Perl's makefile explicitly sets the default stack to 16 MB; on most other platforms, the system default is used, which again may be much larger than is needed. (TBT)
By tuning the stack size to more accurately reflect your application's needs, you may significantly reduce your application's memory usage, and increase the number of simultaneously running threads. (TBT)
Note that on Windows, address space allocation granularity is 64 KB, therefore, setting the stack smaller than that on Win32 Perl will not save any more memory. (TBT)
get_stack_size();Returns the current default per-thread stack size. The default is zero, which means the system default stack size is currently in use. (TBT)
get_stack_size();Returns the stack size for a particular thread. A return value of zero indicates the system default stack size was used for the thread. (TBT)
set_stack_size($new_size);Sets a new default per-thread stack size, and returns the previous setting. (TBT)
Some platforms have a minimum thread stack size. Trying to set the stack size below this value will result in a warning, and the minimum stack size will be used. (TBT)
Some Linux platforms have a maximum stack size. Setting too large of a stack size will cause thread creation to fail. (TBT)
If needed, $new_size will be rounded up to the next multiple of the memory
page size (usually 4096 or 8192).
(TBT)
Threads created after the stack size is set will then either call
pthread_attr_setstacksize() (for pthreads platforms), or supply the
stack size to CreateThread() (for Win32 Perl).
(TBT)
(Obviously, this call does not affect any currently extant threads.) (TBT)
This sets the default per-thread stack size at the start of the application. (TBT)
The default per-thread stack size may be set at the start of the application
through the use of the environment variable PERL5_ITHREADS_STACK_SIZE:
(TBT)
PERL5_ITHREADS_STACK_SIZE=1048576
export PERL5_ITHREADS_STACK_SIZE
perl -e'use threads; print(threads->get_stack_size(), "\n")'
This value overrides any stack_size parameter given to use threads. Its
primary purpose is to permit setting the per-thread stack size for legacy
threaded applications.
(TBT)
To specify a particular stack size for any individual thread, call
->create() with a hash reference as the first argument:
(TBT)
my $thr = threads->create({'stack_size' => 32*4096}, \&foo, @args);
This creates a new thread ($thr2) that inherits the stack size from an
existing thread ($thr1). This is shorthand for the following:
(TBT)
my $stack_size = $thr1->get_stack_size();
my $thr2 = threads->create({'stack_size' => $stack_size}, FUNCTION, ARGS);
When safe signals is in effect (the default behavior - see 安全でないシグナル for more details), then signals may be sent and acted upon by individual threads. (TBT)
Sends the specified signal to the thread. Signal names and (positive) signal
numbers are the same as those supported by
kill(). For example, 'SIGTERM', 'TERM' and
(depending on the OS) 15 are all valid arguments to ->kill().
(TBT)
Returns the thread object to allow for method chaining: (TBT)
$thr->kill('SIG...')->join();
Signal handlers need to be set up in the threads for the signals they are expected to act upon. Here's an example for cancelling a thread: (TBT)
use threads;
sub thr_func
{
# Thread 'cancellation' signal handler
$SIG{'KILL'} = sub { threads->exit(); };
...
}
# Create a thread
my $thr = threads->create('thr_func');
...
# Signal the thread to terminate, and then detach
# it so that it will get cleaned up automatically
$thr->kill('KILL')->detach();
Here's another simplistic example that illustrates the use of thread signalling in conjunction with a semaphore to provide rudimentary suspend and resume capabilities: (TBT)
use threads;
use Thread::Semaphore;
sub thr_func
{
my $sema = shift;
# Thread 'suspend/resume' signal handler
$SIG{'STOP'} = sub {
$sema->down(); # Thread suspended
$sema->up(); # Thread resumes
};
...
}
# Create a semaphore and pass it to a thread
my $sema = Thread::Semaphore->new();
my $thr = threads->create('thr_func', $sema);
# Suspend the thread
$sema->down();
$thr->kill('STOP');
...
# Allow the thread to continue
$sema->up();
CAVEAT: The thread signalling capability provided by this module does not
actually send signals via the OS. It emulates signals at the Perl-level
such that signal handlers are called in the appropriate thread. For example,
sending $thr->kill('STOP') does not actually suspend a thread (or the
whole process), but does cause a $SIG{'STOP'} handler to be called in that
thread (as illustrated above).
(TBT)
As such, signals that would normally not be appropriate to use in the
kill() command (e.g., kill('KILL', $$)) are okay to use with the
->kill() method (again, as illustrated above).
(TBT)
Correspondingly, sending a signal to a thread does not disrupt the operation the thread is currently working on: The signal will be acted upon after the current operation has completed. For instance, if the thread is stuck on an I/O call, sending it a signal will not cause the I/O call to be interrupted such that the signal is acted up immediately. (TBT)
Sending a signal to a terminated thread is ignored. (TBT)
If the program exits without all threads having either been joined or detached, then this warning will be issued. (TBT)
NOTE: If the main thread exits, then this warning cannot be suppressed
using no warnings 'threads'; as suggested below.
(TBT)
See the appropriate man page for pthread_create to determine the actual
cause for the failure.
(TBT)
A thread terminated in some manner other than just returning from its entry
point function, or by using threads->exit(). For example, the thread
may have terminated because of an error, or by using die.
(TBT)
Some platforms have a minimum thread stack size. Trying to set the stack size below this value will result in the above warning, and the stack size will be set to the minimum. (TBT)
The specified SIZE exceeds the system's maximum stack size. Use a smaller value for the stack size. (TBT)
If needed, thread warnings can be suppressed by using: (TBT)
no warnings 'threads';
in the appropriate scope. (TBT)
The particular copy of Perl that you're trying to use was not built using the
useithreads configuration option.
(TBT)
Having threads support requires all of Perl and all of the XS modules in the Perl installation to be rebuilt; it is not just a question of adding the threads module (i.e., threaded and non-threaded Perls are binary incompatible.) (TBT)
The stack size of currently extant threads cannot be changed, therefore, the following results in the above error: (TBT)
$thr->set_stack_size($size);
Safe signals must be in effect to use the ->kill() signalling method.
See 安全でないシグナル for more details.
(TBT)
The particular copy of Perl that you're trying to use does not support the
specified signal being used in a ->kill() call.
(TBT)
Before you consider posting a bug report, please consult, and possibly post a message to the discussion forum to see if what you've encountered is a known problem. (TBT)
See Making your module threadsafe in perlmod when creating modules that may be used in threaded applications, especially if those modules use non-Perl data, or XS code. (TBT)
Unfortunately, you may encounter Perl modules that are not thread-safe. For example, they may crash the Perl interpreter during execution, or may dump core on termination. Depending on the module and the requirements of your application, it may be possible to work around such difficulties. (TBT)
If the module will only be used inside a thread, you can try loading the
module from inside the thread entry point function using require (and
import if needed):
(TBT)
sub thr_func
{
require Unsafe::Module
# Unsafe::Module->import(...);
....
}
If the module is needed inside the main thread, try modifying your
application so that the module is loaded (again using require and
->import()) after any threads are started, and in such a way that no
other threads are started afterwards.
(TBT)
If the above does not work, or is not adequate for your application, then file a bug report on http://rt.cpan.org/Public/ against the problematic module. (TBT)
On all platforms except MSWin32, the setting for the current working directory
is shared among all threads such that changing it in one thread (e.g., using
chdir()) will affect all the threads in the application.
(TBT)
On MSWin32, each thread maintains its own the current working directory setting. (TBT)
現在のところ、MSWin32 以外の全てのプラットフォームでは、
スレッドによって作られた (system() または逆クォートによる) 全ての
system 呼び出しは main スレッドの環境変数設定を使います。
言い換えると、スレッドで行った %ENV への変更は、そのスレッドで作られた
system 呼び出しでは見えません。
これを回避するには、system 呼び出しの一部として環境変数をセットします。 例えば:
my $msg = 'hello';
system("FOO=$msg; echo \$FOO"); # Outputs 'hello' to STDOUT
MSWin32 では、各スレッドでは独自の環境変数集合を管理します。
プラットフォームによっては、子 スレッドがまだ存在している間は 親 スレッドを破壊することができないことがあります。
Creating threads inside BEGIN, CHECK or INIT blocks should not be
relied upon. Depending on the Perl version and the application code, results
may range from success, to (apparently harmless) warnings of leaked scalar, or
all the way up to crashing of the Perl interpreter.
(TBT)
Since Perl 5.8.0, signals have been made safer in Perl by postponing their handling until the interpreter is in a safe state. See perl58delta/"Safe Signals" and Deferred Signals (Safe Signals) in perlipc for more details. (TBT)
Safe signals is the default behavior, and the old, immediate, unsafe signalling behavior is only in effect in the following situations: (TBT)
PERL_OLD_SIGNALS (see perl -V).
PERL_SIGNALS is set to unsafe (see PERL_SIGNALS in perlrun).
If unsafe signals is in effect, then signal handling is not thread-safe, and
the ->kill() signalling method cannot be used.
(TBT)
Returning closures from threads should not be relied upon. Depending of the Perl version and the application code, results may range from success, to (apparently harmless) warnings of leaked scalar, or all the way up to crashing of the Perl interpreter. (TBT)
Returning objects from threads does not work. Depending on the classes involved, you may be able to work around this by returning a serialized version of the object (e.g., using Data::Dumper or Storable), and then reconstituting it in the joining thread. (TBT)
Support for threads extends beyond the code in this module (i.e., threads.pm and threads.xs), and into the Perl interpreter itself. Older versions of Perl contain bugs that may manifest themselves despite using the latest version of threads from CPAN. There is no workaround for this other than upgrading to the latest version of Perl. (TBT)
Even with the latest version of Perl, it is known that certain constructs with threads may result in warning messages concerning leaked scalars or unreferenced scalars. However, such warnings are harmless, and may safely be ignored. (TBT)
Perl 5.8.0 以降
CPAN の threads ディスカッションフォーラム: http://www.cpanforum.com/dist/threads
threads の注釈付き POD: http://annocpan.org/~JDHEDDEN/threads-1.67/threads.pm
ソースレポジトリ: http://code.google.com/p/threads-shared/
threads::shared, perlthrtut
http://www.perl.com/pub/a/2002/06/11/threads.html と http://www.perl.com/pub/a/2002/09/04/threads.html
Perl スレッドメーリングリスト: http://lists.cpan.org/showlist.cgi
スタックサイズの議論: http://www.perlmonks.org/
Artur Bergman <sky AT crucially DOT net>
threads is released under the same license as Perl.
CPAN version produced by Jerry D. Hedden <jdhedden AT cpan DOT org>
Richard Soderberg <perl AT crystalflame DOT net> - Helping me out tons, trying to find reasons for races and other weird bugs!
Simon Cozens <simon AT brecon DOT co DOT uk> - Being there to answer zillions of annoying questions
Rocco Caputo <troc AT netrus DOT net>
Vipul Ved Prakash <mail AT vipul DOT net> - Helping with debugging
Dean Arnold <darnold AT presicient DOT com> - Stack size API