perlretut - Perl の正規表現のチュートリアル
このページでは Perl の正規表現(regular expressions)を理解し、作成し、 使用するための基本的なチュートリアルを提供します。 詳細は正規表現のリファレンスページである perlre にあります。 正規表現は演算子 m//、s///、qr//、split の一部分であり、 本チュートリアルでは "Regexp Quote-Like Operators" in perlop や "split" in perlfunc と重複する部分があります。
Perl はテキスト処理のための優れた道具であると広く知られていて、 正規表現はこの名声の大きな部分です。 Perl の正規表現は他の大部分の言語で知られていない効率性や融通性を 明らかにします。 正規表現の基本的な部分をマスターすることによってさえ驚くほど簡単に テキストを操作することができるようになるでしょう。
正規表現とは何でしょうか? 正規表現とはパターンを表す単純な文字列です。 パターンは今日広く使われています; たとえば、ウェブページを見つけ出すために 検索エンジンにタイプしたり、ディレクトリの中のファイルを リストアップするために ls *.txt とか dir *.* としたりします。 Perlでは、パターンは正規表現によって記述され、文字列を探しだしたり、 文字列の望みの部分を取り出したり、検索と置換の操作をするために使われます。
正規表現には抽象的で理解するのが難しいという不適切な悪名があります。 正規表現は条件とループのような単純なコンセプトを使って構成されていて、 Perl 自身の if であるとか while のようなそれと対応するものに比べて 難しいことはありません。 事実、正規表現を学ぶにあたっての主な挑戦はこれらのコンセプトを 表現するために簡潔な記述を使おうとすることなのです。
本チュートリアルでは表記に関して一度に一つずつ、そして例を多く挙げて 正規表現のコンセプトを論じることによって、学習曲線を平坦化します。 本チュートリアルの最初の部分は基本的な正規表現のコンセプトのための単純な 単語検索から始まります。 最初の部分をマスターすれば、必要とすることの 98% を解決するのに必要な ツールを得ることになるでしょう。 本チュートリアルの二番目の部分はより強力なツールのために十分なものです。 そこではより高度な正規表現演算子について論じ、最新の機能を紹介します。
注意: 'regular expression' はしばしば regexp とか regex と略されます。 regexp は regex よりも自然な略称ですが発音するのが難しいです。 Perl の pod ドキュメントでは regexp と regex が混在しています; Perl では、 略するやり方は一つではないのです。 このチュートリアルでは regexp を使うことにします(訳注: 日本語では 「正規表現」と記します)。
最も単純な正規表現は単なる単語、より一般的には文字の並びです。 正規表現は単語を構成する任意の文字列にマッチングする単語からなります:
"Hello World" =~ /World/; # matchesこの Perl の文が行っていることは何でしょう? "Hello World" は単純な、ダブルクォートで囲まれた文字列です。 World は正規表現であり、 // で囲まれた /World/ は Perl に対してマッチングのために文字列を検索することを指示します。 =~ という演算子は正規表現にマッチングする文字列に結び付けられ、 正規表現がマッチングすれば真の値を生成し、マッチングしなければ偽となります。 この例では、World は "Hello World" の二番目の単語にマッチングするので、 式は真となります。 このような式は条件文に使うにも便利です:
if ("Hello World" =~ /World/) {
print "It matches\n";
}
else {
print "It doesn't match\n";
}便利なバリエーションもあります。 マッチングの成否の意味を反転する演算子 !~ があります:
if ("Hello World" !~ /World/) {
print "It doesn't match\n";
}
else {
print "It matches\n";
}正規表現中のリテラル文字列は変数に置き換えることもができます:
$greeting = "World";
if ("Hello World" =~ /$greeting/) {
print "It matches\n";
}
else {
print "It doesn't match\n";
}特殊デフォルト変数 $_ に対してマッチングを行う場合、$_ =~ の 部分は省略できます:
$_ = "Hello World";
if (/World/) {
print "It matches\n";
}
else {
print "It doesn't match\n";
}最後に、マッチングのための // のデフォルトデリミタは 'm' を 前置することにより任意のものにすることができます:
"Hello World" =~ m!World!; # マッチングする; デリミタは '!'
"Hello World" =~ m{World}; # マッチングする; 組になっている '{}' に注意
"/usr/bin/perl" =~ m"/perl"; # 'usr/bin' の後にマッチングする
# '/' は普通の文字になっている/World/, m!World!, m{World} はすべて同じものを表しています。 例えば " をデリミタとして使ったとき、スラッシュ '/' は 通常の文字となり、トラブルなしに正規表現中で使うことができます。
異なる正規表現がどのように "Hello World" にマッチングするか 考えてみましょう:
"Hello World" =~ /world/; # マッチングしない
"Hello World" =~ /o W/; # マッチングする
"Hello World" =~ /oW/; # マッチングしない
"Hello World" =~ /World /; # マッチングしない最初の正規表現 world はマッチングしません; なぜなら、正規表現は大文字と 小文字を区別するからです。 二番目の正規表現は "Hello World" という文字列の中に 'o W' と いう部分があるのでマッチングします。 スペース ' ' は正規表現の中で他の文字と同じように扱われ、この場合 マッチングするのに必要なものです。 スペースがないことが三番目の正規表現 'oW' がマッチングしない理由です。 四番目の正規表現は正規表現の末尾にスペースがついているのに、文字列の 末尾にはスペースがないのでマッチングしません。 このレッスンでは正規表現は、文が真となるためには 正確に 順序通りに 文字列の一部としてマッチングしなければならないことを示しました。
正規表現が文字列の二箇所以上にマッチングするならば、Perl は常に文字列の中で 最初に現れるものをマッチングしようとします:
"Hello World" =~ /o/; # 'Hello' の 'o' にマッチング
"That hat is red" =~ /hat/; # 'That' の中の 'hat' にマッチング文字マッチングに対する関心と共に、知っておくべき幾つかのポイントが あります。 まず始めに、すべての文字がマッチングにおいて'あるがまま'(as is) に 使われるのではないということです。 メタ文字 と呼ばれる幾つかの文字が正規表現の記述に使うために 予約されています。 メタ文字には以下のものがあります
{}[]()^$.|*+?\これらの文字のそれぞれの重要性は本チュートリアルの残りの部分で 説明されますが、今のところは、メタ文字はバックスラッシュを 前置することによってマッチングさせることができることを知っておくことが 重要です:
"2+2=4" =~ /2+2/; # マッチングしない; + はメタ文字
"2+2=4" =~ /2\+2/; # マッチングする; \+ 普通の + のように扱われる
"The interval is [0,1)." =~ /[0,1)./ # これは文法エラー!
"The interval is [0,1)." =~ /\[0,1\)\./ # マッチングする
"#!/usr/bin/perl" =~ /#!\/usr\/bin\/perl/; # マッチングする最後の正規表現では、スラッシュ '/' もまたバックスラッシュが つけられています; なぜなら、それが正規表現のデリミタとして使われているからです。 これは LTS(leaning toothpick syndrome つまようじ大好き症候群)を 招きがちですが、読みやすくするためにデリミタを変更することが しばしばあります。
"#!/usr/bin/perl" =~ m!#\!/usr/bin/perl!; # より読みやすいバックスラッシュ文字 '\' はそれ自身がメタ文字であり、 バックスラッシュをつける必要があります:
'C:\WIN32' =~ /C:\\WIN/; # マッチングするメタ文字に加え、印字することのできない文字であって エスケープシーケンス によって表現されるいくつかの ASCII 文字があります。 一般的な例では、タブを表す \t、改行を表す \n、復帰を表す \r、 ベルを表す \a があります。 文字列を任意のバイト列としてみなすのなら、\033 のような 8 進エスケープシーケンスや \x1B のような 16 進エスケープシーケンスは バイト列のより自然な表現となります。 以下にあげるのはエスケープの例です:
"1000\t2000" =~ m(0\t2) # マッチングする
"1000\n2000" =~ /0\n20/ # マッチングする
"1000\t2000" =~ /\000\t2/ # マッチングしない; "0" は "\000" ではない
"cat" =~ /\o{143}\x61\x74/ # ASCII でマッチングするが、cat を綴る
# 変な方法あなたがすでに Perl を少なからず知っているのなら、エスケープシーケンスに 付いて述べた以上のことはすでになじみ深いものかもしれません。 同じようなエスケープシーケンスはダブルクォートで囲まれた文字列で 使われていて、事実 Perl における正規表現はほとんどの場合において ダブルクォートで囲まれた文字列のように扱われます。 このことは正規表現の中で変数を使うことができるということを意味します。 ダブルクォートで囲まれた文字列のように、正規表現中の変数の値は マッチングのために正規表現が評価されるより前に置き換えが行われます。 ですから:
$foo = 'house';
'housecat' =~ /$foo/; # マッチングする
'cathouse' =~ /cat$foo/; # マッチングする
'housecat' =~ /${foo}cat/; # マッチングする今のところ順調です。 これまでの知識をもとに任意のリテラル文字列正規表現に関して 検索を行うことができます。 次の例は Unix の grep プログラムの 非常に単純な 模倣です。
% cat > simple_grep
#!/usr/bin/perl
$regexp = shift;
while (<>) {
print if /$regexp/;
}
^D
% chmod +x simple_grep
% simple_grep abba /usr/dict/words
Babbage
cabbage
cabbages
sabbath
Sabbathize
Sabbathizes
sabbatical
scabbard
scabbardsこのプログラムを理解するのは簡単です。 #!/usr/bin/perl はシェルから perl プログラムを起動する標準的な方法です。 $regexp = shift; は最初のコマンドライン引数を正規表現として使うために 保存します; そして残りのコマンドライン引数はファイルとして扱うために そのままにしておきます。 while (<) > ループはすべてのファイルのすべての行に対して 実行されます。 各行において、print if /$regexp/; はその行が正規表現に マッチングしていれば行の内容を出力します。 この行で、print と /$regexp/ は暗黙にデフォルト変数 $_ を 使用します。
これまでの正規表現では、文字列のどこかでマッチングすればマッチングしたと みなしてきました。 しかし、ときには文字列の どこで 正規表現がマッチングするのかを 指定したいときがあります。 これを行うためには、アンカー メタ文字である ^ と $ を使います。 アンカー ^ は文字列の先頭でマッチングすることを意味し、アンカー $ は 文字列の末尾(あるいは文字列の末尾にある改行の前) でマッチングすることを 意味します。 以下に例を挙げます:
"housekeeper" =~ /keeper/; # マッチングする
"housekeeper" =~ /^keeper/; # マッチングしない
"housekeeper" =~ /keeper$/; # マッチングする
"housekeeper\n" =~ /keeper$/; # マッチングする二番目の正規表現はマッチングしません; なぜなら、^ は keeper が文字列の 先頭にあるときにのみマッチングすることを強制しますが、"housekeeper" は その先頭以外にkeeperを含んでいます。 三番目の正規表現は、 $ が keeper が文字列の末尾にあるときにのみ マッチングすることを強制しているのでマッチングします。
^ と$ の両方が同時に使われた場合、その正規表現は文字列の先頭と 末尾両方にマッチングする必要があります; つまり、その正規表現は文字列全体に マッチングするのです。 以下の例で考えてみましょう
"keeper" =~ /^keep$/; # マッチングしない
"keeper" =~ /^keeper$/; # マッチングする
"" =~ /^$/; # ^$ は空文字列にマッチングする最初の正規表現はマッチングしません; なぜなら、文字列は keep 以外のものを 持っているからです。 二番目の正規表現は正確に同じ文字列なのでマッチングします。 ^ と $ を正規表現の中で使うことによって、文字列全体に マッチングすることを強制します; このため、どの文字列がマッチングしどの 文字列がマッチングしないかを完全に制御することができます。 bert という名前の仲間を探しているとしましょう:
"dogbert" =~ /bert/; # マッチングする; しかし望んだものではない
"dilbert" =~ /^bert/; # マッチングしない。しかし…
"bertram" =~ /^bert/; # マッチングする; ということはまだ十分ではない
"bertram" =~ /^bert$/; # マッチングしない; よし
"dilbert" =~ /^bert$/; # マッチングしない; よし
"bert" =~ /^bert$/; # マッチングする; 完璧もちろん、リテラル文字列の場合においては、文字列の比較を $string eq 'bert' を使って簡単に行うことができ、こちらのほうが より効率がよいです。 ^...$ 正規表現は以下に述べるより強力な正規表現ツールにおいて 便利になります。
先に述べたリテラル文字列の正規表現を使ってさえ多くのことができますが、 それは正規表現テクノロジーの表面をひっかいた程度に過ぎません。 このセクションと続くセクションでは、ただ一文字の文字を表すのではなく 文字のクラス全体 を表す正規表現のコンセプト (とそれに結び付けられた メタ文字表記)を紹介します。
そのようなコンセプトは 文字クラス です。 文字クラスは正規表現の特定の場所においてマッチングする可能性のある文字の 集合です(単一の文字ではありません)。 文字クラスはブラケット [...] で表現され、マッチングする可能性のある文字の 集合はその内側に置かれます。 以下にいくつか例を挙げます:
/cat/; # 'cat' にマッチング
/[bcr]at/; # 'bat, 'cat', 'rat' にマッチング
/item[0123456789]/; # 'item0' または ... または 'item9' にマッチング
"abc" =~ /[cab]/; # 'a' にマッチング最後の文において、'c' がクラスの最初の文字であるにもかかわらず 'a' がマッチングします; なぜなら、文字列の最初の文字位置が正規表現が マッチングすることのできる最初の位置にある文字だからです。
/[yY][eE][sS]/; # 大小文字を問わず 'yes' にマッチングする
# 'yes', 'Yes', 'YES' などこの正規表現は一般的な仕事を表しています: 大小文字の違いを無視しての マッチングを行います。 Perl はこのようなブラケットを取り除くやり方を提供しています; それは マッチングの終端に 'i' をつけることです。 したがって、/[yY][eE][sS]/; は /yes/i; と書き換えることができます。 この 'i' は大小文字の違いを無視することを意味していて、マッチング操作の 修飾子 (modifier)の実例です。 本チュートリアルの後の方で他の修飾子がでてくることでしょう。
このセクションの前のほうで、自分自身を表す通常の文字と、 それ自身を表すためには バックスラッシュ \ が必要な特殊文字があることを見てきました。 同じことが文字クラスの中でも言えます; しかし、文字クラスの内側にある通常の 文字と特殊文字の集合は、文字クラスの外側にあるものと異なります。 文字クラスのために特殊な文字は -]\^$ (および(何であれ)デリミタ)です。 ] は文字クラスの終端を表すので特殊です。 $ はスカラ変数を表すので特殊です。 \ はエスケープシーケンスで使われるので特殊です。 以下は特殊文字 ]$\ を扱うやり方です:
/[\]c]def/; # ']def' または 'cdef' にマッチング
$x = 'bcr';
/[$x]at/; # 'bat', 'cat', 'rat' にマッチング
/[\$x]at/; # '$at' または 'xat' にマッチング
/[\\$x]at/; # '\at', 'bat, 'cat', 'rat' にマッチング最後の二つはちょっとトリッキーです。 [\$x] の中ではバックスラッシュはドル記号を保護しているので、 文字クラスは $ とx という二つのメンバを持ちます。 [\\$x] ではバックラッシュが保護されているので、$x は変数として 扱われ、ダブルクォート規則に従って置換が行われます。
特殊文字 '-' は文字クラスの中で範囲演算子として振舞います; このため、 連続した範囲の文字を一つの範囲として記述することができます。 範囲を使うことによって、[0123456789] や [abc...xyz] のような 見づらいものはすっきりとした [0-9] であるとか [a-z] のように 書き換えられます。 幾つか例を挙げましょう
/item[0-9]/; # 'item0' ... 'item9' にマッチングする
/[0-9bx-z]aa/; # '0aa' ... '9aa',
# 'baa', 'xaa', 'yaa', 'zaa' のいずれかにマッチングする
/[0-9a-fA-F]/; # 16 進数にマッチングする
/[0-9a-zA-Z_]/; # Perl の変数名のような
# 「単語」文字にマッチングする'-' が文字クラスの中の最初か最後の文字であった場合、通常の文字として 扱われます; [-ab], [ab-], [a\-b] はすべて等価です。
文字クラスの先頭の位置にある特殊文字 ^ は 反転文字クラス を表し、 ブラケットの中にない文字にマッチングします。 [...] と [^...] の両方とも、一つの文字にマッチングせねばならず、 そうでない場合にはマッチングは失敗します。 ですから
/[^a]at/; # 'aat' や 'at' にはマッチングしないが、その他の
# 'bat', 'cat, '0at', '%at' などにはマッチングする
/[^0-9]/; # 数字以外にマッチングする
/[a^]at/; # 'aat' か '^at'にマッチングする; ここでは '^' は通常の文字ここで、[0-9] でさえ何回も書くには面倒です; ですから、キーストロークの 数を抑えて、かつ正規表現をより読みやすくするために後述するように Perl は 一般的な文字クラスの略記法を持っています。 Unicode の導入のために、//a 修飾子が有効でない限り、これらの文字クラスは ASCII の範囲での数文字よりも多くマッチングします。
\d は数字にマッチングします; 単に [0-9] だけではなく、非ローマ字 スクリプトからの数字もマッチングします
\s は空白文字にマッチングします; [\ \t\r\n\f] やその他のものです
\w は単語を構成する文字(英数字 と _)にマッチングします; 単に [0-9a-zA-Z_] だけではなく、非ローマ字スクリプトからの数字と文字も マッチングします
\D は \d の否定形です; 数字以外の文字、つまり [^\d] を表します。
\S は \s の否定形です; 非空白文字 [^\s] を表します。
\W は \w の否定形です; 単語を構成しない文字[^\w]を表します。
ピリオド '.' は (以下に述べるように、修飾子 //s が有効でない限り) "\n" 以外の任意の文字にマッチングします。
\N は、ピリオドのように、"\n" 以外の任意の文字にマッチングしますが、 //s 修飾子が有効かどうかに関わらずマッチングします。
Perl 5.14 から利用可能の //a 修飾子は、\d, \s, \w を ASCII の範囲に 制限するために使います。 これは、英語風のテキストを処理したいだけの時にプログラムを不必要に 完全な Unicode (とそれに関連するセキュリティの配慮) にさらされないように するのに有用です。 ("a" を重ねて //aa にするとさらに制限されて、ASCII 文字の大文字小文字を 無視したマッチングで非 ASCII 文字にマッチングしなくします; さもなければ、 Unicode の "Kelvin Sign" は "k" や "K" に、大文字小文字を無視したマッチングが 成功します。)
\d\s\w\D\S\W の省略記法は文字クラスの内側でも外側でも使うことができます。 以下はその例です:
/\d\d:\d\d:\d\d/; # hh:mm:ss 形式の時間表記にマッチング
/[\d\s]/; # 数字または空白にマッチング
/\w\W\w/; # 非単語文字が続きさらに単語文字が続く
# 単語文字にマッチング
/..rt/; # 'rt' が続く任意の二文字にマッチング
/end\./; # 'end.' にマッチング
/end[.]/; # 同じこと; 'end.' にマッチングピリオドはメタ文字なので、ピリオドそのものにマッチングさせるにはエスケープする 必要があります。 \d や \w は文字の集合なので [^\d\w] を [\D\W] とみなすのは 間違いです; 事実、[^\d\w] は [^\w] と同じであり、これは [\W] と 等価です。 ド・モルガンの法則を考えてみてください。
基本的な正規表現で便利なアンカーに 語アンカー (word anchor)の \b があります。 これは単語を構成する文字と単語を構成しない文字の間 \w\W や \W\w の 境界にマッチングします:
$x = "Housecat catenates house and cat";
$x =~ /cat/; # 'housecat' の cat にマッチング
$x =~ /\bcat/; # 'catenates' の cat にマッチング
$x =~ /cat\b/; # 'housecat' の cat にマッチング
$x =~ /\bcat\b/; # 文字列の終端の'cat'にマッチング最後の例に注意してください; 文字列の終端は単語境界として認識されています。
'.' が "\n" 以外の任意の文字にマッチングすることに疑問を感じるかも しれません - なぜすべての文字ではないのでしょうか? その答えはマッチングがしばしば行に対して行われ、改行文字を 無視したいからです。 たとえば、文字列 "\n" が一行を表していたとして、それを空の行として みなしたいでしょう。 ですから
"" =~ /^$/; # マッチング
"\n" =~ /^$/; # マッチング; "\n" は無視される
"" =~ /./; # マッチングしない; キャラクタが必要
"" =~ /^.$/; # マッチングしない; キャラクタが必要
"\n" =~ /^.$/; # マッチングしない; "\n" 以外のキャラクタが必要
"a" =~ /^.$/; # マッチングする
"a\n" =~ /^.$/; # マッチングする; "\n" は無視される通常はある行において文字を数えたりマッチングしたりするときには改行を 無視したいので、この動作は便利です。 しかし、ときとして改行を保存したいときがあります。 ^ や $ を文字列の先頭や末尾ではなく行の先頭や末尾に対するアンカーと したいときがあるでしょう。 Perl は //s 修飾子や //m 修飾子を使うことによって改行を無視したり 考慮したりすることを選択することを許しています。 //s と //m はそれぞれ単一行(single line)と複数行(multi-line)を意味し、 文字列を連続した文字としてみなすか行の集合としてみなすかを決定します。 これら二つの修飾子は正規表現がどのように解釈されるかに関して二つの影響を 及ぼします: 1) '.' 文字クラスがどのように定義されるか 2) アンカー ^ と $ がどこにマッチングできるかです。 四つの可能な組み合わせがあります:
修飾子なし (//): デフォルトの動作です。 '.' は "\n" 以外の任意の文字にマッチングします。 ^ は文字列の先頭にのみマッチングし、$ は文字列の末尾もしくは終端にある 改行の直前にのみマッチングします。
s 修飾子 (//s): 文字列を一つの長い行としてみなします。 '.' は "\n" を含めた任意の文字にマッチングします。 ^ は文字列の先頭にのみマッチングし、$ は文字列の末尾もしくは終端にある 改行の直前にのみマッチングします。
m 修飾子 (//m): 文字列を複数行の集合としてみなします。 '.' は "\n" 以外の任意の文字にマッチングします。 ^ と $ はそれぞれ文字列中の任意の行の先頭と末尾にマッチングします。
s 修飾子と m 修飾子の両方 (//sm): 文字列を単一の長い行としてみなしますが、 複数行を検出します。 '.' は "\n" を含めた任意の文字にマッチングします。 しかし、^ と $ はそれぞれ文字列中の任意の行の先頭と末尾に マッチングすることが可能です。
以下はアクション中の //s と //m の例です:
$x = "There once was a girl\nWho programmed in Perl\n";
$x =~ /^Who/; # マッチングしない; "Who" は文字列の先頭にはない
$x =~ /^Who/s; # マッチングしない; "Who" は文字列の先頭にはない
$x =~ /^Who/m; # マッチングする; "Who" は二行目の先頭にある
$x =~ /^Who/sm; # マッチングする; "Who" は二行目の先頭にある
$x =~ /girl.Who/; # マッチングしない; "." は "\n" にマッチングしない
$x =~ /girl.Who/s; # マッチングする; "." は "\n"にマッチングする
$x =~ /girl.Who/m; # マッチングしない; "." は "\n" にマッチングしない
$x =~ /girl.Who/sm; # マッチングする; "." は "\n"にマッチングするほとんどの場合、デフォルトの動作が望んでいるものですが、//s や //m はとても便利なものです。 もし //m を使っているのなら、文字列の先頭は \A で マッチングさせることができ、文字列の末尾はアンカー \Z ($ と同じように、 末尾と末尾にある改行の直前にマッチングします) や \z (末尾にのみマッチング)で マッチングさせることができます:
$x =~ /^Who/m; # マッチングする; "Who" は二行目の先頭にある
$x =~ /\AWho/m; # マッチングしない; "Who" は文字列の先頭にはない
$x =~ /girl$/m; # マッチングする; "girl" は一行目の末尾にある
$x =~ /girl\Z/m; # マッチングしない; "girl" は文字列の末尾にはない
$x =~ /Perl\Z/m; # マッチングする; "Perl" は末尾の直前にある改行の前にある
$x =~ /Perl\z/m; # マッチングしない; "Perl" は文字列の末尾にはない正規表現中で文字クラスをどのように選択するかを学びました。 単語や文字並びに関する選択は? その選択は次のセクションで述べます。
正規表現を異なる単語や文字並びにマッチングさせたいと考えることがあるでしょう。 これは 選択 メタ文字 | によって行うことができます。 dog または cat にマッチングさせるには、正規表現を dog|cat のようにします。 以前述べた通り、Perlは文字列の可能な限り最も早い位置でマッチングを 行おうとします。 それぞれの文字位置で、Perlはまずはじめに最初の選択である dog に マッチングさせることを試みます。 もし dog がマッチングしなければ、Perl は次の選択肢である cat を 試します。 cat もまたマッチングしなければ、マッチングは失敗してPerlは文字列の次の 位置に移動します。 幾つか例を挙げましょう:
"cats and dogs" =~ /cat|dog|bird/; # "cat" にマッチング
"cats and dogs" =~ /dog|cat|bird/; # "cat" にマッチング二番目の正規表現において最初の選択肢が dog であるにもかかわらず、 cat が文字列で最初に現れるマッチング対象です。
"cats" =~ /c|ca|cat|cats/; # "c" にマッチング
"cats" =~ /cats|cat|ca|c/; # "cats" にマッチングここではすべての選択肢が最初の位置でマッチングするので、最初の選択肢が マッチング対象となります。 もし一部の選択肢が他の選択肢を縮めたものであるならば、マッチングのチャンスを 与えるために最も長いものを最初に置きます。
"cab" =~ /a|b|c/ # "c" にマッチング
# /a|b|c/ == /[abc]/この最後の例は文字クラスが文字の選択に似ていることを表しています。 与えられた文字位置で、正規表現のマッチングを成功させるための 最初の選択肢はマッチングする一つとなります。
選択は正規表現が選択肢の中から選び出すことを許しますが、それ自身は 満足できるものではありません。 その理由は、各選択肢は正規表現全体でなければならないのに、正規表現の 一部だけを選択したいときがあるからです。 たとえば、housecats か housekeepers を検索したいとしましょう。 housecat|housekeeper という正規表現はそれができます; しかし、house を 二回タイプしなければならないので効率がよくありません。 正規表現の一部分を house のように定数にできて、そして一部が cat|keeper のように選択肢を持つようにできればよいのです。
グループ化 メタ文字 () はこの問題を解決します。 グループ化は正規表現の一部分を一つのユニットとして扱うことを許します。 ある正規表現の一部はカッコによって囲まれることでグループ化されます。 したがって、housecat|housekeeper は正規表現を house(cat|keeper) と することによって解決することができます。 正規表現 house(cat|keeper) は、cat か keeper が後続する house にマッチングすることを意味します。 幾つか例を挙げましょう
/(a|b)b/; # 'ab' または 'bb' にマッチング
/(ac|b)b/; # 'acb' または 'bb' にマッチング
/(^a|b)c/; # 文字列の先頭にある 'ac' か任意の場所の'bc'にマッチング
/(a|[bc])d/; # 'ad', 'bd', 'cd' にマッチング
/house(cat|)/; # 'housecat' か 'house' にマッチング
/house(cat(s|)|)/; # 'housecats' か 'housecat' か 'house' のいずれかに
# マッチング。グループがネストできることに注意
/(19|20|)\d\d/; # 年を表す19xx, 20xx か 2000 年問題を持つ xx にマッチング
"20" =~ /(19|20|)\d\d/; # 空の選択肢 '()\d\d' にマッチング
# '20\d\d' はマッチングできないから選択はグループの中でもその外側と同じように振舞います: 文字列の与えられた 場所で、正規表現がマッチングする最も左にある選択肢が選ばれます。 ですから、最後の例では最初の文字列位置で二番目の選択肢 "20" に マッチングしますが、残りの二つの数字 \d\d にマッチングするものが 残っていません。 このため、Perlは次の選択肢へと移り、"20" が二つの数字なので空の選択肢で うまくいきます。
ある選択肢を試し、マッチングすればそれを選んで次の選択肢へ移り、 マッチングしなければ文字列の以前の選択肢を試した場所に戻る、 という手順は バックトラッキング (backtracking)と呼ばれます。 'バックトラッキング'という単語は正規表現のマッチングが森の中の散歩に 似ていることからきています。 正規表現のマッチングが成功することは目的地にたどり着くことです。 多くの起点があり、文字列の各位置のひとつで左から右へと順序だてて 一つ一つ試します。 それぞれの起点からは多くの通り道があり、どれかはあなたが目指す場所で 他のどれかは行き止まりになっています。 歩いていて行き止まりに当たったら、あなたはもと来た道を後戻り(backtrack)して 別の道を試してみなければなりません。 目的地に着いたなら、即座に止まって他の道は忘れてしまいます。 あなたは粘り強いので、すべての起点からすべての通り道を試してそれでも 目的地に着かなければ、失敗を宣言します。 具体的に、Perl が正規表現のマッチングを試しているときに行っていることを ステップを追って説明しましょう
"abcde" =~ /(abd|abc)(df|d|de)/;文字列の最初の文字 'a' から始めます。
最初のグループの中の最初の選択肢 'abd' を試します。
'a' とそれに続く 'b' にマッチングします。 よさそうです。
正規表現中の 'd' は文字列中の 'c' にマッチングしません - 行き止まりです。 このため、二文字後戻りして最初のグループの二番目の選択肢である 'abc' を取り出します。
'a', 'b', 'c' と続けてマッチングします。 ここで最初のグループが満足されました。 $1 に 'abc' をセットします。
二番目のグループへ移動して、最初の選択肢である 'df' を取り出します。
'd' にマッチングします。
正規表現中の 'f' は文字列中の 'e' にマッチングしません; 行き止まりです。 一文字後戻りして二番目のグループの二番目の選択肢 'd' を取り出します。
'd' にマッチングします。 二番目のグループは満足されたので、$2 に 'd' をセットします。
正規表現の終端に達しました; これで終わりです! 文字列 "abcde" に対して 'abcd' がマッチングしました。
この調査に関して注意すべき点が二、三あります。 第一に、二番目のグループの三番目の選択肢 'de' もまたマッチングしますが、 そこに行く前に停止しました - 与えられた文字の位置で、最も左のものが 優先されるからです。 第二に、文字列の最初の文字が 'a' であったのでマッチングすることができました。 もし最初の位置でマッチングに成功しなければ、Perl は二番目にある文字 'b' へと 移動して同じことを繰り返します。 すべての可能な文字位置で、すべての可能な道筋が尽きたときにのみ Perl は マッチングをあきらめ、 $string =~ /(abd|abc)(df|d|de)/; が失敗したと宣言します。
これだけのことを行ってさえ、正規表現のマッチングは目立って速いものです。 検索速度を向上させるために、Perl は正規表現をコンパクトでしばしば プロセッサのキャッシュに納まるようなオペコードの並びへと変換します。 そのコードが実行されたとき、これらのオペコードはフルスロットルで 走ることができて非常にすばやく検索します。
グループ化メタ文字 () はまた、まったく異なる別の機能を有しています: マッチングした文字列の一部分を展開することができるのです。 これは一般的に、マッチングしたものを見つけ出したり、テキスト処理のために 非常に便利なものです。 それぞれのグループ化に対して、マッチングした部分が特殊変数 $1, $2 などに 格納されます。 これらの変数は通常の変数と同じように使うことができます:
# extract hours, minutes, seconds
if ($time =~ /(\d\d):(\d\d):(\d\d)/) { # match hh:mm:ss format
$hours = $1;
$minutes = $2;
$seconds = $3;
}この例ではスカラコンテキストなので、 $time =~ /(\d\d):(\d\d):(\d\d)/ は真か偽の値を返します。 リストコンテキストでは、マッチングした値のリスト ($1,$2,$3) を返します。 ですから、コードをよりコンパクトに
# extract hours, minutes, seconds
($hours, $minutes, $second) = ($time =~ /(\d\d):(\d\d):(\d\d)/);正規表現中のグループ化がネストしていた場合、$1 は最も左にある 開きかっこによってグループ化されているものを取り、$2 は 次の開きかっこによるものを取り…となっていきます。 これがネストしたグループをもつ正規表現です:
/(ab(cd|ef)((gi)|j))/;
1 2 34この正規表現がマッチングすると、$1 は 'ab' で始まる文字列が入り、 $2 は 'cd' か 'ef' が入り、$3 は 'gi' か 'j' が入り、 $4 は $3 と同様に 'gi' が入るか、未定義のままです。
便利のため、Perl は $+ に $1, $2 などの代入された番号付け変数の 最も数値の大きなものをセットします(そして、$^N には最も最近代入された $1, $2 などの値がセットされます; つまり、マッチングにおいて使われた 閉じカッコの中で最も右にあるものに結び付けられたものです)。
マッチング変数 $1, $2 …に密接に結び付けられたものは、 後方参照 (backreferences) \g1, \g2 …です。 後方参照は正規表現の 内側 で使うことのできるマッチング変数です。 これは実に良い機能です; 正規表現の中で後でマッチングするものがそれ以前に マッチングしていたものに依存させることができます。 'the the' のように繰り返しされた単語をテキストの中から探したいとしましょう。 以下の正規表現はスペースで分けられた三文字の重複単語を見つけ出します:
/\b(\w\w\w)\s\g1\b/;グループ化は値を \g1 にセットするので、同じ三文字の並びが両方のパーツで 使われます。
似たような作業としては、同じ部分が 2 回繰り返される単語を 探すというものです:
% simple_grep '^(\w\w\w\w|\w\w\w|\w\w|\w)\g1$' /usr/dict/words
beriberi
booboo
coco
mama
murmur
papaこの正規表現は四文字の組み合わせ、三文字の組み合わせなどを扱うただ一つの グループ化を持っています; そして、\g1 は繰り返しを探します。 $1 と \g1 が同じものを表現しているにもかかわらず、マッチング変数 $1, $2 …は正規表現の 外側 のみで用い、 後方参照 \g1, \g2 …は正規表現の 内側 でのみ使うようにすべきです; そうしないと驚くような不満足な結果を招くかもしれません。
後方参照で正しい番号を得るために開きかっこを数えるということは、捕捉 グループが複数になるとすぐに間違いを起こしがちになります。 より便利なテクニックである相対後方参照が Perl 5.10 で利用可能です。 直前の捕捉グループを参照するためには \g{-1} と書き、その手前は \g{-2}、などとなります。
相対後方参照を使うことの、可読性と保守性に加えたよい理由は、以下の、 特定の文字列をマッチングするための単純なパターンが使われている例で示します:
$a99a = '([a-z])(\d)\g2\g1'; # matches a11a, g22g, x33x, etc.ここで、このパターンを便利な文字列として持つことになったので、 これを他のパターンの一部として使いたいと思うかもしれません:
$line = "code=e99e";
if ($line =~ /^(\w+)=$a99a$/){ # unexpected behavior!
print "$1 is valid\n";
} else {
print "bad line: '$line'\n";
}しかしこれはマッチングしません; 少なくとも予想した通りには。 変数展開された $a99a を挿入した後でだけ、結果となる 正規表現のテキストを見ると、後方参照が逆効果となるのは明らかです。 部分式 (\w+) が 1 番を奪ってしまい、$a99a のグループが 1 つ格下げになります。 これは相対後方参照を使うことで回避できます:
$a99a = '([a-z])(\d)\g{-1}\g{-2}'; # safe for being interpolatedPerl 5.10 では名前付きグループと名前付き後方参照も導入されました。 捕捉グループに名前を付けるために、(?<name>...) または (?'name'...) と書けます。 後方参照は \g{name} と書けます。 複数のグループに同じ名前を付けることは出来ますが、一番左のものだけが 参照可能です。 パターンの外側では、名前付き捕捉グループは %+ ハッシュを通して アクセスできます。
yyyy-mm-dd, mm/dd/yyyy, dd.mm.yyyy の 3 つの形式のどれか 1 つで 与えられる日付とマッチングしなければならないと仮定すると、 'd', 'm', 'y' をそれぞれ日付の要素を捕捉するグループの名前として使って、 3 つの適合するパターンを書けます。 マッチング操作は 3 つのパターンの選択として結合します:
$fmt1 = '(?<y>\d\d\d\d)-(?<m>\d\d)-(?<d>\d\d)';
$fmt2 = '(?<m>\d\d)/(?<d>\d\d)/(?<y>\d\d\d\d)';
$fmt3 = '(?<d>\d\d)\.(?<m>\d\d)\.(?<y>\d\d\d\d)';
for my $d qw( 2006-10-21 15.01.2007 10/31/2005 ){
if ( $d =~ m{$fmt1|$fmt2|$fmt3} ){
print "day=$+{d} month=$+{m} year=$+{y}\n";
}
}もし他のマッチングがある場合は、ハッシュ %+ は 3 つのキー-値の組が 含まれることになります。
もう一つのグループの番号付けの技術 (これも Perl 5.10 からです) は、 選択の集合の中にあるグループを参照する問題を扱います。 民間形式と軍形式の時刻にマッチングするパターンを考えます:
if ( $time =~ /(\d\d|\d):(\d\d)|(\d\d)(\d\d)/ ){
# process hour and minute
}結果の処理には、$1 と $2、または $3 と $4 に有用なものが 含まれれているかを決定するために追加の if 文が必要です。 2 番目の選択肢にもグループ番号 1 と 2 をつけられればより簡単になります; これがまさに、選択肢の周りにかっこをつけた構造 (?|...) が 意味するものです。 これは以前のパターンの拡張版です:
if ( $time =~ /(?|(\d\d|\d):(\d\d)|(\d\d)(\d\d))\s+([A-Z][A-Z][A-Z])/ ){
print "hour=$1 minute=$2 zone=$3\n";
}選択番号付けグループの中で、グループ番号はそれぞれの選択に対して 同じ位置から始まります。 このグループの後、番号付けは全ての選択の中での最大値に 1 を加えた値から 続行します。
マッチングしたものに加えて、Perl ではマッチングしたものの位置を @- と @+ という配列の中身によって提供します。 $-[0] はマッチング全体の開始位置で、$+[0] はマッチング全体の 終了位置です。 同様に、 $-[n] は $n の開始位置であり $+[n] はその終了位置です。 $n が未定義であった場合には、$-[n] と $+[n] もまた未定義です。 従ってこのコードは
$x = "Mmm...donut, thought Homer";
$x =~ /^(Mmm|Yech)\.\.\.(donut|peas)/; # matches
foreach $expr (1..$#-) {
print "Match $expr: '${$expr}' at position ($-[$expr],$+[$expr])\n";
}以下の出力を行います
Match 1: 'Mmm' at position (0,3)
Match 2: 'donut' at position (6,11)グループ化を正規表現で使っていなかったとしても、文字列の中で実際に マッチングしたものを見つけ出すことが可能です。 正規表現を使ったとき、 Perl は $` に文字列のマッチングした部分より前の部分を セットし、 $& にはマッチングした部分をセットし、そして $' には マッチングした部分より後の部分をセットします。 例:
$x = "the cat caught the mouse";
$x =~ /cat/; # $` = 'the ', $& = 'cat', $' = ' caught the mouse'
$x =~ /the/; # $` = '', $& = 'the', $' = ' cat caught the mouse'二番目のマッチングでは、$` は '' となります; なぜなら、正規表現は文字列の最初の文字位置でマッチングして止まっているからで、 二番目の 'the' を決して見ないからなのです。 $` や $' を使うことは正規表現マッチングを目立って遅くさせることに 注意することは重要です; 一方 $& も遅くなる原因です; なぜなら、プログラムの中の正規表現でこれらを使ったならばプログラムの中の すべて の正規表現に対してこれらが生成されるからです。 ですから、生のパフォーマンスがあなたの作るアプリケーションのゴールで あるならば、これらを排除すべきです。 もし対応する吹く文字列の展開が必要なら、代わりに @- と@+ を 使いましょう:
$` は substr( $x, 0, $-[0] ) と同じです
$& は substr( $x, $-[0], $+[0]-$-[0] ) と同じです
$' は substr( $x, $+[0] ) と同じですPerl 5.10 から、${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} 変数が 使えます。 これらは /p 修飾子があるときにのみ設定されます。 従って、これらはプログラムの残りの部分では不利益にはなりません。
選択肢の集合をまとめるために必要なグループは、捕捉グループとして 有用な場合もありますし、有用でない場合もあります。 有用でない場合は、これは正規表現の内外で、無駄な捕捉グループ値を 作ることになります。 非捕捉グループ化は (?:regexp) のように表記され regexp を一つの ユニットのように扱うことができるようにしますが、同時に捕捉グループを 作成することはしません。 捕捉するグループ化と捕捉しないグループ化の両方が同じ正規表現の 中で共存することができます。 部分文字列の抜き出しをしないので、非捕捉グループ化は捕捉する グループ化よりも高速です。 非捕捉グループ化はマッチング変数を使って抽出する正規表現の部分を 選択するのに便利です:
# match a number, $1-$4 are set, but we only want $1
/([+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?)/;
# match a number faster , only $1 is set
/([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE][+-]?\d+)?)/;
# match a number, get $1 = whole number, $2 = exponent
/([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE]([+-]?\d+))?)/;非捕捉グループ化は、なんらかの理由でかっこが必要なところで、split 操作が もたらす不愉快な要素を取り除くのにも便利です:
$x = '12aba34ba5';
@num = split /(a|b)+/, $x; # @num = ('12','a','34','a','5')
@num = split /(?:a|b)+/, $x; # @num = ('12','34','5')先のセクションの例では、腹立たしい弱点が明らかになりました。 三文字の単語か、四文字以下の文字の塊にだけマッチングしていました。 \w\w\w\w|\w\w\w|\w\w|\w のような長たらしい選択を書くことなしに任意の 長さの単語やより一般的には、文字列にマッチングさせたいのです。
これは、?, *, +, {} といった 量指定子 (quatifier) メタ文字が作られる元となった問題です。 これらはマッチングさせたいと考えている正規表現の一部分の繰り返し回数を 指定できます。 量指定子は繰り返しを指定したい文字、文字クラス、またはグループの直後に 置きます。 これらは以下のような意味があります:
a? は: 'a' または空文字列にマッチングします。
a* は: 'a' のゼロ回以上の繰り返しにマッチングします。
a+ は: 'a' の一回以上の繰り返しにマッチングします。
a{n,m} は: n 回以上 m 回以下の繰り返しにマッチングします。
a{n,} は: n 回以上の繰り返しにマッチングします。
a{n} は: n 回の繰り返しにマッチングします。
以下にいくつか例を挙げます:
/[a-z]+\s+\d*/; # 小文字の単語、幾つかの空白、それに続く任意の長さの
# 数字にマッチング
/(\w+)\s+\g1/; # 任意の長さの単語の重複にマッチング
/y(es)?/i; # 'y', 'Y', または大小文字を無視して 'yes' にマッチング
$year =~ /^\d{2,4}$/; # 年が少なくとも2桁あるが最大でも4桁になるように
# する
$year =~ /^\d{4}|\d{2}$/; # もっと良い; 3桁をはじく
$year =~ /^\d{2}(\d{2})?$/; # 同じことの違うやり方。しかし、この例では
# $1 を生成する。
% simple_grep '^(\w+)\g1$' /usr/dict/words # isn't this easier?
beriberi
booboo
coco
mama
murmur
papaこれらの量指定子のすべてで、Perl は正規表現のマッチングが成功するのを許す範囲で 可能な限りの文字列をマッチングさせようとします。 したがって、/a?.../ があったとき、Perl は最初に a があるものとして 正規表現のマッチングを試みます; もしそれが失敗したら、Perl は a が ないものとして正規表現のマッチングを試みます。 量指定子 * に関して、以下のようになります:
$x = "the cat in the hat";
$x =~ /^(.*)(cat)(.*)$/; # matches,
# $1 = 'the '
# $2 = 'cat'
# $3 = ' in the hat'これはおそらく期待したもので、文字列の中の cat だけを見つけ出して マッチングします。 しかし、次の例で考えてみましょう:
$x =~ /^(.*)(at)(.*)$/; # matches,
# $1 = 'the cat in the h'
# $2 = 'at'
# $3 = '' (0 characters match)Perl は cat の at を見つけて、そこでストップするだろうと考える人が いるかもしれませんが、それでは最初の量指定子 .* に可能な限りの長い 文字列を与えてはいません。 その代わりに、最初の量指定子 .* は正規表現がマッチングする範囲で可能な限りの 長い文字列をつかみとります。 この例では at が文字列の最後の at になるということを意味します。 ここで明らかになるもう一つの重要な規則は二つ以上の要素が正規表現の中に あるときには、最も左にある 量指定子が可能な限りの長さの文字列を つかみとり、正規表現の残りの部分がどうであるかは放っておくというものです。 したがってこの例では、最初の量指定子 .* は文字列のほとんどをつかみ、 二番目の量指定子 .* は空文字列をつかみます。 可能な限りの文字列をつかみとる量指定子は 最長マッチング とか 貪欲 (greedy) であると呼ばれます。
正規表現が幾つかの異なる道筋で文字列にマッチングすることが可能なとき、 正規表現がどのようにマッチングするかを予測するために以下の法則を 使うことができます:
法則 0: 全体で、任意の正規表現は文字列中の可能な限り先頭に近い場所で マッチングする。
法則 1: 選択 a|b|c... の中で、正規表現全体がマッチングする中で最も左の 選択肢が使われる。
法則 2: 最大マッチング量指定子 ?, *, +, {n,m} は 正規表現全体がマッチングする中で最も長い文字列にマッチングする。
法則 3: 正規表現の中に二つ以上の要素があったならば、貪欲な量指定子が もしあれば、その中で最も左にあるものが正規表現全体がマッチングする条件に おいて可能な限りの長さでマッチングする。 次の貪欲な量指定子があれば、それは残りの中で正規表現全体がマッチングする 条件において最も長い文字列にマッチングする。 これをすべての正規表現要素が満足されるまで繰り返す。
すでに見たように、法則 0 は他のものを上書きしています。 正規表現は可能な限り早い地点でマッチングしようとし、他の法則はその正規表現が どのようにその最も早く現れた文字位置でマッチングするかを決定しています。
以下はこれらの法則をアクションの中で示した例です:
$x = "The programming republic of Perl";
$x =~ /^(.+)(e|r)(.*)$/; # matches,
# $1 = 'The programming republic of Pe'
# $2 = 'r'
# $3 = 'l'この正規表現は最も早い文字列位置 'T' でマッチングします。 選択の中で最も左にあるeがマッチングすると考えた人がいるかもしれませんが、 r が最初の量指定子に関して最長の文字列を生成します。
$x =~ /(m{1,2})(.*)$/; # matches,
# $1 = 'mm'
# $2 = 'ing republic of Perl'ここで、最も早い可能な位置は programming の中の最初の 'm' です。 m{1,2} は最初の量指定子なので、最も長い mm にマッチングするのです。
$x =~ /.*(m{1,2})(.*)$/; # matches,
# $1 = 'm'
# $2 = 'ing republic of Perl'これは、文字列の先頭で正規表現はマッチングします。 最初の量指定子 .* は可能な限りの部分をつかみとり、二番目の量指定子 m{1,2} のためには 'm' 一文字しか残しません。
$x =~ /(.?)(m{1,2})(.*)$/; # matches,
# $1 = 'a'
# $2 = 'mm'
# $3 = 'ing republic of Perl'この例では、.? は文字列の中で可能な限り早い場所での最大一文字、つまり programming の中の 'a' をつかみとります; m{1,2} は両方の m に マッチングする機会を与えられます。 最終的に、
"aXXXb" =~ /(X*)/; # matches with $1 = ''そしてこうなるわけは、文字列の先頭にある 'X' のゼロ回の繰り返しに マッチングすることができるからです。 少なくとも一つの 'X' にマッチングさせたいのであるなら、X* ではなく X+ を使いましょう。
貪欲であることがよくない場合もあります。 文字列の最大の部分ではなく 最小の部分にマッチングする量指定子が欲しいときが あります。 この目的のために、Larry Wall は 最小マッチング(minimal match) あるいは 無欲な(non-greedy) 量指定子 ??, *?, +?, {}? を 作り出しました。 これらは通常の量指定子に ? を付け加えたものです。 これらは以下のような意味があります:
a?? は: 空か 'a' にマッチングします。 はじめに空を試し、それから 'a' を試します。
a*? は: 'a' のゼロ回以上の繰り返しにマッチングします; 任意回の繰り返しができますが、可能な限り少ない回数になります。
a+? は: 'a' の一回以上の繰り返しにマッチングします; 一回以上の任意回の繰り返しができますが、可能な限り少ない回数になります。
a{n,m}? は: n 回以上 m 回以下の繰り返しにマッチングしますが、可能な 限り少ない回数になります。
a{n,}? は: 少なくとも n 回の繰り返しにマッチングしますが、可能な限り 少ない回数になります。
a{n}? は: ちょうど n 回の繰り返しにマッチングします。 ちょうど n 回なので、a{n}? は a{n} と等価であり、一貫性のためだけに 存在します。
先の例を最小量指定子を使ったものにしてみましょう:
$x = "The programming republic of Perl";
$x =~ /^(.+?)(e|r)(.*)$/; # matches,
# $1 = 'Th'
# $2 = 'e'
# $3 = ' programming republic of Perl'マッチングするために文字列の開始位置 ^ と選択の両方を満足する最小の 文字列は Th で、選択 e|r は e にマッチングします。 二番目の量指定子 .* は文字列の残りから自由につかみとることができます。
$x =~ /(m{1,2}?)(.*?)$/; # matches,
# $1 = 'm'
# $2 = 'ming republic of Perl'この正規表現がマッチングすることのできる文字列の最初の位置は programming の中の最初の 'm' です。 この位置で、最小マッチング m{1,2}? はただ一つの 'm' です。 二番目の量指定子 .*? が空にマッチングしようとしますがそれは文字列の 終端アンカー $ が阻止して、文字列の残りにマッチングします。
$x =~ /(.*?)(m{1,2}?)(.*)$/; # matches,
# $1 = 'The progra'
# $2 = 'm'
# $3 = 'ming republic of Perl'この正規表現において、最小量指定子 .*? は空文字列にマッチングすると 考えるかもしれませんが、^アンカーが単語の先頭にマッチングすることを 強制していません。 法則 0 がここで適用されます。 文字列の先頭で正規表現全体をマッチングさせることが可能なので、文字列の先頭で マッチング します。 したがって、最初の量指定子は最初の m までにマッチングします。 二番目の最小量指定子はただ一文字の m にマッチングして、三番目の量指定子が 文字列の残りにマッチングします。
$x =~ /(.??)(m{1,2})(.*)$/; # matches,
# $1 = 'a'
# $2 = 'mm'
# $3 = 'ing republic of Perl'先の正規表現と同じようですが、最初の量指定子 .?? は最初の 'a' の 位置でマッチングできるのでそうします。 二番目の量指定子は貪欲なので mm にマッチングし、三番目のものが文字列の 残りにマッチングします。
先に挙げた法則 3 を、無欲な量指定子を考慮したものにするために修正します:
法則 3: 正規表現の中に二つ以上の要素があったならば、貪欲な量指定子(もしくは 無欲な量指定子)がもしあれば、その中で最も左にあるものが 正規表現全体がマッチングする条件において可能な限りの長さでマッチングする。 次の貪欲な量指定子(もしくは無欲な量指定子)があれば、それは残りの中で 正規表現全体がマッチングする条件において最も長い(最も短い)文字列にマッチングする。 これをすべての正規表現要素が満足されるまで繰り返す。
選択と同じように、量指定子もまたバックトラッキングを行う可能性があります。 以下はステップごとに追った例です
$x = "the cat in the hat";
$x =~ /^(.*)(at)(.*)$/; # matches,
# $1 = 'the cat in the h'
# $2 = 'at'
# $3 = '' (0 matches)文字列の最初の文字't'で始まる。
最初の量指定子 '.*' は文字列全体'the cat in the hat'にまずはじめに マッチングする。
正規表現要素 'at' の 'a' は文字列の末尾にマッチングしない。 一文字後戻りする。
正規表現要素 'at' の 'a' は文字列の最後の文字 't' にマッチングしないので、 更に一文字後戻りする。
ここで 'a' と 't' にマッチングすることができる。
三番目の要素 '.*' に移る。 文字列の末尾に位置していて、'.*' は 0 回の繰り返しに マッチングすることができるので空文字列を代入する。
完了!
ほとんどの場合、前方への移動と後戻りが起こったときには迅速に行われ、 検索は高速です。 しかしながら、中には文字列の長さに応じて指数的に実行時間が延びるような 病理学的(pathological)な正規表現もあります。 そのようなものの例は以下のようなものです
/(a|b+)*/;問題は不確定のネストした量指定子があることです。 + と * の間にある長さ n の文字列には複数の異なる分け方が存在します: 一つは長さ n の b+ で、二つ目は長さ k の b+ と n-k の長さのもの、 繰り返し m は長さ n まで加える、などです。 長さの関数として文字列を分割する方法の数は指数的な数になります。 正規表現は幸運なときには処理の早い段階でマッチングに成功するかもしれませんが、 マッチングしなかった場合には Perl は音を上げるまで すべての 可能性を 試します。 ですから、ネストした *, {n,m}, + には注意してください。 Jeffrey Friedl による Mastering Regular Expressions (邦訳 「詳説正規表現」) という本はこういった効率の問題についてすばらしい 解説をしています。
マッチングのための容赦ない検索中のバックトラッキングは時間の無駄の場合が あります; とくにマッチングが失敗する運命にあるときはそうです。 簡単なパターンを考えてみます
/^\w+\s+\w+$/; # a word, spaces, a wordこれが、"abc " や "abc def " のような、パターンが 想定していなかったような文字列に適用されると、正規表現エンジンは 文字列のそれぞれの文字に対してほぼ 1 回バックトラックを行います。 しかし、私たちは 全ての 最初の単語文字列が最初の繰り返しにマッチングし、 全ての 空白が中間の部分で消費され、2 番目の単語も同じように なるしかない、ということを知っています。
Perl 5.10 での 絶対最大量指定子 の導入によって、 普通の量指定子に + を追加することで、正規表現エンジンに バックトラックしないように指示することができるようになります。 これは貪欲であるのと同様出し惜しみをするようにします; 一旦マッチングすると、 他の解決策のために手放すということをしなくなります。 これらは以下のような意味があります:
a{n,m}+ は: 最小で n 回、最大で m 回の間で出来るだけたくさん マッチングし、そして何も手放しません。 a?+ は a{0,1}+ の省略形です。
a{n,}+ は: 最小で n 回で出来るだけたくさんマッチングし、 そして何も手放しません。 a*+ は a{0,}+ の省略形で、a++ は a{1,}+ の省略形です。
a{n}+ は: 正確に n 回にマッチングします。 これは単に一貫性のためにあります。
これらの絶対最大量指定子は、以下で述べる、より一般的な概念である 独立部分式 の特殊な場合を表現しています。
絶対最大量指定子がふさわしい例として、いくつかのプログラミング言語で 現れるような、クォートされた文字列のマッチングを考えます。 バックスラッシュは次の文字が他の文字と同様リテラルに扱われることを示す エスケープ文字として使われます。 従って、開きクォートの後、選択肢の(空かもしれない)並びを想定します: エスケープされていないクォート文字以外の何らかの文字か、 バックスラッシュか、エスケープされた文字です。
/"(?:[^"\\]++|\\.)*+"/;ここまでで、すべての基本的な正規表現のコンセプトをカバーしました; ですから、もっと複雑な正規表現に行ってみましょう。 例として、数値にマッチングする正規表現を組み立てます。
正規表現を組み立てるにあたっての最初の仕事は何にマッチングさせるかと何を 排除するかを決めることです。 今回は、整数と浮動小数点数の両方にマッチングさせ、数値でない文字列をすべて 排除します。
次の仕事は問題を、より正規表現に変換しやすい小さいな問題に 分解することです。
もっとも簡単なケースは整数です。 これは数字の並びであり、省略可能な符号が先頭にあります。 数字は \d+ で表すことができ、符号は [+-] にマッチングさせることが できます。 したがって、整数にマッチングする正規表現は以下のようになります
/[+-]?\d+/; # matches integers浮動小数点数は符号と、整数部と、小数点と、小数部と、指数部を持つ可能性が あります。 これらの一つ以上のパーツが省略可能であり、可能なものをチェックする必要が あります。 正しい形式の浮動小数点数は123.、0.345、.34、-1e6、25.4E072 といったものを 含みます。 整数と同じように、先頭にある符合は省略可能で [+-]? にマッチングします。 もし指数部がないことがわかれば、浮動小数点数は小数点を持たなければならず、 これがない場合にはそれは整数です。 \d*\.\d* というパターンを使うことを思いつくかもしれませんが、これは 数値ではないただ一つの小数点にもマッチングしてしまいます。 ですから、指数部のない浮動小数点には以下の三つのケースが存在します
/[+-]?\d+\./; # 1., 321., etc.
/[+-]?\.\d+/; # .1, .234, etc.
/[+-]?\d+\.\d+/; # 1.0, 30.56, etc.これらは三つの選択を使った単一の正規表現にまとめることができます:
/[+-]?(\d+\.\d+|\d+\.|\.\d+)/; # floating point, no exponentこの選択肢において、'\d+\.\d+'が'\d+\.' より前に置かれていることが 重要です。 もし '\d+\.' が先頭にあったなら、この正規表現は数値の小数部を無視して マッチングしてしまうでしょう。
ここで指数部を持つ浮動小数点数を考えてみましょう。 ここでのポイントは指数部の前に整数と小数点を伴った数の 両方 が 現れることができるということです。 指数部は符号と同じように、小数点を伴うか伴わないかに関係なくマッチングし、 仮数部から分離することも可能です。 正規表現の全体の形式がこれで明らかになりました:
/^(optional sign)(integer | f.p. mantissa)(optional exponent)$/;指数部は整数が続く e もしくは E です。 ですから指数部の正規表現は以下のようになります
/[eE][+-]?\d+/; # exponentすべてのパーツを一つにまとめることによって、数値にマッチングする正規表現を 手に入れます:
/^[+-]?(\d+\.\d+|\d+\.|\.\d+|\d+)([eE][+-]?\d+)?$/; # Ta da!このような長い正規表現を友人に説明することがあるかもしれませんが、 解読するのが難しいかもしれません。 このような複雑なものにおいては、//x 修飾子は重要なものです。 この修飾子は正規表現に対してその意味を変えることなく、ほぼ任意の空白を 入れたりコメントを入れたりすることを許します。 これを使うことによって、よりわかりやすい形式に正規表現を 「拡張」することができます
/^
[+-]? # まずはじめに、省略可能な符号にマッチング
( # 続いて整数か f.p. 仮数部にマッチング:
\d+\.\d+ # a.b 形式の仮数部
|\d+\. # a. 形式の仮数部
|\.\d+ # .b 形式の仮数部
|\d+ # a 形式の整数
)
([eE][+-]?\d+)? # 最後に、省略可能な指数部にマッチング
$/x;もし空白が余計なものであれば、拡張された正規表現にスペースを含ませるには どうすればよいのでしょうか? その答えは '\ ' のように バックスラッシュを前置するか、[ ] のように文字クラスに 押し込めることです。 同じことが '#' にも言えます: \# か [#] を使います。 たとえば、Perl が符号と仮数部(もしくは整数部) の間に空白を置くことを 許すとすると、以下のように正規表現に加えることができます:
/^
[+-]?\ * # まずはじめに、省略可能な符号と*スペース*にマッチング
( # 続いて整数か f.p. 仮数部にマッチング:
\d+\.\d+ # a.b 形式の仮数部
|\d+\. # a. 形式の仮数部
|\.\d+ # .b 形式の仮数部
|\d+ # a 形式の整数
)
([eE][+-]?\d+)? # 最後に、省略可能な指数部にマッチング
$/x;この形式においては、選択肢を単純にする方法を見つけるのは簡単です。 選択肢 1, 2, 4 はすべて \d+ で始まっています; ですからこれは まとめることができます:
/^
[+-]?\ * # まずはじめに、省略可能な符号にマッチング
( # 続いて整数か f.p. 仮数部にマッチング:
\d+ # はじめは…
(
\.\d* # a.b形式もしくはa.形式の仮数部
)? # ? はa形式の整数を考慮する
|\.\d+ # .b形式の仮数部
)
([eE][+-]?\d+)? # 最後に、省略可能な指数部にマッチング
$/x;あるいはコンパクトな形式で
/^[+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?$/;これが最終形の正規表現です。 ここでは以下のようにして正規表現を組み立てました。
なすべきことを詳細に確定し、
問題を小さなパーツに分割し、
その小さなパーツを正規表現に変換し、
その正規表現を組み合わせ、
組み合わされた最終的な正規表現を最適化する。
これはコンピュータプログラムを書くにあたっての典型的なステップでも あります。 正規表現はパターンを特定する小さなコンピュータ言語で書く プログラムであるので、このことはまさに当てはまります。
Perl 1 の最後のトピックは正規表現がPerlプログラムでどのように 使われているかを説明します。 正規表現は Perl の構文のどこにフィットしているのでしょう?
すでにデフォルトの /regexp/ と任意のデリミタを持つ m!regexp! 形式の マッチング演算子を説明しています。 マッチングさせる文字列を指定するために =~ 演算子や !~ 演算子を 使っています。 マッチング演算子について、単一行修飾子 //s、複数行修飾子 //m、 大小文字の違いを無視する修飾子 //i、拡張修飾子 //x について 述べました。 マッチング演算子に関して、知っておきたいであろういくつかの事柄があります。
もし最初の置換が行われた後で $pattern を変更したとしても、Perl は それを無視します。 すべての置換を行いたくないというのであれば、特殊なデリミタ m'' を使います:
@pattern = ('Seuss');
while (<>) {
print if m'@pattern'; # 'Seuss' ではなくリテラルの '@pattern' にマッチング
}文字列と同様、m'' は正規表現においてシングルクォートのように 振舞います。 他のすべての m デリミタはダブルクォートのように振舞います。 もし正規表現が空文字列を評価したならば、その正規表現は 最後に成功した マッチングにある正規表現が代わりに使われます。
"dog" =~ /d/; # 'd' にマッチング
"dogbert =~ //; # 直前に使われた正規表現である 'd' にマッチングここで議論する最後の二つの修飾子 //g と //c は複数回マッチングに 関連するものです。 修飾子 //g はグローバルマッチングを意味し、マッチング演算子に対して 文字列の中で可能な限りの回数マッチングするようにします。 スカラコンテキストでは、ある文字列に対する連続した呼び出しはマッチングから マッチングへとジャンプする //g を持ち、その文字列の中での位置を記憶します。 pos() 関数を使ってこの位置を取り出したり設定したりすることができます。
//g を使った例を以下に挙げます。 ここで、空白によってくぎら得た単語の並びからなる文字列があるとします。 もしいくつの単語があるかがわかっていれば、グループ化を使って単語を 取り出すことができます:
$x = "cat dog house"; # 3 words
$x =~ /^\s*(\w+)\s+(\w+)\s+(\w+)\s*$/; # matches,
# $1 = 'cat'
# $2 = 'dog'
# $3 = 'house'しかしもし不定個の単語があるとしたら? これが //g が作られた理由となった類の仕事です。 すべての単語を取り出すために、単純な (\w+) という正規表現を使い、 /(\w+)/g をループで使ってすべてにマッチングさせます:
while ($x =~ /(\w+)/g) {
print "Word is $1, ends at position ", pos $x, "\n";
}以下の出力を行います
Word is cat, ends at position 3
Word is dog, ends at position 7
Word is house, ends at position 13マッチングに失敗したり、ターゲット文字列を変更するとこの位置は リセットされます。 もしマッチングに失敗したときに位置をリセットしたくないのであれば、 /regexp/gc のように //c を追加します。 文字列の中のカレント位置はその文字列に結び付けられていて、正規表現にでは ありません。 このことは異なる文字列は異なる位置を持っていて、それらのそれぞれの位置は 独立にセットしたり読み出したりすることが可能です。
リストコンテキストでは、//g はマッチングしたグループのリストを返します; グループ化の指定がなければ、正規表現全体にマッチングするリストを返します。 ですから、単に単語が欲しいのでれば
@words = ($x =~ /(\w+)/g); # matches,
# $words[0] = 'cat'
# $words[1] = 'dog'
# $words[2] = 'house'//g 修飾子は\Gアンカーに強く結び付けられています。 \G アンカーは直前のマッチングで残った部分にマッチングします。 \G はコンテキストを考慮したマッチング(context-sensitive matching)を 容易にさせます。
$metric = 1; # metric ユニットを使う
...
$x = <FILE>; # 測定のために読み込み
$x =~ /^([+-]?\d+)\s*/g; # 重さを取得
$weight = $1;
if ($metric) { # エラーチェック
print "Units error!" unless $x =~ /\Gkg\./g;
}
else {
print "Units error!" unless $x =~ /\Glbs\./g;
}
$x =~ /\G\s+(widget|sprocket)/g; # 処理を続ける//g と \G の組み合わせは一度に文字列を少しだけ処理して、次に 行うことを決定するために任意の Perl のロジックを使うことを可能にします。 現在のところ、\G アンカーはパターンの最初に使われたときのみ 完全にサポートされます。
\G はまた、正規表現を使って固定長のレコードを処理するときに 貴重なものです。 基礎となる組み合わせ文字でエンコードされた ATCGTTGAAT... のような DNA の符号化部分があるとして、すべてのストップコドン (codon: 3 つの ヌクレオチドから成る，遺伝情報の単位)を見つけ出したいとしましょう。 符号化部分の中では、コドンは三文字の並びなので DNA の断片を 三文字のレコードの並びとしてみなすことができます。 単純な正規表現である
# expanded, this is "ATC GTT GAA TGC AAA TGA CAT GAC"
$dna = "ATCGTTGAATGCAAATGACATGAC";
$dna =~ /TGA/;はうまくいきません; これは TGA にマッチングはしますが、 GTT GAA のようにコドンの境界にないものにもマッチングしてしまいます。 より良い解決策は以下のようなものです
while ($dna =~ /(\w\w\w)*?TGA/g) { # note the minimal *?
print "Got a TGA stop codon at position ", pos $dna, "\n";
}これは以下を出力します
Got a TGA stop codon at position 18
Got a TGA stop codon at position 23Position 18 は良いですが、23 は変です。 何が起きているのでしょう?
その答えは、私たちの正規表現が最後に本当にマッチングしたところまでは うまくいっているからです。 それからこの正規表現は TGA の同期に失敗して私たちが望んでいない場所から マッチングのステップを始めてしまうのです。 解決策は、コドンの境界にマッチングさせるために \G を 使って印付けをすることです:
while ($dna =~ /\G(\w\w\w)*?TGA/g) {
print "Got a TGA stop codon at position ", pos $dna, "\n";
}これは
Got a TGA stop codon at position 18を出力し、そして正しい答えです。 この例はマッチングしたものにマッチングすることだけが重要なのではなく、 望んでいないものを排除することもまたそうなのだということを 明らかにしました。
(//o のようなその他の正規表現修飾子も利用可能ですが、これらの特殊な 使用法はこの序論のスコープからは外れます。)
正規表現はまた、Perl における検索と置換操作において大きな役割を 果たしています。 検索と置換は s/// 演算子に結び付けられています。 一般的な形は s/regexp/replacement/modifiers で、知っているすべての 正規表現と修飾子をここで使うことができます。 replacement は Perlでのダブルクォートで囲まれた文字列で、 regexp にマッチングした文字列を置き換えるものです。 =~ 演算子もまた s/// を伴った文字列に結びつけられるために 使われます。 $_ に対してマッチングを行う場合には、$_ =~ は省略できます。 マッチングに成功した場合には s/// は置換が行われた数を返します; 失敗した場合には偽を返します。 幾つか例を挙げましょう:
$x = "Time to feed the cat!";
$x =~ s/cat/hacker/; # $x の内容は "Time to feed the hacker!"
if ($x =~ s/^(Time.*hacker)!$/$1 now!/) {
$more_insistent = 1;
}
$y = "'quoted words'";
$y =~ s/^'(.*)'$/$1/; # シングルクォートを剥ぎ取る
# $y の内容は "quoted words"最後の例では、文字列全体がマッチングしますが、シングルクォートの内部の 部分のみがグループ化されます。 s/// 演算子では、マッチングした変数 $1, $2, などは置換式で 使えるように直ちに利用可能になるので、クォートされた文字列を中身で 置換するために $1 を使います。 グローバル修飾子付きなので、s///g は文字列中の全てを検索して置換します:
$x = "I batted 4 for 4";
$x =~ s/4/four/; # すべてにはマッチングしない:
# $x の内容は "I batted four for 4"
$x = "I batted 4 for 4";
$x =~ s/4/four/g; # すべてにマッチング:
# $x の内容は "I batted four for four"このチュートリアルにある 'regexp' を 'regex' にすることを望むのなら、 以下のプログラムを使って置換することができます:
% cat > simple_replace
#!/usr/bin/perl
$regexp = shift;
$replacement = shift;
while (<>) {
s/$regexp/$replacement/g;
print;
}
^D
% simple_replace regexp regex perlretut.podsimple_replace では各行のすべての正規表現にマッチングする部分を 置換するために s///g 修飾子を使います。 (正規表現がループ中にあるように見えますが、Perl はこれを一度だけ コンパイルするぐらい賢いです。) simple_grep と同様、print と s/$regexp/$replacement/g で $_ を暗黙に使用しています。
基の変数を変更するために s/// を使いたくないなら、非破壊置換修飾子である s///r が使えます。 これは、s///r が (置換の数ではなく)最終的に置換された文字列を返すように 振る舞いを変更します:
$x = "I like dogs.";
$y = $x =~ s/dogs/cats/r;
print "$x $y\n";この例は、"I like dogs. I like cats" を表示します。 元の $x 変数は影響を受けないことに注意してください。 置換の結果全体は代わりに $y に補完されます。 置換が何も影響を与えなかった場合、元の文字列が返されます:
$x = "I like dogs.";
$y = $x =~ s/elephants/cougars/r;
print "$x $y\n"; # prints "I like dogs. I like dogs."s///r フラグによるもう一つの興味深いことは、置換の連鎖です:
$x = "Cats are great.";
print $x =~ s/Cats/Dogs/r =~ s/Dogs/Frogs/r =~ s/Frogs/Hedgehogs/r, "\n";
# prints "Hedgehogs are great."検索と置換において使うことのできる修飾子に評価修飾子 s///e があります。 s///e は は置換文字列をダブルクォートされた文字列ではなく Perl コードとして扱います。 コードが返した値はマッチングした部分文字列と置換されます。 s///e は置換テキストの処理においてちょっとした計算を行う必要が あるときに便利です。 以下の例はある行の文字の出現頻度を数えます:
$x = "Bill the cat";
$x =~ s/(.)/$chars{$1}++;$1/eg; # 最終的に $1 はそれ自身の文字に置換される
print "frequency of '$_' is $chars{$_}\n"
foreach (sort {$chars{$b} <=> $chars{$a}} keys %chars);これは
frequency of ' ' is 2
frequency of 't' is 2
frequency of 'l' is 2
frequency of 'B' is 1
frequency of 'c' is 1
frequency of 'e' is 1
frequency of 'h' is 1
frequency of 'i' is 1
frequency of 'a' is 1m// 演算子と同様に、s/// も s!!! や s{}{} 、 果ては s{}// のように異なるデリミタを使うことができます。 s''' のようにシングルクォートが使われた場合、その正規表現と 置換テキストはシングルクォート文字列のように扱われ、変数の置き換えは 行われません。 リストコンテキストでの s/// はスカラコンテキストのときと同じように、 マッチングした数を返します。
split() 関数は、正規表現が使えるもう一つの場所です。 split /regexp/, string, limit は string オペランドを部分文字列の リストに分割し、そのリストを返します。 正規表現は、目的の部分文字列のセパレータを構成するものに マッチングするようにしなければなりません。 limit が与えられた場合には、文字列を limit 個を超える数には 分割しません。 たとえば、文字列を単語に分割するには以下のようにします
$x = "Calvin and Hobbes";
@words = split /\s+/, $x; # $word[0] = 'Calvin'
# $word[1] = 'and'
# $word[2] = 'Hobbes'// が使われた場合には、その正規表現は常にマッチングし、文字列は個々の文字に 分割されます。 正規表現がグループ化を伴っていた場合には、グループ化されたものも部分文字列に 含まれるようになります。 例を挙げると以下のようになります
$x = "/usr/bin/perl";
@dirs = split m!/!, $x; # $dirs[0] = ''
# $dirs[1] = 'usr'
# $dirs[2] = 'bin'
# $dirs[3] = 'perl'
@parts = split m!(/)!, $x; # $parts[0] = ''
# $parts[1] = '/'
# $parts[2] = 'usr'
# $parts[3] = '/'
# $parts[4] = 'bin'
# $parts[5] = '/'
# $parts[6] = 'perl'$x の最初の文字に正規表現がマッチングしているので、split はリストの 最初の要素に空要素を置きます。
ここまで読み進めてきたのならおめでとう! あなたは広範囲のテキスト処理を解決するのに必要な正規表現の基本的な部分を すべて会得しました。 このチュートリアルを初めて読んでここまできたのなら、ここで立ち止まって 正規表現を使ってみるのも良いでしょう。 Part 2 ではより難解な正規表現の側面に言及します。
あなたはすでに正規表現の基本的なことを知っていて、より深く 知ろうとしています。 正規表現のマッチングが森の中を歩くことに類似しているのなら、Part 1 で 述べられたツールは地図でありコンパスであり、いつも使う基本的な道具です。 Part 2 での大部分のツールは照明弾であり、衛星電話です。 ハイキングにはそうそう使うものではありませんが、困り果てたときには とても貴重なものです。
以下に挙げるものは Perl の正規表現においてより高度で、 あまり使うことのない、時として難解な機能です。 Part 2 では、あなたが基本を良く知っていてより進んだ機能に集中できることを 仮定しています。
まだカバーしていない幾つかのエスケープシーケンスや文字クラスがあります。
文字や文字列の大小文字を変換するエスケープシーケンスがあり、 これらもパターンで使えます。 \l や \u は続く文字をそれぞれ小文字と大文字に変換します:
$x = "perl";
$string =~ /\u$x/; # $string の中の 'Perl' にマッチング
$x = "M(rs?|s)\\."; # 二重のバックスラッシュに注意
$string =~ /\l$x/; # 'mr.', 'mrs.', 'ms.' にマッチング\L や \U は、\E で終端されるか、別の \U や \L で 上書きされるまで、大文字小文字を変換することを示します:
$x = "This word is in lower case:\L SHOUT\E";
$x =~ /shout/; # マッチングする
$x = "I STILL KEYPUNCH CARDS FOR MY 360"
$x =~ /\Ukeypunch/; # パンチカード文字列にマッチングする\E がない場合には、大小文字の変換は文字列の終端まで行われます。 \L\u$word や \u\L$word は $word の最初の文字を大文字へと変換し、 残りの文字は小文字にします。
制御文字は \c を使ってエスケープすることができます; ですから、 control-Z 文字は \cZ にマッチングします。 \Q...\E というエスケープシーケンスは大部分の非アルファベット文字を クォートまたはプロテクトします。 たとえば
$x = "\QThat !^*&%~& cat!";
$x =~ /\Q!^*&%~&\E/; # check for rough languageこれは $ や @ をプロテクトしないので、変数の置換は行われます。
\Q, \L, \l, \U, \u, \E は実際にはダブルクォート風文法の 一部で、正規表現文法の一部ではありません。 これらはプログラム中の正規表現に直接埋め込まれている場合は動作しますが、 パターン内で展開された文字列に含まれている場合には動作しません。
Perl の正規表現は標準の ASCII 文字セットを超えた扱いをすることができます。 Perl は現在は事実上世界の全ての言語のアルファベットを表現する標準である Unicode をサポートしています。 Perl のテキスト文字列は Unicode 文字列で、255 以上の値(コードポイントまたは 文字番号)を持つ文字を含みます。
このことが正規表現に及ぼす影響は? そう、正規表現ユーザーは perl での文字列の内部表現を知る必要はありません。 しかし、知っておくべきことがあります; 1) 正規表現において Unicode 文字をどのように表現するか 2) マッチング操作がバイト列ではなく、Unicode 文字列として扱うということです。 1)に対する答えは chr(255) を越える Unicode 文字は \x{hex} 表記を 使って表現されるだろうということです(ここで hex は十六進整数); なぜなら、16 進数の \x 表記(中かっこなし) は 255 を超えないからです。 (Perl 5.14 から、8 進数が好みなら、\o{oct} も使えます。)
/\x{263a}/; # match a Unicode smiley face :)注意: Perl 5.6.0 では何かしらの Unicode 機構を使うときには use utf8 を 宣言する必要がありました。 これは現在ではあてはまりません: ほとんどすべての Unicode 処理においては、 utf8 プラグマは必要ありません。 (これが意味を持つただ一つのケースは、 あなたの Perl スクリプトが Unicode で書かれていて、かつそれが UTF-8 で エンコーディングされている場合で、このときは陽に use utf8 を指定する必要があります。)
あなたが必要な Unicode 文字を 16 進数で表記することや、別の誰かが 16 進表記の Unicode 正規表現を解読することは、機械語で プログラミングすることを楽しむかのようです。 ですから、Unicode 文字を指定する別の方法として \N{name} のような 名前付き文字 エスケープシーケンスを使うものがあります。 name は Unicode 文字に対する名前であって、Unicode standard で 定義されているものです。 たとえば、水星を表す占星術記号を表したりマッチングさせるために 以下のようにします
$x = "abc\N{MERCURY}def";
$x =~ /\N{MERCURY}/; # マッチング「短い」名前を使うこともできます:
print "\N{GREEK SMALL LETTER SIGMA} is called sigma.\n";
print "\N{greek:Sigma} is an upper-case sigma.\n";charnames プラグマを指定することで名前を特定のアルファベットに 制限することもできます:
use charnames qw(greek);
print "\N{sigma} is Greek sigma\n";文字名の一覧は Unicode Consortium の http://www.unicode.org/charts/charindex.html からオンラインで 利用可能です; その他のリソースへのリンクを含む説明に関する情報は http://www.unicode.org/standard/where にあります。
2) の答えは、正規表現は(ほとんど) Unicode 文字を使うというものです。 「ほとんど」というのはぐちゃぐちゃな後方互換性の理由ですが、 Perl 5.14 から、use feature 'unicode_strings' (これは use 5.012 以上が 有効なスコープ内では自動的にオンになります) によって「ほとんど」は「常に」に なります。 Unicode を適切に扱いたいなら、'unicode_strings' をオンに するようにするべきです。 内部では、これは UTF-8 かネイティブな 8 ビットエンコーディングを使った バイトでエンコードされてます; どちらかは文字列の履歴に依存します; しかし理論的には、これはバイトの列ではなく文字の列です。 これに関するチュートリアルについては perlunitut を参照してください。
Unicode 文字クラスについて述べましょう。 Unicode 文字と同様に、名前付けされた Unicode の文字クラスがあり、 \p{name} エスケープシーケンスで表されます。 \P{name} は \p{name} の反対の意味を持つ文字クラスです。 たとえば小文字や大文字の文字にマッチングさせるには
$x = "BOB";
$x =~ /^\p{IsUpper}/; # マッチングする; 大文字の文字クラス
$x =~ /^\P{IsUpper}/; # マッチングしない; 文字クラスは大文字以外
$x =~ /^\p{IsLower}/; # マッチングしない; 小文字の文字クラス
$x =~ /^\P{IsLower}/; # マッチングする; 文字クラスは小文字以外("Is" はオプションです。)
以下は、Perl での名前つきクラスと伝統的な Unicode クラスの間の関係です:
Perl class name Unicode class name or regular expression
IsAlpha /^[LM]/
IsAlnum /^[LMN]/
IsASCII $code <= 127
IsCntrl /^C/
IsBlank $code =~ /^(0020|0009)$/ || /^Z[^lp]/
IsDigit Nd
IsGraph /^([LMNPS]|Co)/
IsLower Ll
IsPrint /^([LMNPS]|Co|Zs)/
IsPunct /^P/
IsSpace /^Z/ || ($code =~ /^(0009|000A|000B|000C|000D)$/
IsSpacePerl /^Z/ || ($code =~ /^(0009|000A|000C|000D|0085|2028|2029)$/
IsUpper /^L[ut]/
IsWord /^[LMN]/ || $code eq "005F"
IsXDigit $code =~ /^00(3[0-9]|[46][1-6])$/Unicode の 'letters' である f\p{L} とか大文字である \p{Lu} とか 数字以外の\P{Nd}のように、公式なUncodeクラス名を \p や \P を 使って使用することができます。 name がただ一文字であった場合には、ブレースは省略することができます。 たとえば、\pM は Unicode の 'marks' の文字クラスで、 アクセント記号などが当てはまります。 リスト全部については perlunicode を参照してください。
Unicode はまた、\p{In...}(含まれる) と \P{In...} (含まれない) で 調べることのできる文字の集合に分けられます。 ある文字が用字の要素として含まれているか(あるいは含まれていないか)を 調べるには、例えば \p{Latin}, \p{Greek}, \P{Katakana} のように、 用字名が使えます。
今のところ記述してきたものは \p{...} 文字クラスの単一形式です。 あなたが出会うであろう複合形式もあります。 これらは \p{name=value} や \p{name:value} のような形です (等号と コロンは交換可能です)。 これらは単一形式よりより一般的で、実際ほとんどの単一形式は単に 共通複合形式の Perl 定義のショートカットです。 例えば、以前の段落でのスクリプトの例は \p{Script=Latin}, \p{Script:Greek}, \P{script=katakana} と等価に書けます (大文字小文字は {} の中では無意味です)。 複合形式を使う必要は決してありませんが、ときどき必要に杏里、これを使うことで コードが理解しやすくなります。
\X は、Unicode の 拡張書記素クラスタ (extended grapheme cluster) を 構成する文字クラスの並びの略記です。 これは「論理文字」を表現します: 一つの文字のように見えるけれども、内部では 複数で表現されるものです。 例えば、A + COMBINING RING のような Unicode の完全な名前を使うと、 基底文字 A と結合文字 COMBINING RING による書記素クラスタで、 これはデンマーク語では A の上に丸がものに変換され、オングストロームという 単語で使われます。
Unicode に関するすべての情報や最新の情報を得るには、Unicode standard の 最新のものを見るか、Unicode コンソーシアムの web サイト http://www.unicode.org/ を参照してください。
これらのクラスでは不足と言うかのように、Perl は POSIX 形式の文字クラスも 定義します。 これらは [:name:] の形式で、name は POSIX クラス名です。 POSIX クラスは alpha, alnum, ascii, cntrl, digit, graph, lower, print, punct, space, upper, xdigit および二つの拡張 word (\w にマッチングする Perl 拡張), blank (GNU 拡張) です。 //a 修飾子はこれらを ASCII の範囲だけでマッチングするように制限します; さもなければ対応する Perl Unicode クラスと同じようにマッチングします: [:upper:] は \p{IsUpper} と同じ、などです。 (ここにはいくつかの例外とコツがあります; 完全な議論については perlrecharclass を参照してください。) [:digit:], [:word:], [:space:] は親しんでいる \d, \w, \s 文字クラスに対応します。 POSIX クラスを否定するためには名前の前に ^ を置きます; 従って、例えば [:^digit:] は \D に対応し、Unicode では \P{IsDigit} に対応します。 Unicode と POSIX の文字クラスはちょうど \d のように使えますが、 POSIX 文字クラスは文字クラスの中でのみ使えます:
/\s+[abc[:digit:]xyz]\s*/; # match a,b,c,x,y,z, or a digit
/^=item\s[[:digit:]]/; # match '=item',
# followed by a space and a digit
/\s+[abc\p{IsDigit}xyz]\s+/; # match a,b,c,x,y,z, or a digit
/^=item\s\p{IsDigit}/; # match '=item',
# followed by a space and a digitふう! これが文字と文字クラスで残っていたこと全てです。
In Part 1 we mentioned that Perl compiles a regexp into a compact sequence of opcodes. 従って、コンパイルされた正規表現は一度だけ格納されて繰り返し使うことのできる データ構造です。 qr// で表される正規表現クォートは次のようなものです: qr/string/ は string を正規表現としてコンパイルして結果を変数に 代入することのできる形式へと変換します:
$reg = qr/foo+bar?/; # reg はコンパイル済み正規表現を保持する$reg は正規表現として使うことができます:
$x = "fooooba";
$x =~ $reg; # マッチングする; /foo+bar?/ と同様
$x =~ /$reg/; # 同じことを別の形式で$reg はより大きな正規表現の中で展開することもできます:
$x =~ /(abc)?$reg/; # これもマッチングするマッチング演算子を伴ったときのように正規表現クォートは qr!!, qr{}, qr~~ のような異なるデリミタを使うことができます。 シングルクォートを使ったデリミタ (qr'') は変数展開を抑止します。
コンパイル済み正規表現は、現れるたびにコンパイルする必要のない動的な マッチングを生成するのに便利です。 コンパイル済み正規表現を使って、ひとつのパターンを満足したらすぐに 次のパターンに進むような、パターンの並びを grep する grep_step を書けます。
% cat > grep_step
#!/usr/bin/perl
# grep_step - match <number> regexps, one after the other
# usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
$number = shift;
$regexp[$_] = shift foreach (0..$number-1);
@compiled = map qr/$_/, @regexp;
while ($line = <>) {
if ($line =~ /$compiled[0]/) {
print $line;
shift @compiled;
last unless @compiled;
}
}
^D
% grep_step 3 shift print last grep_step
$number = shift;
print $line;
last unless @compiled;コンパイル済み正規表現を配列 @compiled に格納することで、 再コンパイルすることなく正規表現を使うことができ、これにより 速度を犠牲にすることなく柔軟性を手に入れることができました。
バックトラッキングは、異なる正規表現を繰り返し試すよりも効果的です。 もしいくつかの正規表現があって、そのどれとマッチングしてもいい場合、 それらを選択肢の集合に結合できます。 もしこの正規表現が入力データなら、これは結合操作をプログラミングすることで 行えます。 このアイデアを simple_grep プログラムの拡張版 (複数のパターンにマッチングするプログラム)で利用することにします:
% cat > multi_grep
#!/usr/bin/perl
# multi_grep - match any of <number> regexps
# usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
$number = shift;
$regexp[$_] = shift foreach (0..$number-1);
$pattern = join '|', @regexp;
while ($line = <>) {
print $line if $line =~ /$pattern/;
}
^D
% multi_grep 2 shift for multi_grep
$number = shift;
$regexp[$_] = shift foreach (0..$number-1);入力を検査して、マッチング操作の左側に許される値として使うために パターンを構築することには好都合な場合もあります。 このいくらか奇妙な状況の例として、入力は与えられたコマンド動詞の集合の どれか一つにマッチングするもので、かつ、与えられた文字列がユニークで ある限りコマンド名を省略できる、と仮定します。 以下のプログラムは基本的なアルゴリズムを例示します。
% cat > keymatch
#!/usr/bin/perl
$kwds = 'copy compare list print';
while( $command = <> ){
$command =~ s/^\s+|\s+$//g; # trim leading and trailing spaces
if( ( @matches = $kwds =~ /\b$command\w*/g ) == 1 ){
print "command: '@matches'\n";
} elsif( @matches == 0 ){
print "no such command: '$command'\n";
} else {
print "not unique: '$command' (could be one of: @matches)\n";
}
}
^D
% keymatch
li
command: 'list'
co
not unique: 'co' (could be one of: copy compare)
printer
no such command: 'printer'入力をキーワードとマッチングしようとするのではなく、キーワードの 集合を結合したものを入力とマッチングします。 パターンマッチング操作 $kwds =~ /\b($command\w*)/g は 同時に複数のことを行います。 これは与えられたコマンドがキーワードの開始位置で始まることを確認します (\b)。 これは \w* を追加することによって短縮を許容します。 これはマッチングした数 (scalar @matches) と、実際にマッチングした キーワードを知らせます。 これ以上聞きたいこともないでしょう。
このセクションのはじめで、Perl の 拡張パターン(extended patterns)の 集合について述べると言いました。 以下に述べるのは、伝統的な正規表現構文を拡張して、パターンマッチングに おいて新しい強力なツールを提供するものです。 すでに、??, *?, +?, {n,m}?, {n,}? といった 最小マッチングの拡張について述べました。 後述する拡張のほとんどは (?char...) という形式で、char は 拡張の型を指定する文字です。
最初の拡張はコメント (?#text) です。 これは正規表現に、その意味を変更することなくコメントを埋め込みます。 コメントはテキストの中で閉じカッコ以外の任意のものを持てます。 例を挙げましょう
/(?# Match an integer:)[+-]?\d+/;このスタイルのコメントは、//x 修飾子を使ったときの自由形式の コメントにとって代わられています。
//i, //m, //s, //x のようなほとんどの修飾子(あるいはその 組み合わせ)は (?i), (?m), (?s), (?x) を使って正規表現に 埋め込むこともできます。 例を挙げましょう:
/(?i)yes/; # 大小文字の違いを無視して 'yes' にマッチング
/yes/i; # 同じこと
/(?x)( # 自由形式の整数にマッチングする正規表現
[+-]? # 省略可能な符号
\d+ # 数字の並びにマッチング
)
/x;埋め込み修飾子は通常の修飾子に比べて二つの利点があります。 埋め込み修飾子は正規表現のパターンの それぞれに 別々の修飾子を 与えることができます。 これは異なる修飾子を持った正規表現の配列にマッチングさせるのに有利です:
$pattern[0] = '(?i)doctor';
$pattern[1] = 'Johnson';
...
while (<>) {
foreach $patt (@pattern) {
print if /$patt/;
}
}二番目の利点は、埋め込み修飾子(正規表現全体を修正する //p を除きます) はそれが埋め込まれたグループの中にある正規表現にだけ影響するということです。 このため、グループ化を修飾子の影響を局所化するために使うことができます:
/Answer: ((?i)yes)/; # 'Answer: yes', 'Answer: YES' などにマッチング埋め込み修飾子は (?-i) のようにして任意の修飾子を無効にすることも できます。 修飾子は一つの式にまとめることもでき、たとえば (?s-i) は 単一行モードを有効にして大小文字の違いを無視ししないようにします。
埋め込みの修飾子は非捕捉グループ化にも追加できます。 (?i-m:regexp) は regexp に大小文字の違いを無視してマッチングし 複数行モードをオフにする非捕捉グループ化です。
本セクションでは先読み(lookahead)と戻り読み(後読み: lookbehind)の 表明について述べます。 まずはじめにちょっとした背景から。
Perlの正規表現では、ほとんどの正規表現要素はそれにマッチングしたときに文字列の 一部を「食い取り」(eat up)します。 たとえば、[abc}] という正規表現要素はそれにマッチングしたときに文字列の 文字一つを食い取ります; そして Perl はマッチングの後で文字列の次の位置の 文字へと移動します。 しかしながら、マッチングしたときに文字を食い取らない(が、文字位置は進める) 要素が存在します。 その例はアンカーとしてすでに登場しています。 ^ というアンカーは行の先頭にマッチングしますが文字を食い取ることはしません。 同様に語境界アンカー \b はたとえば単語を構成する文字で、次が単語を 構成する文字でない場所にマッチングしますが、文字を食い取ることはしません。 アンカーは「ゼロ幅の表明」(zero-width assertions) の実例です: 文字を消費しないのでゼロ幅で、文字列のなんらかの属性をテストするので 表明です。 正規表現のマッチングを森の中での歩行にたとえた文脈で言えば、大部分の 正規表現要素は移動を伴うものであるが、アンカーは足を止めて周囲を 確認するようなものです。 局所的な環境をチェックしたなら、進むことができます。 しかし局所的な環境が私たちを満足するものでなければ、私たちは 後戻りしなければなりません。
環境をチェックすることは道の上で先を見通したり、後ろを振り返ったり することです。 ^ は後ろを振り返って、文字が存在していないかどうかを確認します。 $ は先を見て、更に文字が続いていないかどうかを確認します。 \b は先や後ろを、そこにある文字がそれぞれに対して異なる 単語属性("word-ness")であるかどうかを確認します。
先読み表明や戻り読み表明はアンカーの考え方を一般化したものです。 先読み表明と戻り読み表明はゼロ幅の表明で、文字が テストしたいものであることを指定します。 先読み表明は (?=regexp) で表され、戻り読み表明は (?<=fixed-regexp) で表されます。 幾つか例を挙げましょう
$x = "I catch the housecat 'Tom-cat' with catnip";
$x =~ /cat(?=\s)/; # 'housecat'の'cat'にマッチング
@catwords = ($x =~ /(?<=\s)cat\w+/g); # マッチングする
# $catwords[0] = 'catch'
# $catwords[1] = 'catnip'
$x =~ /\bcat\b/; # 'Tom-cat'の'cat'にマッチング
$x =~ /(?<=\s)cat(?=\s)/; # マッチングしない; $xの中間に 'cat' はない(?=regexp) と (?<=regexp) の中にあるカッコが、これらがゼロ幅の 表明であるために捕捉を行わないことに注意してください。 したがって、二番目の正規表現では捕捉された部分文字列は 正規表現全体に対応するものになります。 先読み表明 (?=regexp) には任意の正規表現を使うことができますが、 戻り読み表明 (?<=fixed-regexp) は固定長の正規表現、たとえば 固定長の文字並びでのみ使うことができます。 このため、(?<=(ab|bc)) は大丈夫ですが (?<=(ab)*) は 使えません。 先読み表明と戻り読み表明の否定形はそれぞれ (?!regexp) と (?<!fixed-regexp) で表されます。 これらはその正規表現がマッチングしなかったときに真となります。
$x = "foobar";
$x =~ /foo(?!bar)/; # マッチングしない; 'bar' が 'foo' に続いている
$x =~ /foo(?!baz)/; # マッチングする; 'baz' は 'foo' に続いていない
$x =~ /(?<!\s)foo/; # マッチングする; \s は 'foo' の前にない\C は戻り読みでサポートされていません; なぜなら、\C の定義がすでに 当てにならないもので後ろに戻るときにはより一層当てにならないからです。
これは、空白で区切られた単語、数値、一つのダッシュを含む文字列を、その要素で split するという例です。 単に /\s+/ だけを使っても動作しません; なぜならダッシュの間、単語、 ダッシュには空白が不要だからです。 split のための追加の場所は前方参照と後方参照で構築されます:
$str = "one two - --6-8";
@toks = split / \s+ # a run of spaces
| (?<=\S) (?=-) # any non-space followed by '-'
| (?<=-) (?=\S) # a '-' followed by any non-space
/x, $str; # @toks = qw(one two - - - 6 - 8)独立部分式 (Independent subexpressions) はより大きな正規表現の中で 独立した機能を持った正規表現です。 つまり、より大きな正規表現がマッチングすることには関係なく、望む限りの大きな 文字列もしくは望む限りの小さな文字列にマッチングしたものを消費します。 独立部分式は (?>regexp) で表されます。 これの振る舞いを通常の正規表現を使って説明しましょう:
$x = "ab";
$x =~ /a*ab/; # マッチングするこれは明らかにマッチングしますが、しかし、マッチングのプロセスにおいて 部分式 a* は最初に a をつかみとります。 それを行うことによって、正規表現全体がマッチングすることを許さず、そのために バックトラッキングが起きて a* は a を戻して空文字列にマッチングします。 ここで、a* は正規表現の残りの部分のマッチングに依存してマッチングしました。
独立部分式を使うと対照的に:
$x =~ /(?>a*)ab/; # マッチングしない!この独立部分式 (?>a*) は正規表現の残りの部分を考慮しません; そのため、a を見つけたらそれをつかみとります。 そして残りの正規表現 ab はマッチングできません。 (?>a*) は独立しているので、バックトラッキングは行わず、独立部分式は a を戻すこともありません。 結果として正規表現全体のマッチングは失敗します。 同様の動作が、完全に独立した正規表現においても発生します:
$x = "ab";
$x =~ /a*/g; # マッチングする; 'a' を食い取る
$x =~ /\Gab/g; # マッチングしない; 'a' がないここで、//g と \G は「タッグチーム」を結成していて、一つの 正規表現から別の正規表現へと文字列を手渡ししています。 独立部分式を持った正規表現はこれと同じようにマッチングし、独立部分式に文字列を 手渡しして、それにマッチングした文字列を戻します。
バックトラッキングを阻止するという独立部分式の能力はとても便利です。 2 レベルの深さを持つカッコに囲まれたから出ない文字列にマッチングさせることを 考えてみましょう。 それは以下のような正規表現になります:
$x = "abc(de(fg)h"; # 対応の取れていないかっこ
$x =~ /\( ( [^()]+ | \([^()]*\) )+ \)/x;この正規表現は開きかっこ、選択肢にある一つか二つのコピー、そして 閉じかっこにマッチングします。 この選択肢は二分岐で、最初の選択肢は括弧のない部分文字列にマッチングする [^()]+ で、二番目の選択肢はかっこによって区切られた部分文字列に マッチングする \([^()]*\) です。 この正規表現の問題点は病理学的なものです: (a+|b)+ のように非決定的な 量指定子がネストしています。 Part 1 において、ネストした量指定子はマッチングに失敗するときには実行に 指数的な時間を要することについて言及しました。 これを防ぐために、不要なバックトラッキングを抑制することが必要となります。 これは内側の量指定子を独立部分式としてやることで行うことができます:
$x =~ /\( ( (?>[^()]+) | \([^()]*\) )+ \)/x;ここで、(?>[^()]+) は可能な限りマッチングしたものをつかみとって 保持することによって文字列の分割の退行を邪魔しています。 それからマッチングは即座に失敗することになります。
条件式 (conditional expression) は if-the-else の形式の文で、何らかの 条件に基づいてどちらのパターンをマッチングさせるかを選択できます。 条件式には二つのタイプがあります: (?(condition)yes-regexp) と (?(condition)yes-regexp|no-regexp) です。 (?(condition)yes-regexp) は Perl の 'if () {}' 文のようなものです。 もし condition が真であれば、yes-regexp がマッチングの対象となります。 condition が偽であった場合、yes-regexp はスキップされて、 Perl は次の正規表現要素へと進みます。 二番目の形式は Perl の 'if () {} else {}' 文のようなものです。 conditon が真であれば yes-regexp がマッチングの対象となり、偽であれば no-regexp がマッチングの対象となります。
condition はいくつかのの形式を取ることができます。 最初の形式は単純な整数をカッコでくくったもの (integer) です。 これは対応する後方参照 \integer が先行する正規表現の部分の中で マッチングしていれば真となります。 同じことは、捕捉グループに結び付けられた名前を使って、 (<name>) や ('name') のように書くことでもできます。 二番目の形式はゼロ幅の表明 (?...) で、先読み、戻り読み、もしくは コード表明 (code assertion 次のセクションで説明します)のいずれかです。 3番目の形式は、もし式が再帰 ((R)) の中で実行されるか、 数値 ((R1), (R2),...) か名前 ((R&name)) で参照される捕捉グループから 呼び出されていると真を返すというテストを提供します。
整数または名前形式の condition はより一層の融通性を伴って選択することを 可能にします; マッチングするかどうかは正規表現の先行する部分が マッチングするかどうかに依存します。 以下の例は "$x$x" や "$x$y$y$x" という形式の単語を検索します。
% simple_grep '^(\w+)(\w+)?(?(2)\g2\g1|\g1)$' /usr/dict/words
beriberi
coco
couscous
deed
...
toot
toto
tutu戻り読みの condition は後方参照といっしょで、マッチングの先行する部分が マッチングの後ろの部分に影響を及ぼします。 たとえば
/[ATGC]+(?(?<=AA)G|C)$/;これは AAG で終わるかその他の C とのコンビネーションのペアと なっている DNA シーケンスにマッチングします。 この形式は (?(?<=AA)G|C) であって、 (?((?<=AA))G|C) でないことに注意してください; 先読み、戻り読み、コードの表明に対しては条件部分を囲むカッコは 必要ありません。
同じ部分パターンを複数の箇所で使う正規表現もあります。 Perl 5.10 から、パターンのどこでも名前で呼び出せるようにするために、 パターンの一部で名前付き部分パターンを定義できるようになっています。 この定義グループのためのパターン文法は (?(DEFINE)(?<name>pattern)...) です。 名前付きパターンの挿入は (?&name) のように書きます。
以下の例では以前に説明した浮動小数点数のためのパターンを使った この機能を示しています。 複数回使われる 3 つの副パターンは、省略可能の符号、整数のための 数字並び、小数点です。 パターンの末尾の DEFINE グループはこれらの定義を含んでいます。 小数点のパターンは整数のパターンを再利用できる最初の位置であることに 注意してください。
/^ (?&osg)\ * ( (?&int)(?&dec)? | (?&dec) )
(?: [eE](?&osg)(?&int) )?
$
(?(DEFINE)
(?<osg>[-+]?) # optional sign
(?<int>\d++) # integer
(?<dec>\.(?&int)) # decimal fraction
)/x(Perl 5.10 から導入された)この機能は、Perl のパターンマッチングの力を 大きく拡張します。 パターン中の任意の位置の捕捉グループを (?group-ref) 定数で参照することで、 参照されたグループ内の パターン はグループ参照自身の代わりに 独立した副パターンとして使われます。 グループ参照は参照しているグループの 内側 に含まれる場合もあるので、 今までは再帰パーサが必要であった処理に対してパターンマッチングを 適用できるようになります。
この機能を説明するために、文字列が回文である場合にマッチングするパターンを 設計します。 (回文とは、空白、句読点、大文字小文字を無視したとき、 先頭から読んでも末尾から読んでも同じになる単語や文のことです。) まず、空文字列あるいは一つの単語文字からなる文字列を回文として 観測することから始めます。 さもなければ、回文とは先頭と末尾に同じ単語文字があって、その間に 回文があるものです。
/(?: (\w) (?...ここは回文...) \g{-1} | \w? )/x無視するべきものを削除するためにどちらかの側に \W* を追加して、すでに 完全なパターンを得ています:
my $pp = qr/^(\W* (?: (\w) (?1) \g{-1} | \w? ) \W*)$/ix;
for $s ( "saippuakauppias", "A man, a plan, a canal: Panama!" ){
print "'$s' is a palindrome\n" if $s =~ /$pp/;
}(?...) の中では絶対と相対の両方の後方参照が使えます。 パターン全体は (?R) または (?0) で再挿入できます。 グループに名前を付けたいなら、そのグループを再帰させるために (?&name) が 使えます。
通常、正規表現は Perl の式の一部です。 コード評価 (code evaluation) 式は任意の Perl のコードを正規表現の 一部として使うことができるようにします。 コード評価式は (?{code}) で表され、code は Perl の文である 文字列です。
この機能は実験的であると考えられており、予告なしに 変更されるかもしれないことを警告しておきます。
コード式はゼロ幅の表明で、その値は環境に依存したものです。 そこには二つの可能性があります: コード式が条件式の中で (?(condition)...) のように使われるかそうでないかです。 もしコード式が条件式に使われていれば、そのコードは評価された後その結果 (最後の文の結果)が真か偽かを決定するのに使われます。 コード式が条件式として使われていなければ、その表明は常に真であり その結果は特殊変数 $^R に格納されます。 変数 $^R は正規表現の後の部分のコード式で使うことができます。 以下に単純な例を挙げます:
$x = "abcdef";
$x =~ /abc(?{print "Hi Mom!";})def/; # マッチングする
# 'Hi Mom!' を主力
$x =~ /aaa(?{print "Hi Mom!";})def/; # マッチングしない
# 'Hi Mom!'は出力されない次の例に注目してください:
$x =~ /abc(?{print "Hi Mom!";})ddd/; # マッチングしない;
# 'Hi Mom!' は出力されない
# でもなぜ?ぱっと見て、出力されないとは思わなかったでしょう; なぜなら ddd は 明らかにターゲット文字列にマッチングするものではないからです。 しかし次の例を見ると:
$x =~ /abc(?{print "Hi Mom!";})[dD]dd/; # マッチングしない;
# しかし出力「される」ふーむ。 何が起きたのでしょう? 先のパターンが効果としては最後のものと (おとんど) 同じであることをあなたは 知っています; 文字クラスの中に閉じ込められた d はマッチングを 変えるものではありません。 では、なぜ最初のパターンは出力されないのに二番目のものは 出力されたのでしょう?
その答えは正規表現エンジンが行う最適化にあります。 最初のケースでは、 エンジンが見ているものは普通の古い文字(?{} 構造は別として) です。 パターンを実際に実行するよりも前にターゲット文字列が 'ddd' という 文字列を含んでいないことがわかるくらい賢いのです。 しかし二番目のケースでは、より複雑なパターンであると 思わせるようなトリックを使いました。 文字クラスを見て、エンジンはマッチングするかどうかは実際にパターンを 実行してみなければならないと判断し、その実行の最中にマッチングしないことが わかるよりも前にある print 文にヒットするのです。
エンジンがどのように最適化を行うかについては後にあるセクション "Pragmas and debugging" を参照してください。
?{} でもっと楽しいことが起きます:
$x =~ /(?{print "Hi Mom!";})/; # マッチングする
# 'Hi Mom!' を出力
$x =~ /(?{$c = 1;})(?{print "$c";})/; # マッチングする
# '1' を出力
$x =~ /(?{$c = 1;})(?{print "$^R";})/; # マッチングする
# '1' を出力このセクションのタイトルにある「ちょっとした魔法」というのは マッチングのために検索処理をしているときのバックトラックが 起きたときのことを言っています。 もしバックトラックがコード式をまたいで発生して、local によって その中に局所化された変数を使っていた場合、コード式による変数の変更は 巻き戻されます! したがって、グループの中にある文字の数を数えたい場合には
$x = "aaaa";
$count = 0; # 'a' のカウントを初期化する
$c = "bob"; # $c が上書きされているかを調べる
$x =~ /(?{local $c = 0;}) # カウントを初期化
( a # 'a' にマッチング
(?{local $c = $c + 1;}) # カウントをインクリメント
)* # これを任意回繰り返すが
aa # 最後に 'aa' にマッチング
(?{$count = $c;}) # ローカルの $c を $count にコピー
/x;
print "'a' count is $count, \$c variable is '$c'\n";これは
'a' count is 2, $c variable is 'bob'もし (?{local $c = $c + 1;}) を (?{$c = $c + 1;}) にすると、 バックトラックによって変数の変更は 巻き戻されず、結果は 以下のようになります
'a' count is 4, $c variable is 'bob'局所化された変数の変更だけが巻き戻されるということに注意してください。 コード式の別の副作用は恒久的です。 したがって
$x = "aaaa";
$x =~ /(a(?{print "Yow\n";}))*aa/;これは以下の結果となります
Yow
Yow
Yow
Yow結果である $^R は自動的に局所化されるので、バックトラックが 行われても適切に振舞います。
以下の例は、条件にコード式を使って英語の 'the' か ドイツ語の 'der|die|das' にマッチングさせるものです:
$lang = 'DE'; # ドイツ語を使う
...
$text = "das";
print "matched\n"
if $text =~ /(?(?{
$lang eq 'EN'; # 言語は英語か?
})
the | # そうなら 'the' にマッチング
(der|die|das) # そうでないなら 'der|die|das' にマッチング
)
/xi;ここでの構文が (?((?{...}))yes-regexp|no-regexp) ではなく (?(?{...})yes-regexp|no-regexp) であることに注意してください。 言い換えれば、コード式の場合には条件を囲む余計なかっこは いらないということです。
コード式を、パターン中にリテラルに書くのではなく、展開された変数の中に 入れると、Perl はあなたを驚かせるかもしれません:
$bar = 5;
$pat = '(?{ 1 })';
/foo(?{ $bar })bar/; # コンパイル ok; $barは展開されない
/foo(?{ 1 })$bar/; # コンパイルエラー!
/foo${pat}bar/; # コンパイルエラー!
$pat = qr/(?{ $foo = 1 })/; # コード正規表現をプリコンパイル
/foo${pat}bar/; # コンパイル okもし正規表現がコード式に展開される変数を持っているなら、Perl はその正規表現を エラーとします。 しかしながら、コード式が変数にプリコンパイルされていた場合には、 変数展開は ok です。 疑問は、これがなぜエラーになるかです。
その理由は、変数展開とコード式を組み合わせることでセキュリティ上の リスクが発生するからです。 この組み合わせは検索エンジンを記述する多くのプログラマがしばしば ユーザーからの入力を取り、それをダイレクトに変数に押し込むから 危険なのです。
$regexp = <>; # ユーザーが提供する正規表現を読み込む
$chomp $regexp; # 改行があれば取り除く
$text =~ /$regexp/; # $text から $regexp を探し出すもし変数 $regexp がコード式を含んでいたら、ユーザーは任意の Perl コードを実行することが可能となります。 たとえば、一部の不心得者が system('rm -rf *'); を検索したら、 あなたのファイルを消すことになります。 このため、変数展開とコード式の組み合わせは正規表現を 汚染する ものと みなされます。 そのためデフォルトでは、同じ正規表現の中で変数展開とコード式の両方を 使うことを許していないのです。 もし悪意あるユーザーを考慮しないのであれば、use re 'eval'を 実行することによってセキュリティチェックをバイパスすることが可能です:
use re 'eval'; # 注意を無視する
$bar = 5;
$pat = '(?{ 1 })';
/foo${pat}bar/; # コンパイル okもう一つのコード式は パターンコード式(pattern code expression) です。 パターンコード式は通常のコード式に似ていますが、コードの評価結果が 正規表現として扱われ、即座にマッチングに使われる点が異なります。 単純な例を挙げましょう
$length = 5;
$char = 'a';
$x = 'aaaaabb';
$x =~ /(??{$char x $length})/x; # マッチングする; 5個の 'a'がある最後の例はコード式とパターンコード式の両方を含んだものです。 これは 2 進文字列 1101010010001... に、1 の フィボナッチ空白 0,1,1,2,3,5,... があるかを見つけ出します:
$x = "1101010010001000001";
$z0 = ''; $z1 = '0'; # initial conditions
print "It is a Fibonacci sequence\n"
if $x =~ /^1 # match an initial '1'
(?:
((??{ $z0 })) # match some '0'
1 # and then a '1'
(?{ $z0 = $z1; $z1 .= $^N; })
)+ # repeat as needed
$ # that is all there is
/x;
printf "Largest sequence matched was %d\n", length($z1)-length($z0);$^N は最後に完了した捕捉グループでマッチングしたものがセットされることを 忘れないでください。 これは以下を表示します
It is a Fibonacci sequence
Largest sequence matched was 5ほら! これを、ありふれた正規表現パッケージで試してみてください…
$z0 と $z1 という変数は正規表現がコンパイルされたときには、 コード式の外側で通常の変数が使われたときのような置換は行われないということに 注意してください。 代わりに、コードブロック全体は、リテラルな正規表現が含まれたコードが コンパイルされるのと同時に perl によって perl コードとしてパースされます。
//x 修飾子がない正規表現は
/^1(?:((??{ $z0 }))1(?{ $z0 = $z1; $z1 .= $^N; }))+$/のようになり、それでもコード部分には空白を入れることが可能です。 それでもなお、コード式と条件式を使ったときには、正規表現の拡張された形式は 正規表現を生成してデバッグする必要があるでしょう。
Perl 5.10 から、正規表現エンジンに直接影響を与えることと、監視技術を 提供することによって、バックトラッキング処理を詳細に制御するための 制御同士が導入されました。 この分野の全ての機能は実験的であり、Perl の将来のバージョンでは 変更されたり削除されたりする可能性があります; 興味を持った読者は、詳細な記述については "Special Backtracking Control Verbs" in perlre を参照してください。
以下は、制御動詞 (*FAIL) ((*F) と省略できます) を例示した 単なる一つの例です。 これが正規表現に挿入されると、パターンと文字列で不一致があったかのように、 失敗を引き起こします。 正規表現の処理は「通常の」失敗の後のように続行され、 例えば、文字列内の次の位置や、他の選択肢が試行されます。 マッチングの失敗は捕捉グループに保存されたり結果を生成したりしないので、 これは組み込みコードと組み合わせて使う必要があるでしょう。
%count = ();
"supercalifragilisticexpialidocious" =~
/([aeiou])(?{ $count{$1}++; })(*FAIL)/i;
printf "%3d '%s'\n", $count{$_}, $_ for (sort keys %count);パターンは文字のサブクラスにマッチングするクラスで始まります。 どこでマッチングしても、$count{'a'}++; のような分が実行され、 その文字の缶多をインクリメントします。 それから (*FAIL) がその名前の通りのことを行い、正規表現エンジンは 本に従って続行します: 文字列の末尾に到達するまで、次の母音を探す前の 位置まで進みます。 従って、マッチングしたかどうかには違いはなく、正規表現エンジンは文字列全体が 検査されるまで続行します。 (注意することは、以下のような代替手段は
$count{lc($_)}++ for split('', "supercalifragilisticexpialidocious");
printf "%3d '%s'\n", $count2{$_}, $_ for ( qw{ a e i o u } );かなり遅いということです。)
デバッグに関して、Perlで正規表現を制御したりデバッグするために幾つかの プラグマがあります。 前のセクションですでに use re 'eval'; という正規表現の中で 変数展開とコード式を共存させることを許可するプラグマが登場しています。 他のプラグマには以下のものがあります
use re 'taint';
$tainted = <>;
@parts = ($tainted =~ /(\w+)\s+(\w+)/; # @parts は汚染されているtaint プラグマは汚染された変数に対するマッチングによる部分文字列を 同様に汚染されたものにするというものです。 これは通常の場合では行われず、正規表現はしばしば汚染された変数から 安全な情報を取り出すのに使われています。 安全な情報を取り出すのではないとき taint を使いますが、他の処理を 行います。 プラグマ taint と eval は両方ともレキシカルスコープで、その プラグマを囲むブロックの最後までしか影響が及びません。
use re '/m'; # or any other flags
$multiline_string =~ /^foo/; # /m is implied(Perl 5.14 で導入された) re '/flags' プラグマは、レキシカルスコープの 終わりまで、与えられた正規表現フラグを有効にします。 さらなる詳細は "'/flags' mode" in re を参照してください。
use re 'debug';
/^(.*)$/s; # デバッグ情報を出力する
use re 'debugcolor';
/^(.*)$/s; # デバッグ情報を色つきで出力するdebug プラグマと debugcolor プラグマは正規表現のコンパイルと 実行に関する詳細なデバッグ情報を提供します。 debugcolor は debug と同じですが、デバッグ情報を色付きで (termcap のカラーシーケンスを出力することのできる)ターミナルに出力します。 以下は出力の例です:
% perl -e 'use re "debug"; "abc" =~ /a*b+c/;'
Compiling REx 'a*b+c'
size 9 first at 1
1: STAR(4)
2: EXACT <a>(0)
4: PLUS(7)
5: EXACT <b>(0)
7: EXACT <c>(9)
9: END(0)
floating 'bc' at 0..2147483647 (checking floating) minlen 2
Guessing start of match, REx 'a*b+c' against 'abc'...
Found floating substr 'bc' at offset 1...
Guessed: match at offset 0
Matching REx 'a*b+c' against 'abc'
Setting an EVAL scope, savestack=3
0 <> <abc> | 1: STAR
EXACT <a> can match 1 times out of 32767...
Setting an EVAL scope, savestack=3
1 <a> <bc> | 4: PLUS
EXACT <b> can match 1 times out of 32767...
Setting an EVAL scope, savestack=3
2 <ab> <c> | 7: EXACT <c>
3 <abc> <> | 9: END
Match successful!
Freeing REx: 'a*b+c'このチュートリアルを読み進めてきたのであれば、デバッグ出力の異なる部分が あなたに情報を伝えているのではないかと思うかも知れません。 最初の部分
Compiling REx 'a*b+c'
size 9 first at 1
1: STAR(4)
2: EXACT <a>(0)
4: PLUS(7)
5: EXACT <b>(0)
7: EXACT <c>(9)
9: END(0)はコンパイルステージのものです。 STAR(4) は star のついたオブジェクト、この場合は 'a' があって、 それがマッチングした場合には line 4、つまり PLUS(7) へ 移動することを意味しています。 真中の数行はマッチング前の幾つかの発見的手法(heuristics)と 最適化が行われたことを示しています:
floating 'bc' at 0..2147483647 (checking floating) minlen 2
Guessing start of match, REx 'a*b+c' against 'abc'...
Found floating substr 'bc' at offset 1...
Guessed: match at offset 0その後でマッチングが実行され、残りの行はそのプロセスを説明しています:
Matching REx 'a*b+c' against 'abc'
Setting an EVAL scope, savestack=3
0 <> <abc> | 1: STAR
EXACT <a> can match 1 times out of 32767...
Setting an EVAL scope, savestack=3
1 <a> <bc> | 4: PLUS
EXACT <b> can match 1 times out of 32767...
Setting an EVAL scope, savestack=3
2 <ab> <c> | 7: EXACT <c>
3 <abc> <> | 9: END
Match successful!
Freeing REx: 'a*b+c'各ステップは n <x> <y> という形式で、<x> は マッチングした文字列の部分で、<y> はまだマッチングしていない部分です。 | 1: STAR は Perl が先のコンパイルリストの中の行番号 1 の 位置にあることを示しています。 詳細は "Debugging regular expressions" in perldebguts を参照してください。
これとは別の正規表現のデバッグ手法は正規表現の中に print 文を 埋め込むことです。 以下の例は選択肢の中のバックトラッキングを逐一数えるものです:
"that this" =~ m@(?{print "Start at position ", pos, "\n";})
t(?{print "t1\n";})
h(?{print "h1\n";})
i(?{print "i1\n";})
s(?{print "s1\n";})
|
t(?{print "t2\n";})
h(?{print "h2\n";})
a(?{print "a2\n";})
t(?{print "t2\n";})
(?{print "Done at position ", pos, "\n";})
@x;以下の出力を行います
Start at position 0
t1
h1
t2
h2
a2
t2
Done at position 4コード式、条件式、独立式は 実験的 なものです。 商用のコードでは使わないようにしましょう。 今のところは。
本ドキュメントはチュートリアルです。 Perl の正規表現に関する完全な説明は正規表現に関する リファレンスページである perlre を参照してください。
マッチング m// や置換 s/// に関するより詳細な情報は "Regexp Quote-Like Operators" in perlop を参照してください。 split 操作に関する情報は "split" in perlfunc を参照してください。
正規表現に関するすばらしい情報源として Jeffrey Friedl による書籍 Mastering Regular Expressions があります(O'Reillyから出版; ISBN 1556592-257-3)(日本語版は 「詳説 正規表現」ISBN4-87311-130-7 (第二版のもの))。
Copyright (c) 2000 Mark Kvale All rights reserved.
This document may be distributed under the same terms as Perl itself.
The inspiration for the stop codon DNA example came from the ZIP code example in chapter 7 of Mastering Regular Expressions.
The author would like to thank Jeff Pinyan, Andrew Johnson, Peter Haworth, Ronald J Kimball, and Joe Smith for all their helpful comments.