NAME

perlboot - Perl オブジェクト指向導入編

DESCRIPTION

他の言語でオブジェクトに親しんでいたのでなければ、 他の Perl オブジェクトのドキュメントのいくつかは気力をくじかせるでしょう。 オブジェクトを使うための基本的なリファレンス perlobj、 Perl のオブジェクトシステムの特性のチュートリアル的な紹介 perltoot 等のように。

そこで、別のアプローチをとって、 オブジェクトの経験がないことを前提にしましょう。 もし、サブルーチン(perlsub)や、リファレンス(perlref等)、 パッケージ(perlmod) を知っているのならそれが役に立ちますので、 もしまだわからなければまずそちらを先に知っておくべきでしょう。

もし動物と会話できたら…

動物さんたちにちょっとしゃべってもらいましょう。

    sub Cow::speak {
      print "a Cow goes moooo!\n";
    }
    sub Horse::speak {
      print "a Horse goes neigh!\n";
    }
    sub Sheep::speak {
      print "a Sheep goes baaaah!\n";
    }

    Cow::speak;
    Horse::speak;
    Sheep::speak;

これは次の結果を得ます:

    a Cow goes moooo!
    a Horse goes neigh!
    a Sheep goes baaaah!

目新しいコトはありません。 別々のパッケージに分かれていて完全なパッケージ名を使って 呼び出していますが、単なるサブルーチンです。 では、牧場を作ってみましょう。

    # Cow::speak, Horse::speak, Sheep::speak as before
    @pasture = qw(Cow Cow Horse Sheep Sheep);
    foreach $animal (@pasture) {
      &{$animal."::speak"};
    }

これは次の結果を得ます:

    a Cow goes moooo!
    a Cow goes moooo!
    a Horse goes neigh!
    a Sheep goes baaaah!
    a Sheep goes baaaah!

うわ。 ここにあるシンボリックcoderefのデリファレンスはかなり粗雑です。 no strict subs モードも考えてみると、大きなプログラムには全然向きません。 なぜその様なものが必要とされるのでしょう? それはパッケージ名を、そのパッケージの呼び出そうとしている サブルーチンの名前から分離できないからです。 ("Cow::speek" というメソッド名が必要だから。)

ではどうしましょう?

メソッド呼び出しの矢印

いまのところ、Class->methodClass パッケージの method サブルーチンを呼び出すとだけ言っておきましょう。 (ここで "Class" は "カテゴリ" の意味です。 "学級" ではありません。) 完全に厳密ではありませんが、少しずつ進めていきましょう。 これは次のように使います:

    # Cow::speak, Horse::speak, Sheep::speak as before
    Cow->speak;
    Horse->speak;
    Sheep->speak;

そしてこれは次の結果を得ます:

    a Cow goes moooo!
    a Horse goes neigh!
    a Sheep goes baaaah!

別におもしろくもありませんね。 同じ文字数ですし全て定数で変数もありません。 でも、今度はパッケージ名を分離できるのです。 次を見てください:

    $a = "Cow";
    $a->speak; # invokes Cow->speak

関数名からパッケージ名を分けれるので、 パッケージ名に変数を使うことができるのです! そして今度は use strict refs が有効であってもちゃんと機能するのです。

裏庭の呼び出し

新しい矢印呼び出しを使って、裏庭の例に戻ってみましょう:

    sub Cow::speak {
      print "a Cow goes moooo!\n";
    }
    sub Horse::speak {
      print "a Horse goes neigh!\n";
    }
    sub Sheep::speak {
      print "a Sheep goes baaaah!\n";
    }

    @pasture = qw(Cow Cow Horse Sheep Sheep);
    foreach $animal (@pasture) {
      $animal->speak;
    }

みんなちゃんとしゃべってくれます! また今度はシンボリック coderef を使っていなくて安全です。

でも、コードをよく見てみると、各 speak 関数はよく似た構造を持っています。 print 演算子と、2 語を除くと同一のテキストを含んでいるだけです。 共通箇所を分解するのはよいことです; 例えば、後で全ての goessays に変えることもできるようになります。

また、大騒ぎすることなくそれを行う方法も実際ありますが、 メソッド呼び出しの矢印が何を行ってくれているのかについて ここで少し知っておかなければなりません。

メソッド呼び出しの追加パラメータ

メソッド呼び出し:

    Class->method(@args)

は、Class::Method 関数を次のように呼び出そうとします:

    Class::method("Class", @args);

(もし関数を見つけることができなかったときには、「継承」が走査されます。 これに関してはあとで説明します。) これは最初のパラメータとしてクラス名を得ることを意味します (もし引数がなければそれがただ1 つのパラメータになります)。 このことから Sheep のおしゃべり関数を次のように書き改めることが できます:

    sub Sheep::speak {
      my $class = shift;
      print "a $class goes baaaah!\n";
    }

また他の動物たちも同様になります:

    sub Cow::speak {
      my $class = shift;
      print "a $class goes moooo!\n";
    }
    sub Horse::speak {
      my $class = shift;
      print "a $class goes neigh!\n";
    }

それぞれにおいて $class にはその関数の特定の値を得ます。 しかしもう一度考え直してみると、かなりよく似た構造になっています。 さらに分離することはできないでしょうか? それは同じクラスの別のメソッドを呼ぶことで可能です。

簡単に 2 つ目のメソッドを呼び出す

speak から補助メソッド sound を呼び出してみましょう。 このメソッドはその鳴き声として固定文字列を提供します。

    { package Cow;
      sub sound { "moooo" }
      sub speak {
        my $class = shift;
        print "a $class goes ", $class->sound, "!\n";
      }
    }

さて、Cow->speak を呼び出すと speak では $class として Cow を得ました。 これをつかって moooo を返す Cow->sound メソッドを選択します。 では Horse の時はどこが変わるでしょう。

    { package Horse;
      sub sound { "neigh" }
      sub speak {
        my $class = shift;
        print "a $class goes ", $class->sound, "!\n";
      }
    }

パッケージ名と鳴き声の指定だけが変わりました。 ところで Cow と Horse で speak の定義を共有する方法はないでしょうか? それが継承です!

気管を継承する

共通の関数のパッケージとして Animal を作ります; ここで speak を定義します

    { package Animal;
      sub speak {
        my $class = shift;
        print "a $class goes ", $class->sound, "!\n";
      }
    }

次に各動物たちに対して、それぞれの鳴き声の定義と一緒に、 Animal から「継承」します:

    { package Cow;
      @ISA = qw(Animal);
      sub sound { "moooo" }
    }

ここで、@ISA 配列が加えられていることに注意してください。 少々これについて説明します。

ところで、ここで Cow->speak を呼び出すとなにが起こるのでしょう?

まず、Perl が引数リストを構築します。 今回は単純に Cow だけです。 それから Perl は Cow::speak を探します。 しかしそれはありません。 そのため Perl は継承配列 @Cow::ISA を調べます。 それは存在し、名前を 1 つ Animal を格納しています。

Perl は次に AnimalspeakAnimal::speak の様に調べます。 今度は見つかりました。 そこで Perl はこの関数をさっき作っておいた引数リストで呼び出します。

Animal::speak 関数においては、$classCow になります (これが 1 つめの引数です)。 そのため $class->sound の呼び出しにおいて Cow->sound を 得ます。 最初は @ISA を探すことなく調べます。 そしてこれは成功します。

@ISA に関して追記

この魔法の @ISA 変数 ( "アイサ"ではなく"イズ-ア") は、 CowAnimal の「一種である(is-a)」と宣言しています。 これが単なる 1 つの値ではなく配列であることに注意してください。 稀ではありますが、メソッドが見つからなかったときに探す親クラスを 1 つ以上もつこともあるためです。

もし Animal@ISA をもっていたらそれも同様に調べられます。 デフォルトでは、検索は @ISA の中を再帰的に、深さ優先、左から右に 行われます(代替案については mro を参照してください)。 典型的に、各 @ISA がただ1つのみ要素を持っています。 そのため良好な継承ツリーを得ます。 (複数の要素を持っていれば複数の継承、複数の難問を持っています。)

use strict を有効にしたとき、@ISA は明示的なパッケージ名を 持っていないため、そしてレキシカル変数 ("my") でもないため警告を受けます。 この変数はレキシカル変数にはできません。 (継承メカニズムが探索できるように、パッケージに属していなければなりません。) これに対処する方法は 2 つあります。

一番簡単な方法はパッケージ名をつけて使うことです:

    @Cow::ISA = qw(Animal);

もしくは暗黙に名付けられたパッケージ変数を許可することです:

    package Cow;
    use vars qw(@ISA);
    @ISA = qw(Animal);

もしオブジェクト指向モジュールを通して外部からクラスに持ち込むのなら:

    package Cow;
    use Animal;
    use vars qw(@ISA);
    @ISA = qw(Animal);

これを次のように変更します:

    package Cow;
    use base qw(Animal);

ずいぶんコンパクトになります。

メソッドのオーバーライド

ねずみを追加してみましょう。 その声は微かでしょう。

    # Animal package from before
    { package Mouse;
      @ISA = qw(Animal);
      sub sound { "squeak" }
      sub speak {
        my $class = shift;
        print "a $class goes ", $class->sound, "!\n";
        print "[but you can barely hear it!]\n";
      }
    }

    Mouse->speak;

これは次のようになります。

    a Mouse goes squeak!
    [but you can barely hear it!]

ここでは MouseAnimal->speak を呼ぶのではなく 自分用のおしゃべりルーティン Mouse->speak を持っています。 これは、「オーバーライド」と呼ばれています。 事実、MouseAnimal の一種であるという必要はまったくありません。 おしゃべり(speak)に必要なメソッドは全て Mouse に定義されています。

しかしそれでもいくらかのコードを Animal->speak から写しています。 これはまたメンテナンスの悩みを再現させています。 この悩みを回避することはできないでしょうか? Animal が行っていることを Mouse でも、少々コメントを追加して 行う方法はないでしょうか? もちろんあります!

まず Animal::speak メソッドを直接呼び出してみましょう:

    # Animal package from before
    { package Mouse;
      @ISA = qw(Animal);
      sub sound { "squeak" }
      sub speak {
        my $class = shift;
        Animal::speak($class);
        print "[but you can barely hear it!]\n";
      }
    }

メソッド矢印をやめたために、Animal::speak の 1 つめの引数として $class パラメータ(おそらくは "Mouse" という値 )を含めなければ いけないことに注意してください。 なぜやめてしまったのでしょう? ええ、もしここで Animal->speak と呼び出せば最初のパラメータは "Mouse" ではなく "Animal" になってしまいます。 そして sound が呼び出されたときに正しくこのクラスに戻ってくることが できなくなってしまうのです。

しかし Animal::speak を直接呼び出すのはいまいちです。 もし Animal::speak が存在せず、@Animal::ISA に 指定されるクラスから継承していたらどうなるのでしょう? メソッド矢印をすでに使っていないために正しくサブルーチンを探し当てる チャンスはこの方法しかなくなってしまっているのです。

Animal クラス名が関数の中に書き込まれていることにも注意してください。 もしだれかがコードを修正し、speal のにある Animal に気付かないまま Mouse@ISA を書き換えてしまったらまずいことになります。 結局、これは適切な方法ではないのです。

異なる場所から探索を始める

より望ましい解法は Perl に継承ツリーのより高位から探索することを Perl に伝えることです:

    # same Animal as before
    { package Mouse;
      # same @ISA, &sound as before
      sub speak {
        my $class = shift;
        $class->Animal::speak;
        print "[but you can barely hear it!]\n";
      }
    }

これはちゃんと動作します。 この構文を使うことで、speak の探索を Animal から開始することが できます。 そして Animal に直接見つからなくても Animal の全ての継承連鎖を使う ことができます。 さらに、1 つめのパラメータは $class になるため、 見つかった speak メソッドでは 1 つめのエントリに Mouse を得て、 ついに Mouse::sound に戻って動作する様になります。

しかしこれはまだ最良の解ではありません。 @ISA と同等の最初の探索パッケージを維持しなければなりません。 さらに悪いことに Mouse@ISA に複数のエントリを持っていたら 実際に speak を定義しているのがどれなのかわかりません。 もっと良い方法はないでしょうか?

SUPER 解答

呼び出し時の Animal クラスを SUPER クラスに変えることで 検索を自動的に全ての基底クラス群(@ISA に記述されているクラス群) に対して行うことができます。

    # same Animal as before
    { package Mouse;
      # same @ISA, &sound as before
      sub speak {
        my $class = shift;
        $class->SUPER::speak;
        print "[but you can barely hear it!]\n";
      }
    }

つまり、SUPER::speak は現在のパッケージの @ISA から speak を探し、 最初に見つかったものを呼び出します。 これは $class@ISA見ない 点に注意してください。

現在地点

これまでに見てきたものは、メソッド矢印構文:

  Class->method(@args);

その等価な文:

  $a = "Class";
  $a->method(@args);

構築される引数リスト:

  ("Class", @args)

呼び出され方

  Class::method("Class", @Args);

しかし、Class:method が見つからなければ @Class::ISA が(再帰的に) 実際 method を含んでいるパッケージを探すために使われます。

この簡単な構文を使うことでクラスメソッド、(複数の)継承、オーバーライド、 そして拡張を行えるようになりました。 これまでに見てきたもの丈で共通処理を抽出し、様々な実装に再利用する 良好な方法を提供することができます。 これはオブジェクトが提供するものの核心です。 とはいえオブジェクトはこれ以外にもまだ説明していませんが インスタンスデータも提供します。

馬は馬、もちろん -- ですか?

Animal クラスと Horse クラスを書いてみましょう。

  { package Animal;
    sub speak {
      my $class = shift;
      print "a $class goes ", $class->sound, "!\n";
    }
  }
  { package Horse;
    @ISA = qw(Animal);
    sub sound { "neigh" }
  }

Horse->speak を呼び出すことで Animal::speak に渡り、 そこから Horse::sound に鳴き声を作りに戻ります。 結果は次のようになります:

  a Horse goes neigh!

しかしこのすべての Horse オブジェクトは完全に同一です。 サブルーチンを追加しても、全ての馬が自動的にそれを共有します。 同じ馬を作るが目的ならすばらしいことですが、 個々の馬を識別したい時にはどうすれば良いのでしょうか? 例えば最初の馬に名前を付けたい時にはどうすれば良いのでしょう。 もちろん、それぞれの馬の名前を分離して維持する方法があります。

「インスタンス」と呼ばれる新しい区別を使うことでそれを行うことができます。 「インスタンス」 は一般的にクラスに生成されます。 Perl では任意のリファレンスならインスタンスになることができます。 そこでまず単純なリファレンスとして、馬の名前を保持するスカラリファレンス を使ってみましょう。

  my $name = "Mr. Ed";
  my $talking = \$name;

これで $talking はインスタンス指向のデータ(名前)のリファレンスに なりました。 これを実際のインスタンスにする最後のステップは bless と呼ばれる 特別な操作です。

  bless $talking, Horse;

これはパッケージ名 Horse に関する情報を リファレンスに指されているものに格納する操作を行います。 これにより、$talkingHorse のインスタンスになったといいます。 これで、個々の馬を識別できます。 リファレンスはそれ以外に変化はありませんし、 伝統的なデリファレンス操作を使うこともできます。

インスタンスメソッドの呼び出し

メソッド矢印はパッケージ(クラス)名の時と同じように、 インスタンスに対しても使うことができます。 では、$talking の作り出す音を取り出してみましょう:

  my $noise = $talking->sound;

sound を呼び出すために、Perl は始めに $talking が bless されたリファレンス(つまりインスタンス)であることを確認します。 それから引数リストを構成します、 今回は ($talking) だけです。 (後ほど、クラスの時と同様にインスタンス変数に続けて引数を置くのも 説明します。)

さて、ここがおもしろいところです: Perl はインスタンスが bless されているクラス、今回は Horse を取り出し、 メソッド呼び出しを行うための関数の場所を特定するためにそれを使います。 今回は、Horse::sound が直接に(継承を使うことなしに) みつかり、最終的に次の関数呼び出しとなります:

  Horse::sound($talking)

この最初のパラメータは、先ほどのようなクラス名ではなく インスタンスのままである点に注意してください。 この結果 neigh を復帰値として受け取り、 これが $noise 変数に代入されます。

もし Horse::sound が見つからなかったときには、 クラスメソッドの時と同じように、スーパークラスの 中でメソッドが見つかるかどうか @Horse::ISA リストをたどります。 クラスメソッドとインスタンスメソッドとの違いは その最初の引数がインスタンス(bless されたリファレンス) なのかクラス名(文字列)なのかという点だけです。

インスタンスのデータへのアクセス

最初の引数としてインスタンスを得ることができるので、 インスタンス固有のデータにアクセスすることができます。 今回は、名前にアクセスする方法を追加してみましょう:

  { package Horse;
    @ISA = qw(Animal);
    sub sound { "neigh" }
    sub name {
      my $self = shift;
      $$self;
    }
  }

これでその名前を呼ぶことができます:

  print $talking->name, " says ", $talking->sound, "\n";

Horse::name の内側では、@_ 配列には shift$self に 代入される $talking のみが含まれています。 (インスタンスメソッドにおいて、その最初のパラメータを $self という名前の 変数に shift して代入するのはお約束なので、ここでは あまり理由を追い求めないでください。) それから、$self はスカラリファレンスとして デリファレンスされ、Mr. Ed が取り出され、 それでおしまいです。 結果は次のようになります:

  Mr. Ed says neigh.

馬の作り方

もちろん、すべての馬を手で作っていては時々失敗することもあるでしょう。 また馬の「内臓」が外から見えてしまうのはオブジェクト指向 プログラミングの約束事を 1 つ破っています。 もしあなたが獣医であればそれもよいでしょうが、 自分の馬を持ちたいだけであればそうではありません。 なので Horse クラスに新しい馬を作ってもらいましょう:

  { package Horse;
    @ISA = qw(Animal);
    sub sound { "neigh" }
    sub name {
      my $self = shift;
      $$self;
    }
    sub named {
      my $class = shift;
      my $name = shift;
      bless \$name, $class;
    }
  }

この新しく作った named メソッドで馬を作ることができます:

  my $talking = Horse->named("Mr. Ed");

ここで私たちはクラスメソッドに戻っていることに注意してください; また Horse::named の2つの引数は Horse および Mr. Ed になります。 bless 演算子は $name を bless するだけでなく、 $name へのリファレンスを返します、それによって これは適切な復帰値となります。 これが馬の作り方です。

ここではコンストラクタを named としたので、このコンストラクタの引数が 特定の Horse の名前ということを示しています。 (家系や誕生日を記録するといった)違った方法でオブジェクトに 「命を吹き込む」別のコンストラクタには また違った名前をつけることができます。 しかし、もっと制限の課せられていた言語から Perl へと来たほとんどの人々は new という 1 つのコンストラクタに、様々な引数の処理方法を 加えて使います。 どちらの方法でも、オブジェクトを作り出すあなたの特定のやり方をあなたが ドキュメント化している限りは問題ありません。 (そしてそれを行ってきている、そうですよね?)

コンストラクタの継承

でもこのメソッドに Horse 特有のことってありますか? 答えは No です。 従って、Animal から継承して何かを構築するのと 同じレシピを使うことができます、やってみましょう:

  { package Animal;
    sub speak {
      my $class = shift;
      print "a $class goes ", $class->sound, "!\n";
    }
    sub name {
      my $self = shift;
      $$self;
    }
    sub named {
      my $class = shift;
      my $name = shift;
      bless \$name, $class;
    }
  }
  { package Horse;
    @ISA = qw(Animal);
    sub sound { "neigh" }
  }

あぁ、でもインスタンスに対して speak を呼び出したら どうなるのでしょう?

  my $talking = Horse->named("Mr. Ed");
  $talking->speak;

これはデバッグ情報になってしまいます:

  a Horse=SCALAR(0xaca42ac) goes neigh!

なぜこうなってしまうのでしょう? それは、この Animal::speak ルーチンはその最初の引数には インスタンスではなくクラス名が来ると思っているからです。 インスタンスが渡されるとブレスされたスカラリファレンスを 文字列として使うことになってしまい、それが先ほどみたものに なってしまうのです。

メソッドをクラスでもインスタンスでも動作できるようにする

今必要なことは、クラスに対して呼ばれたのか それともインスタンスに対して呼ばれたのかを区別する方法です。 一番率直な方法は ref 演算子を使うことです。 これは bless されたリファレンスに対して使うと文字列(クラス名)を返し、 (クラス名のような)文字列に対して使うと空文字列を返します。 ではまず変わったことがわかるように name メソッドを 変更してみましょう。

  sub name {
    my $either = shift;
    ref $either
      ? $$either # it's an instance, return name
      : "an unnamed $either"; # it's a class, return generic
  }

ここで ?: 演算子はでリファレンスするか派生された文字列かを 簡単に選択するために使っています。 さてこれでこのメソッドをインスタンスでもクラスでも使えるようにできました。 最初のパラメータを保持する変数の名前を使う意図に合わせて $either に変更しています:

  my $talking = Horse->named("Mr. Ed");
  print Horse->name, "\n"; # prints "an unnamed Horse\n"
  print $talking->name, "\n"; # prints "Mr Ed.\n"

そして speak もこれを使うように直してみましょう:

  sub speak {
    my $either = shift;
    print $either->name, " goes ", $either->sound, "\n";
  }

そして sound は既にクラスでもインスタンスでも動作する ようになっているので、これで完了です!

メソッドにパラメータを追加する

次は私たちの動物に食べることをしつけてみましょう:

  { package Animal;
    sub named {
      my $class = shift;
      my $name = shift;
      bless \$name, $class;
    }
    sub name {
      my $either = shift;
      ref $either
        ? $$either # it's an instance, return name
        : "an unnamed $either"; # it's a class, return generic
    }
    sub speak {
      my $either = shift;
      print $either->name, " goes ", $either->sound, "\n";
    }
    sub eat {
      my $either = shift;
      my $food = shift;
      print $either->name, " eats $food.\n";
    }
  }
  { package Horse;
    @ISA = qw(Animal);
    sub sound { "neigh" }
  }
  { package Sheep;
    @ISA = qw(Animal);
    sub sound { "baaaah" }
  }

そして試してみます:

  my $talking = Horse->named("Mr. Ed");
  $talking->eat("hay");
  Sheep->eat("grass");

これは次のように出力します:

  Mr. Ed eats hay.
  an unnamed Sheep eats grass.

パラメータを持ったインスタンスメソッドは、そのインスタンスと パラメータのリストとともに呼び出されます。 そのため最初の呼び出しは次のようになります:

  Animal::eat($talking, "hay");

もっと面白いインスタンス

インスタンスにもっとデータがほしくなったらどうすればよいでしょう? たいていの面白いインスタンスはそれぞれがリファレンスや ほかのオブジェクトだったりする多くの要素で構成されています。 これらを格納する一番簡単な方法はハッシュを使うことです。 ハッシュのキーはオブジェクトの部品(「インスタンス変数」若しくは 「メンバ変数」と呼ばれます)の名前として提供され、 それに対応する値は、まぁ、その値です。

でも馬をハッシュにするにはどうしたらよいでしょう? オブジェクトはブレスされた任意のリファレンスであるということを 思い出してください。 リファレンスを参照している箇所を適切に修正すれば、bless された スカラリファレンスと同じように簡単に、それを bless された ハッシュリファレンスで作ることができます。

では羊を名前と色を持つようにしてみましょう:

  my $bad = bless { Name => "Evil", Color => "black" }, Sheep;

これで $bad->{Name}Evil になり、 $bad->{Color}black になります。 でも $bad->name でその名前にアクセスできるようにしたい ですが、それはスカラリファレンスを前提にしているので台無しにされています。 でも心配しないでください、これはとっても簡単に直ります:

  ## in Animal
  sub name {
    my $either = shift;
    ref $either ?
      $either->{Name} :
      "an unnamed $either";
  }

そしてもちろん named はスカラの羊を作っているので これも同じようになおしましょう。

  ## in Animal
  sub named {
    my $class = shift;
    my $name = shift;
    my $self = { Name => $name, Color => $class->default_color };
    bless $self, $class;
  }

この default_color って何でしょう? named が名前だけで呼ばれても色を設定する必要があります、 そこでクラス毎に初期値となる色を持てるようにしています。 羊には白を定義しておきましょう:

  ## in Sheep
  sub default_color { "white" }

そして追加したそれぞれのクラスで色を定義する必要がないように、 「デフォルトのデフォルト」を提供する 「安全ネット」メソッドを Animal で直接定義しておきます:

  ## in Animal
  sub default_color { "brown" }

そして、namenamed だけがオブジェクトの「構造」を 参照していたので、残りのメソッドはそのままに しておくことができます、speak は前のままでそのまま動作します。

違った色の馬

でも私たちの馬の全部が全部茶色では飽きてしまいます。 なので色を取得/設定するためのメソッドを 1 つか 2 つ作ってみましょう。

  ## in Animal
  sub color {
    $_[0]->{Color}
  }
  sub set_color {
    $_[0]->{Color} = $_[1];
  }

引数にアクセスするための別の方法に関する補足: $_[0]shift の代わりに in-place に 使うことができます。 (これは頻繁に呼び出される箇所で時間を節約することができます。) さてこれで Mr. Ed の色を変えることができます:

  my $talking = Horse->named("Mr. Ed");
  $talking->set_color("black-and-white");
  print $talking->name, " is colored ", $talking->color, "\n";

これは次の結果になります:

  Mr. Ed is colored black-and-white

まとめ

さて、これまでにクラスメソッド、コンストラクタ、 インスタンスメソッド、インスタンスデータ、そして アクセッサをも見てきました。 しかしこれらは Perl の提供しているもののまだ始まりにすぎません。 まだゲッター(getter)でありセッター(setter)でもある アクセッサやデストラクタ、間接オブジェクト表記、 インスタンスデータを追加するサブクラス、クラス毎のデータ、 オーバーロード、"isa" および "can" によるテスト、 UNIVERSAL クラス、等々についてはまだ話し始めてもいません。 これらは他の Perl ドキュメントでカバーされています。 願わくば、これがあなたの一歩となりますように。

SEE ALSO

もっと詳しい情報は、 perlobj (ここで基礎を見た、Perl オブジェクトに関するすべての強固な詳細)、 perltoot (オブジェクトを知っている人のためのチュートリアル)、 perltooc (クラスデータの取り扱い)、 perlbot (もっとトリッキーなこととか)、 そして Damian Conway の優秀な Object Oriented Perl 等の書籍を 参照してください。

おもしろさを垣間見れるモジュールとして、 Class::Accessor、Class::Class、Class::Contract, Class::Data::Inheritable、Class::MethodMaker そして Tie::SecureHash。

COPYRIGHT

Copyright (c) 1999, 2000 by Randal L. Schwartz and Stonehenge Consulting Services, Inc. Permission is hereby granted to distribute this document intact with the Perl distribution, and in accordance with the licenses of the Perl distribution; derived documents must include this copyright notice intact.

Portions of this text have been derived from Perl Training materials originally appearing in the Packages, References, Objects, and Modules course taught by instructors for Stonehenge Consulting Services, Inc. and used with permission.

Portions of this text have been derived from materials originally appearing in Linux Magazine and used with permission.