perlrecharclass - Perl 正規表現文字クラス
Perl 正規表現に関する最上位文書は perlre です。
このマニュアルページは Perl 正規表現の文字クラスの文法と使用法について 議論します。
文字クラスは、集合の中の一文字がマッチングするというような方法で、 文字の集合を指定するための方法です。 次のことを覚えておくことは重要です: 文字集合はソース文字列の中から正確に 一文字だけを消費します。 (ソース文字列とは正規表現がマッチングしようとしている文字列です。)
Perl 正規表現には 3 種類の文字クラスがあります: ドット、 逆スラッシュシーケンス、大かっこで囲まれた形式です。 しかし、「文字クラス」という用語はしばしば大かっこ形式だけを意味するために 使われることに注意してください。 確かに、ほとんどの Perl 文書ではそうなっています。
ドット (またはピリオド) . はおそらくもっともよく使われ、そして確実に もっともよく知られている文字クラスです。 デフォルトでは、ドットは改行を除く任意の文字にマッチングします。 デフォルトは 単一行 修飾子を使うことで改行にもマッチングするように 変更されます: 正規表現全体に対して /s 修飾子を使うか、ローカルには (?s) を使います。 (後述する実験的な \N 逆スラッシュシーケンスでは、単一行 修飾子に 関わりなく改行以外の任意の文字にマッチングします。)
以下は例です:
"a" =~ /./ # マッチングする
"." =~ /./ # マッチングする
"" =~ /./ # マッチングしない (ドットは文字にマッチングする必要がある)
"\n" =~ /./ # マッチングしない (ドットは改行にはマッチングしない)
"\n" =~ /./s # マッチングする (グローバル「単一行」修飾子)
"\n" =~ /(?s:.)/ # マッチングする (ローカル「単一行」修飾子)
"ab" =~ /^.$/ # マッチングしない (ドットは一文字にマッチングする)A backslash sequence is a sequence of characters, the first one of which is a backslash. Perl ascribes special meaning to many such sequences, and some of these are character classes. That is, they match a single character each, provided that the character belongs to the specific set of characters defined by the sequence. (TBT)
以下は文字クラスの逆スラッシュシーケンスの一覧です。 以下でさらに詳細に議論します。 (文字クラスではない逆スラッシュシーケンスについては、perlrebackslash を 参照してください。)
\d 10 進数字にマッチング。
\D 非 10 進数字にマッチング。
\w 「単語」文字にマッチング。
\W 非「単語」文字にマッチング。
\s 空白文字にマッチング。
\S 非空白文字にマッチング。
\h 水平空白文字にマッチング。
\H 水平空白でない文字にマッチング。
\v 垂直空白文字にマッチング。
\V 垂直空白でない文字にマッチング。
\N 改行以外の文字にマッチング。実験的。
\pP, \p{Prop} 指定された Unicode 特性を持つ文字にマッチング。
\PP, \P{Prop} 指定された Unicode 特性を持たない文字にマッチング。\d は 10 進 数字 と考えられる単一の文字にマッチングします。 If the /a modifier in effect, it matches [0-9]. Otherwise, it matches anything that is matched by \p{Digit}, which includes [0-9]. (An unlikely possible exception is that under locale matching rules, the current locale might not have [0-9] matched by \d, and/or might match other characters whose code point is less than 256. Such a locale definition would be in violation of the C language standard, but Perl doesn't currently assume anything in regard to this.) (TBT)
これが意味することは、/a 修飾子が有効でない限り、\d は数字 '0' - '9' だけでなく、アラビア文字、デバナーガリ文字、およびその他の言語の 数字もマッチングします。 これは混乱やセキュリティ問題を引き起こすことがあります。
Some digits that \d matches look like some of the [0-9] ones, but have different values. For example, BENGALI DIGIT FOUR (U+09EA) looks very much like an ASCII DIGIT EIGHT (U+0038). An application that is expecting only the ASCII digits might be misled, or if the match is \d+, the matched string might contain a mixture of digits from different writing systems that look like they signify a number different than they actually do. "num()" in Unicode::UCD can be used to safely calculate the value, returning undef if the input string contains such a mixture. (TBT)
What \p{Digit} means (and hence \d except under the /a modifier) is \p{General_Category=Decimal_Number}, or synonymously, \p{General_Category=Digit}. Starting with Unicode version 4.1, this is the same set of characters matched by \p{Numeric_Type=Decimal}. But Unicode also has a different property with a similar name, \p{Numeric_Type=Digit}, which matches a completely different set of characters. These characters are things such as CIRCLED DIGIT ONE or subscripts, or are from writing systems that lack all ten digits. (TBT)
The design intent is for \d to exactly match the set of characters that can safely be used with "normal" big-endian positional decimal syntax, where, for example 123 means one 'hundred', plus two 'tens', plus three 'ones'. This positional notation does not necessarily apply to characters that match the other type of "digit", \p{Numeric_Type=Digit}, and so \d doesn't match them. (TBT)
In Unicode 5.2, the Tamil digits (U+0BE6 - U+0BEF) can also legally be used in old-style Tamil numbers in which they would appear no more than one in a row, separated by characters that mean "times 10", "times 100", etc. (See http://www.unicode.org/notes/tn21.) (TBT)
\d にマッチングしない任意の文字は \D にマッチングします。
\w は単語全体ではなく、単一の英数字(つまり英字または数字)または 下線(_) のような接続句読点にマッチングします。 これは単語全体にはマッチングしません。 単語全体にマッチングするには、\w+ を使ってください。 This isn't the same thing as matching an English word, but in the ASCII range it is the same as a string of Perl-identifier characters. (TBT)
/a 修飾子が有効なら ...\w は 63 文字 [a-zA-Z0-9_] にマッチングします。
\w はこの範囲で \p{Word} がマッチングするものと同じものに マッチングします。 つまり、タイ文字、ギリシャ文字などです。 This includes connector punctuation (like the underscore) which connect two words together, or diacritics, such as a COMBINING TILDE and the modifier letters, which are generally used to add auxiliary markings to letters. (TBT)
\w は、プラットフォームのネイティブな下線に加えてロケールが英数字と 考えるものにマッチングします。
\w は \p{Word} がマッチングするものと同じものにマッチングします。
\w は [a-zA-Z0-9_] にマッチングします。
どの規則を適用するかは "Which character set modifier is in effect?" in perlre で 記述されている方法で決定されます。
完全な Unicode の単語文字の一覧には多くのセキュリティ問題があります。 http://unicode.org/reports/tr36 を参照してください。
Also, for a somewhat finer-grained set of characters that are in programming language identifiers beyond the ASCII range, you may wish to instead use the more customized Unicode properties, "ID_Start", ID_Continue", "XID_Start", and "XID_Continue". See http://unicode.org/reports/tr31. (TBT)
\w にマッチングしない任意の文字は \W にマッチングします。
\s は空白と考えられる単一の文字にマッチングします。
/a 修飾子が有効なら ...\s は [\t\n\f\r ] の 5 文字にマッチングします; つまり、水平タブ、 改行、改頁、復帰、スペースです。 (ASCII プラットフォームでは \cK である垂直タブには マッチングしないことに注意してください。)
\s matches exactly the code points above 255 shown with an "s" column in the table below. (TBT)
\s はロケールが空白だと考えるものにマッチングします。 これは非ロケールの \s と異なりおそらく垂直スペースを含むことに 注意してください。
\s は正確に以下の表で "s" の列にある文字にマッチングします。
\s は [\t\n\f\r ] にマッチングします。 この一覧にはノーブレークスペースが含まれていないことに注意してください。
どの規則を適用するかは "Which character set modifier is in effect?" in perlre で 記述されている方法で決定されます。
\s にマッチングしない任意の文字は \S にマッチングします。
\h は水平空白と考えられる任意の文字にマッチングします; これはスペースと タブ文字および以下の表に上げられているいくつかのその他の文字です。 \H は水平空白と考えられない文字にマッチングします。
\v は垂直空白と考えられる任意の文字にマッチングします; これは復帰と 行送り(改行)文字に加えていくつかのその他の文字です; 全ては以下の表に 挙げられています。 \V は垂直空白と考えられない任意の文字にマッチングします。
\R は Unicode の規則で改行と考えられるものにマッチングします。 複数文字の並びにマッチングすることもあるので、これは 文字クラスではありません。 従って、大かっこ文字クラスの中では使えません; 代わりに \v (垂直空白) を 使ってください。 詳細は perlrebackslash で議論しています。
\s (および \d と \w) と違って、\h および \v は、ソース文字列が UTF-8 形式かどうかといった他の要素に関わらず同じ文字にマッチングします。
\s が [\h\v] と等価と考える人がいるかもしれません。 これは正しくありません。 例えば、垂直タブ ("\x0b") は \s にマッチングしませんが、垂直空白と 考えられます。
以下の表は Unicode 6.0 現在で \s, \h, \v にマッチングする文字の 完全な一覧です。
最初の列は文字の符号位置(16 進形式)、2 番目の列は (Unicode の)名前です。 3 番目の列はどのクラスにマッチングするかを示しています (\s のマッチングを変更するようなロケールや EBCDIC コードページが 有効でないことを仮定しています)。
0x00009 CHARACTER TABULATION h s
0x0000a LINE FEED (LF) vs
0x0000b LINE TABULATION v
0x0000c FORM FEED (FF) vs
0x0000d CARRIAGE RETURN (CR) vs
0x00020 SPACE h s
0x00085 NEXT LINE (NEL) vs [1]
0x000a0 NO-BREAK SPACE h s [1]
0x01680 OGHAM SPACE MARK h s
0x0180e MONGOLIAN VOWEL SEPARATOR h s
0x02000 EN QUAD h s
0x02001 EM QUAD h s
0x02002 EN SPACE h s
0x02003 EM SPACE h s
0x02004 THREE-PER-EM SPACE h s
0x02005 FOUR-PER-EM SPACE h s
0x02006 SIX-PER-EM SPACE h s
0x02007 FIGURE SPACE h s
0x02008 PUNCTUATION SPACE h s
0x02009 THIN SPACE h s
0x0200a HAIR SPACE h s
0x02028 LINE SEPARATOR vs
0x02029 PARAGRAPH SEPARATOR vs
0x0202f NARROW NO-BREAK SPACE h s
0x0205f MEDIUM MATHEMATICAL SPACE h s
0x03000 IDEOGRAPHIC SPACE h sNEXT LINE と NO-BREAK SPACE はどの規則が有効かによって \s に マッチングしたりマッチングしなかったりします。 the beginning of this section を参照してください。
\N は 5.12 の新機能で、実験的なものです。 これは、ドットのように、改行以外の任意の文字にマッチングします。 違いは、\N は 単一行 正規表現修飾子の影響を受けないことです (上述の "The dot" 参照)。 \N{...} 型式は何か全く違うものを意味するかも知れないことに 注意してください。 {...} が 量指定子 なら、これは指定された回数の 非改行文字にマッチングします。 例えば、\N{3} は三つの非改行にマッチングします; \N{5,} は五つ以上の非改行にマッチングします。 しかし、{...} が有効な量指定子でない場合、これは名前付き文字と 推定されます。 これについては charnames を参照してください。 例えば、\N{COLON}, \N{4F}, \N{F4} はどれも有効な 量指定子ではないので、Perl はそれぞれ COLON, 4F, F4 という名前の 文字を探そうとします。
\pP と \p{Prop} は指定された Unicode 特性に一致する文字に マッチングする文字クラスです。 一文字特性は \pP 形式で、\p に引き続いて特性名です; さもなければ 中かっこが必要です。 中かっこを使うとき、単に特性名を中かっこで囲んだ単一形式と、 \p{name=value} のような形で、文字の特性 "name" が特定の "value" を 持つものにマッチングすることになる複合形式があります。 例えば、数字にマッチングするものは /\pN/ または /\p{Number}/ または /\p{Number=True}/ と書けます。 小文字は LowercaseLetter 特性にマッチングします; これには Ll と言う短縮形式があります。 中かっこが必要なので、/\p{Ll}/ または /\p{Lowercase_Letter}/ または /\p{General_Category=Lowercase_Letter}/ と書きます(下線はオプションです)。 /\pLl/ も妥当ですが、違う意味になります。 これは 2 文字にマッチングします: 英字 (Unicode 特性 \pL)に引き続いて 小文字の l です。
/a 修飾子もロケール規則も有効でない場合、Unicode 特性を使うと 正規表現に Unicode 規則を使うように強制します。
ほとんど全ての特性は大文字小文字を無視したマッチングから免除されることに 注意してください。 つまり、/i 正規表現修飾子はこれらがマッチングするものに影響を 与えないということです。 There are two sets that are affected. The first set is Uppercase_Letter, Lowercase_Letter, and Titlecase_Letter, all of which match Cased_Letter under /i matching. The second set is Uppercase, Lowercase, and Titlecase, all of which match Cased under /i matching. (The difference between these sets is that some things, such as Roman Numerals, come in both upper and lower case so they are Cased, but aren't considered to be letters, so they aren't Cased_Letters. They're actually Letter_Numbers.) This set also includes its subsets PosixUpper and PosixLower, both of which under /i matching match PosixAlpha. (TBT)
Unicode 特性に関するさらなる詳細については、 "Unicode Character Properties" in perlunicode を参照してください; 特性の完全な 一覧については which notes all forms that have /i differences "Properties accessible through \p{} and \P{}" in perluniprops を参照して ください。 独自の特性を定義することも可能です。 これは "User-Defined Character Properties" in perlunicode で 議論されています。 (TBT)
"a" =~ /\w/ # マッチング; "a" は「単語」文字。
"7" =~ /\w/ # マッチング; "7" も「単語」文字。
"a" =~ /\d/ # マッチングしない; "a" は数字ではない。
"7" =~ /\d/ # マッチング; "7" は数字。
" " =~ /\s/ # マッチング; スペースは空白。
"a" =~ /\D/ # マッチング; "a" は非数字。
"7" =~ /\D/ # マッチングしない; "7" は非数字ではない。
" " =~ /\S/ # マッチングしない; スペースは非空白ではない。
" " =~ /\h/ # マッチング; スペースは水平空白。
" " =~ /\v/ # マッチングしない; スペースは垂直空白ではない。
"\r" =~ /\v/ # マッチング; 復帰は垂直空白。
"a" =~ /\pL/ # マッチング; "a" は英字。
"a" =~ /\p{Lu}/ # マッチングしない; /\p{Lu}/ は大文字にマッチングする。
"\x{0e0b}" =~ /\p{Thai}/ # マッチング; \x{0e0b} は文字
# 'THAI CHARACTER SO SO' で、これは
# Thai Unicode クラスにある。
"a" =~ /\P{Lao}/ # マッチング; "a" はラオス文字ではない。It is worth emphasizing that \d, \w, etc, match single characters, not complete numbers or words. To match a number (that consists of digits), use \d+; to match a word, use \w+. But be aware of the security considerations in doing so, as mentioned above. (TBT)
Perl 正規表現で使える文字クラスの第 3 の形式は大かっこ文字クラスです。 もっとも単純な形式では、以下のように大かっこの中にマッチングする文字を リストします: [aeiou]. これは a, e, i, o, u のどれかにマッチングします。 他の文字クラスと同様、正確に一つの文字にマッチングします。 文字クラスで言及した文字で構成されるより長い文字列にマッチングするには、 文字クラスに 量指定子 を付けます。 例えば、[aeiou]+ は一つまたはそれ以上の小文字英語母音に マッチングします。
文字クラスの中で文字を繰り返しても効果はありません; 一度だけ現れたものと 考えられます。
例:
"e" =~ /[aeiou]/ # マッチング; "e" はクラスにある。
"p" =~ /[aeiou]/ # マッチングしない; "p" はクラスにない。
"ae" =~ /^[aeiou]$/ # マッチングしない; 一つの文字クラスは
# 一文字だけにマッチングする。
"ae" =~ /^[aeiou]+$/ # マッチング; 量指定子により。
-------* There is an exception to a bracketed character class matching only a single character. When the class is to match caselessely under /i matching rules, and a character inside the class matches a multiple-character sequence caselessly under Unicode rules, the class (when not inverted) will also match that sequence. For example, Unicode says that the letter LATIN SMALL LETTER SHARP S should match the sequence ss under /i rules. Thus, (TBT)
'ss' =~ /\A\N{LATIN SMALL LETTER SHARP S}\z/i # Matches
'ss' =~ /\A[aeioust\N{LATIN SMALL LETTER SHARP S}]\z/i # Matches正規表現内でメタ文字(つまり、., *, ( のように特別な意味を持つ 文字)となるほとんどの文字は文字クラス内ではエスケープしなくても特別な意味を 失うので、エスケープする必要はありません。 例えば、[()] は開きかっこまたは閉じかっこにマッチングし、文字クラスの中の かっこはグループや捕捉にはなりません。
文字クラスの中でも特別な意味を持つ文字は: \, ^, -, [, ] で、以下で議論します。 これらは逆スラッシュでエスケープできますが、不要な場合もあり、そのような 場合では逆スラッシュは省略できます。
シーケンス \b は大かっこ文字クラスの内側では特別です。 文字クラスの外側では \b 二つの単語文字か二つの非単語文字のどちらかではない 位置を示す表明ですが、大かっこ文字クラスの内側では \b は後退文字に マッチングします。
並び \a, \c, \e, \f, \n, \N{NAME}, \N{U+hex char}, \r, \t, \x も特別で、大かっこ文字クラスの外側と同じ意味を持ちます。 (However, inside a bracketed character class, if \N{NAME} expands to a sequence of characters, only the first one in the sequence is used, with a warning.) (TBT)
また、逆スラッシュに引き続いて 2 または 3 桁の 8 進数字があると 8 進数として 扱われます。
[ は、POSIX 文字クラス(後述の "POSIX Character Classes" 参照)の 開始でない限りは文字クラスの中では特別ではありません。 これは普通エスケープは不要です。
A ] は普通は POSIX 文字クラス(後述の "POSIX Character Classes" 参照)の 終わりか、大かっこ文字クラスの終了を示すかどちらかです。 文字集合に ] を含める必要がある場合、一般的には エスケープしなければなりません。
しかし、] が大かっこ文字クラスの 最初 (または最初の文字がキャレットなら 2 番目) の文字の場合、(空クラスを作ることはできないので)これはクラスの 終了を意味せず、エスケープなしでマッチングできる文字の集合の一部と 考えられます。
例:
"+" =~ /[+?*]/ # マッチング; 文字クラス内の "+" は特別ではない。
"\cH" =~ /[\b]/ # マッチング; 文字クラスの内側の \b は後退と
# 等価。
"]" =~ /[][]/ # マッチング; 文字クラスに [ と ] の両方を
# 含んでいる。
"[]" =~ /[[]]/ # マッチング; パターンは ] だけを含んでいる
# 文字クラスと、それに引き続く
# ] からなる。文字のある範囲にマッチングしたいというのは珍しくありません。 幸運なことに、その範囲の文字を全て一覧に書く代わりに、ハイフン (-) を 使えます。 大かっこ文字クラスの内側で二つの文字がハイフンで区切られていると、 二つの文字の間の全ての文字がクラスに書かれているかのように扱われます。 例えば、[0-9] は任意の ASCII 数字にマッチングし、[a-m] は 古い ASCII アルファベットの前半分の小文字にマッチングします。
ハイフンのそれぞれの側の二つの文字は両方とも英字であったり両方とも 数字であったりする必要はないことに注意してください。 任意の文字が可能ですが、勧められません。 ['-?] は文字の範囲を含みますが、ほとんどの人はどの文字が含まれるか 分かりません。 さらに、このような範囲は、コードが EBCDIC のような異なった文字集合を使う プラットフォームで実行されると移植性の問題を引き起こします。
例えば文字クラスの最初または最後であったり、範囲の直後のために、文字クラスの 中のハイフンが文法的に範囲の一部となれない場合、ハイフンは特別ではなく、 リテラルにマッチングするべき文字として扱われます。 マッチングする文字の集合にハイフンを入れたいけれどもその位置が範囲の 一部として考えられる場合はハイフンを逆スラッシュで エスケープしなければなりません。
例:
[a-z] # 小文字 ASCII 英字にマッチング。
[a-fz] # 'a' から 'f' の英字およびと 'z' の英字に
# マッチング。
[-z] # ハイフン ('-') または英字 'z' にマッチング。
[a-f-m] # 'a' から 'f' の英字、ハイフン ('-')、英字 'm' に
# マッチング。
['-?] # 文字 '()*+,-./0123456789:;<=>? のどれかにマッチング
# (しかし EBCDIC プラットフォームでは異なります)。代わりにマッチングしたくない文字の一覧を指定することも可能です。 文字クラスの先頭の文字としてキャレット (^) を使うことで実現します。 例えば、[^a-z] 小文字の ASCII 英字以外の文字にマッチングします。 , which therefore includes almost a hundred thousand Unicode letters. The class is said to be "negated" or "inverted". (TBT)
この文法はキャレットを大かっこ文字クラスの内側で特別な文字にしますが、 クラスの最初の文字の場合のみです。 それでマッチングしたい文字の一つでキャレットを使いたい場合、キャレットを エスケープするか、最初以外の位置に書いてください。
In inverted bracketed character classes, Perl ignores the Unicode rules that normally say that a given character matches a sequence of multiple characters under caseless /i matching, which otherwise could be highly confusing: (TBT)
"ss" =~ /^[^\xDF]+$/ui;This should match any sequences of characters that aren't \xDF nor what \xDF matches under /i. "s" isn't \xDF, but Unicode says that "ss" is what \xDF matches under /i. So which one "wins"? Do you fail the match because the string has ss or accept it because it has an s followed by another s? (TBT)
例:
"e" =~ /[^aeiou]/ # マッチングしない; 'e' がある。
"x" =~ /[^aeiou]/ # マッチング; 'x' は小文字の母音ではない。
"^" =~ /[^^]/ # マッチングしない; キャレット以外全てにマッチング。
"^" =~ /[x^]/ # マッチング; キャレットはここでは特別ではない。大かっこ文字クラスの中に(\N と \R を例外として)逆スラッシュシーケンス 文字クラスを置くことができ、逆スラッシュシーケンスにマッチングする全ての 文字を文字クラスの中に置いたかのように動作します。 例えば、[a-f\d] は任意の 10 進数字、あるいは 'a' から 'f' までの小文字に マッチングします。
大かっこ文字クラスの中のドット . が特別な意味を持たないのと同じ理由で、 大かっこ文字クラスの中の \N は \N{name} または \N{U+hex char} の形式で、かつ非改行マッチング形式でない形でなければ なりません: これはほとんど何でもマッチングするので、一般的には起こって 欲しいことではありません。
例:
/[\p{Thai}\d]/ # タイ文字または数字の文字に
# マッチングする。
/[^\p{Arabic}()]/ # アラビア文字でもかっこでもない文字に
# マッチングする。逆スラッシュシーケンス文字クラスは範囲の端点の一つにはできません。 従って、以下のようにはできません:
/[\p{Thai}-\d]/ # Wrong!POSIX 文字クラスは [:class:] の形式で、class は名前、[: と :] は デリミタです。 POSIX 文字クラスは大かっこ文字クラスの 内側 にのみ現れ、文字のグループを 一覧するのに便利で記述的な方法です。
文法について注意してください、
# Correct:
$string =~ /[[:alpha:]]/
# Incorrect (will warn):
$string =~ /[:alpha:]/後者のパターンは、コロンおよび a, l, p, h の文字からなる 文字クラスです。 これら文字クラスはより大きな大かっこ文字クラスの一部にできます。 例えば、
[01[:alpha:]%]これは妥当で、'0'、'1'、任意の英字、パーセントマークにマッチングします。
Perl は以下の POSIX 文字クラスを認識します:
alpha 任意の英字 ("[A-Za-z]")。
alnum 任意の英数字。("[A-Za-z0-9]")
ascii 任意の ASCII 文字集合の文字。
blank GNU 拡張; スペースまたは水平タブ ("\t") と同じ。
cntrl 任意の制御文字。後述の [2] 参照。
digit 任意の 10 進数字 ("[0-9]"); "\d" と等価。
graph 任意の表示文字; スペースを除く。後述の [3] 参照。
lower 任意の小文字 ("[a-z]")。
print 任意の表示文字; スペースを含む。後述の [4] 参照。
punct 任意の「単語」文字を除く表示文字。[5] 参照。
space 任意の空白文字。"\s" に加えて水平タブ ("\cK")。
upper 任意の大文字 ("[A-Z]")。
word Perl 拡張 ("[A-Za-z0-9_]"); "\w" と等価。
xdigit 任意の 16 進文字 ("[0-9a-fA-F]")。ほとんどの POSIX 文字クラスには、対応する二つの Unicode 式の \p 特性が あります。 (これは公式 Unicode 特性ではなく、公式 Unicode 特性から派生した Perl エクステンションです。) 以下の表は POSIX 文字クラスと対応するものとの関連を示します。
対応物の一つである、表で "ASCII-range Unicode" と書かれた列のものは、 ASCII 文字集合の文字にのみマッチングします。
もう一つの対応物である、"Full-range Unicode" と書かれた列のものは、 Unicode 文字集合全体の中の適切な任意の文字にマッチングします。 例えば、\p{Alpha} は単に ASCII アルファベット文字だけでなく、 Unicode 文字集合全体の中からアルファベットと考えられる任意の文字に マッチングします。 The column labelled "backslash sequence" is a (short) synonym for the Full-range Unicode form. (TBT)
(それぞれの対応物には様々な同義語もあります。 "Properties accessible through \p{} and \P{}" in perluniprops に 全ての同義語と、ASCII 範囲のそれぞれでマッチングする全ての文字の一覧が あります。 例えば、\p{AHex} は \p{ASCII_Hex_Digit} の同義語で、 任意の \p 特性名は、\p{IsAlpha} のように、"Is" 接頭辞が使えます。)
Both the \p counterparts always assume Unicode rules are in effect. On ASCII platforms, this means they assume that the code points from 128 to 255 are Latin-1, and that means that using them under locale rules is unwise unless the locale is guaranteed to be Latin-1 or UTF-8. In contrast, the POSIX character classes are useful under locale rules. They are affected by the actual rules in effect, as follows: (TBT)
/a modifier, is in effect ...Each of the POSIX classes matches exactly the same as their ASCII-range counterparts. (TBT)
The POSIX class matches the same as its Full-range counterpart. (TBT)
The POSIX class matches according to the locale. (TBT)
The POSIX class matches the same as the Full-range counterpart. (TBT)
The POSIX class matches the same as the ASCII range counterpart. (TBT)
どの規則を適用するかは "Which character set modifier is in effect?" in perlre で 記述されている方法で決定されます。
Perl の将来のバージョンではこの振る舞いを変えることが提案されています; whether or not Unicode rules are in effect would not change the behavior: Outside of locale or an EBCDIC code page, the POSIX classes would behave like their ASCII-range counterparts. この提案にコメントしたいなら、perl5-porters@perl.org にメールを 送ってください。 (TBT)
[[:...:]] ASCII-range Full-range backslash Note
Unicode Unicode sequence
-----------------------------------------------------
alpha \p{PosixAlpha} \p{XPosixAlpha}
alnum \p{PosixAlnum} \p{XPosixAlnum}
ascii \p{ASCII}
blank \p{PosixBlank} \p{XPosixBlank} \h [1]
or \p{HorizSpace} [1]
cntrl \p{PosixCntrl} \p{XPosixCntrl} [2]
digit \p{PosixDigit} \p{XPosixDigit} \d
graph \p{PosixGraph} \p{XPosixGraph} [3]
lower \p{PosixLower} \p{XPosixLower}
print \p{PosixPrint} \p{XPosixPrint} [4]
punct \p{PosixPunct} \p{XPosixPunct} [5]
\p{PerlSpace} \p{XPerlSpace} \s [6]
space \p{PosixSpace} \p{XPosixSpace} [6]
upper \p{PosixUpper} \p{XPosixUpper}
word \p{PosixWord} \p{XPosixWord} \w
xdigit \p{PosixXDigit} \p{XPosixXDigit}\p{Blank} と \p{HorizSpace} は同義語です。
制御文字はそれ自体は出力されず、普通は何か端末を制御します: 例えば 改行と後退は制御文字です。 ASCII の範囲では、符号位置が 0 から 31 までの範囲の文字および 127 (DEL) が 制御文字です。
EBCDIC プラットフォームでは、コードページは [[:cntrl:]] を、ASCII 制御文字の EBCDIC 等価物に加えて、Unicode で符号位置 128 から 139 を 持つものと定義しています。
graphical、つまり見える文字。 このクラスは全ての英数字と全ての句読点文字。
全ての表示可能な文字; 全ての graphical 文字に加えて制御文字でない空白文字。
ASCII の範囲の \p{PosixPunct} と [[:punct:]] は全ての非制御、非英数字、 非空白文字にマッチングします: [-!"#$%&'()*+,./:;<=>?@[\\\]^_`{|}~] (しかしロケールが有効なら、 [[:punct:]] の振る舞いが変わります)。
The similarly named property, \p{Punct}, matches a somewhat different set in the ASCII range, namely [-!"#%&'()*,./:;?@[\\\]_{}]. That is, it is missing [$+<=>^`|~]. This is because Unicode splits what POSIX considers to be punctuation into two categories, Punctuation and Symbols. (TBT)
\p{XPosixPunct} and (in Unicode mode) [[:punct:]], match what \p{PosixPunct} matches in the ASCII range, plus what \p{Punct} matches. This is different than strictly matching according to \p{Punct}. Unicode 規則が有効な場合のもう一つの言い方は、[[:punct:]] は Unicode が 句読点として扱うものに加えて、Unicode が "symbols" として扱う ASCII 範囲の 全ての文字にマッチングします。 (TBT)
\p{SpacePerl} と \p{Space} の違いは、非ロケールマッチングでは \p{Space} は垂直タブ \cK にもマッチングすると言うことだけです。 二つの ASCII のみの範囲の形式では同じです。
There are various other synonyms that can be used for these besides \p{HorizSpace} and \\p{XPosixBlank}. 例えば、\p{PosixAlpha} は \p{Alpha} と書けます。 全ての一覧は "Properties accessible through \p{} and \P{}" in perluniprops に あります。 (TBT)
POSIX 文字クラスに対する Perl の拡張は否定の機能です。 これはクラス名の前にキャレット (^) を置くことで実現します。 いくつかの例です:
POSIX ASCII-range Full-range backslash
Unicode Unicode sequence
-----------------------------------------------------
[[:^digit:]] \P{PosixDigit} \P{XPosixDigit} \D
[[:^space:]] \P{PosixSpace} \P{XPosixSpace}
\P{PerlSpace} \P{XPerlSpace} \S
[[:^word:]] \P{PerlWord} \P{XPosixWord} \W逆スラッシュシーケンスは ASCII- か Full-range Unicode のどちらかを意味します; どちらが使われるかは "Which character set modifier is in effect?" in perlre で 記述されている様々な要素に依存します。
Perl は POSIX 文字クラス [=class=] と [.class.] を認識しますが、 これらには(まだ?)対応していません。 このような構文を使おうとすると例外が発生します。
/[[:digit:]]/ # 数字の文字にマッチングする。
/[01[:lower:]]/ # 小文字、'0'、'1' のいずれかの文字に
# マッチングする。
/[[:digit:][:^xdigit:]]/ # 'a' から 'f' 以外の任意の文字に
# マッチング。これはメインの文字クラスでは二つの
# POSIX 文字クラスが OR され、一つは任意の数字に
# マッチングし、もう一つは 16 進文字でない全ての
# 文字にマッチングします。従って
# 'a' から 'f' および 'A' から 'F' を
# 除く全ての文字に
# マッチングすることになります。