perlsyn - Perl の文法
Perl プログラムは、宣言と文の並びから構成され、上から下へと実行されます。 ループ、サブルーチン、その他の制御機構でコードの色々なところに ジャンプできます。
Perl は 自由書式 言語ですが、好きなように整形したりインデントしたり できます。 空白が文法の重要な要素である Python のような言語と異なり、 空白はほとんどトークンの分割の役目です。
Perl の多くの文法要素は 省略可能 です。 全ての関数をかっこで括ったり、全ての変数を宣言したりすることを 要求するのではなく、しばしばそのような明示的な要素を置いておいて、 Perl にあなたが意味しているところを見つけ出させることができます。 これは Do What I Mean と知られ、頭文字を取って DWIM と呼ばれます。 これによって、プログラマを 怠惰 にでき、彼らが快適だと思うスタイルで コーディングできるようにします。
Perl は、awk, sed, C, Bourne Shell, Smalltalk, Lisp, 果ては英語といった、 多くの言語からコンセプトと 文法を借用 しています。 他の言語も Perl から文法を借用しています; 特に正規表現拡張をです。 従って、他の言語でプログラミングしていたなら、Perl にも見たことがあるような ものがあるでしょう。 それらはしばしば同じように動作しますが、違う点についての情報は perltrap を参照してください。
Perl で宣言が必要なものはレポートフォーマットとサブルーチンだけです (サブルーチンすら宣言が不要な場合もあります)。 変数は、undef 以外の定義された値を代入されるまでは未定義値(undef)と なります。 数値として使われる場合、undef は 0 として扱われます; 文字列として使われる場合、これは空文字列 "" として扱われます; リファレンスとして使われる場合、これは何も代入されていないので、エラーとして 扱われます。 警告を有効にしているなら、undef を文字列や数値として扱おうとすると 未初期価値を指摘されます。 ええ、普通は。 次のような真偽値コンテキストなら:
my $a;
if ($a) {}(定義済みかどうかではなく、真かどうかを考慮するので)警告から免れます。 未定義の左辺値を操作する、++, --, +=, -=, .= のような 演算子でも:
my $a;
$a++;とすることでもそのような警告から免れます。
宣言は、文が置けるところであればどこにでも置くことができますが、 基本的な文の並びは実行時には何の効果も持ちません -- 宣言はコンパイル時に すべての効果が表れます。 典型的なすべての宣言は、スクリプトの先頭か終端に置かれます。 しかしながら、局所変数を my() を使って作成してレキシカルなスコープを 使っているのであれば、フォーマットやサブルーチンの定義を、同じブロックの スコープの中でその局所変数にアクセスすることが可能であるようにしておく 必要があるでしょう。
サブルーチンの宣言は、プログラムの後のほうにあるサブルーチン名を リスト演算子のように使うことを許します。 定義されていないサブルーチンの宣言を、sub name と記述することで 宣言できるので、以下のようにできます:
sub myname;
$me = myname $0 or die "can't get myname";myname() 関数は、リスト演算子のように働くのであり、単項演算子としてでは ないということに注意してください; ですから、こういった場合に || の代わりに or を使うことには 注意してください。 しかし、サブルーチンを sub myname ($) のように宣言しているのであれば、 or でも || でもうまく行きます。
サブルーチンの宣言は require 文を使って詰め込むこともできますし、 use 文を使って自分の名前空間にロードしたりインポートしたりすることが できます。 これに関する詳細は perlmod を参照してください。
文の並びはレキシカルスコープを持った変数の宣言を含むことができますが、 変数名の宣言とは切り離され、その宣言は通常の文のように振る舞い、 それが通常の文であるかのように文の並びに組みこまれます。 これは、そういった宣言がコンパイル時の効果と実行時の効果の両方を 持っているということです。
コメントは “#” 文字から、行末まで続き、その部分は無視されます。 例外は、文字列や正規表現の中にある "#" です。
単純文となる唯一の種類は、その副作用のために評価される式です。 すべての単純文は、それがセミコロンを省略することのできるブロックの 最後にない限りは文を終端するためのセミコロンがなければなりません (ブロックが二行以上に渡る場合には、セミコロンを付けることをお薦めします。 なぜなら、別の行を追加する可能性があるからです)。 eval {} や do {} のように、一見複合文のようにみえるけれども そうではない(これらは単なる式における TERM です)ものがあって、 そういったものを文の最後のアイテムとして使った場合には明示的に終端する 必要があるのだということに注意してください。
数値 0, 文字列 '0' と '', 空リスト (), undef は全て真偽値 コンテキストでは偽となります。 その他の全ての値は真です。 真の値を ! や not で否定すると、特殊な偽の値を返します。 これを文字列として評価すると '' として扱われますが、数値として評価すると 0 として扱われます。
任意の単純文には、一つ の修飾子を終端のセミコロンの直前(もしくは ブロックの終端の直前)に付けることができます。 使うことのできる修飾子は以下の通りです。
if EXPR
unless EXPR
while EXPR
until EXPR
when EXPR
for LIST
foreach LIST修飾子に引き続く EXPR は「条件」として参照されます。 その真偽値が修飾子の振る舞いを決定します。
if は もし 条件が真の場合にのみ文を実行します。 unless は逆で、条件が真 でない限り (つまり、条件が偽なら) 文を 実行します。
print "Basset hounds got long ears" if length $ear >= 10;
go_outside() and play() unless $is_raining;when は、$_ が EXPR にスマートマッチングした 時に 文を 実行し、それから、given スコープの中の場合は break し、 直接 for ループの内側にあるなら next します。 "Switch statements" も参照してください。
given ($something) {
$abc = 1 when /^abc/;
$just_a = 1 when /^a/;
$other = 1;
}
for (@names) {
admin($_) when [ qw/Alice Bob/ ];
regular($_) when [ qw/Chris David Ellen/ ];
}foreach 修飾子は反復子です: LIST の値それぞれ毎に文を実行します(実行中は $_ がそれぞれの値の エイリアスとなります)。
print "Hello $_!\n" foreach qw(world Dolly nurse);while は条件が真 の間 文を繰り返します。 until は逆で、条件が真 になるまで (つまり条件が偽の間) 文を 繰り返します:
# Both of these count from 0 to 10.
print $i++ while $i <= 10;
print $j++ until $j > 10;修飾子 while と until は、一般的な "while loop" の意味を 持っています(条件が最初に評価される)が、do-ブロック(もしくは現在では 使用を推奨されていない do-サブルーチン文)に適用されるときは例外で、 このときは条件が評価されるよりも前に、一度ブロックが実行されます。 このため、次のようなループを記述することができます。
do {
$line = <STDIN>;
...
} until $line eq ".\n";"do" in perlfunc を参照してください。 後述するループの制御文は、修飾子がループラベルを取らないために この構造文では 動作しない ということにも注意してください。 申し訳ない。 こういった場合に対処するのに別のブロックを内側に入れたり(next の場合)、 別のブロックで囲む(last の場合)という方法が常に使えます。 next では単に中かっこを二重にします:
do {{
next if $x == $y;
# do something here
}} until $x++ > $z;last の場合は、もっと念入りにする必要があります:
LOOP: {
do {
last if $x = $y**2;
# do something here
} while $x++ <= $z;
}注意: (my $x if ... のような) 条件構造やループ構造で修飾された my 文の振る舞いは 未定義 です。 my 変数の値は undef かも知れませんし、以前に代入された値かも 知れませんし、その他の如何なる値の可能性もあります。 この値に依存してはいけません。 perl の将来のバージョンでは現在のバージョンとは何か違うかも知れません。 ここには厄介なものがいます。
Perl では、スコープを定義するような文の並びをブロックと呼びます。 ブロックはそれを含むファイルによって範囲が定められることがあります (ファイルが require されたときか、プログラム全体としての場合)し、 文字列の展開によって範囲が定められる(eval の場合)こともあります。
しかし一般的には、ブロックは中かっこによって範囲が定められます。 この構文的な構造をブロックと呼びます。
以下に挙げる複合文を制御フローとして使うことができます:
if (EXPR) BLOCK
if (EXPR) BLOCK else BLOCK
if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
unless (EXPR) BLOCK
unless (EXPR) BLOCK else BLOCK
unless (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
LABEL while (EXPR) BLOCK
LABEL while (EXPR) BLOCK continue BLOCK
LABEL until (EXPR) BLOCK
LABEL until (EXPR) BLOCK continue BLOCK
LABEL for (EXPR; EXPR; EXPR) BLOCK
LABEL foreach VAR (LIST) BLOCK
LABEL foreach VAR (LIST) BLOCK continue BLOCK
LABEL BLOCK continue BLOCKしかし注意して欲しいのは、C や Pascal とは異なり、ブロックを取るように 定義されていて文を取るではないということです。 つまり、中かっこは 必要なもの です -- 曖昧な文が許されません。 中かっこなしの条件文を使いたいのであれば、いくつかのやり方があります。 以下の全ては同じことです:
if (!open(FOO)) { die "Can't open $FOO: $!"; }
die "Can't open $FOO: $!" unless open(FOO);
open(FOO) or die "Can't open $FOO: $!"; # FOO or bust!
open(FOO) ? 'hi mom' : die "Can't open $FOO: $!";
# a bit exotic, that last oneif 文は明解です。 ブロックは常に中かっこで区切られるので、if と else の対応が 曖昧になるようなことは決してありません。 unless を if の代わりに使うと、検査を反転します。 if と同様、unless は else に引き続くことができます。 unless は一つまたはそれ以上の elsif に引き続くことすらできますが、 この特定の言語構文を使う前に二倍考えたいでしょう; あなたのコードを読む 誰もが何が行われているのかを理解する前に少なくとも二倍考える必要が あるからです。
while 文は、式が 真 である間、ブロックを 実行します。 until 文は、式が偽である間、ブロックを実行します。 LABEL は省略可能ですが、ある場合には、コロンを伴った識別子になります。 LABEL は next、last、redo といったループ制御文のループを規定します。 LABEL が省略された場合、ループ制御文はそれを含むループの中で最も内側の ループを参照します。 これは、実行時に LABEL を検出するための呼び出しスタックの動的な後戻り検索を 含むことができます。 そのような推奨されない振る舞いは、use warnings プラグマや -w フラグを 使った場合には警告を引き起こします。
continue ブロックが存在する場合、 常に条件が再評価される直前に実行されます。 したがって、このブロックをループ変数のインクリメントのために 使うことができます; これは、ループがnext文を通して継続されるときでも実行されます。
エクステンションモジュールは新しい種類の複合文を定義するために Perl パーサをフックできます。 これらはエクステンションが認識するキーワードで導入され、キーワードに 引き続く文法は完全にエクステンションで定義されます。 もしあなたが実装車なら、仕組みについては "PL_keyword_plugin" in perlapi を 参照してください。 あなたがそのようなモジュールを使うなら、定義されている文法の詳細については そのモジュールの文書を参照してください。
next コマンドはループの次の繰り返しを開始します:
LINE: while (<STDIN>) {
next LINE if /^#/; # discard comments
...
}last コマンドはループから即座に脱出します。 continue ブロックがあっても、それは実行されません:
LINE: while (<STDIN>) {
last LINE if /^$/; # exit when done with header
...
}redo コマンドは、条件の再評価をすることなしにループブロックの 再実行を行います。 continue ブロックがあっても、それは 実行されません。 このコマンドは通常、プログラムに対する入力に関してプログラム自身を だましたいといったときに使われます。
たとえば、/etc/termcap のようなファイルを処理することを 考えてみましょう。 もし入力された行の行末が継続を示すバックスラッシュであった場合、先へ進んで 次のレコードを取り出したいと思うでしょう。
while (<>) {
chomp;
if (s/\\$//) {
$_ .= <>;
redo unless eof();
}
# now process $_
}これは Perl の省略記法で、もっとはっきりと書くと以下のようになります:
LINE: while (defined($line = <ARGV>)) {
chomp($line);
if ($line =~ s/\\$//) {
$line .= <ARGV>;
redo LINE unless eof(); # not eof(ARGV)!
}
# now process $line
}上記の例で continue ブロックがあったとしたら、それは (redo は continue ブロックをスキップするので) 正規表現によって 捨てられた行だけが実行されるということに注意してください。 continue ブロックは行カウンターをリセットするとか、 一度だけマッチする m?pat? をリセットするのに使われます。
# inspired by :1,$g/fred/s//WILMA/
while (<>) {
m?(fred)? && s//WILMA $1 WILMA/;
m?(barney)? && s//BETTY $1 BETTY/;
m?(homer)? && s//MARGE $1 MARGE/;
} continue {
print "$ARGV $.: $_";
close ARGV if eof; # reset $.
reset if eof; # reset ?pat?
}while を until で置き換えた場合検査の意味は逆転しますが、 繰り返しが実行されるより前に条件が検査されることは変わりありません。
ループ制御文は if や unless 中では動作しません; なぜならそこはループではないからです。 しかし中かっこを二重にしてこれに対処することはできます。
if (/pattern/) {{
last if /fred/;
next if /barney/; # same effect as "last", but doesn't document as well
# do something here
}}これは、ブロック自身は一度だけ実行されるループとして動作するからです; "Basic BLOCKs" を参照してください。
Perl 4 では使うことのできた while/if BLOCK BLOCK という形式は、 もはや使うことができません。 if BLOCK の部分を if (do BLOCK) で置き換えてください。
Perl の C 形式の for ループは、対応する while ループと同様に 動作します; つまり、以下のものは:
for ($i = 1; $i < 10; $i++) {
...
}以下のものと同じです:
$i = 1;
while ($i < 10) {
...
} continue {
$i++;
}小さな違いが一つあります: for の初期化部で my を使って変数が 宣言された場合、この変数のレキシカルスコープは for ループ (ループ本体と制御部) と完全に同じです。
通常の、配列に対する添え字付けのループのほかにも、for は他の 多くの興味深いアプリケーションのために借用することができます。 以下の例は、対話的なファイル記述子の終端を明示的に検査してしまうと プログラムをハングアップしたように見えてしまう問題を回避するものです。
$on_a_tty = -t STDIN && -t STDOUT;
sub prompt { print "yes? " if $on_a_tty }
for ( prompt(); <STDIN>; prompt() ) {
# do something
}for ループの条件として readline (または演算子形式の <EXPR>) を 使う場合、以下のように省略形が使えます。 この振る舞いは while ループ条件と同じです。
for ( prompt(); defined( $_ = <STDIN> ); prompt() ) {
# do something
}foreach ループは 通常のリスト値に対しての繰り返しを行い、変数 VAR に リストの要素を繰り返し一回に一つずつセットします。 変数の前に my というキーワードが置かれていた場合、その変数は レキシカルスコープを持ち、したがってそれはループの中でのみ可視となります。 このキーワードがなければ、変数はループに対してローカルとなり、ループを 抜けた後で以前の値が再度取得されます。 変数が事前に my を使って宣言されていたならば、グローバルなものの 代わりにその変数を使いますが、それもループにローカルなものとなります。 この暗黙のローカル化は foreach の中で のみ 起きます。
読みやすさのために foreach を、簡潔さのために for を使うことが できます。 (あるいは C シェルよりも Bourne シェルに親しんでいるのなら for の方が自然でしょう。) VAR が省略された場合には、$_ に値が設定されます。
LIST の要素が左辺値であった場合、ループの中で VAR を変更することにより、 対応する値を変更することができます。 逆に、LIST の要素が左辺値でない場合は、この要素を修正しようとしても 失敗します。 言い換えると、foreach ループの帰納変数がループの対象となっている リスト中の個々のアイテムに対するエイリアスになっているからです。
LIST のいずれかの部分が配列であった場合に、たとえば splice を使って ループの本体でその要素を削除したりあるいは追加したりすると foreach は非常に混乱してしまいます。 ですからそういうことをしてはいけません。
VAR が tie されていたりあるいは他の特殊変数であった場合には foreach はあなたのもくろみどおりには動かないでしょう。 こういうこともしてはいけません。
例:
for (@ary) { s/foo/bar/ }
for my $elem (@elements) {
$elem *= 2;
}
for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') {
print $count, "\n"; sleep(1);
}
for (1..15) { print "Merry Christmas\n"; }
foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
print "Item: $item\n";
}以下の例は、C プログラマーが Perl でとあるアルゴリズムを記述するときに 使うであろうやり方です:
for (my $i = 0; $i < @ary1; $i++) {
for (my $j = 0; $j < @ary2; $j++) {
if ($ary1[$i] > $ary2[$j]) {
last; # can't go to outer :-(
}
$ary1[$i] += $ary2[$j];
}
# this is where that last takes me
}それに対して、次の例は Perl プログラマーが同じことをよりゆったりとして 行うやり方です:
OUTER: for my $wid (@ary1) {
INNER: for my $jet (@ary2) {
next OUTER if $wid > $jet;
$wid += $jet;
}
}どのくらいこれが簡単になったように見えますか? これは明確で、安全で、 高速です。 これは余計なものが少ないので明確なのです。 これは後で内側のループと外側のループとの間にコードを付加えた場合でも、 それを間違って実行することがないので安全なのです。 next は内側のループを終了するのではなく、外側のループの繰り返しを 行います。 そしてこれは、Perl は foreach 文をそれと等価な for ループよりも すばやく実行するので高速なのです。
ブロックそれ自身は(ラベルが付いていようがついてなかろうが)一度だけ 実行されるループと、文法的には等価なものです。 このため、ブロックから脱出するためやブロックの再スタートのために 任意のループ制御文を使うことができます。 (これは eval{}、sub{}、 さらに一般的な認識とは異なり ループではない do{} ブロックに対しては 真ではない ということに注意してください。) continue ブロックは省略することができます。
BLOCK 構造は case 構造を行うのにも使えます。
SWITCH: {
if (/^abc/) { $abc = 1; last SWITCH; }
if (/^def/) { $def = 1; last SWITCH; }
if (/^xyz/) { $xyz = 1; last SWITCH; }
$nothing = 1;
}古いバージョンの Perl には公式の switch 文がなかったので、このような 構文はとてもよく使われています。
Perl 5.10 から、以下のように書くと:
use feature "switch";Perl 6 で提案されているものを基礎とした switch 機能が有効になります。
キーワード given と when は他の言語での switch および case と 同様のものなので、上記のコードは以下のように書けます:
given($_) {
when (/^abc/) { $abc = 1; }
when (/^def/) { $def = 1; }
when (/^xyz/) { $xyz = 1; }
default { $nothing = 1; }
}この構造はとても柔軟で、強力です。 例えば:
use feature ":5.10";
given($foo) {
when (undef) {
say '$foo is undefined';
}
when ("foo") {
say '$foo is the string "foo"';
}
when ([1,3,5,7,9]) {
say '$foo is an odd digit';
continue; # Fall through
}
when ($_ < 100) {
say '$foo is numerically less than 100';
}
when (\&complicated_check) {
say 'a complicated check for $foo is true';
}
default {
die q(I don't know what to do with $foo);
}
}given(EXPR) はブロックのレキシカルスコープ内で EXPR を $_ に 代入するので、これは以下と似ています:
do { my $_ = EXPR; ... }しかし、ブロックは when が成功するか、明示的な break によって 自動的に破壊されるところが違います。
強力さのほとんどは暗黙のスマートマッチングによるものです:
when($foo)は正確に以下と等価です:
when($_ ~~ $foo)ほとんどの場合で、when(EXPR) は暗黙的な $_ へのスマートマッチング (つまり $_ ~~ EXPR) として扱われます。 (スマートマッチングに関するさらなる情報については "Smart matching in detail" を参照してください。) しかし、EXPR が以下の例外ケースの一つの場合は、直接真偽値として扱われます:
サブルーチンかメソッド呼び出し
正規表現マッチング: つまり、/REGEX/ や $foo =~ /REGEX/ や 正規表現マッチングの否定 (!/REGEX/ or $foo !~ /REGEX/)。
$_ < 10 や $x eq "abc" (や、もちろん $_ ~~ $c) のような比較
defined(...), exists(...), eof(...) のいずれか
否定表現 !(...), not (...), 排他的論理和 (...) xor (...)
真偽値ではなく数値を返す -s, -M, -A, -C を除く ファイルテスト演算子。
フリップフロップ演算子 .. と ...。
このような場合、EXPR の値は直接真偽値として使われます。
更に、Perl はオペランドに上述のテストを適用することで、それぞれに スマートマッチングを使うかどうかを決定するために二項真偽値演算子の オペランドを調べます:
EXPR が ... && ... または ... and ... の場合、テストは両方の オペランドに対して再帰的に適用されます。 両方の オペランドがテストに成功した場合、この式は真偽値として 扱われます; さもなければ、スマートマッチングが使われます。
EXPR が ... || ..., ... // ..., ... or ... の場合、テストは最初の オペランド(例えば、より高い優先順位である AND 演算子)に対して再帰的に 適用されます。 最初のオペランドがスマートマッチングを使うなら、両方のオペランドが そうします; そうでなければ、二番目の引数はどちらでもありません。
これらの規則は複雑に見えますが、普通はあなたが実行したい通りに実行します。 例えば:
when (/^\d+$/ && $_ < 75) { ... }これは真偽値マッチングとして扱われます; 規則では正規表現マッチングと $_ への明示的なテストはどちらも真偽値として扱われるからです。
また:
when ([qw(foo bar)] && /baz/) { ... }これはスマートマッチングを使います; オペランドの 一つ だけが 真偽値だからです; もう片方はスマートマッチングを使うので、こちらが 優先されます。
さらに:
when ([qw(foo bar)] || /^baz/) { ... }これはスマートマッチングを使います(最初のオペランドのみが考慮されます); 一方
when (/^baz/ || [qw(foo bar)]) { ... }これは正規表現のみがテストされ、両方のオペランドは真偽値として 扱われることになります。 この場合、配列リファレンスは常に真の値なので、効率的に冗長になることに 注目してください。
恒久的な真偽値演算子は最適化されて除去されます。 以下のように書こうとしないでください
when ('foo' or 'bar') { ... }これは 'foo' に最適化されるので、'bar' は (たとえ規則では 'foo' に スマートマッチングを使うとなっていたとしても) 考慮されることはありません。 このような代替としては、配列リファレンスは動作します; これは スマートマッチングを使わせるからです:
when ([qw(foo bar)] { ... }これはある意味 C スタイルの switch 文の次の条件への移動(fallthrough)機能と 等価です(Perl の 次の条件への移動機能と混同しないでください - 後述します); 複数の case 文に同じブロックが使われます。
その他の便利な省略記法としては、given の引数としてリテラルな配列や ハッシュを書くと、これはリファレンスに変化します。 それで、例えば given(@foo) は given(\@foo) と同じです。
default は正確に when(1 == 1) のように振る舞い、常に マッチングします。
囲まれている given ブロックから脱出するために、break キーワードが 使えます。 全ての when ブロックの末尾には暗黙に break があります。
一つの条件から次へ移動するためには、continue キーワードが使えます:
given($foo) {
when (/x/) { say '$foo contains an x'; continue }
when (/y/) { say '$foo contains a y' }
default { say '$foo does not contain a y' }
}given が有効な式でもある(例えばブロックの最後の文である)場合、 以下のように評価されます:
明示的な break に遭遇した直後なら空リスト。
もしあれば、成功した when/default 節で最後に評価された式の値。
どの条件も真でなければ given ブロックで最後に評価された式の値。
最後の二つの場合、最後の式は適用された given ブロックに適用された コンテキストで評価されます。
if や unless と異なり、失敗した when 文は常に空リストに 評価されます。
my $price = do { given ($item) {
when ([ 'pear', 'apple' ]) { 1 }
break when 'vote'; # My vote cannot be bought
1e10 when /Mona Lisa/;
'unknown';
} };現在のところ、given ブロックは常に適切な式として使うことはできません。 これは将来のバージョンの perl に対処されるでしょう。
given() を使う代わりに、foreach() ループを使えます。 たとえば、以下は配列内に特定の文字列が何回現れるかを数えるための ひとつの方法です:
my $count = 0;
for (@array) {
when ("foo") { ++$count }
}
print "\@array contains $count copies of 'foo'\n";when ブロックの末尾に、暗黙の next があります。 もし最初のマッチングだけに興味があるなら、明示的な last でこれを 上書きできます。
これは、for $item (@array) のように明示的にループ変数を指定した場合は 動作しません。 デフォルト変数 $_ を使う必要があります。 (for my $_ (@array) は使えます。)
スマートマッチングの振る舞いは引数にどのような型が使われたかに依存します。 振る舞いは以下の表によって決定されます: 適用される最初の行がマッチングの振る舞いを決定します (従って普通は右側のオペランドの型で決定されます)。 スマートマッチングは bless されていないハッシュや配列のリファレンスを 暗黙的にデリファレンスするので、これらの場合 "Hash" と "Array" の エントリが適用されます。 (bless されたリファレンスの場合、"Object" エントリが適用されます。)
"Matching Code" の列は常に正確な説明というわけではないことに 注意してください。 例えば、スマートマッチング演算子の短絡化はいつでも可能ですが、grep は そうではありません。
$a $b 暗黙に行われるマッチング マッチングコード
====== ===== ======================== =============
Any undef 未定義か !defined $a
Any Object $object の ~~ オーバーロードを起動するか die する
Hash CodeRef sub が各キーで真か [1] !grep { !$b->($_) } keys %$a
Array CodeRef sub が各要素で真か [1] !grep { !$b->($_) } @$a
Any CodeRef サブルーチンが真か $b->($a)
Hash Hash ハッシュキーが同じか (全てのキーが両方のハッシュにあるか)
Array Hash ハッシュキーの積集合 grep { exists $b->{$_} } @$a
Regex Hash ハッシュキー grep grep /$a/, keys %$b
undef Hash 常に偽 (undef はキーになれない)
Any Hash ハッシュエントリがあるか exists $b->{$a}
Hash Array ハッシュキー積集合 grep { exists $a->{$_} } @$b
Array Array 配列が比較可能[2]
Regex Array 配列 grep grep /$a/, @$b
undef Array 配列に undef があるか grep !defined, @$b
Any Array 配列要素に対するマッチング[3]
grep $a ~~ $_, @$b
Hash Regex ハッシュキー grep grep /$b/, keys %$a
Array Regex 配列 grep grep /$b/, @$a
Any Regex パターンマッチング $a =~ /$b/
Object Any $object の ~~ オーバーロードを起動するかフォールバック:
Any Num 数値比較 $a == $b
Num numish[4] 数値比較 $a == $b
undef Any 未定義か !defined($b)
Any Any 文字列比較 $a eq $b
1 - 空のハッシュや配列はマッチングする。
2 - これは、各要素をもう一つの配列の同じ添え字の要素と
スマートマッチングする。 [3]
3 - 循環参照が発見されると、参照の等価性にフォールバックする。
4 - 実数か、数値のように見える文字列~~ 演算子をオーバーロードすることで、オブジェクトのマッチングする方法を 変更できます。 これは通常のスマートマッチングの意味論を置き換えられます。
~~ は、(オブジェクトの基礎となる構造に依存するのを避けるために) これをオーバーロードしていないオブジェクトに対しては動作しないことを 注意するべきです。
また、スマートマッチングのマッチングルールはオーバーロードより 優先順位が高いので、$obj がスマートマッチングをオーバーロードしていて、
$obj ~~ Xとしても X を引数としたオーバーロードメソッドは自動的には起動されません; 代わりに上述の表が通常通り適用され、X の型に基づいて、オーバーロード メソッドは起動されたり起動されなかったりします。
overload を参照してください。
Perl 5 のスマートマッチングと given/when 構文は Perl 6 のものと 完全に同一ではありません。 もっとも目に見える違いは、Perl 5 では、given() と when() の引数は (後者を文修飾子として使う場合を除いて)かっこでくくる必要があります。 Perl 6 では、if(), while(), when() のような制御構造での かっこは常に省略可能です; Perl 5 では、潜在的な大混乱と引き換えにしなければこれを省略できません; なぜなら Perl 5 は以下のような表現において:
given $foo {
...
}given の引数はハッシュ %foo の要素であるかのようにパースして、 中かっこをハッシュ要素文法として解釈するからです。
スマートマッチングの表は Perl 6 仕様で提案されれているものと 同一ではありません; 主に Perl 6 と Perl 5 のデータモデルの違いによります。
Perl 6 では、when() は常にその引数に対する暗黙のスマートマッチングを 行いますが、Perl 5 では上述の通り、状況によっては暗黙のスマートマッチングを 抑制したほうが便利です。 (主な違いは、Perl 5 は内部的にさえ真偽値型を持たないことによります。)
気弱な人のためでないにも関らず、Perl は goto 文をサポートしています。 goto-LABEL、goto-EXPR、goto-&NAME の三つの形式があります。 ループのラベルは実際には goto の正当なターゲットではなく、 ループの名前にすぎません。
goto-LABEL 形式は LABEL でラベル付けされた文を見つけだし、そこから 実行を再開します。 これはサブルーチンであるとか foreach ループのような 初期化を必要とするような構造へ飛び込むために使うことはできません。 また、最適化されて無くなってしまうような構造へ飛び込むこともできません。 動的スコープの中以外のほとんどの場所へは、サブルーチンの外も含めて 移動することができます; しかし、通常は last や die のような 別のやり方を使ったほうが良いでしょう。 Perl の作者は、未だかつてこの形式の goto を使うことが 必要だと感じたことはありません(Perl の場合です--C の場合はまた別の話です)。
goto-EXPR 形式は動的に解決されるスコープを持っているラベル名を 期待しています。 これによって FORTRAN の計算型 goto が実現できますが、 これは保守性に重きを置くのであれば使うことは止めた方が良いでしょう。
goto(("FOO", "BAR", "GLARCH")[$i]);goto-&NAME は高度にマジカルで、名前付きサブルーチンの呼び出しを カレントで実行されているサブルーチンに置き換えます。 これは別のサブルーチンをロードして、最初の場所で呼び出された 別のサブルーチンを要求することをしようとする AUTOLOAD() サブルーチンで使われていてます (カレントのサブルーチンにおける @_ に対するもの以外の変更は、 別のサブルーチンへ伝播します)。 goto の後で、caller() でなくてもこのサブルーチンが 最初に呼ばれたのだということを伝えることすらできるでしょう。
このようなケースのほとんどすべての場合、goto に頼るのではなくて next、last、redo といった制御フロー機構を使うことが、 ずっとずっと良いアイデアでしょう。 一部のアプリケーションに対しては、eval{} と die() を catch と throw のペアとして例外処理を行うための賢明なアプローチとして 使うことができるでしょう。
Perl は、ソースコードとドキュメントとを混ぜ書きするための仕掛けを 持っています。 新しい文の始まりが期待されているときに、コンパイラは 以下の例のような = 記号で始まっている語を見つけると:
=head1 Here There Be Pods!そのテキストと、=cut で始まる行までの内容を無視します。 間に入るテキストの書式は perlpod で説明されています。
これによって、ソースコードとドキュメントとを以下に示す例のように 自由に混ぜることができるようになります。
=item snazzle($)
The snazzle() function will behave in the most spectacular
form that you can possibly imagine, not even excepting
cybernetic pyrotechnics.
=cut back to the compiler, nuff of this pod stuff!
sub snazzle($) {
my $thingie = shift;
.........
}コンパイラはパラグラフの途中に pod エスケープがあったとしてもそれを 認識できるのに、pod トランスレータは pod 指示子で始まっている パラグラフのみに注目すべき(これは構文解析を簡単にするためです)で あるということに注意して下さい。 つまり、以下の例にある "secret stuff" はコンパイラからも、 トランスレータからも無視されるということです。
$a=3;
=secret stuff
warn "Neither POD nor CODE!?"
=cut back
print "got $a\n";この例の warn() のようなものが、将来に渡って無視されるということに 依存すべきではありません。 すべての pod トランスレータがそのように振る舞うわけではありませんし、 コンパイラは将来これを無視しないようになるかもしれません。
pod 指示子を、コードの一部を手っ取り早くコメントアウトするために 使うこともできます。
C のプリプロセッサと同じように、Perl は行指示子を処理できます。 これを使うことによって、エラーメッセージや警告メッセージにある ファイル名や行番号を制御することができます (特に、eval() で処理される文字列のために)。 この仕組みの構文はほとんどの C のプリプロセッサとほとんど同じで、正規表現:
# example: '# line 42 "new_filename.plx"'
/^\# \s*
line \s+ (\d+) \s*
(?:\s("?)([^"]+)\g2)? \s*
$/xにマッチしたものの $1 が次の行の行番号となり、省略することもできる $3 は(クォートありかなしで指定された)ファイル名となります。 最近の C プリプロセッサとは違って、# の前に空白を置けないことに 注意してください。
行指示子にはかなり明らかな技があります: デバッガとプロファイラは、 与えられたファイルの特定の行番号に対して現れた最新のソース行のみを 表示します。 あとでデバッグしたいコードでは行番号の衝突が起きないように注意するべきです。
コマンドシェルでタイプすることのできる例をいくつか挙げます:
% perl
# line 200 "bzzzt"
# the `#' on the previous line must be the first char on line
die 'foo';
__END__
foo at bzzzt line 201.
% perl
# line 200 "bzzzt"
eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
__END__
foo at - line 2001.
% perl
eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
__END__
foo at foo bar line 200.
% perl
# line 345 "goop"
eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
print $@;
__END__
foo at goop line 345.