perlobj - Perl オブジェクトのリファレンス
この文書は、Perl のオブジェクト指向機能のリファレンスを提供します。 Perl でのオブジェクト指向プログラミングの概要を探しているなら、 perlootut を参照してください。
Perl のオブジェクトを理解するためには、まず Perl のリファレンスを 理解する必要があります。 詳しくは perlreftut を参照してください。
この文書は Perl のオブジェクト指向 (OO) 機能の全てを一から記述しています。 単に自分自身でオブジェクト指向のコードを書く方法を探しているなら、 おそらく CPAN から perlootut に記述されているオブジェクトシステムの 一つを使うことによってよりよく扱えるでしょう。
自分自身のオブジェクトシステムの書き方を探していたり、 一からオブジェクトを実装しているコードを保守する必要があるなら、 この文書はどうやって Perl がオブジェクト指向を行っているかを正確に 理解する助けになるでしょう。
オブジェクト指向 Perl を定義するいくつかの基本的な原則があります:
オブジェクトは単に、どのクラスに属するかを知っているデータ構造です。
クラスは単にパッケージです。 クラスはオブジェクトを操作することを想定したメソッドを提供します。
メソッドは単に、最初の引数としてオブジェクト (またはクラスメソッドの場合は パッケージ名) を想定するサブルーチンです。
それぞれの原則を深く見てみましょう。
オブジェクト指向に対応しているその他の多くの言語と違って、 Perl はオブジェクトを構築するための特別な文法を提供していません。 オブジェクトは、特定のクラスと明示的に関連付けられている 単なる Perl データ構造(ハッシュ、配列、スカラ、ファイルハンドルなど)です。
明示的な関連付けは組み込みの bless 関数によって作られます; これは典型的にはクラスの コンストラクタ サブルーチンの中で使われます。
以下は単純なコンストラクタです:
package File;
sub new {
my $class = shift;
return bless {}, $class;
}new という名前は特別ではありません。 コンストラクタに他の名前を付けることも出来ます:
package File;
sub load {
my $class = shift;
return bless {}, $class;
}OO モジュールのモダンな慣習は、コンストラクタの名前として 常に new を使うというものですが、そうする必要性はありません。 データ構造をクラスに bless するどんなサブルーチンも Perl での 正当なコンストラクタです。
前述の例で、{} というコードは、空の無名ハッシュへのリファレンスを 作ります。 それから bless 変数はこのリファレンスを取り、ハッシュを $class のクラスと関連付けます。 最も単純な場合では、$class 変数は "File" という文字列を含んでいます。
また、オブジェクトとして bless するデータ構造へのリファレンスを補完する 変数を使うことも出来ます:
sub new {
my $class = shift;
my $self = {};
bless $self, $class;
return $self;
}$self で参照されているハッシュを bless すれば、 それに含まれるメソッドを呼び出し始められます。 オブジェクトの初期化を独自の分離されたメソッドで行いたい場合に これは有用です:
sub new {
my $class = shift;
my $self = {};
bless $self, $class;
$self->_initialize();
return $self;
}オブジェクトはハッシュでもあるので、これをハッシュとして扱うことが出来、 オブジェクトに関連付けられているデータを保管するのに使えます。 典型的には、クラス内のコードはハッシュをアクセス可能なデータ構造として 扱い、クラスの外側のコードは常にオブジェクトを不透明なものとして 扱うべきです。 これは カプセル化 と呼ばれます。 カプセル化とは、オブジェクトのユーザーはそれがどのように実装されているかを 知る必要がないということです。 ユーザーは単にオブジェクトの文書化されたメソッドを呼び出します。
しかし、(その他の OO 言語のほとんどと違って) Perl はなんらかの方法で カプセル化を保証したり強制したりしません。 もしあなたがオブジェクトを本当に不透明に する ことを望むなら、 あなた自身でそうなるように準備する必要があります。 これをするには、"Inside-Out objects"" in " や CPAN のモジュールを使うことを 含めて様々な方法があります。
私たちが何かを bless するとき、 私たちはそのものへのリファレンスを含んでいる変数を bless しているのではなく、 変数に保管されているリファレンスを bless しているのでもありません。 私たちは変数が参照している何か(時々 参照先 (referent) として知られます) を bless しています。 これはこのコードで最も良く表されています:
use Scalar::Util 'blessed';
my $foo = {};
my $bar = $foo;
bless $foo, 'Class';
print blessed( $bar ) // 'not blessed'; # prints "Class"
$bar = "some other value";
print blessed( $bar ) // 'not blessed'; # prints "not blessed"変数に対して bless を呼び出すと、実際には変数が参照している 基となるデータ構造を bless しています。 リファレンス自身や、リファレンスを保管している変数を bless しているのでは ありません。 これが、2 番目の blessed( $bar ) が偽を返す理由です。 この時点では $bar はもはやオブジェクトへのリファレンスを 保管していません。
時々古い本や文書で「リファレンスを bless する」という記述や、 オブジェクトのことを「bless されたリファレンス」と説明しているのを 見るかも知れませんが、これは不正確です。 bless されたリファレンスがオブジェクトなのではありません; リファレンスが参照しているもの (つまり参照先) です。
Perl はクラス定義のための特別な文法を提供しません。 パッケージは変数とサブルーチンを含む単なる名前空間です。 クラスとの唯一の違いは、サブルーチンはその最初の引数に オブジェクトへのリファレンスかクラス名を想定すると言うことです。 これは純粋に規約の問題なので、一つのクラスにメソッドと、オブジェクトや クラスを操作 しない サブルーチンの両方を含むことも出来ます。
各パッケージは @ISA と呼ばれる特別な配列を持ちます。 @ISA 配列は (もしあれば) そのクラスの親クラスの一覧からなります。 この配列は、後述する、Perl がメソッド解決をするときにチェックされます。
パッケージからのメソッド呼び出しは、もちろん それを読み込まなければならないということなので、 しばしばモジュールを読み込んでそれを同時に @ISA に追加したいでしょう。 parent を使って 1 ステップでそうできます。 (古いコードでは base プラグマに遭遇するかもしれません; これは最近では同様に非推奨の fields プラグマと共に動作するのでない限り 非推奨です。)
しかし、親クラスが設定されると、そのパッケージの @ISA 変数は それらの親のリストになります。 これは単純にスカラのリストで、それぞれはパッケージ名に対応する 文字列です。
全てのクラスは暗黙に UNIVERSAL クラスから継承されます。 UNIVERSAL クラスは Perl コアによって実装されていて、 isa(), can(), and VERSION() のようないくつかのデフォルトメソッドを 提供します。 UNIVERSAL クラスは 決して パッケージの @ISA 変数に表れません。
Perl は組み込み機能としてメソッド継承 のみ を提供します。 属性継承は実装されるクラスに残されています。 詳しくは "Writing Accessors" 節を参照してください。
Perl はメソッドを定義するための特別な文法を提供しません。 メソッドは単に通常のサブルーチンで、sub によって宣言されます。 メソッドを特別にしているのは、それが最初の引数として オブジェクトかクラス名を受け取ることを想定していると言うことです。
Perl には -> 演算子というメソッド起動のための特別な文法が あります。 後にこれに関する詳細を取り上げます。
あなたの書くほとんどのメソッドはオブジェクトを操作することを想定します:
sub save {
my $self = shift;
open my $fh, '>', $self->path() or die $!;
print {$fh} $self->data() or die $!;
close $fh or die $!;
}オブジェクトのメソッドの呼び出しは $object->method のように書けます。
メソッド起動 (つまり矢印) 演算子の左側はオブジェクト(またはメソッド名)で、 右側はメソッド名です。
my $pod = File->new( 'perlobj.pod', $data );
$pod->save();-> 文法は、リファレンスをデリファレンスするためにも使われます。 これは同じ演算子のように見えますが、これらは二つの異なった処理です。
メソッドを呼び出すとき、矢印の左側のものがメソッドの最初の引数として 渡されます。 つまり、Critter->new() を呼び出すと、 new() メソッドは最初の引数として文字列 "Critter" を受け取ります。 $fred->speak() を呼び出すと、 $fred 変数が speak() の最初の引数として渡されます。
他の Perl のサブルーチンと同様、@_ で渡される全ての引数は 元の引数への別名です。 これにはオブジェクト自身も含まれます。 $_[0] に直接代入すると、オブジェクトへのリファレンスを 保持している変数の内容を変更します。 あなたが何をしているのかを正確に分かっていない限り、 これをしないことを勧めます。
Perl は、矢印の左側を見ることで、メソッドがどのパッケージにあるかを知ります。 左側がパッケージ名なら、そのパッケージのメソッドを探します。 左側がオブジェクトなら、Perl はオブジェクトに bless されている パッケージのメソッドを探します。
左側がパッケージ名でもオブジェクトでもない場合、メソッド呼び出しは エラーになりますが、さらなるニュアンスについては "Method Call Variations" の説を参照してください。
特別な @ISA 配列と parent プラグマについては既に話しました。
あるクラスが他のクラスを継承すると、親クラスで定義されているどのメソッドも 子クラスで利用可能です。 あるオブジェクトで自分自身のクラスで定義されていないメソッドを 呼び出そうとすると、Perl は親クラスにあるメソッドも探します。
package File::MP3;
use parent 'File'; # sets @File::MP3::ISA = ('File');
my $mp3 = File::MP3->new( 'Andvari.mp3', $data );
$mp3->save();File::MP3 クラスに save() メソッドを定義していないので、 Perl は save() メソッドを見つけるために File::MP3 クラスの 親クラスを見ます。 Perl が継承階層のどこにも save() メソッドを見つけられないと、 die します。
この場合、File クラスの save() メソッドを見つけます。 この場合、メソッドは File クラスで見つかったとしても、 save() に渡されるオブジェクトはやはり File::MP3 であることに 注意してください。
子クラスのメソッドで親クラスのメソッドをオーバーライドできます。 そうしたとき、SUPER 疑似クラスで親クラスのメソッドを呼び出すことも 出来ます。
sub save {
my $self = shift;
say 'Prepare to rock';
$self->SUPER::save();
}SUPER 修飾子はメソッド呼び出しで のみ 使えます。 通常のサブルーチン呼び出しやクラスメソッドでは使えません:
SUPER::save($thing); # FAIL: looks for save() sub in package SUPER
SUPER->save($thing); # FAIL: looks for save() method in class
# SUPER
$thing->SUPER::save(); # Okay: looks for save() method in parent
# classesSUPER 疑似クラスは、呼び出しが行われたパッケージから解決されます。 これはオブジェクトのクラスを元にして解決 されません 。 これは重要です; なぜならこれにより 深い継承階層でそれぞれ異なったレベルにあるメソッドが それぞれの親メソッドを正しく呼び出せるようになるからです。
package A;
sub new {
return bless {}, shift;
}
sub speak {
my $self = shift;
say 'A';
}
package B;
use parent -norequire, 'A';
sub speak {
my $self = shift;
$self->SUPER::speak();
say 'B';
}
package C;
use parent -norequire, 'B';
sub speak {
my $self = shift;
$self->SUPER::speak();
say 'C';
}
my $c = C->new();
$c->speak();この例では、次のような出力になります:
A
B
Cこれはどのように SUPER が解決されるかを図示します。 たとえオブジェクトが C クラスに bless されていても、 B クラスの speak() メソッドはまだ SUPER::speak() を呼び出して、正しく B (つまりメソッド呼び出しされた クラス)の親クラスを見ることを想定します; C (つまりオブジェクトが属するクラス) の親クラスではありません。
このパッケージを基にした解決が問題になる稀な場合があります。 サブルーチンをあるパッケージから他にコピーすると、 SUPER の解決は元のパッケージを基にして行われます。
多重継承はしばしば設計上の問題を表しますが、しかしあなたが求めるなら、 Perl は常にあなた自身がぶら下がるのに十分なロープを与えます。
多重継承を宣言するには、 単に複数のクラス名を use parent に渡す必要があります:
package MultiChild;
use parent 'Parent1', 'Parent2';メソッド解決順序は多重継承の場合にのみ問題になります。 単一継承の場合は、Perl はメソッドを見つけるために単純に継承チェーンを 探します:
Grandparent
|
Parent
|
ChildChild オブジェクトのメソッドを呼び出して、そのメソッドが Child クラスに定義されていない場合、 Perl はParent クラスのメソッドを探し、 それからもし必要なら Grandparent クラスを探します。
Perl がこれらのクラスのどこからもこのメソッドを見つけられない場合、 エラーメッセージと共に die します。
クラスが複数の親を持つとき、メソッド検索順序はより複雑になります。
デフォルトでは、Perl はメソッドに対して深さ優先左から右探索を行います。 つまり、@ISA 配列の最初の親から始め、それからその全ての親、祖父母、 というように探索します。 メソッドを見つけることに失敗すると、元のクラスの @ISA 配列の 次の親に行き、そこから探索します。
SharedGreatGrandParent
/ \
PaternalGrandparent MaternalGrandparent
\ /
Father Mother
\ /
Child従って、前述した図の場合、Perl は Child, Father, PaternalGrandparent, SharedGreatGrandParent, Mother そして最後に MaternalGrandparent を探索します。 これは SharedGreatGrandParent クラスを、その全ての派生クラスを チェックする (つまり Mother と MaternalGrandparent を試す) 前に 見るので、問題があるかも知れません。
mro プラグマで異なったメソッド解決順序を使うようにすることができます。
package Child;
use mro 'c3';
use parent 'Father', 'Mother';このプラグマは "C3" 解決順序に切り替えます。 簡単に言えば、"C3" 順序は 共有親クラスが子クラスより先に探索されないことを保証するので、 Perl は次の順で探索するようになります: Child, Father, PaternalGrandparent, Mother MaternalGrandparent そして最後に SharedGreatGrandParent。 しかし、これは「幅優先」探索ではないことに注意してください: (共通の祖先を除く) 全ての Father の祖先は、 Mother の祖先より前に探索されます。
C3 順序はまた、next 疑似クラスで兄弟クラスのメソッドを 呼び出せるようにします。 この機能に関するさらなる詳細については mro 文書を参照してください。
Perl がメソッドを探すとき、結果をキャッシュするので、 そのメソッドを将来呼び出しても再び探す必要はありません。 クラスの親クラスが変更されたり、クラスにサブルーチンが追加されると、 そのクラスのキャッシュは無効化されます。
mro プラグマはメソッドキャッシュを直接操作するための いくつかの関数を提供します。
前述したように、Perl はコンストラクタのための特別な文法を提供しません。 つまり、クラスは自身のコンストラクタを実装しなければなりません。 コンストラクタは新しいオブジェクトへのリファレンスを返す単なる クラスメソッドです。
コンストラクタはまた、オブジェクトを定義するための追加の引数を受け取れます。 以前に使った File クラスの実際のコンストラクタを書いてみましょう:
package File;
sub new {
my $class = shift;
my ( $path, $data ) = @_;
my $self = bless {
path => $path,
data => $data,
}, $class;
return $self;
}ここで見られるように、パスとファイルデータをオブジェクト自身に 保管しています。 水面下では、このオブジェクトはまだ単なるハッシュであることを 忘れないでください。 後で、このデータを操作するためのアクセサを書きます。
この File::MP3 クラスのために、与えられたパスが ".mp3" で終わっているかを チェックできます:
package File::MP3;
sub new {
my $class = shift;
my ( $path, $data ) = @_;
die "You cannot create a File::MP3 without an mp3 extension\n"
unless $path =~ /\.mp3\z/;
return $class->SUPER::new(@_);
}このコンストラクタは親クラスに実際のオブジェクト構築を行わせます。
属性は特定のオブジェクトに所属するデータ片です。 ほとんどのオブジェクト指向言語と異なり、Perl は属性の宣言や操作に 対応する特別な文法を提供しません。
属性はしばしばオブジェクト自身に保管されます。 例えば、オブジェクトが無名ハッシュなら、属性名をキーとして使って そのハッシュに属性値を保管できます。
これらのハッシュキーをクラスの外側から直接参照することは可能ですが、 全ての属性へのアクセスをアクセサメソッドで包むのがベストプラクティスと 考えられています。
これにはいくつかの利点があります。 アクセサは、後に元の API を保存したままオブジェクトの実装を 変更するのをより簡単にします。
アクセサは属性アクセスに関する追加のコードを追加できるようにします。 例えば、コンストラクタで設定されない属性のデフォルトを適用したり、 属性の新しい値が受け入れられるかの検証をしたり出来ます。
最後に、アクセサを使うと継承が遙かに簡単になります。 サブクラスはアクセサを使うことで、親クラスが内部でどのように 実装されているかを知る必要がなくなります。
コンストラクタと同様、Perl は特別なアクセサ宣言文法を持たないので、 クラスは明示的に書かれたアクセサメソッドを提供しなければなりません。 アクセサには 2 種類あります; 読み込み専用と読み書き用です。
単純な読み込み専用アクセサは単純に単一の属性の値を取得します:
sub path {
my $self = shift;
return $self->{path};
}読み書きアクセサは、呼び出し側が取得と共に値の設定もできるようにします:
sub path {
my $self = shift;
if (@_) {
$self->{path} = shift;
}
return $self->{path};
}このコンストラクタとアクセサはあまり賢くありません。 $path が定義されているかをチェックしませんし、 $path が有効なファイルシステムパスかをチェックしません。
これらのチェックを手で書くのはすぐに退屈になります。 たくさんのアクセサを手で書くのもとても退屈です。 より安全でより簡潔なコードを書くことを助けるための、 perlootut で推奨されているモジュールを含む多くのモジュールが CPAN にあります。
Perl には $object->method() という使用法以外にもメソッドを呼び出す 方法がいくつかあるのでそれを見ていきます。
Perl はメソッドをその完全修飾名(パッケージ名とメソッド名)を使って 呼び出すことを許します:
my $mp3 = File::MP3->new( 'Regin.mp3', $data );
$mp3->File::save();File::save のような完全修飾メソッド名を使った場合、 save メソッドのためのメソッド解決探索は File クラスから始め、File::MP3 クラスが定義しているかも知れない save メソッドは飛ばされます。 必要があれば File クラスの親クラスは探索されます。
この機能は祖先クラスから継承されたメソッドを明示的に呼ぶために 使われるのがもっとも一般的ですが、それに限定する技術的な制限はありません:
my $obj = Tree->new();
$obj->Dog::bark();この呼び出しは、たとえ二つのクラスが完全に無関係でも、 Tree クラスのオブジェクトで Dog クラスの bark メソッドを呼び出します。 これはとても注意して使ってください。
前述した SUPER 疑似クラスは完全修飾名でのメソッド呼び出しと 同じ ではありません 。 詳しくは前述した "Inheritance" の節を参照してください。
Perl は文字列を含むスカラ変数をメソッド名として使うことを許しています:
my $file = File->new( $path, $data );
my $method = 'save';
$file->$method();これは正確に $file->save() 呼び出しと同様です。 これは動的コードを書くのにとても有用です。 例えば、他のメソッドの引数として呼び出されるメソッド名を渡せるようになります。
Perl は文字列を含むスカラをクラス名として使うことを許しています:
my $class = 'File';
my $file = $class->new( $path, $data );再び、これによりとても動的なコードが書けます。
サブルーチンリファレンスをメソッドとして使うことも出来ます:
my $sub = sub {
my $self = shift;
$self->save();
};
$file->$sub();これは $sub->($file) と書くのと正確に等価です。 世の中ではこの慣用句を can の呼び出しと結びつけられているのを 見ることがあるでしょう:
if ( my $meth = $object->can('foo') ) {
$object->$meth();
}Perl はまた、メソッド呼び出しの中でデリファレンスされたスカラリファレンスを 使うことを許しています。 これは分かりにくいので、コードを見てください:
$file->${ \'save' };
$file->${ returns_scalar_ref() };
$file->${ \( returns_scalar() ) };
$file->${ returns_ref_to_sub_ref() };これは、デリファレンスが文字列 または サブルーチンリファレンスを 生成するときに動作します。
水面下では、Perl のファイルハンドルは IO::Handle または IO::File クラスのインスタンスです。 一度ファイルハンドルを開くと、そのメソッドを呼び出せます。 さらに、STDIN, STDOUT, STDERR ファイルハンドルのメソッドを 呼び出せます。
open my $fh, '>', 'path/to/file';
$fh->autoflush();
$fh->print('content');
STDOUT->autoflush();Perl はパッケージ名とサブルーチン名に裸の単語を使うことを許しているので、 時々裸の単語の意味を誤って解釈します。 例えば、Class->new() という構文は、 'Class'->new() または Class()->new() のどちらでも解釈できます。 英語では、2 番目の解釈は「Class() という名前のサブルーチンを呼び出し、 それから Class() の返り値のメソッドとして new() を呼び出す」と読めます。 現在の名前空間に Class() という名前のサブルーチンがある場合、 Perl は常に Class->new() を 2 番目の選択肢のように解釈します: Class() から返されたオブジェクトの new() を呼び出します。
二つの方法で最初の解釈 (つまり "Class" というクラスのメソッド呼び出し) を Perl に強制できます。 まず、:: をクラス名に追加できます:
Class::->new()Perl は常にこれをメソッド呼び出しとして解釈します。
あるいは、クラス名をクォートできます:
'Class'->new()もちろん、クラス名がスカラであれば Perl は同様に正しいことを行います:
my $class = 'Class';
$class->new();ファイルハンドルの場合を除いて、この文法の使用は非推奨です; Perl インタプリタを混乱させることがあるからです。 さらなる詳細については以降を参照してください。
Perl は、「間接オブジェクト」記法と呼ばれるもう一つのメソッド起動文法に 対応しています。 この文法は、起動されるオブジェクトの前にメソッド名が来るので 「間接」と呼ばれます。
この文法は任意のクラスおよびオブジェクトメソッドで使えます:
my $file = new File $path, $data;
save $file;いくつかの理由により、この文法は避けることを勧めます。
まず、これは読むのに混乱することがあります。 前述の例では、save が File によって提供されるメソッドなのか 最初の引数としてファイルオブジェクトを想定する単なるサブルーチンなのかが はっきりしません。
クラスメソッドで使うとき、問題はさらに悪くなります。 Perl はサブルーチン名を裸の単語として書くことを許しているので、 メソッドの後の裸の単語がクラス名なのかサブルーチン名なのかを Perl が推測する必要があります。 言い換えると、Perl はこの文法を File->new( $path, $data ) あるいは new( File( $path, $data ) ) と解釈できます。
このコードをパースするために、 Perl はどんなパッケージ名が見られるか、どんなサブルーチンが現在の パッケージに存在するか、どんな裸の単語が以前に見られたか、 およびその他の入力を元にした経験則を使います。 言うまでもなく、経験則はとても驚く結果を招くことがあります!
より古い文書 (およびいくつかの CPAN モジュール) では、 特にコンストラクタについて、この文法を推奨していたので、 まだ世の中でこれを見ることがあるかもしれません。 しかし、新しいコードにこれを使うことは避けることを推奨します。
以前に見たように、クラス名に "::" を付けることで、Perl が裸の単語として 解釈することを強制できます:
my $file = new File:: $path, $data;bless, blessed, ref既に見たように、オブジェクトは bless 関数でクラスに bless された 単なるデータ構造です。 bless 関数は一つまたは二つの引数を取ります:
my $object = bless {}, $class;
my $object = bless {};1 番目の形式では、無名ハッシュは $class のクラスに bless されます。 2 番目の形式では、無名ハッシュは現在のパッケージに bless されます。
2 番目の形式は強く非推奨です; なぜならこれは親のコンストラクタを 再利用するサブクラスの能力を壊すからです; しかし既に存在しているコードではまだこれを見ることがあるでしょう。
あるスカラがオブジェクトを参照しているかどうかを知りたい場合、 Perl コアと同梱されている Scalar::Util からエクスポートされている blessed 関数が使えます。
use Scalar::Util 'blessed';
if ( defined blessed($thing) ) { ... }$thing がオブジェクトを参照しているなら、この関数はオブジェクトが bless されているパッケージ名を返します。 $thing が bless されたオブジェクトへのリファレンスを含んでいないなら、 blessed 関数は undef を返します。
$thing が "0" という名前のクラスに bless されている場合も blessed($thing) は偽を返すことに注意してください。 これは可能ですが、かなり極端です。 何をしているか分かっていない限り、"0" という名前のクラスを 作らないでください。
同様に、Perl の組み込みの ref 関数は bless されたオブジェクトへの リファレンスを特別に扱います。 ref($thing) を呼び出して、$thing がオブジェクトへのリファレンスを 保持している場合、これはオブジェクトが bless されているクラス名を返します。
単純にある変数がオブジェクトリファレンスを含んでいるかをチェックしたい場合、 defined blessed($object) を使うことを勧めます; ref はオブジェクトだけでなく全てのリファレンスに関して真の値を 返すからです。
全てのクラスは、Perl コアに組み込まれている UNIVERSAL クラスから 継承されます。 このクラスは、全てクラスまたはオブジェクトから呼ばれる いくつかのメソッドを提供します。 また、自身のクラスでこれらのメソッドのいくつかを オーバーライドすることを選ぶことも出来ます。 そうする場合は、後述する組み込みの意味論に従うことを勧めます。
isa メソッドは、オブジェクトが $class のクラスか、$class の サブクラスの場合に 真 を返します。
このメソッドをオーバーライドする場合、決して例外を投げないように するべきです。
DOES メソッドは、オブジェクトがロール $role を実行すると主張している 場合に 真 を返します。 デフォルトでは、これは isa と等価です。 このメソッドは、Moose and Role::Tiny のように、ロールを実装している オブジェクトシステム拡張によって使われるために提供されています。
また、自身のクラスで直接 DOES をオーバーライドすることも出来ます。 このメソッドをオーバーライドする場合、決して例外を投げないように するべきです。
can メソッドは、呼び出されたクラスまたはオブジェクトが $method という名前のメソッドを持っているかをチェックします。 これはそのクラスおよび全ての親のメソッドをチェックします。 メソッドが存在する場合、サブルーチンへのリファレンスを返します。 存在しなければ undef が返されます。
あなたのクラスが AUTOLOAD 経由のメソッド呼び出しに対応する場合、 AUTOLOAD メソッドが扱うメソッドについてサブルーチンリファレンスを 返すように can をオーバーロードした方が良いでしょう。
このメソッドをオーバーライドする場合、決して例外を投げないように するべきです。
VERSION メソッドはクラス (パッケージ) のバージョン番号を返します。
$need 引数が指定された場合、現在のバージョン (パッケージの $VERSION 変数によって定義されているもの) が $need 以上かどうかを チェックします; そうでない場合は die します。 このメソッドは use の VERSION 形式によって自動的に呼び出されます。
use Package 1.2 qw(some imported subs);
# implies:
Package->VERSION(1.2);他のパッケージのバージョンにアクセスする場合は、直接 $Package::VERSION を見るのではなくこのメソッドを使うことを勧めます。 見ようとしているパッケージは VERSION メソッドを オーバーライドしているかも知れません。
また、あるモジュールのバージョンが十分かどうかをチェックするのに このメソッドを使うことを勧めます。 内部実装は、異なった種類のバージョン番号が正しく比較されるように version モジュールを使います。
クラスに存在しないメソッドを呼び出すと、Perl は例外を投げます。 しかし、そのクラスまたは親クラスに AUTOLOAD メソッドが定義されていると、代わりに AUTOLOAD メソッドが 呼び出されます。
AUTOLOAD は通常のメソッドとして呼び出され、呼び出し元は 違いを知ることは出来ません。 AUTOLOAD メソッドが返した値が呼び出し元に返されます。
呼び出された完全修飾メソッド名はあなたのクラスのパッケージグローバル変数 $AUTOLOAD から利用可能です。 これはグローバルなので、 strict 'vars' の基でパッケージ名接頭辞なしでこれを参照したい場合は、 宣言する必要があります。
# XXX - this is a terrible way to implement accessors, but it makes
# for a simple example.
our $AUTOLOAD;
sub AUTOLOAD {
my $self = shift;
# Remove qualifier from original method name...
my $called = $AUTOLOAD =~ s/.*:://r;
# Is there an attribute of that name?
die "No such attribute: $called"
unless exists $self->{$called};
# If so, return it...
return $self->{$called};
}
sub DESTROY { } # see belowour $AUTOLOAD 宣言なしだと、このコードは strict プラグマの基ではコンパイル出来ません。
コメントにあるように、これはアクセサを実装するための良い方法ではありません。 これは遅く、はるかに賢すぎます。 しかし、古い Perl コードでアクセサを提供する方法としてこれを 見ることがあるかも知れません。 Perl での OO コーディングの推奨については perlootut を参照してください。
クラスに AUTOLOAD メソッドがある場合、 can もオーバーライドすることを強く勧めます。 オーバーライドされた can メソッドは、AUTOLOAD が対応する メソッドについてサブルーチンリファレンスを返すべきです。
オブジェクトへの最後のリファレンスがなくなると、オブジェクトは破壊されます。 オブジェクトへの一つのリファレンスをレキシカルなスカラに入れているだけの 場合、スカラがスコープ外に出るとオブジェクトは破壊されます。 オブジェクトをパッケージグローバルに保管すると、プログラムが終了するまで オブジェクトはなくならないかもしれません。
オブジェクトが破壊されるときに何かをしたい場合、 自分のクラスに DESTROY メソッドを定義できます。 このメソッドは、空でない限り、適切な時点で常に Perl によって呼び出されます。
これは、他のメソッドと同様、オブジェクトを最初の引数として呼び出されます。 これは追加の引数は受け取りません。 しかし、$_[0] 変数はデストラクタの中では読み込み専用なので、 これに値を代入することは出来ません。
DESTROY メソッドが例外を投げても、メソッドの終了の先に 制御を移すことはしません。 例外は "(in cleanup)" とマークされた警告として STDERR に報告され、Perl はその前にしていたことを続けます。
DESTROY メソッドはあらゆる時点で呼び出される可能性があるので、 DESTROY メソッドの中ですることによって設定されるかも知れない全ての グローバル状態変数をローカル化するべきです。 特定の状態変数について疑わしいときは、それをローカル化しても 問題はありません。 グローバル状態変数は五つあるので、最も安全な方法は五つ全てを ローカル化することです:
sub DESTROY {
local($., $@, $!, $^E, $?);
my $self = shift;
...;
}クラス内で AUTOLOAD を定義している場合、 Perl は DESTROY メソッドを扱うために AUTOLOAD を呼び出します。 オートロードの例で行ったように、空の DESTROY を定義することによって これを防げます。 また、$AUTOLOAD の値をチェックして、DESTROY を扱うために 呼び出されたときには何もせずに返ることもできます。
プログラムが終了する前のグローバルな破壊の間にオブジェクトが破壊される 順序は予測できません。 つまり、あなたのオブジェクトに含まれているオブジェクトは既に 破壊されているかも知れないということです。 含まれているオブジェクトを呼び出す前にそのメソッドが定義されているかどうかを チェックするべきです:
sub DESTROY {
my $self = shift;
$self->{handle}->close() if $self->{handle};
}現在グローバル破壊フェーズ中なのかを検出するために、 ${^GLOBAL_PHASE} 変数が使えます:
sub DESTROY {
my $self = shift;
return if ${^GLOBAL_PHASE} eq 'DESTRUCT';
$self->{handle}->close();
}この変数は Perl 5.14.0 で追加されたことに注意してください。 より古いバージョンの Perl でグローバル破壊フェーズを検出したい場合は、 CPAN の Devel::GlobalDestruction モジュールを使えます。
DESTROY メソッドがグローバルな破壊中に警告を出した場合、 Perl インタプリタは警告に " during global destruction" という文字列を 追加します。
グローバルな破壊の間、Perl は常にリファレンスの bless 解除の前に オブジェクトをガベージコレクションします。 グローバルな破壊に関するさらなる情報については "PERL_DESTRUCT_LEVEL" in perlhacktips を参照してください。
今までの全ての例ではオブジェクトは bless されたハッシュを基にしていました。 しかし、スカラ、グロブ、サブルーチンを含むあらゆる種類のデータ構造や 参照先を bless することが出来ます。 世の中のコードを見たときにそのようなものを見るかも知れません。
これは bless されたスカラとしてのモジュールの例です:
package Time;
use strict;
use warnings;
sub new {
my $class = shift;
my $time = time;
return bless \$time, $class;
}
sub epoch {
my $self = shift;
return $$self;
}
my $time = Time->new();
print $time->epoch();過去に、Perl コミュニティは「インサイドアウトオブジェクト」と呼ばれる テクニックを実験しました。 インサイドアウトオブジェクトは、そのデータをオブジェクト自身ではなく、 そのメモリアドレスのようなオブジェクトのユニークな属性をインデックスとして、 オブジェクトのリファレンスの外側に保管します。 これは、オブジェクトの属性のカプセル化を強制するという利点があります; なぜならそれらのデータはオブジェクト自身に保管されないからです。
このテクニックはしばらくの間人気があり (そして Damian Conway の Perl Best Practices で推奨され) ましたが、 一般的な採用を達成することはありませんでした。 CPAN の Object::InsideOut モジュールはこのテクニックの包括的な 実装を提供し、世の中ではこれやその他のインサイドアウトモジュールを 見かけるかも知れません。
これは Hash::Util::FieldHash コアモジュールを使ったこのテクニックの 簡単な例です。 このモジュールはインサイドアウトオブジェクト実装に対応するために コアに追加されました。
package Time;
use strict;
use warnings;
use Hash::Util::FieldHash 'fieldhash';
fieldhash my %time_for;
sub new {
my $class = shift;
my $self = bless \( my $object ), $class;
$time_for{$self} = time;
return $self;
}
sub epoch {
my $self = shift;
return $time_for{$self};
}
my $time = Time->new;
print $time->epoch;疑似ハッシュ機能は、以前のバージョンの Perl で導入され、 5.10.0 で削除された実験的機能です。 疑似ハッシュは、ハッシュのように名前付きのキーを使ってアクセスされる 配列リファレンスです。 これを使ったコードに出くわすことがあるかも知れません。 さらなる情報については fields プラグマを参照してください。
Perl でのオブジェクト指向プログラミングに関するより親切で優しい チュートリアルは perlootut にあります。 また、モジュールとクラスの両方を構築するためのスタイルガイドについて perlmodlib をチェックするべきです。