perlsyn - Perl の文法
Perl プログラムは、宣言と文の並びから構成され、上から下へと実行されます。 ループ、サブルーチン、その他の制御機構でコードの色々なところに ジャンプできます。
Perl は 自由書式 言語です: 好きなように整形したりインデントしたり できます。 空白が文法の重要な要素である Python や、意味のない Fortran のような言語と 異なり、空白はほとんどトークンの分割の役目です。
Perl の多くの文法要素は 省略可能 です。 全ての関数をかっこで括ったり、全ての変数を宣言したりすることを 要求するのではなく、しばしばそのような明示的な要素を置いておいて、 Perl にあなたが意味しているところを見つけ出させることができます。 これは Do What I Mean と知られ、頭文字を取って DWIM と呼ばれます。 これによって、プログラマを 怠惰 にでき、彼らが快適だと思うスタイルで コーディングできるようにします。
Perl は、awk, sed, C, Bourne Shell, Smalltalk, Lisp, 果ては英語といった、 多くの言語からコンセプトと 文法を借用 しています。 他の言語も Perl から文法を借用しています; 特に正規表現拡張をです。 従って、他の言語でプログラミングしていたなら、Perl にも見たことがあるような ものがあるでしょう。 それらはしばしば同じように動作しますが、違う点についての情報は perltrap を参照してください。
Perl で宣言が必要なものはレポートフォーマットとサブルーチンだけです (サブルーチンすら宣言が不要な場合もあります)。 スカラ変数は、undef 以外の定義された値を代入されるまでは未定義値 (undef)となります。 数値として使われる場合、undef は 0 として扱われます; 文字列として使われる場合、これは空文字列 "" として扱われます; リファレンスとして使われる場合、これは何も代入されていないので、エラーとして 扱われます。 警告を有効にしているなら、undef を文字列や数値として扱おうとすると 未初期価値を指摘されます。 ええ、普通は。 次のような真偽値コンテキストなら:
if ($a) {}(定義済みかどうかではなく、真かどうかを考慮するので)警告から免れます。 未定義の変数を操作する、++, --, +=, -=, .= のような 演算子でも:
undef $a;
$a++;とすることでもそのような警告から免れます。
宣言は、文が置けるところであればどこにでも置くことができますが、 基本的な文の並びは実行時には何の効果も持ちません: 宣言はコンパイル時に すべての効果が表れます。 典型的にはすべての宣言は、スクリプトの先頭か終端に置かれます。 しかしながら、局所変数を my(),state(), or our() を使って作成して レキシカルなスコープを使っているのであれば、フォーマットやサブルーチンの 定義を、同じブロックのスコープの中でその局所変数にアクセスすることが 可能であるようにしておく必要があるでしょう。
サブルーチンの宣言は、プログラムの後のほうにあるサブルーチン名を リスト演算子のように使うことを許します。 定義されていないサブルーチンの宣言を、sub name と記述することで 宣言できるので、以下のようにできます:
sub myname;
$me = myname $0 or die "can't get myname";関数の宣言のような裸の宣言はリスト演算子のように働くのであり、 単項演算子としてではありません; ですから、かっこ (または || の代わりに or) を使うことには注意してください。 || 演算子はリスト演算子の後ろに使うには束縛が強すぎます; 最後の要素の 一部になります。 リスト演算子の周りをかっこで囲むことでいつでもリスト演算子を 関数呼び出しのように振る舞わせるようにできます。 あるいは、サブルーチンを単項演算子に変えるためにプロトタイプ ($) も使えます:
sub myname ($);
$me = myname $0 || die "can't get myname";これは予想した通りにパースしますが、それでもこのような場合にはかっこを使う 習慣を付けるべきです。 プロトタイプに関してさらなる情報は、perlsub を参照してください。
サブルーチンの宣言は require 文を使って詰め込むこともできますし、 use 文を使って自分の名前空間にロードしたりインポートしたりすることが できます。 これに関する詳細は perlmod を参照してください。
文の並びはレキシカルスコープを持った変数の宣言を含むことができますが、 変数名の宣言とは切り離され、その宣言は通常の文のように振る舞い、 それが通常の文であるかのように文の並びに組みこまれます。 これは、そういった宣言がコンパイル時の効果と実行時の効果の両方を 持っているということです。
コメントは “#” 文字から、行末まで続き、その部分は無視されます。 例外は、文字列や正規表現の中にある "#" です。
単純文となる唯一の種類は、その副作用のために評価される式です。 すべての単純文は、それがセミコロンを省略することのできるブロックの 最後にない限りは文を終端するためのセミコロンがなければなりません。 ブロックが二行以上に渡る場合には、とにかくセミコロンを付けてください; なぜなら、別の行を追加する可能性があるからです。 eval {}, sub {}, do {} のように、一見複合文のように 見える けれども そうではない--これらは単なる式における TERM です--ものがあって、 そういったものを文の最後のアイテムとして使った場合には明示的に終端する 必要があるのだということに注意してください。
数値 0, 文字列 '0' と "", 空リスト (), undef は全て真偽値 コンテキストでは偽となります。 その他の全ての値は真です。 真の値を ! や not で否定すると、特殊な偽の値を返します。 これを文字列として評価すると "" として扱われますが、数値として評価すると 0 として扱われます。 真または偽を返す、ほとんど Perl の演算子はこのように振る舞います。
任意の単純文には、一つ の修飾子を終端のセミコロンの直前(もしくは ブロックの終端の直前)に付けることができます。 使うことのできる修飾子は以下の通りです。
if EXPR
unless EXPR
while EXPR
until EXPR
for LIST
foreach LIST
when EXPR修飾子に引き続く EXPR は「条件」として参照されます。 その真偽値が修飾子の振る舞いを決定します。
if は もし 条件が真の場合にのみ文を実行します。 unless は逆で、条件が真 でない限り (つまり、条件が偽なら) 文を 実行します。
print "Basset hounds got long ears" if length $ear >= 10;
go_outside() and play() unless $is_raining;for(each) 修飾子は反復子です: LIST の値それぞれ毎に文を実行します(実行中は $_ がそれぞれの値の エイリアスとなります)。
print "Hello $_!\n" for qw(world Dolly nurse);while は条件が真 の間 文を繰り返します。 until は逆で、条件が真 になるまで (つまり条件が偽の間) 文を 繰り返します:
# Both of these count from 0 to 10.
print $i++ while $i <= 10;
print $j++ until $j > 10;修飾子 while と until は、一般的な "while loop" の意味を 持っています(条件が最初に評価される)が、do-ブロック(もしくは Perl4 の do-サブルーチン文)に適用されるときは例外で、 このときは条件が評価されるよりも前に、一度ブロックが実行されます。
このため、次のようなループを記述することができます:
do {
$line = <STDIN>;
...
} until !defined($line) || $line eq ".\n""do" in perlfunc を参照してください。 後述するループの制御文は、修飾子がループラベルを取らないために この構造文では 動作しない ということにも注意してください。 申し訳ない。 こういった場合に対処するのに別のブロックを内側に入れたり(next の場合)、 別のブロックで囲む(last の場合)という方法が常に使えます。 next では単に中かっこを二重にします:
do {{
next if $x == $y;
# do something here
}} until $x++ > $z;last の場合は、もっと念入りにする必要があります:
LOOP: {
do {
last if $x = $y**2;
# do something here
} while $x++ <= $z;
}注意: (my $x if ... のような) 条件構造やループ構造で修飾された my state,our 文の振る舞いは 未定義 です。 my 変数の値は undef かも知れませんし、以前に代入された値かも 知れませんし、その他の如何なる値の可能性もあります。 この値に依存してはいけません。 perl の将来のバージョンでは現在のバージョンとは何か違うかも知れません。 ここには厄介なものがいます。
when 修飾子は Perl 5.14 で最初に現れた実験的機能です。 使うには、use v5.14 宣言を含めます。 (技術的には、switch 機能だけが必要ですが、この観点では 5.14 より前では 利用できません。) foreach ループか given ブロックの内側でのみ動作可能で、 スマートマッチング $_ ~~ EXPR が真の場合にのみ実行されます。 文が実行されると、foreach の内側からは next に、given の 内側からは break に引き続きます。
現在の実装では、foreach ループは when 修飾子の動的スコープの内側の どこでも使えますが、given ブロックのレキシカルスコープの内側で なければなりません。 この制限は将来のリリースで緩和されるかもしれません。 後述する "Switch Statements" を参照してください。
Perl では、スコープを定義するような文の並びをブロックと呼びます。 ブロックはそれを含むファイルによって範囲が定められることがあります (ファイルが require されたときか、プログラム全体としての場合)し、 文字列の展開によって範囲が定められる(eval の場合)こともあります。
しかし一般的には、ブロックは中かっこによって範囲が定められます。 この構文的な構造をブロックと呼びます。
以下に挙げる複合文を制御フローとして使うことができます:
if (EXPR) BLOCK
if (EXPR) BLOCK else BLOCK
if (EXPR) BLOCK elsif (EXPR) BLOCK ...
if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
unless (EXPR) BLOCK
unless (EXPR) BLOCK else BLOCK
unless (EXPR) BLOCK elsif (EXPR) BLOCK ...
unless (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
given (EXPR) BLOCK
LABEL while (EXPR) BLOCK
LABEL while (EXPR) BLOCK continue BLOCK
LABEL until (EXPR) BLOCK
LABEL until (EXPR) BLOCK continue BLOCK
LABEL for (EXPR; EXPR; EXPR) BLOCK
LABEL for VAR (LIST) BLOCK
LABEL for VAR (LIST) BLOCK continue BLOCK
LABEL foreach (EXPR; EXPR; EXPR) BLOCK
LABEL foreach VAR (LIST) BLOCK
LABEL foreach VAR (LIST) BLOCK continue BLOCK
LABEL BLOCK
LABEL BLOCK continue BLOCK
PHASE BLOCK実験的な given 文は 自動的には有効になりません; そうするための 方法と、付随する問題点については後述する "Switch Statements" を 参照してください。
C や Pascal とは異なり、Perl ではブロックを取るように 定義されていて文を取るのではありません。 つまり、中かっこは 必要なもの です -- 曖昧な文が許されません。 中かっこなしの条件文を使いたいのであれば、いくつかのやり方があります。 以下の全ては同じことです:
if (!open(FOO)) { die "Can't open $FOO: $!" }
die "Can't open $FOO: $!" unless open(FOO);
open(FOO) || die "Can't open $FOO: $!";
open(FOO) ? () : die "Can't open $FOO: $!";
# a bit exotic, that last oneif 文は明解です。 ブロックは常に中かっこで区切られるので、if と else の対応が 曖昧になるようなことは決してありません。 unless を if の代わりに使うと、検査を反転します。 if と同様、unless は else に引き続くことができます。 unless は一つまたはそれ以上の elsif に引き続くことすらできますが、 この特定の言語構文を使う前に二倍考えたいでしょう; あなたのコードを読む 誰もが何が行われているのかを理解する前に少なくとも二倍考える必要が あるからです。
while 文は、式が 真 である間、ブロックを 実行します。 until 文は、式が偽である間、ブロックを実行します。 LABEL は省略可能ですが、ある場合には、コロンを伴った識別子になります。 LABEL は next、last、redo といったループ制御文のループを規定します。 LABEL が省略された場合、ループ制御文はそれを含むループの中で最も内側の ループを参照します。 これは、実行時に LABEL を検出するための呼び出しスタックの動的な後戻り検索を 含むことができます。 そのような推奨されない振る舞いは、use warnings プラグマや -w フラグを 使った場合には警告を引き起こします。
continue ブロックが存在する場合、 常に条件が再評価される直前に実行されます。 したがって、このブロックをループ変数のインクリメントのために 使うことができます; これは、ループがnext文を通して継続されるときでも実行されます。
ブロックの前に BEGIN, END, INIT, CHECK, UNITCHECK のような コンパイルフェーズキーワードが前置されると、ブロックは対応する実行フェーズの 間にだけ実行されます。 さらなる詳細については perlmod を参照してください。
エクステンションモジュールは新しい種類の複合文を定義するために Perl パーサをフックできます。 これらはエクステンションが認識するキーワードで導入され、キーワードに 引き続く文法は完全にエクステンションで定義されます。 もしあなたが実装車なら、仕組みについては "PL_keyword_plugin" in perlapi を 参照してください。 あなたがそのようなモジュールを使うなら、定義されている文法の詳細については そのモジュールの文書を参照してください。
next コマンドはループの次の繰り返しを開始します:
LINE: while (<STDIN>) {
next LINE if /^#/; # discard comments
...
}last コマンドはループから即座に脱出します。 continue ブロックがあっても、それは実行されません:
LINE: while (<STDIN>) {
last LINE if /^$/; # exit when done with header
...
}redo コマンドは、条件の再評価をすることなしにループブロックの 再実行を行います。 continue ブロックがあっても、それは 実行されません。 このコマンドは通常、プログラムに対する入力に関してプログラム自身を だましたいといったときに使われます。
たとえば、/etc/termcap のようなファイルを処理することを 考えてみましょう。 もし入力された行の行末が継続を示すバックスラッシュであった場合、先へ進んで 次のレコードを取り出したいと思うでしょう。
while (<>) {
chomp;
if (s/\\$//) {
$_ .= <>;
redo unless eof();
}
# now process $_
}これは Perl の省略記法で、もっとはっきりと書くと以下のようになります:
LINE: while (defined($line = <ARGV>)) {
chomp($line);
if ($line =~ s/\\$//) {
$line .= <ARGV>;
redo LINE unless eof(); # not eof(ARGV)!
}
# now process $line
}上記の例で continue ブロックがあったとしたら、それは (redo は continue ブロックをスキップするので) 正規表現によって 捨てられた行だけが実行されるということに注意してください。 continue ブロックは行カウンターをリセットするとか、 一度だけマッチする m?pat? をリセットするのに使われます。
# inspired by :1,$g/fred/s//WILMA/
while (<>) {
m?(fred)? && s//WILMA $1 WILMA/;
m?(barney)? && s//BETTY $1 BETTY/;
m?(homer)? && s//MARGE $1 MARGE/;
} continue {
print "$ARGV $.: $_";
close ARGV if eof; # reset $.
reset if eof; # reset ?pat?
}while を until で置き換えた場合検査の意味は逆転しますが、 繰り返しが実行されるより前に条件が検査されることは変わりありません。
ループ制御文は if や unless 中では動作しません; なぜならそこはループではないからです。 しかし中かっこを二重にしてこれに対処することはできます。
if (/pattern/) {{
last if /fred/;
next if /barney/; # same effect as "last",
# but doesn't document as well
# do something here
}}これは、ブロック自身は一度だけ実行されるループとして動作するからです; "Basic BLOCKs" を参照してください。
Perl 4 では使うことのできた while/if BLOCK BLOCK という形式は、 もはや使うことができません。 if BLOCK の部分を if (do BLOCK) で置き換えてください。
Perl の C 形式の for ループは、対応する while ループと同様に 動作します; つまり、以下のものは:
for ($i = 1; $i < 10; $i++) {
...
}以下のものと同じです:
$i = 1;
while ($i < 10) {
...
} continue {
$i++;
}小さな違いが一つあります: for の初期化部で my を使って変数が 宣言された場合、この変数のレキシカルスコープは for ループ (ループ本体と制御部) と完全に同じです。
通常の、配列に対する添え字付けのループのほかにも、for は他の 多くの興味深いアプリケーションのために借用することができます。 以下の例は、対話的なファイル記述子の終端を明示的に検査してしまうと プログラムをハングアップしたように見えてしまう問題を回避するものです。
$on_a_tty = -t STDIN && -t STDOUT;
sub prompt { print "yes? " if $on_a_tty }
for ( prompt(); <STDIN>; prompt() ) {
# do something
}for ループの条件として readline (または演算子形式の <EXPR>) を 使う場合、以下のように省略形が使えます。 この振る舞いは while ループ条件と同じです。
for ( prompt(); defined( $_ = <STDIN> ); prompt() ) {
# do something
}foreach ループは 通常のリスト値に対しての繰り返しを行い、変数 VAR に リストの要素を繰り返し一回に一つずつセットします。 変数の前に my というキーワードが置かれていた場合、その変数は レキシカルスコープを持ち、したがってそれはループの中でのみ可視となります。 このキーワードがなければ、変数はループに対してローカルとなり、ループを 抜けた後で以前の値が再度取得されます。 変数が事前に my を使って宣言されていたならば、グローバルなものの 代わりにその変数を使いますが、それもループにローカルなものとなります。 この暗黙のローカル化は foreach の中で のみ 起きます。
foreach は実際には for の同義語なので、どちらでも使えます。 VAR が省略された場合には、$_ に値が設定されます。
LIST の要素が左辺値であった場合、ループの中で VAR を変更することにより、 対応する値を変更することができます。 逆に、LIST の要素が左辺値でない場合は、この要素を修正しようとしても 失敗します。 言い換えると、foreach ループの帰納変数がループの対象となっている リスト中の個々のアイテムに対するエイリアスになっているからです。
LIST のいずれかの部分が配列であった場合に、たとえば splice を使って ループの本体でその要素を削除したりあるいは追加したりすると foreach は非常に混乱してしまいます。 ですからそういうことをしてはいけません。
VAR が tie されていたりあるいは他の特殊変数であった場合には foreach はあなたのもくろみどおりには動かないでしょう。 こういうこともしてはいけません。
例:
for (@ary) { s/foo/bar/ }
for my $elem (@elements) {
$elem *= 2;
}
for $count (reverse(1..10), "BOOM") {
print $count, "\n";
sleep(1);
}
for (1..15) { print "Merry Christmas\n"; }
foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
print "Item: $item\n";
}以下の例は、C プログラマーが Perl でとあるアルゴリズムを記述するときに 使うであろうやり方です:
for (my $i = 0; $i < @ary1; $i++) {
for (my $j = 0; $j < @ary2; $j++) {
if ($ary1[$i] > $ary2[$j]) {
last; # can't go to outer :-(
}
$ary1[$i] += $ary2[$j];
}
# this is where that last takes me
}それに対して、次の例は Perl プログラマーが同じことをよりゆったりとして 行うやり方です:
OUTER: for my $wid (@ary1) {
INNER: for my $jet (@ary2) {
next OUTER if $wid > $jet;
$wid += $jet;
}
}どのくらいこれが簡単になったように見えますか? これは明確で、安全で、 高速です。 これは余計なものが少ないので明確なのです。 これは後で内側のループと外側のループとの間にコードを付加えた場合でも、 それを間違って実行することがないので安全なのです。 next は内側のループを終了するのではなく、外側のループの繰り返しを 行います。 そしてこれは、Perl は foreach 文をそれと等価な for ループよりも すばやく実行するので高速なのです。
ブロックそれ自身は(ラベルが付いていようがついてなかろうが)一度だけ 実行されるループと、文法的には等価なものです。 このため、ブロックから脱出するためやブロックの再スタートのために 任意のループ制御文を使うことができます。 (これは eval{}、sub{}、 さらに一般的な認識とは異なり ループではない do{} ブロックに対しては 真ではない ということに注意してください。) continue ブロックは省略することができます。
BLOCK 構造は case 構造を行うのにも使えます。
SWITCH: {
if (/^abc/) { $abc = 1; last SWITCH; }
if (/^def/) { $def = 1; last SWITCH; }
if (/^xyz/) { $xyz = 1; last SWITCH; }
$nothing = 1;
}主題化器とスイッチを作るために使われた foreach ループも見るかもしれません:
SWITCH:
for ($var) {
if (/^abc/) { $abc = 1; last SWITCH; }
if (/^def/) { $def = 1; last SWITCH; }
if (/^xyz/) { $xyz = 1; last SWITCH; }
$nothing = 1;
}古いバージョンの Perl には公式の switch 文がなく、直後に記述する 新しいバージョンはまだ実験的で時々混乱させることがあるので、 このような構文はとてもよく使われています。
Perl 5.10.1 から(えっと、5.10.0 からですが、正しく動いていませんでした)、 以下のように書くと:
use feature "switch";実験的な switch 機能を有効にします。 これはおおまかに Perl 6 提案の古い版を基にしていますが、もはや Perl 6 の構文と共通点はありません。 コードが 5.10 以降の Perl バージョンで実行されるように宣言したときもいつでも switch 機能を得られます。 例えば:
use v5.14;"switch" 機能の基では、Perl は実験的なキーワード given, when, default, continue, break を得ます。 Perl 5.16 から、use feature 文なしで機能にアクセスするために、 switch キーワードに CORE:: を前置できます。 キーワード given と when は他の言語での switch および case と 同様のものなので、前の節のコードは以下のように書き直せます:
use v5.10.1;
for ($var) {
when (/^abc/) { $abc = 1 }
when (/^def/) { $def = 1 }
when (/^xyz/) { $xyz = 1 }
default { $nothing = 1 }
}foreach は主題化器を設定する実験的でない方法です。 とても実験的な given を使いたいなら、以下のように書けます:
use v5.10.1;
given ($var) {
when (/^abc/) { $abc = 1 }
when (/^def/) { $def = 1 }
when (/^xyz/) { $xyz = 1 }
default { $nothing = 1 }
}5.14 現在、これは以下のようにも書けます:
use v5.14;
for ($var) {
$abc = 1 when /^abc/;
$def = 1 when /^def/;
$xyz = 1 when /^xyz/;
default { $nothing = 1 }
}あるいは、安全にすることを気にしないなら、以下のようにします:
use v5.14;
given ($var) {
$abc = 1 when /^abc/;
$def = 1 when /^def/;
$xyz = 1 when /^xyz/;
default { $nothing = 1 }
}given と when への引数はスカラコンテキストで、 given は $_ 変数に注目している値を代入します。
when への EXPR 引数が正確に何をするかを正確に記述するのは 難しいですが、一般的には、あなたのしたいことを推測しようとします。 これは $_ ~~ EXPR として解釈される場合もあり、そうでない場合も あります。 これはまた、given ブロックでレキシカルに囲まれた場合は、foreach ループによって動的に囲まれた場合とは異なった振る舞いをします。 規則はここで記述されたよりも遥かに理解しにくいものです。 後述する "Experimental Details on given and when" を参照してください。
Perl 5.10 と 5.14 の間での given の実装方法による不幸なバグにより、 現在の実装では、given によって管理される $_ は、 foreach の場合やオリジナルと現在両方の Perl 6 言語仕様のように 元のものの動的スコープな別名ではなく、単なるレキシカルスコープのコピーです。 このバグは Perl の将来のリリースで対応されると期待されています。 前方互換性のために、本当にレキシカルな $_ がほしいなら、明示的に 指定します:
given(my $_ = EXPR) { ... }当面の間は、主題化器には foreach を使うことで不幸を減らせます。
気弱な人のためでないにも関らず、Perl は goto 文をサポートしています。 goto-LABEL、goto-EXPR、goto-&NAME の三つの形式があります。 ループのラベルは実際には goto の正当なターゲットではなく、 ループの名前にすぎません。
goto-LABEL 形式は LABEL でラベル付けされた文を見つけだし、そこから 実行を再開します。 これはサブルーチンであるとか foreach ループのような 初期化を必要とするような構造へ飛び込むために使うことはできません。 また、最適化されて無くなってしまうような構造へ飛び込むこともできません。 動的スコープの中以外のほとんどの場所へは、サブルーチンの外も含めて 移動することができます; しかし、通常は last や die のような 別のやり方を使ったほうが良いでしょう。 Perl の作者は、未だかつてこの形式の goto を使うことが 必要だと感じたことはありません(Perl の場合です--C の場合はまた別の話です)。
goto-EXPR 形式は動的に解決されるスコープを持っているラベル名を 期待しています。 これによって FORTRAN の計算型 goto が実現できますが、 これは保守性に重きを置くのであれば使うことは止めた方が良いでしょう。
goto(("FOO", "BAR", "GLARCH")[$i]);goto-&NAME は高度にマジカルで、名前付きサブルーチンの呼び出しを カレントで実行されているサブルーチンに置き換えます。 これは別のサブルーチンをロードして、最初の場所で呼び出された 別のサブルーチンを要求することをしようとする AUTOLOAD() サブルーチンで使われていてます (カレントのサブルーチンにおける @_ に対するもの以外の変更は、 別のサブルーチンへ伝播します)。 goto の後で、caller() でなくてもこのサブルーチンが 最初に呼ばれたのだということを伝えることすらできるでしょう。
このようなケースのほとんどすべての場合、goto に頼るのではなくて next、last、redo といった制御フロー機構を使うことが、 ずっとずっと良いアイデアでしょう。 一部のアプリケーションに対しては、eval{} と die() を catch と throw のペアとして例外処理を行うための賢明なアプローチとして 使うことができるでしょう。
Perl 5.12 から、Perl はまだ実装していないコードのプレースホルダとして 省略 "..." を受け付けるようになりました。 この形式の省略、未実装文は、二項フリップフロップ ... 演算子と 混乱しないでください。 片方は文で、もう片方は演算子です。 (Perl は普通混乱しません; なぜなら普通は Perl は演算子を求めているか 文を求めているかを伝えるからです; しかし以下の例外を参照してください。)
Perl 5.12 以降で省略文に遭遇すると、エラーなくパースしますが、実際に 実行しようとすると、Unimplemented というテキストと共に例外を投げます:
use v5.12;
sub unimplemented { ... }
eval { unimplemented() };
if ($@ =~ /^Unimplemented at /) {
say "I found an ellipsis!";
}完全な文を使える場所でのみ省略文を使えます。 次の例は省略がどのように動作するかの例です:
use v5.12;
{ ... }
sub foo { ... }
...;
eval { ... };
sub somemeth {
my $self = shift;
...;
}
$x = do {
my $n;
...;
say "Hurrah!";
$n;
};... はフリップフロップ演算子("Range Operators" 参照)の 3 点版でも あるので、省略文はより大きな文の一部の式としては使えません。
省略を使おうとする以下の例は文法エラーになります:
use v5.12;
print ...;
open(my $fh, ">", "/dev/passwd") or ...;
if ($condition && ... ) { say "Howdy" };式と文との違いをすぐに説明できない場合があります。 例えば、ブロックと無名ハッシュリファレンスのコンストラクタは、 Perl にヒントを与える中かっこがなければ同じに見えます。 省略文は Perl が { ... } をブロックと判断できなかった場合は 文法エラーとなります。 この場合、文ではなく式と推測するので、... は省略とは判断されません:
@transformed = map { ... } @input; # 文法エラー{ ... } がブロックであって、ハッシュリファレンスのコンストラクタでは ないことを示すためにブロックの中で ; を使えます。 これで省略は動作します:
@transformed = map {; ... } @input; # ; 曖昧でない
@transformed = map { ...; } @input; # ; 曖昧でない注意: 一部の人間はこの句読点を口語的に「ヤダヤダ」や「3 点」として 参照しますが、真の名前は実際には省略です。 Perl はまだ Unicode 版の U+2026 HORIZONTAL ELLIPSIS を ... の別名として 認識しませんが、いつかそうなるかもしれません。
Perl は、ソースコードとドキュメントとを混ぜ書きするための仕掛けを 持っています。 新しい文の始まりが期待されているときに、コンパイラは 以下の例のような = 記号で始まっている語を見つけると:
=head1 Here There Be Pods!そのテキストと、=cut で始まる行までの内容を無視します。 間に入るテキストの書式は perlpod で説明されています。
これによって、ソースコードとドキュメントとを以下に示す例のように 自由に混ぜることができるようになります。
=item snazzle($)
The snazzle() function will behave in the most spectacular
form that you can possibly imagine, not even excepting
cybernetic pyrotechnics.
=cut back to the compiler, nuff of this pod stuff!
sub snazzle($) {
my $thingie = shift;
.........
}コンパイラはパラグラフの途中に pod エスケープがあったとしてもそれを 認識できるのに、pod トランスレータは pod 指示子で始まっている パラグラフのみに注目すべき(これは構文解析を簡単にするためです)で あるということに注意して下さい。 つまり、以下の例にある "secret stuff" はコンパイラからも、 トランスレータからも無視されるということです。
$a=3;
=secret stuff
warn "Neither POD nor CODE!?"
=cut back
print "got $a\n";この例の warn() のようなものが、将来に渡って無視されるということに 依存すべきではありません。 すべての pod トランスレータがそのように振る舞うわけではありませんし、 コンパイラは将来これを無視しないようになるかもしれません。
pod 指示子を、コードの一部を手っ取り早くコメントアウトするために 使うこともできます。
C のプリプロセッサと同じように、Perl は行指示子を処理できます。 これを使うことによって、エラーメッセージや警告メッセージにある ファイル名や行番号を制御することができます (特に、eval() で処理される文字列のために)。 この仕組みの構文はほとんどの C のプリプロセッサとほとんど同じで、正規表現:
# example: '# line 42 "new_filename.plx"'
/^\# \s*
line \s+ (\d+) \s*
(?:\s("?)([^"]+)\g2)? \s*
$/xにマッチしたものの $1 が次の行の行番号となり、省略することもできる $3 は(クォートありかなしで指定された)ファイル名となります。 最近の C プリプロセッサとは違って、# の前に空白を置けないことに 注意してください。
行指示子にはかなり明らかな技があります: デバッガとプロファイラは、 与えられたファイルの特定の行番号に対して現れた最新のソース行のみを 表示します。 あとでデバッグしたいコードでは行番号の衝突が起きないように注意するべきです。
コマンドシェルでタイプすることのできる例をいくつか挙げます:
% perl
# line 200 "bzzzt"
# the '#' on the previous line must be the first char on line
die 'foo';
__END__
foo at bzzzt line 201.
% perl
# line 200 "bzzzt"
eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
__END__
foo at - line 2001.
% perl
eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
__END__
foo at foo bar line 200.
% perl
# line 345 "goop"
eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
print $@;
__END__
foo at goop line 345.既に述べたように、"switch" 機能は非常に実験的であると考えられています; ほとんど知らせることなく変更されることがあります。 得に、 given と when はトリッキーな振る舞いがあり、将来よりトリッキーで なくなるように変更される予定です。 現在の(誤)実装に依存しないでください。
これはより長い given の例です:
use feature ":5.10";
given ($foo) {
when (undef) {
say '$foo is undefined';
}
when ("foo") {
say '$foo is the string "foo"';
}
when ([1,3,5,7,9]) {
say '$foo is an odd digit';
continue; # Fall through
}
when ($_ < 100) {
say '$foo is numerically less than 100';
}
when (\&complicated_check) {
say 'a complicated check for $foo is true';
}
default {
die q(I don't know what to do with $foo);
}
}現在の実装では、given(EXPR) は EXPR の値を単にレキシカルスコープを持つ $_ の コピー (!) に代入します; foreach がするような動的スコープを 持つ別名ではありません。 これは以下と似ています:
do { my $_ = EXPR; ... }しかし、ブロックは when が成功するか、明示的な break によって 自動的に破壊されるところが違います。 これはただのコピーで、動的スコープではなくレキシカルなスコープしか 持たないので、foreach ループの中でできるようなことはできません。 特に、おそらく任意の関数呼び出しはできません。 そのためには foreach にこだわるのが最良です。
強力さのほとんどは時々適用される暗黙のスマートマッチングによるものです。 ほとんどの場合、when(EXPR) は暗黙の $_ のスマートマッチング、 つまり $_ ~~ EXPR として扱われます。 (スマートマッチングに関するさらなる情報については "Smartmatch Operator" in perlop を参照してください。) しかし EXPR が後述する 10 の例外の場合(および似たような場合) の 一つの場合、直接真偽値として使われます。
ユーザー定義サブルーチンかメソッド呼び出し。
/REGEX/, $foo =~ /REGEX/, $foo =~ EXPR 形式の 正規表現マッチング。 また、!/REGEX/, $foo !~ /REGEX/, $foo !~ EXPR 形式の 正規表現マッチングの否定。
EXPR ~~ EXPR のように、明示的に ~~ 演算子を使うスマートマッチング。
$_ < 10 や $x eq "abc" のような真偽値比較。 これを適用する関係演算子は、六つの数値比較 (<, >, <=, >=, ==, !=) および 六つの文字列比較 (lt, gt, le, ge, eq, ne) です。
注意: しばしば $c ~~ $_ を使う必要があることに注意してください; なぜならデフォルトの場合は $_ ~~ $c を使い、これはしばしばしたいことの 逆だからです。
少なくとも三つの組み込み関数 defined(...), exists(...), eof(...)。 これらについて考えるとき、いつかもっと追加するかもしれません。
否定表現 !(EXPR) または not(EXPR)、 排他的論理和 (EXPR1) xor (EXPR2)。 ビット版 (~ と ^) は含まれません。
真偽値ではなく数値を返す四つの例外: -s, -M, -A, -C を除く ファイルテスト演算子。 -z ファイルテスト演算子は例外の一覧には含まれません。
フリップフロップ演算子 .. と ...。 ... フリップフロップ演算子は先に記述した ... 省略文とは完全に 異なることに注意してください。
上述の八つの場合、EXPR の値は直接真偽値として使われるため、 スマートマッチングは行われません。 スマートマッチングとして when を考えるかもしれません。
更に、Perl はオペランドに上述のテストを適用することで、それぞれに スマートマッチングを使うかどうかを決定するために論理演算子の オペランドを調べます:
EXPR が EXPR1 && EXPR2 または EXPR1 and EXPR2 の場合、テストは EXPR1 と EXPR2 の両方に 再帰的 に適用されます。 両方の オペランドがテストに 再帰的に 成功した場合にのみ、この式は 真偽値として扱われます。 さもなければ、スマートマッチングが使われます。
EXPR が EXPR1 || EXPR2, EXPR1 // EXPR2, or EXPR1 or EXPR2 の場合、 テストは EXPR1 (例えば、より高い優先順位である AND 演算子; 従って 前述の規則に従う)のみに対して 再帰的に 適用されます; EXPR2 には 適用されません。 EXPR1 がスマートマッチングを使うなら、EXPR2 も、その内容に関わらず そうします。 しかし EXPR2 がスマートマッチングを塚ｗないなら、二番目の引数はどちらでも ありません。 これは既に記述した && の場合とはかなり異なりますので注意してください。
これらの規則は複雑ですが、この目標は (たとえあなたがなぜそうしているかを 完全に理解していなくても) あなたが実行したい通りに実行することです。 例えば:
when (/^\d+$/ && $_ < 75) { ... }これは真偽値マッチングとして扱われます; 規則では正規表現マッチングと $_ への明示的なテストはどちらも真偽値として扱われるからです。
また:
when ([qw(foo bar)] && /baz/) { ... }これはスマートマッチングを使います; オペランドの 一つ だけが 真偽値だからです: もう片方はスマートマッチングを使うので、こちらが 優先されます。
さらに:
when ([qw(foo bar)] || /^baz/) { ... }これはスマートマッチングを使います(最初のオペランドのみが考慮されます); 一方
when (/^baz/ || [qw(foo bar)]) { ... }これは正規表現のみがテストされ、両方のオペランドは真偽値として 扱われることになります。 この場合、配列リファレンスは常に真の値なので、効率的に冗長になることに 注目してください。 良い考えではありません。
恒久的な真偽値演算子は最適化されて除去されます。 以下のように書こうとしないでください
when ("foo" or "bar") { ... }これは "foo" に最適化されるので、"bar" は (たとえ規則では "foo" に スマートマッチングを使うとなっていたとしても) 考慮されることはありません。 このような代替としては、配列リファレンスは動作します; これは スマートマッチングを使わせるからです:
when ([qw(foo bar)] { ... }これはある意味 C スタイルの switch 文の次の条件への移動(fallthrough)機能と 等価です(Perl の 次の条件への移動機能と混同しないでください-- 後述します); 複数の case 文に同じブロックが使われます。
その他の便利な省略記法としては、given の引数としてリテラルな配列や ハッシュを書くと、これはリファレンスに変化します。 それで、例えば given(@foo) は given(\@foo) と同じです。
default は正確に when(1 == 1) のように振る舞い、常に マッチングします。
囲まれている given ブロックから脱出するために、break キーワードが 使えます。 全ての when ブロックの末尾には暗黙に break があります。
一つの条件から次へ移動するためには、continue キーワードが使えます:
given($foo) {
when (/x/) { say '$foo contains an x'; continue }
when (/y/) { say '$foo contains a y' }
default { say '$foo does not contain a y' }
}given が有効な式でもある(例えばブロックの最後の文である)場合、 以下のように評価されます:
明示的な break に遭遇した直後なら空リスト。
もし成功していれば、成功した when/default 節で最後に評価された式の値。
どの条件も真でなければ given ブロックで最後に評価された式の値。
最後の二つの場合、最後の式は適用された given ブロックに適用された コンテキストで評価されます。
if や unless と異なり、失敗した when 文は常に空リストに 評価されます。
my $price = do {
given ($item) {
when (["pear", "apple"]) { 1 }
break when "vote"; # My vote cannot be bought
1e10 when /Mona Lisa/;
"unknown";
}
};現在のところ、given ブロックは常に適切な式として使うことはできません。 これは将来のバージョンの Perl に対処されるでしょう。
given() を使う代わりに、foreach() ループを使えます。 たとえば、以下は配列内に特定の文字列が何回現れるかを数えるための ひとつの方法です:
use v5.10.1;
my $count = 0;
for (@array) {
when ("foo") { ++$count }
}
print "\@array contains $count copies of 'foo'\n";あるいはより最近のバージョンでは:
use v5.14;
my $count = 0;
for (@array) {
++$count when "foo";
}
print "\@array contains $count copies of 'foo'\n";when ブロックの末尾に、暗黙の next があります。 もし最初のマッチングだけに興味があるなら、明示的な last でこれを 上書きできます。
これは、for $item (@array) のように明示的にループ変数を指定した場合は 動作しません。 デフォルト変数 $_ を使う必要があります。
Perl 5 のスマートマッチングと given/when 構文は Perl 6 のものと 互換性はありません。 もっとも目に見えて、もっとも重要でない違いは、Perl 5 では、given() と when() の引数は (後者を文修飾子として使う場合を除いて)かっこでくくる 必要があります。 Perl 6 では、if(), while(), when() のような制御構造での かっこは常に省略可能です; Perl 5 では、潜在的な大混乱と引き換えにしなければこれを省略できません; なぜなら Perl 5 は以下のような表現において:
given $foo {
...
}given の引数はハッシュ %foo の要素であるかのようにパースして、 中かっこをハッシュ要素文法として解釈するからです。
しかし、ここにはとても多くのその他の違いがあります。 例えば、これは Perl 5 で動作します:
use v5.12;
my @primary = ("red", "blue", "green");
if (@primary ~~ "red") {
say "primary smartmatches red";
}
if ("red" ~~ @primary) {
say "red smartmatches primary";
}
say "that's all, folks!";しかしこれは Perl 6 では全く動作しません。 代わりに、(並列化可能な) any 演算子を使います:
if any(@primary) eq "red" {
say "primary smartmatches red";
}
if "red" eq any(@primary) {
say "red smartmatches primary";
}"Smartmatch Operator" in perlop のスマートマッチングの表は Perl 6 仕様で 提案されれているものと同一ではありません; 主に Perl 6 と Perl 5 の データモデルの違いによりますが、Perl 6 の仕様は Perl 5 が早期に採用した 後に変更されたからです。
Perl 6 では、when() は常にその引数に対する暗黙のスマートマッチングを 行いますが、Perl 5 では既に大まかに示した通り、ゆるく定義された状況によっては 暗黙のスマートマッチングを抑制したほうが便利(たとえ混乱させるかも 知れないにしても)です。 (主な違いは、Perl 5 は内部的にさえ真偽値型を持たないことによります。)