NAME

perlfunc - Perl 組み込み関数

DESCRIPTION

この節の関数は、式の中で項として使うことができます。 これらは、大きく二つに分けられます: リスト演算子と名前付き単項演算子です。 これらの違いは、その後に出て来るコンマとの優先順位の関係にあります。 (perlop の優先順位の表を参照してください。) リスト演算子は 2 個以上の引数をとるのに対して、単項演算子が複数の引数を とることはありません。 つまり、コンマは単項演算子の引数の終わりとなりますが、リスト演算子の 場合には、引数の区切りでしかありません。 単項演算子は一般に、引数に対してスカラコンテキストを与えるのに対して、 スカラ演算子の場合には、引数に対してスカラコンテキストを与える場合も、 リストコンテキストを与える場合もあります。 一つのリスト演算子が両方のコンテキストを与える場合には、スカラ引数が いくつか並び、最後にリスト引数が一つ続きます; そしてそのようなリスト引数は一つだけしかありません。 たとえば、splice() は三つのスカラ引数に一つのリスト引数が続きます; 一方 gethostbyname() は四つのスカラ引数を持ちます。

後に載せる構文記述では、リストをとり (そのリストの要素にリストコンテキストを 与える)リスト演算子は、引数として LIST をとるように書いています; そのようなリストには、任意のスカラ引数の組み合わせやリスト値を 含めることができ、リスト値はリストの中に、個々の要素が展開されたように 埋め込まれます。 1 次元の長いリスト値が形成されることになります。 LIST のリテラルな要素は、コンマで区切られます。

以下のリストの関数はすべて、引数の前後の括弧は省略可能となっています。 (構文記述では省略しています。) 括弧を使うときには、単純な、(しかし、ときには驚く結果となる規則が 適用できます: 関数に見えるならば、それは関数で、優先順位は関係ありません。 そう見えなければ、それはリスト演算子か単項演算子で、優先順位が関係します。 関数と開き括弧の間の空白は関係ありませんので、ときに 気を付けなければなりません:

    print 1+2+4;      # Prints 7.
    print(1+2) + 4;   # Prints 3.
    print (1+2)+4;    # Also prints 3!
    print +(1+2)+4;   # Prints 7.
    print ((1+2)+4);  # Prints 7.

Perl に -w スイッチを付けて実行すれば、こういったものには警告を 出してくれます。 たとえば、上記の三つめは、以下のような警告が出ます:

    print (...) interpreted as function at - line 1.
    Useless use of integer addition in void context at - line 1.

いくつかの関数は引数を全くとらないので、単項演算子としても リスト演算子としても動作しません。 このような関数としては timeendpwent があります。 例えば、time+86_400 は常に time() + 86_400 として扱われます。

スカラコンテキストでも、リストコンテキストでも使える関数は、致命的でない エラーを示すために、スカラコンテキストでは未定義値を返し、 リストコンテキストでは空リストを返します。

以下に述べる重要なルールを忘れないで下さい: リストコンテキストでの 振る舞いとスカラコンテキストでの振る舞いの関係、あるいはその逆に ルールはありません。 2 つの全く異なったことがあります。 それぞれの演算子と関数は、スカラコンテキストでは、もっとも適切と 思われる値を返します。 リストコンテキストで返す時のリストの長さを返す演算子もあります。 リストの最初の値を返す演算子もあります。 リストの最後の値を返す演算子もあります。 成功した操作の数を返す演算子もあります。 一般的には、一貫性を求めない限り、こちらが求めることをします。

スカラコンテキストでの名前付き配列は、スカラコンテキストでのリストを 一目見たものとは全く違います。 コンパイラはコンパイル時にコンテキストを知っているので、 (1,2,3) のようなリストをスカラコンテキストで得ることはできません。 これはスカラコンマ演算子を生成し、コンマのリスト作成版ではありません。 これは初めからリストであることはないことを意味します。

一般的に、同じ名前のシステムコールのラッパーとして動作する Perl の関数 (chown(2), fork(2), closedir(2) など)は、以下に述べるように、 成功時に真を返し、そうでなければ undef を返します。 これは失敗時に -1 を返す C のインターフェースとは違います。 このルールの例外は wait, waitpid, syscall です。 システムコールは失敗時に特殊変数 $! をセットします。 その他の関数は、事故を除いて、セットしません。

エクステンションモジュールは、新しい種類のキーワードが頭に付いた式を 定義するために Perl パーサをフックできます。 これらは関数のように見えるかもしれませんが、全く別物かもしれません。 キーワード以降の文法は完全にエクステンションによって定義されます。 もしあなたが実装者なら、この機構については "PL_keyword_plugin" in perlapi を 参照してください。 もしあなたがそのようなモジュールを使っているなら、 定義されている文法の詳細についてはモジュールの文書を参照してください。

カテゴリ別の Perl 関数

以下に、カテゴリ別の関数(キーワードや名前付き演算子のような、 関数のように見えるものも含みます)を示します。 複数の場所に現れる関数もあります。

スカラや文字列のための関数

chomp, chop, chr, crypt, fc, hex, index, lc, lcfirst, length, oct, ord, pack, q//, qq//, reverse, rindex, sprintf, substr, tr///, uc, ucfirst, y///

fc"fc" 機能が有効か CORE:: が前置されたときにのみ利用可能です。 "fc" 機能は現在のスコープで use v5.16 (またはそれ以上) が宣言されると 自動的に有効になります。

正規表現とパターンマッチング

m//, pos, qr//, quotemeta, s///, split, study

数値関数

abs, atan2, cos, exp, hex, int, log, oct, rand, sin, sqrt, srand

実配列のための関数

each, keys, pop, push, shift, splice, unshift, values

リストデータのための関数

grep, join, map, qw//, reverse, sort, unpack

実ハッシュのための関数

delete, each, exists, keys, values

入出力関数

binmode, close, closedir, dbmclose, dbmopen, die, eof, fileno, flock, format, getc, print, printf, read, readdir, readline rewinddir, say, seek, seekdir, select, syscall, sysread, sysseek, syswrite, tell, telldir, truncate, warn, write

say"say" 機能が有効か CORE:: が前置されたときにのみ利用可能です。 "say" 機能は現在のスコープで use v5.10 (またはそれ以上) が宣言されると 自動的に有効になります。

固定長データやレコードのための関数

pack, read, syscall, sysread, sysseek, syswrite, unpack, vec

ファイルハンドル、ファイル、ディレクトリのための関数

-X, chdir, chmod, chown, chroot, fcntl, glob, ioctl, link, lstat, mkdir, open, opendir, readlink, rename, rmdir, stat, symlink, sysopen, umask, unlink, utime

break, caller, continue, die, do, dump, eval, evalbytes exit, __FILE__, goto, last, __LINE__, next, __PACKAGE__, redo, return, sub, __SUB__, wantarray

break"switch" 機能が有効か CORE:: 接頭辞を使ったときにのみ 利用可能です。 "switch" 機能は "Switch Statements" in perlsyn で文書化されている default, given, when 文も有効にします。 "switch" 機能は現在のスコープで use v5.10 (またはそれ以上) が 宣言されると自動的に有効になります。 Perl v5.14 以前では、continue は他のキーワードと同様に "switch" 機能が 必要です。

evalbytes"evalbytes" 機能 (feature 参照) が有効か CORE:: が 前置されたときにのみ利用可能です。 __SUB__"current_sub" 機能が有効か CORE:: が前置されたときにのみ 利用可能です。 "evalbytes""current_sub" の両方の機能は現在のスコープで use v5.16 (またはそれ以上) が宣言されると自動的に有効になります。

caller, import, local, my, our, package, state, use

state"state" 機能が有効か CORE:: を前置した場合にのみ 利用可能です。 "state" 機能は現在のスコープで use v5.10 (またはそれ以上) を宣言した 場合自動的に有効になります。

さまざまな関数

defined, formline, lock, prototype, reset, scalar, undef

プロセスとプロセスグループのための関数

alarm, exec, fork, getpgrp, getppid, getpriority, kill, pipe, qx//, readpipe, setpgrp, setpriority, sleep, system, times, wait, waitpid

do, import, no, package, require, use

bless, dbmclose, dbmopen, package, ref, tie, tied, untie, use

低レベルソケット関数

accept, bind, connect, getpeername, getsockname, getsockopt, listen, recv, send, setsockopt, shutdown, socket, socketpair

System V プロセス間通信関数

msgctl, msgget, msgrcv, msgsnd, semctl, semget, semop, shmctl, shmget, shmread, shmwrite

ユーザーとグループの情報取得

endgrent, endhostent, endnetent, endpwent, getgrent, getgrgid, getgrnam, getlogin, getpwent, getpwnam, getpwuid, setgrent, setpwent

ネットワーク情報取得

endprotoent, endservent, gethostbyaddr, gethostbyname, gethostent, getnetbyaddr, getnetbyname, getnetent, getprotobyname, getprotobynumber, getprotoent, getservbyname, getservbyport, getservent, sethostent, setnetent, setprotoent, setservent

gmtime, localtime, time, times

Non-function keywords

and, AUTOLOAD, BEGIN, CHECK, cmp, CORE, __DATA__, default, DESTROY, else, elseif, elsif, END, __END__, eq, for, foreach, ge, given, gt, if, INIT, le, lt, ne, not, or, UNITCHECK, unless, until, when, while, x, xor

移植性

Perl は Unix 環境で生まれたので、全ての共通する Unix システムコールに アクセスします。 非 Unix 環境では、いくつかの Unix システムコールの機能が使えなかったり、 使える機能の詳細が多少異なったりします。 これによる影響を受ける Perl 関数は以下のものです:

-X, binmode, chmod, chown, chroot, crypt, dbmclose, dbmopen, dump, endgrent, endhostent, endnetent, endprotoent, endpwent, endservent, exec, fcntl, flock, fork, getgrent, getgrgid, gethostbyname, gethostent, getlogin, getnetbyaddr, getnetbyname, getnetent, getppid, getpgrp, getpriority, getprotobynumber, getprotoent, getpwent, getpwnam, getpwuid, getservbyport, getservent, getsockopt, glob, ioctl, kill, link, lstat, msgctl, msgget, msgrcv, msgsnd, open, pipe, readlink, rename, select, semctl, semget, semop, setgrent, sethostent, setnetent, setpgrp, setpriority, setprotoent, setpwent, setservent, setsockopt, shmctl, shmget, shmread, shmwrite, socket, socketpair, stat, symlink, syscall, sysopen, system, times, truncate, umask, unlink, utime, wait, waitpid

これらの関数の移植性に関するさらなる情報については、 perlport とその他のプラットホーム固有のドキュメントを参照してください。

Alphabetical Listing of Perl Functions

-X FILEHANDLE
-X EXPR
-X DIRHANDLE
-X

X は以下にあげる文字で、ファイルテストを行ないます。 この単項演算子は、ファイル名かファイルハンドルを唯一の 引数として動作し、「あること」について真であるか否かを 判定した結果を返します。 引数が省略されると、-t では STDIN を調べますが、その他は $_ を調べます。 特に記述されていなければ、真として 1 を返し、偽として '' を返し、ファイルが存在しなければ、未定義値を返します。 みかけは変わっていますが、優先順位は名前付き単項演算子と同じで、 他の単項演算子と同じく、引数を括弧で括ることもできます。 演算子には以下のものがあります:

    -r  ファイルが実効 uid/gid で読み出し可。
    -w  ファイルが実効 uid/gid で書き込み可。
    -x  ファイルが実効 uid/gid で実行可。
    -o  ファイルが実効 uid の所有物。

    -R  ファイルが実 uid/gid で読み出し可。
    -W  ファイルが実 uid/gid で書き込み可。
    -X  ファイルが実 uid/gid で実行可。
    -O  ファイルが実 uid の所有物。

    -e  ファイルが存在する。
    -z  ファイルの大きさがゼロ(空)。
    -s  ファイルの大きさがゼロ以外 (バイト単位での大きさを返す)。

    -f  ファイルは通常ファイル。
    -d  ファイルはディレクトリ。
    -l  ファイルはシンボリックリンク。
    -p  ファイルは名前付きパイプ (FIFO) またはファイルハンドルはパイプ。
    -S  ファイルはソケット。
    -b  ファイルはブロック特殊ファイル。
    -c  ファイルはキャラクタ特殊ファイル。
    -t  ファイルハンドルは tty にオープンされている。

    -u  ファイルの setuid ビットがセットされている。
    -g  ファイルの setgid ビットがセットされている。
    -k  ファイルの sticky ビットがセットされている。

    -T  ファイルは ASCII テキストファイル (発見的に推測します)。
    -B  ファイルは「バイナリ」ファイル (-T の反対)。

    -M  スクリプト実行開始時刻からファイル修正時刻を引いたもの(日単位)。
    -A  同様にアクセスがあってからの日数。
    -C  同様に(Unix では) inode が変更されてからの日数(それ以外の
        プラットフォームでは違うかもしれません)。

例:

    while (<>) {
        chomp;
        next unless -f $_;  # ignore specials
        #...
    }

-s/a/b は、置換演算 (s///) の符号反転ではありません。 しかし、-exp($foo) は期待どおりに動作します; しかし、マイナス記号の後に 英字が 1 字続くときにのみ、ファイルテストと解釈されます。

これらの演算子は上述の「関数のように見えるルール」から免除されます。 つまり、演算子の後の開きかっこは、引き続くコードのどこまでが引数を 構成するかに影響を与えません。 演算子を引き続くコードから分離するには、演算子の前に開きかっこを 置いてください (これはもちろん、単項演算子より高い優先順位を持つ 演算子にのみ適用されます):

    -s($file) + 1024   # probably wrong; same as -s($file + 1024)
    (-s $file) + 1024  # correct

ファイルのパーミッション演算子 -r, -R, -w, -W, -x, -X の解釈は、ファイルのモードとユーザの実効/実 uid と 実効/実 gid のみから判断されます。 実際にファイルが読めたり、書けたり、実行できたりするためには、 別の条件が必要かもしれません: 例えば、ネットワークファイルシステムアクセスコントロール、 ACL(アクセスコントロールリスト)、読み込み専用ファイルシステム、 認識できない実行ファイルフォーマット、などです。 これらの 6 つの演算子を、特定の操作が可能かどうかを確認するために使うのは 通常は誤りであることに注意してください; なぜなら、これらは競合条件を 招きやすいからです。

ローカルファイルシステムのスーパーユーザには、 -r, -R, -w, -W に対して、常に 1 が返り、モード中の いずれかの実行許可ビットが立っていれば、-x, -X にも 1 が 返ることにも注意してください。 スーパーユーザが実行するスクリプトでは、ファイルのモードを調べるためには、 stat() を行なうか、実効 uid を一時的に別のものにする 必要があるでしょう。

ACL を使っている場合は、生の stat() モードビットより 精度の高い結果を作成する filetest プラグマがあります。 use filetest 'access' とした場合、上述したファイルテストは システムコールの access(2) ファミリーを使って権限が与えられているか どうかをテストします。 また、このプラグマが指定されている場合、-x-X は たとえ実行許可ビット(または追加の実行許可 ACL)がセットされていない 場合でも真を返すことに注意してください。 この挙動は使用するシステムコールの定義によるものです。 use filetest 'access' の実装により、このプラグマが有効の場合は _ 特殊ファイルハンドルはファイルテストの結果をキャッシュしないことに 注意してください。 さらなる情報については filetest プラグマのドキュメントを 参照してください。

ファイルテスト -T-B の動作原理は、次のようになっています。 ファイルの最初の数ブロックを調べて、変わった制御コードや 上位ビットがセットされているような、通常のテキストには現れない文字を探します。 そのような文字が、たくさん (>30%) 見つかるようであれば、 そのファイルは -B ファイルであると判断されます; さもなければ -T ファイルとなります。 最初のブロックにヌル文字が含まれるファイルも、 バイナリファイルとみなされます。 -T-B をファイルハンドルに対して用いると、 最初のブロックを調べる代わりに、IO バッファを調べます。 調べたファイルの中身が何もないときや、 ファイルハンドルを調べたときに EOF に達して いたときには、-T-B も「真」を返します。 -T テストをするためにはファイルを読み込まないといけないので、 たいていは next unless -f $file && -T $file というような形で まず調べたいファイルに対して -f を使いたいはずです。

どのファイルテスト (あるいは、statlstat) 演算子にも、 下線だけから成る特別なファイルハンドルを与えると、 前回のファイルテスト (や stat) の stat 構造体が使われ、 システムコールを省きます。 (-t には使えませんし、lstat() や -l は実ファイルではなく、 シンボリックリンクの情報を stat 構造体に残すことを 覚えておく必要があります。) (また、stat バッファが lstat 呼び出しで埋まった場合、 -T-B の結果は stat _ の結果でリセットされます。 例:

    print "Can do.\n" if -r $a || -w _ || -x _;

    stat($filename);
    print "Readable\n" if -r _;
    print "Writable\n" if -w _;
    print "Executable\n" if -x _;
    print "Setuid\n" if -u _;
    print "Setgid\n" if -g _;
    print "Sticky\n" if -k _;
    print "Text\n" if -T _;
    print "Binary\n" if -B _;

Perl 5.10.0 から、純粋にシンタックスシュガーとして、ファイルテスト演算子を スタックさせることができるので、-f -w -x $file-x $file && -w _ && -f _ と等価です。 (これは文法上だけの話です; もし -f $file の返り値を他のファイルテスト 演算子の引数として使う場合は、何の特別なことも起きません。)

移植性の問題: "-X" in perlport

あなたのコードのユーザーが不思議な文法エラーで混乱することを 避けるために、スクリプトの先頭に以下のようなことを書いてください:

    use 5.010;  # so filetest ops can stack
abs VALUE
abs

引数の絶対値を返します。 VALUE が省略された場合は、$_ を使います。

accept NEWSOCKET,GENERICSOCKET

accept(2) システムコールと同様に、着信するソケットの接続を受け付けます。 成功時にはパックされたアドレスを返し、失敗すれば偽を返します。 "Sockets: Client/Server Communication" in perlipc の例を参照してください。

ファイルに対する close-on-exec フラグをサポートしているシステムでは、 フラグは $^F の値で決定される、新しくオープンされたファイル記述子に対して セットされます。 "$^F" in perlvar を参照してください。

alarm SECONDS
alarm

指定した壁時計秒数が経過した後に、自プロセスに SIGALRM が 送られてくるようにします。 SECONDS が指定されていない場合は、$_ に格納されている値を使います。 (マシンによっては、秒の数え方が異なるため、指定した秒数よりも最大で 1 秒ずれます。)

一度には一つのタイマだけが設定可能です。 呼び出しを行なう度に、以前のタイマを無効にしますし、 新しくタイマを起動しないで以前のタイマをキャンセルするために 引数に 0 を指定して呼び出すことができます。 以前のタイマの残り時間が、返り値となります。

1 秒より精度の高いスリープを行なうには、 Time::HiRes モジュール(CPAN から、また Perl 5.8 からは 標準配布されています) が ualarm() を提供します。 Perl の 4 引数版 select() を最初の 3 引数を未定義にして使うか、 setitimer(2) をサポートしているシステムでは、Perl の syscall インタフェースを使ってアクセスすることもできます。 詳しくは perlfaq8 を参照してください。

alarmsleep を混ぜて使うのは普通は間違いです; なぜなら、 sleep は内部的に alarm を使って内部的に実装されているかも しれないからです。

alarm をシステムコールの時間切れのために使いたいなら、 eval/die のペアで使う必要があります。 システムコールが失敗したときに $!EINTR がセットされることに 頼ってはいけません; なぜならシステムによっては Perl は システムコールを再開するためにシグナルハンドラを設定するからです。 eval/die は常にうまく動きます; 注意点については "Signals" in perlipc を参照してください。

    eval {
        local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
        alarm $timeout;
        $nread = sysread SOCKET, $buffer, $size;
        alarm 0;
    };
    if ($@) {
        die unless $@ eq "alarm\n";   # propagate unexpected errors
        # timed out
    }
    else {
        # didn't
    }

さらなる情報については perlipc を参照してください。

移植性の問題: "alarm" in perlport

atan2 Y,X

-πからπの範囲で Y/X の逆正接を返します。

正接を求めたいときは、Math::Trig::tan を使うか、 以下のよく知られた関係を使ってください。

    sub tan { sin($_[0]) / cos($_[0])  }

atan2(0,0) の返り値は実装依存です; さらなる情報については atan2(3) man ページを参照してください。

移植性の問題: "atan2" in perlport

bind SOCKET,NAME

bind(2) システムコールと同様に、ネットワークアドレスをソケットに結び付けます。 成功時には真を、さもなければ偽を返します。 NAME は、ソケットに対する、適切な型のパックされた アドレスでなければなりません。 "Sockets: Client/Server Communication" in perlipc の例を参照してください。

binmode FILEHANDLE, LAYER
binmode FILEHANDLE

バイナリファイルとテキストファイルを区別する OS において、 FILEHANDLE を「バイナリ」または「テキスト」で読み書きするように 指定します。 FILEHANDLE が式である場合には、その式の値がファイルハンドルの 名前として使われます。 成功時には真を返し、失敗時には undef を返して $! (errno) を設定します。

テキストファイルでないものを扱う場合に binmode() が必要な システムもあります(一般的には DOS と Windows ベースのシステムです)。 移植性のために、適切なときには常にこれを使い、適切でないときには 決して使わないというのは良い考えです。 また、デフォルトとして I/O を bytes ではなく UTF-8 エンコードされた Unicode にセットすることも出来ます。

言い換えると: プラットフォームに関わらず、 例えばイメージのようなバイナリファイルに対しては binmode() を 使ってください。

LAYER が存在すると、それは単一の文字列ですが、複数の指示子を 含むことができます。 指示子はファイルハンドルの振る舞いを変更します。 LAYER が存在すると、テキストファイルでの binmode が意味を持ちます。

LAYER が省略されたり、:raw が指定されると、ファイルハンドルはバイナリ データの通過に適するように設定されます。 これには CRLF 変換をオフにしたり、それぞれを(Unicode 文字ではなく) バイトであるとマークしたりすることを含みます。 "プログラミング Perl"(ラクダ本第三版) やその他で暗示されているにも関わらず、 :raw は単なる :crlf逆ではありません。 ストリームのバイナリとしての性質に影響を与える その他の層も無効にされますPerlIO, perlrun およびPERLIO 環境変数に関する議論を参照してください。

:bytes, :crlf, and :utf8, 及びその他の :... 形式の指示子は I/O が呼び出されます。 open プラグマはデフォルト I/O 層を指定するために使われます。 open を参照してください。

binmode() 関数の LAYER パラメータは 「プログラミングPerl 第3版」では 「ディシプリン(DISCIPLINE)」と表現されていました。 しかし、「ラクダ本第3版」として知られているこの本の出版後、この機能の名前は 「ディシプリン」から「層」に変更することで合意されました。 従って、このバージョンの Perl の全ての文書では「ディシプリン」ではなく 「層」と記述されています。では通常の解説に戻ります…

FILEHANDLE が UTF-8 であるというマークをつけるには、:utf8:encoding(UTF-8) を使ってください。 :utf8 は、さらなるチェックなしにデータが UTF-8 としてマークしますが、 :encoding(UTF-8) はデータが実際に有効な UTF-8 かどうかをチェックします。 さらなる詳細は PerlIO::encoding にあります。

一般的に binmode() は open() を呼び出した後、このファイルハンドルに対する I/O 操作をする前に呼び出すべきです。 binmode() を呼び出すと、普通はこのファイルハンドルに対して バッファリングされている全ての出力データ (およびおそらくは入力データ)をフラッシュします。 例外は、このハンドルに対するデフォルト文字エンコーディングを変更する :encoding 層です; "open" を参照してください。 :encoding 層はストリームの途中で呼び出す必要があることがあり、 それによってストリームはフラッシュされません。 Perl は内部で UTF-8 エンコードされた Unicode 文字を操作しているので、 :encoding は暗黙のうちに自身を :utf8 層の上に押し上げます。

オペレーションシステム、デバイスドライバ、C ライブラリ、 Perl ランタイムシステムは全て、プログラマが外部表現に関わらず 1 文字 (\n) を行終端として扱えるように協調作業します。 多くのオペレーティングシステムでは、ネイティブテキストファイル表現は 内部表現と同じですが、\n の外部表現が複数文字になる プラットフォームもあります。

全ての Unix 系、(新旧の)Mac OS、VMS の Stream_LF ファイルは テキストの外部表現として各行の末尾に一つの文字を 使っています(しかしその文字は古い Darwin 以前の Mac OS では復帰で、 Unix とほとんどのVMS のファイルでは改行です)。 VMS, MS-DOS, MS-Windows 系といったその他のシステムでは、 プログラムからは \n は単純に \cJ に見えますが、 テキストファイルとして保存される場合は \cM\cJ の 2 文字になります。 つまり、もしこれらのシステムで binmode() を使わないと、 ディスク上の \cM\cJ という並びは入力時に \n に変換され、 プログラムが出力した全ての \n\cM\cJ に逆変換されます。 これはテキストファイルの場合は思い通りの結果でしょうが、 バイナリファイルの場合は悲惨です。

binmode() を(いくつかのシステムで)使うことによるその他の作用としては、 特別なファイル終端マーカーがデータストリームの一部として 見られることです。 Microsoft ファミリーのシステムでは、binmode() を使っていないと もしバイナリデータに \cZ が含まれていたときに、I/O サブシステムが これをファイル終端とみなすことを意味します。

binmode() は readline() と print() 操作にだけではなく、 read(), seek(), sysread(), syswrite(), tell() を使うときにも重要です (詳細は perlport を参照してください)。 入出力の行端末シーケンスを手動でセットする方法については perlvar$/ 変数と $\ 変数を参照してください。

移植性の問題: "binmode" in perlport

bless REF,CLASSNAME
bless REF

この関数は、REF で渡された オブジェクトに対し、 CLASSNAME 内のオブジェクトとなったことを伝えます。 CLASSNAME が省略された場合には、その時点のパッケージとなります。 bless は通常、コンストラクタの最後に置かれますので、 簡便のためにそのリファレンスを返します。 派生クラスが bless される関数を継承する場合は、 常に 2 引数版を使ってください。 オブジェクトの bless (や再 bless) について、詳しくは と perlobj を 参照してください。

大文字小文字が混じっている CLASSNAME のオブジェクトは常に bless することを 考慮してください。 全て小文字の名前を持つ名前空間は Perl プラグマのために予約されています。 組み込みの型は全て大文字の名前を持ちます。 混乱を避けるために、 パッケージ名としてこのような名前は避けるべきです。 CLASSNAME は真の値を持つようにしてください。

"Perl Modules" in perlmod を参照してください。

break

given() ブロックから脱出します。

このキーワードは "switch" 機能によって有効になります; "switch" に関する さらなる情報については feature を参照してください。 CORE:: を前置することによってもアクセスできます。 または、現在のスコープに use v5.10 以降を含めてください。

caller EXPR
caller

その時点のサブルーチン呼び出しのコンテキストを返します。 スカラコンテキストでは、呼び元が ある 場合 (サブルーチン、evalrequire の中にいるとき) には 呼び出し元のパッケージ名を返し、その他のときには未定義値を返します。 リストコンテキストでは、以下を返します:

    # 0         1          2
    ($package, $filename, $line) = caller;

EXPR を付けると、デバッガがスタックトレースを表示するために使う情報を返します。 EXPR の値は、現状から数えて、 いくつ前のコールフレームまで戻るかを示します。

    #  0         1          2      3            4
    ($package, $filename, $line, $subroutine, $hasargs,

    #  5          6          7            8       9         10
    $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
     = caller($i);

もしフレームがサブルーチン呼び出しではなく eval だった場合、この $subroutine は (eval) になります。 この場合、追加の要素である $evaltext と $is_require がセットされます: $is_require はフレームが require または use で作られた場合に 真になり、$evaltext は eval EXPR のテキストが入ります。 特に、eval BLOCK の場合、$subroutine は (eval) になりますが、 $evaltext は未定義値になります。 (それぞれの useeval EXPR の中で require フレームを作ることに 注意してください。) $subroutine は、そのサブルーチンがシンボルテーブルから削除された場合は (unknown) になります。 $hasargs はこのフレーム用に @_ の新しい実体が設定された場合に 真となります。 $hints$bitmask は caller がコンパイルされたときの 実際的なヒントを含みます。 $hints$^H に対応し、$bitmask${^WARNING_BITS} に 対応します。 $hints$bitmask は Perl のバージョンによって変更される 可能性があるので、外部での使用を想定していません。

$hinthash は、caller がコンパイルされた時の %^H の値を含む ハッシュへのリファレンスか、あるいは %^H が空の場合は undef です。 このハッシュの値は構文木に保管されている実際の値なので、変更しないで下さい。

さらに、DB パッケージの中からリストコンテキストで引数付きで呼ばれた場合は、 caller はより詳細な情報を返します; サブルーチンが起動されたときの引数を 変数 @DB::args に設定します。

caller が情報を得る前にオプティマイザが呼び出しフレームを最適化して しまうかもしれないことに注意してください。 これは、caller(N)N > 1 のとき、 あなたが予測した呼び出しフレームの情報を返さないかもしれないことを意味します。 特に、@DB::argscaller が前回呼び出された時の情報を 持っているかもしれません。

@DB::args の設定は ベストエフォート で、デバッグやバックトレースの 生成を目的としていて、これに依存するべきではないということにも 注意してください。 特に、@_ は呼び出し元の引数へのエイリアスを含んでいるので、Perl は @_ のコピーを取らず、従って @DB::args はサブルーチンが @_ やその内容に行った変更を含んでいて、呼び出し時の元の値ではありません。 @DB::args は、@_ と同様、その要素への明示的なリファレンスを 保持しないので、ある種の状況では、解放されて他の変数や一時的な値のために 再割り当てされているかもしれません。 最後に、現在の実装の副作用は、shift @_ の効果は 普通は 行われない (しかし pop @_ やその他の splice は違い、そして もし @_ のリファレンスが取られると違い、そして 再割り当てされた要素に関する 問題になりやすいです)ことなので、@DB::args は実際には現在の状態と @_ の初期状態との合成物となります。 ご用心を。

chdir EXPR
chdir FILEHANDLE
chdir DIRHANDLE
chdir

(可能であれば、) カレントディレクトリを EXPR に移します。 EXPR を指定しないと、$ENV{HOME} が設定されていれば、そのディレクトリに 移ります; そうでなく、$ENV{LOGDIR}が設定されていれば、そのディレクトリに 移ります。 (VMS では $ENV{SYS$LOGIN} もチェックされ、もしセットされていれば 使われます。) どちらも設定されていなければ、chdir は何もしません。 成功時には真を返し、そうでなければ偽を返します。 die の項の例を参照してください。

fchdir(2) に対応しているシステムでは、ファイルハンドルや ディレクトリハンドルを引数として渡せます。 fchdir に対応していないシステムでは、ハンドルを渡すと例外が発生します。

chmod LIST

LIST に含まれるファイルの、パーミッションを変更します。 LIST の最初の要素は、数値表現のモードでなければなりません; 恐らく 8 進表記の数であるべきでしょう: しかし、8 進表記の 文字列ではいけません: 0644 は OK ですが、 '0644' は だめ、ということです。 変更に成功したファイルの数を返します。 文字列を使いたい場合は、"oct" を参照してください。

    $cnt = chmod 0755, "foo", "bar";
    chmod 0755, @executables;
    $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
                                             # --w----r-T
    $mode = "0644"; chmod oct($mode), "foo"; # this is better
    $mode = 0644;   chmod $mode, "foo";      # this is best

fchmod(2) に対応しているシステムでは、ファイルハンドルを引数として渡せます。 fchmod(2) に対応していないシステムでは、ファイルハンドルを渡すと 例外が発生します。 ファイルハンドルを認識させるためには、グロブまたはリファレンスとして 渡されなければなりません; 裸の単語はファイル名として扱われます。

    open(my $fh, "<", "foo");
    my $perm = (stat $fh)[2] & 07777;
    chmod($perm | 0600, $fh);

Fcntl モジュールから S_I* シンボル定数をインポートすることもできます:

    use Fcntl qw( :mode );
    chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
    # Identical to the chmod 0755 of the example above.

移植性の問題: "chmod" in perlport

chomp VARIABLE
chomp( LIST )
chomp

より安全な chop (以下を参照してください) です; $/ (English モジュールでは、$INPUT_RECORD_SEPARATOR とも言う) のその時点の 値に対応する行末文字を削除します。 全ての引数から削除した文字数の合計を返します。 入力レコードから、改行を削除したいのだけれど、最後のレコードには改行が 入っているのかわからないような場合に、使用できます。 段落モード ($/ = "") では、レコードの最後の改行をすべて取り除きます。 吸い込みモード ($/ = undef) や 固定長レコードモード ($/ が整数へのリファレンスや類似のものの場合; perlvarを参照してください) では、chomp() は何も取り除きません。 VARIABLE が省略されると、$_ を対象として chomp します。 例:

    while (<>) {
        chomp;  # avoid \n on last field
        @array = split(/:/);
        # ...
    }

VARIABLE がハッシュなら、ハッシュのキーではなく値について chomp します。

左辺値であれば、代入を含めて、任意のものを chomp できます:

    chomp($cwd = `pwd`);
    chomp($answer = <STDIN>);

リストを chomp すると、個々の要素が chomp され、 削除された文字数の合計が返されます。

単純な変数以外のものを chomp する場合はかっこが必要であることに 注意してください。 これは、chomp $cwd = `pwd`; は、予測している chomp( $cwd = `pwd` ) ではなく、(chomp $cwd) = `pwd`; と 解釈されるからです。 同様に、chomp $a, $bchomp($a, $b) ではなく chomp($a), $b と解釈されます。

chop VARIABLE
chop( LIST )
chop

文字列の最後の文字を切り捨てて、その切り取った文字を返します。 文字列の検索もコピーも行ないませんので s/.$//s よりも、ずっと効率的です。 VARIABLE が省略されると、$_ を対象として chop します。 VARIABLE がハッシュの場合、ハッシュの value を chop しますが、 key は chop しません。

実際のところ、代入を含む左辺値となりうるなんでも chop できます。

リストを chop すると、個々の要素が chop されます。 最後の chop の値だけが返されます。

chop は最後の文字を返すことに注意してください。 最後以外の全ての文字を返すためには、substr($string, 0, -1) を 使ってください。

"chomp" も参照してください。

chown LIST

LIST に含まれるファイルの所有者 (とグループ) を変更します。 LIST の最初の二つの要素には、数値表現 の uid と gid を この順序で与えなければなりません。 どちらかの値を -1 にすると、ほとんどのシステムではその値は 変更しないと解釈します。 変更に成功したファイルの数を返します。

    $cnt = chown $uid, $gid, 'foo', 'bar';
    chown $uid, $gid, @filenames;

fchown(2) に対応しているシステムでは、ファイルハンドルを引数として渡せます。 fchown(2) に対応していないシステムでは、ファイルハンドルを渡すと 例外が発生します。 ファイルハンドルを認識させるためには、グロブまたはリファレンスとして 渡されなければなりません; 裸の単語はファイル名として扱われます。

passwd ファイルから数値表現でない uid を検索する例を 示します:

    print "User: ";
    chomp($user = <STDIN>);
    print "Files: ";
    chomp($pattern = <STDIN>);

    ($login,$pass,$uid,$gid) = getpwnam($user)
        or die "$user not in passwd file";

    @ary = glob($pattern);  # expand filenames
    chown $uid, $gid, @ary;

ほとんどのシステムでは、スーパーユーザーだけがファイルの所有者を 変更できますが、グループは実行者の副グループに変更できるべきです。 安全でないシステムでは、この制限はゆるめられています; しかしこれは 移植性のある仮定ではありません。 POSIX システムでは、以下のようにしてこの条件を検出できます:

    use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
    $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);

移植性の問題: "chmod" in perlport

chr NUMBER
chr

特定の文字セットでの NUMBER で表わされる文字を返します。 たとえば、chr(65) は ASCII と Unicode の両方で "A" となります; chr(0x263a) は Unicode のスマイリーフェイスです。

負の数は Unicode の置換文字 (chr(0xfffd)) を与えますが、 bytes プラグマの影響下では、(integer に切り詰められた)値の下位 8 ビットが 使われます。

NUMBER が省略された場合、$_ を使います。

逆を行うためには、"ord" を参照してください。

128 から 255 までの文字は過去との互換性のために デフォルトでは UTF-8 Unicode にエンコードされません。

Unicode については perlunicode を参照してください。

chroot FILENAME
chroot

同じ名前のシステムコールと同じことをします: 現在のプロセス及び子プロセスに 対して、/で始まるパス名に関して指定されたディレクトリを新しい ルートディレクトリとして扱います。 (これはカレントディレクトリを変更しません; カレントディレクトリは そのままです。) セキュリティ上の理由により、この呼び出しはスーパーユーザーしか行えません。 FILENAME を省略すると、$_chroot します。

移植性の問題: "chroot" in perlport

close FILEHANDLE
close

FILEHANDLE に対応したファイルまたはパイプをクローズして、 IO バッファをフラッシュし、システムファイル記述子をクローズします。 操作が成功し、PerlIO 層からエラーが報告されなかった場合に真を返します。 引数が省略された場合、現在選択されているファイルハンドルをクローズします。

クローズしてすぐにまた、同じファイルハンドルに対してオープンを行なう 場合には、open が自動的に close を行ないますので、 close FILEHANDLE する必要はありません。 (open を参照してください。) ただし、明示的にクローズを行なったときにのみ入力ファイルの 行番号 ($.) のリセットが行なわれ、open によって行なわれる 暗黙の close では行なわれません。

ファイルハンドルがパイプつきオープンなら、close はその他の システムコールが失敗したりプログラムが非ゼロのステータスで終了した場合にも 偽を返します。 プログラムが非ゼロで終了しただけの場合は、$!0にセットされます。 後でパイプの出力を見たい場合のために、パイプのクローズでは、パイプ上で 実行されているプロセスの終了を待ち、また自動的にコマンドのステータス値を $?${^CHILD_ERROR_NATIVE} に設定します。

複数のスレッドがある場合、パイプで開かれたファイルハンドルに対する close は、そのファイルハンドルが他のスレッドでまだ開かれている場合、 子プロセスの終了を待たずに真を返します。

書き込み側が閉じる前に途中でパイプの読み込み側が閉じた場合、 書き込み側に SIGPIPE が配送されます。 書き込み側がこれを扱えない場合、パイプを閉じる前に 確実に全てのデータが読み込まれるようにする必要があります。

例:

    open(OUTPUT, '|sort >foo')  # pipe to sort
        or die "Can't start sort: $!";
    #...                        # print stuff to output
    close OUTPUT                # wait for sort to finish
        or warn $! ? "Error closing sort pipe: $!"
                   : "Exit status $? from sort";
    open(INPUT, 'foo')          # get sort's results
        or die "Can't open 'foo' for input: $!";

FILEHANDLE は式でもかまいません; この場合、値は間接ファイルハンドルと して扱われ、普通は実際のファイルハンドル名か自動有効化されたハンドルです。

closedir DIRHANDLE

opendir でオープンしたディレクトリをクローズし、 システムコールの返り値を返します。

connect SOCKET,NAME

connect(2) システムコールと同様に、リモートソケットへの接続を試みます。 成功時には真を、さもなければ偽を返します。 NAME は、ソケットに対する、適切な型のパックされた アドレスでなければなりません。 "Sockets: Client/Server Communication" in perlipc の例を参照してください。

continue BLOCK
continue

BLOCK が引き続く場合、continue は実際には関数ではなく、実行制御文です。 continue BLOCK が BLOCK (典型的には while または foreach の中)にあると、 これは条件文が再評価される直前に常に実行されます; これは C における for ループの 3 番目の部分と同様です。 従って、これは next 文 (これは C の continue 文と似ています) を使って ループが繰り返されるときでもループ変数を増やしたいときに使えます。

last, next, redocontinue ブロック内に現れる可能性があります; lastredo はメインブロックの中で実行されたのと同じように振舞います。 next の場合は、continue ブロックを実行することになるので、 より面白いことになります。

    while (EXPR) {
        ### redo always comes here
        do_something;
    } continue {
        ### next always comes here
        do_something_else;
        # then back the top to re-check EXPR
    }
    ### last always comes here

continue 節を省略するのは、空の節を指定したのと同じで、 論理的には十分なので、この場合、next は直接ループ先頭の 条件チェックに戻ります。

BLOCK がなければ、continue は動的に囲まれた foreach や レキシカルに囲まれた given で反復するのではなく、現在の when または default のブロックを通り抜けるための文です。 Perl 5.14 以前では、この形式の continue"switch" 機能が有効の 場合にのみ利用可能です。 さらなる情報については feature"Switch Statements" in perlsyn を 参照してください。

cos EXPR
cos

(ラジアンで示した) EXPR の余弦を返します。 EXPR が省略されたときには、$_ の余弦を取ります。

逆余弦を求めるためには、Math::Trig::acos() 関数を使うか、 以下の関係を使ってください。

    sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
crypt PLAINTEXT,SALT

C ライブラリの crypt(3) 関数と全く同じように、ダイジェスト文字列を 作成します(一時的な必需品として、まだ絶滅していないバージョンを 持っていると仮定しています)。

crypt() は一方向ハッシュ関数です。 PLAINTEXT と SALT はダイジェストと呼ばれる短い文字列に変えられて、 それが返されます。 PLAINTEXT と SALT が同じ場合は常に同じ文字列を返しますが、ハッシュから 元の PLAINTEXT を得る(既知の)方法はありません。 PLAINTEXT や SALT を少し変更してもダイジェストは大きく変更されます。

復号化関数はありません。 この関数は暗号化のためにはまったく役に立ちません(このためには、 お近くの CPAN ミラーで Crypt モジュールを探してください)ので、 "crypt" という名前は少し間違った名前です。 その代わりに、一般的には二つのテキスト片が同じかどうかをテキストそのものを 転送したり保管したりせずにチェックするために使います。 例としては、正しいパスワードが与えられたかどうかをチェックがあります。 パスワード自身ではなく、パスワードのダイジェストが保管されます。 ユーザーがパスワードを入力すると、保管されているダイジェストと同じ salt で crypt() します。 二つのダイジェストが同じなら、パスワードは正しいです。

すでにあるダイジェスト文字列を検証するには、ダイジェストを (crypt($plain, $digest) eq $digest のようにして)salt として使います。 ダイジェストを作るのに使われた SALT はダイジェストの一部として見えます。 これにより、crypt() は同じ salt で新しい文字列をダイジェストとして ハッシュ化できるようにします。 これによって標準的な crypt|/crypt や、より風変わりな実装でも動作します。 言い換えると、返される文字列や、SALT が何バイトあるかといったことに対して、 どのような仮定もしてはいけません。

伝統的には結果は 13 バイトの文字列です: 最初の 2 バイトは salt、引き続いて 集合 [./0-9A-Za-z] からの 11 バイトで、PLAINTEXT の最初の 8 バイトだけが意味があります。 しかし、(MD5 のように) 異なったハッシュ手法、 (C2 のような) 高レベルセキュリティ手法、非 Unix プラットフォームでの 実装などでは異なった文字列が生成されることがあります。

新しい salt を選択する場合は、集合 [./0-9A-Za-z] から (join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64] のようにして) ランダムに2 つの文字を選びます。 この文字集合は単なる推薦です; salt として許される文字はシステムの暗号化 ライブラリだけに依存し、Perl は crypt() がどのような salt を受け付けるかに ついて制限しません。

プログラムを実行する人が、 自分のパスワードを知っていることを確認する例です:

    $pwd = (getpwuid($<))[1];

    system "stty -echo";
    print "Password: ";
    chomp($word = <STDIN>);
    print "\n";
    system "stty echo";

    if (crypt($word, $pwd) ne $pwd) {
        die "Sorry...\n";
    } else {
        print "ok\n";
    }

もちろん、自分自身のパスワードを誰にでも入力するのは賢明ではありません。

crypt 関数は大量のデータのハッシュ化には向いていません; これは 情報を戻せないという理由だけではありません。 より頑強なアルゴリズムについては Digest モジュールを参照してください。

Unicode 文字列(潜在的には 255 を越えるコードポイントを持つ文字を 含みます)に crypt() を使った場合、Perl は crypt() を呼び出す前に与えられた 文字列を8 ビットバイト文字列にダウングレードする(文字列のコピーを作る) ことで状況のつじつまを合わせようとします。 うまく動けば、それでよし。 動かなければ、crypt() は Wide character in crypt というメッセージと共に die します。

移植性の問題: "crypt" in perlport

dbmclose HASH

[この関数は、untie 関数に大きくとって代わられました。]

DBM ファイルとハッシュの連結をはずします。

移植性の問題: "dbmclose" in perlport

dbmopen HASH,DBNAME,MASK

[この関数は、tie 関数に 大きくとって代わられました。]

dbm(3), ndbm(3), sdbm(3), gdbm(3) ファイルまたは Berkeley DB ファイルを 連想配列に結び付けます。 HASH は、その連想配列の名前です。 (普通の open とは違って、最初の引数はファイルハンドル ではありません; まあ、似たようなものですが)。 DBNAME は、データベースの名前です (拡張子の .dir や .pag はもしあっても つけません)。 データベースが存在しなければ、MODE MASK (を umask で修正したもの) で 指定されたモードで作られます。 存在しないときにデータベースを作成しないようにするには、MODE に 0 を 設定でき、データベースを見つけられなかった場合は関数は偽を返します。 古い DBM 関数のみをサポートしているシステムでは、プログラム中で 1 度だけ dbmopen() を実行することができます。 昔のバージョンの Perl では、DBM も ndbm も持っていないシステムでは、 dbmopen() を呼び出すと致命的エラーになります; 現在では sdbm(3) に フォールバックします。

DBM ファイルに対して、書き込み権が無いときには、ハッシュ 配列を読みだすことだけができ、設定することはできません。 書けるか否かを調べたい場合には、ファイルテスト 演算子を使うか、エラーをトラップするための eval の中で、 ダミーのハッシュエントリを設定してみることになります。

大きな DBM ファイルを扱うときには、keysvalues のような関数は、 巨大なリストを返します。 大きな DBM ファイルでは、each 関数を使って繰り返しを行なった方が 良いかもしれません。 例:

    # print out history file offsets
    dbmopen(%HIST,'/usr/lib/news/history',0666);
    while (($key,$val) = each %HIST) {
        print $key, ' = ', unpack('L',$val), "\n";
    }
    dbmclose(%HIST);

様々な dbm 手法に対する利点欠点に関するより一般的な記述および 特にリッチな実装である DB_File に関しては AnyDBM_File も参照してください。

dbmopen() を呼び出す前にライブラリを読み込むことで、 どの DBM ライブラリを使うかを制御できます:

    use DB_File;
    dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
        or die "Can't open netscape history file: $!";

移植性の問題: "dbmopen" in perlport

defined EXPR
defined

左辺値 EXPR が未定義値 undef 以外の値を持つか否かを示す、ブール値を 返します。 EXPR がない場合は、$_ がチェックされます。

多くの演算子が、EOF や未初期化変数、システムエラーといった、 例外的な条件で undef を返すようになっています。 この関数は、他の値と undef とを区別するために使えます。 (単純な真偽値テストでは、undef、0、"0" のいずれも偽を返すので、 区別することができません。) undef は有効なスカラ値なので、その存在が 必ずしも 例外的な状況を表すとは限らないということに注意してください: pop は引数が空の配列だったときに undef を返しますが、 あるいは 返すべき要素がたまたま undef だったのかもしれません。

defined(&func) とすることでサブルーチン &func の存在を、 確かめることもできます。 返り値は &func の前方定義には影響されません。 定義されていないサブルーチンも呼び出し可能です: 最初に呼び出されたときに存在するようにするための AUTOLOAD メソッドを持ったパッケージかもしれません; perlsub を参照してください。

集合(ハッシュや配列)への defined の使用は非推奨です。 これはその集合にメモリが割り当てられたかを報告するのに 用いられていました。 この振る舞いは将来のバージョンの Perl では消滅するかもしれません。 代わりにサイズに対する簡単なテストを使うべきです。

    if (@an_array) { print "has array elements\n" }
    if (%a_hash)   { print "has hash members\n"   }

ハッシュの要素に対して用いると、value が定義されているか否かを 返すものであって、ハッシュに key が存在するか否かを返すのではありません。 この用途には、"exists" を使ってください。

例:

    print if defined $switch{D};
    print "$val\n" while defined($val = pop(@ary));
    die "Can't readlink $sym: $!"
        unless defined($value = readlink $sym);
    sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
    $debugging = 0 unless defined $debugging;

注意: 多くの人々が defined を使いすぎて、0""(空文字列) が 実際のところ定義された値であることに驚くようです。 例えば、以下のように書くと:

    "ab" =~ /a(.*)b/;

パターンマッチングが成功し、$1 が定義されても、実際には 「なし」にマッチしています。 しかしこれは何にもマッチしていないわけではありません。 何かにはマッチしているのですが、たまたまそれが長さ 0 だっただけです。 これは非常に率直で正直なことです。 関数が未定義値を返すとき、正直な答えを返すことができないことを 告白しています。 ですので、あなたが自分がしようとしていることの完全性を確認するときにだけ defined を使うべきです。 その他の場合では、単に 0 または "" と比較するというのがあなたの 求めているものです。

"undef", "exists", "ref" も参照してください。

delete EXPR

ハッシュの要素やスライスを指定する式を取り、delete は 指定された要素をハッシュから削除するので、 その要素に対する exists() はもはや真を返さなくなります。 ハッシュ要素に未定義値をセットしてもそのキーは削除されませんが、 delete では削除されます; "exists" を参照してください。

リストコンテキストでは削除された要素を返し、スカラコンテキストでは 削除された要素のうち最後のものを返します。 返されたリストの長さは常に引数リストの長さと一致します: 存在しない要素を削除すると、対応する位置に未定義値をセットして返します。

delete() は配列や配列のスライスに対しても使えますが、その振る舞いは あまり直感的ではありません。 削除されたエントリに対しては exists() は偽を返しますが、 配列要素を削除しても、存在する値の添え字は変わりません; このためには shift() や splice() を使ってください。 しかし、全ての削除された要素が配列の末尾であった場合、配列のサイズは exists() が真となる最大位置の要素(それがない場合は 0)に切り詰められます。

警告: 配列の値に対して delete を呼び出すことは非推奨で、将来の バージョンの Perl では削除される予定です。

%ENV から削除を行なうと、実際に環境変数を変更します。 DBM ファイルに tie された配列からの削除は、その DBM ファイルからエントリを 削除します。 しかし、tie されたハッシュや配列からの削除は、 値を返すとは限りません; これは tie されたパッケージの DELETE メソッドの実装に依存するので、どんなことでも起こります。

delete local EXPR 構文は、現在のブロックの削除を実行時にローカル化します。 ブロックから出るまで、ローカルで削除された要素は存在しなくなります。 "Localized deletion of elements of composite types" in perlsub を 参照してください。

    %hash = (foo => 11, bar => 22, baz => 33);
    $scalar = delete $hash{foo};         # $scalar is 11
    $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
    @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)

以下は、%HASH と @ARRAY のすべての値を(非効率的に)削除します:

    foreach $key (keys %HASH) {
        delete $HASH{$key};
    }

    foreach $index (0 .. $#ARRAY) {
        delete $ARRAY[$index];
    }

そして以下のようにもできます:

    delete @HASH{keys %HASH};

    delete @ARRAY[0 .. $#ARRAY];

しかし、これら二つは両方とも、構造を空にするための慣習的な方法である、 単に空リストを代入するか、%HASH や @ARRAY を undef するより遅いです:

    %HASH = ();     # completely empty %HASH
    undef %HASH;    # forget %HASH ever existed

    @ARRAY = ();    # completely empty @ARRAY
    undef @ARRAY;   # forget @ARRAY ever existed

最終的な操作が集合の要素かスライスである限りは、 いずれかである限りは、EXPR には任意の複雑な式を置くことができます:

    delete $ref->[$x][$y]{$key};
    delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};

    delete $ref->[$x][$y][$index];
    delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
die LIST

die は例外を発生させます。 eval の中で使用すると、エラーメッセージが $@ に入り、eval は 未定義値を返して終了します。 例外が全ての eval の外側の場合は、捕捉されなかった例外は LIST を STDERR に表示して、非 0 の値で終了します。 特定の終了コードでプロセスを終了させる必要がある場合は、"exit" を 参照してください。

等価な例:

    die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
    chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"

LIST の最後の要素が改行で終わっていなければ、その時点のスクリプト名と スクリプトの行番号、(もしあれば) 入力ファイルの行番号と改行文字が、続けて 表示されます。 「入力行番号」("chunk" とも呼ばれます)は「行」という概念が現在有効であると 仮定しています; また特殊変数 $. でも利用可能です。 "$/" in perlvar"$." in perlvar も参照してください。

ヒント: メッセージの最後を ", stopped" のようなもので 終わるようにしておけば、"at foo line 123" のように 追加されて、わかりやすくなります。 "canasta" というスクリプトを実行しているとします。

    die "/etc/games is no good";
    die "/etc/games is no good, stopped";

これは、それぞれ以下のように表示します。

    /etc/games is no good at canasta line 123.
    /etc/games is no good, stopped at canasta line 123.

出力が空で $@ が(典型的には前回の eval で)既に値を持っている場合、 値は "\t...propagated" を追加した後再利用されます。 これは例外を伝播させる場合に有効です:

    eval { ... };
    die unless $@ =~ /Expected exception/;

出力が空で、$@PROPAGATE メソッドを含むオブジェクトへの リファレンスを含む場合、このメソッドが追加ファイルと行番号を引数として 呼び出されます。 返り値は $@ の値を置き換えます; つまり、$@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; が 呼び出されたかのようになります。

$@ が空の場合、"Died" が使われます。

例外が捕捉されないとインタプリタは終了し、終了コードは以下の 擬似コードのように、$!$? の値から決定されます:

    exit $! if $!;              # errno
    exit $? >> 8 if $? >> 8;    # child exit status
    exit 255;                   # last resort

この意図は、できるだけ多くの似たような原因に関する情報を、システム終了 コードという限られた領域に圧縮することです。 しかし、$! はシステムコールによって設定される可能性がある C の errno の値であり、die によって使われる終了コードの値は 予測不能であることを意味するので、非 0 ということ以上にこの値に 依存するべきではありません。

die() はリファレンス引数と共に呼び出すこともでき、これが eval() 内部でトラップされた場合、$@ はそのリファレンスを持ちます。 これは、例外の性質について任意の状態を管理するオブジェクトを使った より複雑な例外処理の実装を可能にします。 このようなスキームは $@ の特定の文字列値を正規表現を使って マッチングするときに時々好まれます。 $@ はグローバル変数で、eval はオブジェクト実装の内部で 使われることがあるので、エラーオブジェクトの解析はグローバル変数の リファレンスを置き換えないことに注意を払わなければなりません。 他の操作をする前にリファレンスのローカルコピーを 作るのが一番簡単です。 以下に例を示します:

    use Scalar::Util "blessed";

    eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
    if (my $ev_err = $@) {
        if (blessed($ev_err)
            && $ev_err->isa("Some::Module::Exception")) {
            # handle Some::Module::Exception
        }
        else {
            # handle all other possible exceptions
        }
    }

perl は捕らえられなかった例外のメッセージを表示する前に文字列化するので、 このようなカスタム例外オブジェクトの文字列化をオーバーロードしたいと 思うかもしれません。 これに関する詳細は overload を参照してください。

$SIG{__DIE__} フックをセットすることで、die がその行動を行う 直前に実行されるコールバックを設定できます。 結び付けられたハンドラはエラーテキストと共に呼び出され、 必要なら再び die を呼び出すことでエラーテキストを変更できアス。 %SIG のエントリをセットする詳細については、"%SIG" in perlvar を、 例については "eval BLOCK" を参照してください。 この機能はプログラムが終了しようとする前に 1 回だけ実行していましたが、 現在ではそうではありません: $SIG{__DIE__} フックは eval() されたブロック/文字列の中でも 呼ばれるのです! もしそのような状況で何もしなくない時は:

    die @_ if $^S;

をハンドラの最初の行に置いてください("$^S" in perlvar を参照してください)。 これは離れたところで不思議な行動を引き起こすので、 この直感的でない振る舞いは将来のリリースで修正されるかもしれません。

exit() と warn() と Carp モジュールも参照してください。

do BLOCK

実際は関数ではありません。 BLOCK で示されるコマンド列の最後の値を返します。 whileuntil ループ修飾子で修飾すると、 ループ条件を調べる前に 1 度、BLOCK を実行します。 (これ以外の実行文は、ループ修飾子により、条件が最初に 調べられます。)

do BLOCK はループとしては 扱われません; 従って、next, last, redo といったループ制御文はブロックから抜けたり 再開することはできません。 その他の戦略については perlsyn を参照してください。

do SUBROUTINE(LIST)

この形のサブルーチン呼び出しは非推奨です。 SUBROUTINE には裸の単語またはスカラ変数が使えます。

do EXPR

EXPR の値をファイル名として用い、そのファイルの中身を Perl のスクリプトとして実行します。

    do 'stat.pl';

はだいたい以下のものと同じようなものですが、

    eval `cat stat.pl`;

より簡潔で、外部プログラムを起動せず、エラーメッセージでファイル名がわかる、 カレントディレクトリでファイルが見つからなかったときに @INC ディレクトリを検索する、ファイルがあったときに %INC を更新する、 といったことがあります。 これらの変数については "@INC" in perlvar"%INC" in perlvar を 参照してください。 do FILENAME で評価されたコードは、入れ子のスコープにある レキシカル変数を見ることができないのに対し、eval STRINGではできる、 という違いがあります。 しかし、呼び出すたびにファイルを解析し直すという点では同じですから、 ループ内でこれを使おうなどとは、間違っても思ったりしないように。

do がファイルを読み込めたがコンパイルできなかった場合、 undef を返して $@ にエラーメッセージを設定します。 doがファイルを読み込めなかった場合、undef を返して $! に エラーを設定します。 コンパイルに失敗したときにも $! が設定されるので、常に $@ を 先にチェックします。 ファイルのコンパイルに成功した場合、do は最後に評価した表現の値を返します。

ライブラリモジュールのインクルードには、use 演算子や require 演算子を 使った方がよいです; これらは自動的にエラーをチェックして、問題があれば例外を 発生させます。

do をプログラム設定ファイルを読み込むのに使いたいかもしれません。 手動のエラーチェックは以下のようにして行えます:

    # read in config files: system first, then user
    for $file ("/share/prog/defaults.rc",
               "$ENV{HOME}/.someprogrc")
    {
        unless ($return = do $file) {
            warn "couldn't parse $file: $@" if $@;
            warn "couldn't do $file: $!"    unless defined $return;
            warn "couldn't run $file"       unless $return;
        }
    }
dump LABEL
dump EXPR
dump

この関数は即座にコアダンプを行ないます。 同様のことを行う perlrun-u オプションも参照してください。 プログラムの先頭で、 すべての変数を初期化したあとのコアダンプを undump プログラム(提供していません)を使って実行ファイルに返ることができます。 この新しいバイナリが実行されると、goto LABEL から始めます (goto に関する制限はすべて適用されます)。 コアダンプをはさんで再生する goto と考えてください。 LABEL が省略されると、プログラムを先頭から再開します。 Perl 5.18.0 から利用可能な dump EXPR 形式では、実行時に計算される 名前が使えます; その他は dump LABEL と同一です。

警告: dump 時点でオープンされていたファイルは、プログラムが 再生されたときには、もはやオープンされていません; Perl を混乱させる可能性が あります。

この関数は大幅に時代遅れのものです; 主な理由としては、コアファイルを 実行形式に変換するのが非常に困難であることです。 これが、今ではタイプミスの可能性を警告されたくないなら CORE::dump() として起動するべき理由です。

ほとんどの名前付き演算子と異なり、これは代入と同じ優先順位を持ちます。 また、関数のように見えるものの規則からも免れるので、dump ("foo")."bar" と すると "bar" は dump への引数の一部になります。

移植性の問題: "dump" in perlport

each HASH
each ARRAY
each EXPR

ハッシュに対してリストコンテキストで呼び出した場合は、次の要素に対する、 ハッシュのキーと値を返します。 Perl 5.12 以降でのみ、配列のインデックスと値からなる 2 要素のリストを返すので、反復を行えます; より古い Perl ではこれは 文法エラーと考えられます。 スカラコンテキストで呼び出した場合は、 ハッシュの場合は(値ではなく)キー、配列の場合はインデックスを返します。

ハッシュ要素は見かけ上、ランダムな順序で返されます。 実際のランダムな順序はハッシュに固有です; 二つのハッシュに全く同じ一連の 操作を行っても、ハッシュによって異なった順序になります。 ハッシュへの挿入によって順序が変わることがあります; 削除も同様ですが、 each または keys によって返されたもっとも最近のキーは順序を 変えることなく削除できます。 ハッシュが変更されない限り、keys, values, each が繰り返し同じ順序で 返すことに依存してもかまいません。 なぜハッシュの順序がランダム化されているかの詳細については "Algorithmic Complexity Attacks" in perlsec を参照してください。 ここで保証したことを除いて、Perl のハッシュアルゴリズムとハッシュ横断順序の 正確な詳細は Perl のリリースによって変更される可能性があります。

each がハッシュをすべて読み込んでしまった後、リストコンテキストでは 空リストが返され、スカラコンテキストでは undef が返されます; そのあと もう一度呼び出すと、再び反復を始めます。 ハッシュや配列毎にそれぞれ反復子があり、eachkeysvalues で アクセスされます。 反復子は、前述したように each が要素をすべて読むことによって 暗黙にリセットされます; また、ハッシュや配列に対して keys HASH, values HASH を呼び出すことで明示的にリセットできます。 繰り返しを行なっている間に、ハッシュに要素を追加したり削除したりすると、 要素が飛ばされたり重複したりするので、してはいけません。 例外: 現在の実装では一番最近に each() から返されたものを削除するのは常に 安全です; これは以下のようなコードが正しく動くことを意味します:

        while (($key, $value) = each %hash) {
          print $key, "\n";
          delete $hash{$key};   # This is safe
        }

これは、printenv(1) プログラムのように環境変数を表示しますが、 順序は異なっています:

    while (($key,$value) = each %ENV) {
        print "$key=$value\n";
    }

Perl 5.14 から、each はスカラの EXPR を取ることができるようになりました; これは bless されていないハッシュや配列へのリファレンスでなければなりません。 引数は自動的にデリファレンスされます。 each のこの動作は高度に実験的であると考えられています。 正確な振る舞いは将来のバージョンの Perl で変わるかも知れません。

    while (($key,$value) = each $hashref) { ... }

Perl 5.18 から while ループの中に裸の each を書けます; これは 繰り返し毎に $_ を設定します。

    while(each %ENV) {
        print "$_=$ENV{$_}\n";
    }

あなたのコードを以前のバージョンの Perl で実行したユーザーが不思議な 文法エラーで混乱することを避けるために、コードが最近のバージョンの Perl で のみ 動作することを示すためにファイルの先頭に以下のようなことを 書いてください:

    use 5.012;  # so keys/values/each work on arrays
    use 5.014;  # so keys/values/each work on scalars (experimental)
    use 5.018;  # so each assigns to $_ in a lone while test

keysvaluessort も参照してください。

eof FILEHANDLE
eof ()
eof

次に FILEHANDLE 上で読み込みを行なったときに、EOF が返されるときか、 または FILEHANDLE がオープンされていないと、1 を返します。 FILEHANDLE は、値が実際のファイルハンドルを示す式であってもかまいません。 (この関数は、実際に文字を読み、ungetc を行ないますので、 対話型の場合には有用ではありません。) 端末ファイルは EOF に達した後にさらに読み込んだり eof(FILEHANDLE) を 呼び出したりしてはいけません。 そのようなことをすると、端末のようなファイルタイプは EOF 状態を失ってしまうかもしれません。

引数を省略した eof は、最後に読み込みを行なったファイルを使います。 空の括弧をつけた eof() は異なります。 これはコマンドラインのファイルリストで構成され、<> 演算子経由で アクセスされる擬似ファイルを示すために用いられます。 通常のファイルハンドルと違って <> は明示的にオープンされないので、 <> を使う前に eof() を使うと、 入力が正常か確認するために @ARGV がテストされます。 同様に、<> が EOF を返した後の eof() は、 他の @ARGV リストを処理していると仮定し、もし @ARGV を セットしていないときは STDIN から読み込みます; "I/O Operators" in perlop を参照してください。

while (<>) ループの中では、個々のファイルの終わりを調べるには、 eofeof(ARGV) を用いるのに対して eof() は最後のファイルの終わりのみを調べます。 例:

    # reset line numbering on each input file
    while (<>) {
        next if /^\s*#/;  # skip comments
        print "$.\t$_";
    } continue {
        close ARGV if eof;  # Not eof()!
    }

    # insert dashes just before last line of last file
    while (<>) {
        if (eof()) {  # check for end of last file
            print "--------------\n";
        }
        print;
        last if eof();     # needed if we're reading from a terminal
    }

現実的なヒント: Perl で eof が必要となることは、ほとんどありません; 基本的には、データがなくなったときやエラーがあったときに、入力演算子が undef を返してくれるからです。

eval EXPR
eval BLOCK
eval

第一の形式では、EXPR の返り値が Perl のプログラムであるかのように 解析され、実行されます。 式の値(それ自身スカラコンテキストの中で決定されます)はまずパースされ、 エラーがなければ Perl プログラムのレキシカルコンテキストの中のブロックとして実行されます。 これは、特に、外側のレキシカル変数は見えていて、パッケージ変数の設定や サブルーチンやフォーマットの定義はその後も残っているということです。

返される値は eval が実行されるごとにパースされることに注意してください。 EXPR が省略されると、$_ を評価します。 この形は主に EXPR のテキストのパースと実行を実行時にまで 遅延させるのに用います。

unicode_eval 機能が有効の場合(これは use 5.16 またはそれ以上が 宣言されている場合はデフォルトです)、EXPR や $_ は文字単位の文字列として 扱われるので、use utf8 宣言は無効で、ソースフィルタは禁止されます。 unicode_eval 機能がなければ、文字列は内部エンコーディングに依存して 時々文字単位として扱われ、時々バイト単位で扱われます; そして eval の 中で有効になったソースフィルタは、まだコンパイル中である一部の外側のファイル スコープに影響を与えるという、間違っているけれども歴史的な振る舞いを 見せます。 入力を常にバイト列として扱い、ソースフィルタが適切に動作する "evalbytes" キーワードおよび feature プラグマを参照してください。

第二の形式では、BLOCK 内部のコードは一度だけパースされ -- コードを 囲む eval 自身がパースされるのと同じ時点です -- 現在の Perl プログラムの コンテキストで実行されます。 この形式は典型的には第一の形式より効率的に例外をトラップします(後述); また BLOCK 内部のコードはコンパイル時にチェックされるという利点を提供します。

最後のセミコロンは、もしあれば、EXPR の値や BLOCK の中身から省くことができます。

どちらの形式でも、返される値はミニプログラムの内部で最後に評価された 表現の値です; サブルーチンと同様、return 文も使えます。 返り値として提供される表現は、eval 自身のコンテキストに依存して 無効・スカラ・リストのいずれかのコンテキストで評価されます。 評価コンテキストの決定方法についての詳細は "wantarray" を参照してください。

構文エラーや実行エラーが発生するか、die 文が実行されると、 eval はスカラコンテキストでは undef が、リストコンテキストでは 空リスト が設定されます。 (5.16 以前では、バグによって、リストコンテキストで構文エラーの時には undef を返していましたが、実行エラーの時には返していませんでした。) エラーがなければ、$@ は空文字列に設定されます。 lastgoto のようなフロー制御演算子は $@ の設定を回避できます。 eval を、STDERR に警告メッセージを表示させない目的や、 警告メッセージを $@ に格納する目的では使わないでください。 そのような用途では、$SIG{__WARN__} 機能を使うか、 no warnings 'all' を使って BLOCK か EXPR の内部での警告を オフにする必要があります。 "warn", perlvar, warnings, perllexwarn を参照してください。

eval は、致命的エラーとなるようなものをトラップすることができるので、 (socketsymlink といった) 特定の機能が実装されているかを、 調べるために使うことができることに注意してください。 die 演算子が例外を発生させるものとすれば、これはまた、Perl の例外捕捉機能と 捉えることもできます。

XS モジュールのロード中のエラーをトラップしたいなら、 (Perl バージョンの違いのような) バイナリインターフェースに関する問題に ついては $ENV{PERL_DL_NONLAZY} がセットされていない eval でも 致命的エラーになるかもしれません。 perlrun を参照してください。

実行するコードが変わらないのであれば、毎回多量の再コンパイルすることなしに、 実行時エラーのトラップを行なうために、 eval-BLOCK 形式を使うことができます。 エラーがあれば、やはり $@ に返されます。 例:

    # make divide-by-zero nonfatal
    eval { $answer = $a / $b; }; warn $@ if $@;

    # same thing, but less efficient
    eval '$answer = $a / $b'; warn $@ if $@;

    # a compile-time error
    eval { $answer = }; # WRONG

    # a run-time error
    eval '$answer =';   # sets $@

eval{} 形式をライブラリの例外を捕捉するために使うときには 問題があります。 現在の __DIE__ フックの状態はほぼ確実に壊れているという理由で、 ユーザーのコードが設定した __DIE__ フックを実行したくないかもしれません。 この目的には以下の例のように、local $SIG{__DIE__} 構造が使えます。

    # a private exception trap for divide-by-zero
    eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
    warn $@ if $@;

これは特に顕著です; 与えられた __DIE__ フックは die をもう一度 呼び出すことができ、これによってエラーメッセージを変える効果があります:

    # __DIE__ hooks may modify error messages
    {
       local $SIG{'__DIE__'} =
              sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
       eval { die "foo lives here" };
       print $@ if $@;                # prints "bar lives here"
    }

これは距離の離れた行動であるため、この直感的でない振る舞いは 将来のリリースでは修正されるかもしれません。

eval では、以下のような場合に、 何が調べられるかに特に注意しておくことが必要です:

    eval $x;        # CASE 1
    eval "$x";      # CASE 2

    eval '$x';      # CASE 3
    eval { $x };    # CASE 4

    eval "\$$x++";  # CASE 5
    $$x++;          # CASE 6

上記の CASE 1 と CASE 2 の動作は同一で、変数 $x 内の コードを実行します。 (ただし、CASE 2 では、必要のないダブルクォートによって、 読む人が何が起こるか混乱することでしょう (何も起こりませんが)。) 同様に CASE 3 と CASE 4 の動作も等しく、$x の値を返す以外に 何もしない $x というコードを実行します (純粋に見た目の問題で、CASE 4 が好まれますが、 実行時でなくコンパイル時にコンパイルされるという利点もあります)。 CASE 5 の場合は、通常ダブルクォートを使用します。 この状況を除けば、CASE 6 のように、単に シンボリックリファレンスを使えば良いでしょう。

Perl 5.14 より前では、$@ への代入はローカル化された変数の復帰の前に 起きるので、古いバージョンで実行される場合は、全てではなく一部だけの エラーをマスクしたい場合には一時変数が必要です:

    # alter $@ on nefarious repugnancy only
    {
       my $e;
       {
         local $@; # protect existing $@
         eval { test_repugnancy() };
         # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
         $@ =~ /nefarious/ and $e = $@;
       }
       die $e if defined $e
    }

eval BLOCK はループとして 扱われません; 従って、next, last, redo といったループ制御文でブロックから離れたり再実行したりはできません。

DB パッケージで定義されたサブルーチン内で eval '' を実行すると、通常の レキシカルスコープではなく、これを呼び出した最初の非 DB コード片の スコープになります。 Perl デバッガを書いているのでない限り、普通はこれについて心配する必要は ありません。

evalbytes EXPR
evalbytes

この関数は文字列引数の "eval" と同様ですが、引数(EXPR が省略された場合は $_) を常にバイト単位のの文字列として扱います。 序数が 255 を超える文字を含む文字列はエラーになります。 eval されたコード内で有効になったソースフィルタはコード自体に適用されます。

この関数は evalbytes 機能が有効か、use v5.16 (またはそれ以上) が 宣言されるか、CORE:: 接頭辞付きの場合にのみ有効です。 さらなる情報については feature を参照してください。

exec LIST
exec PROGRAM LIST

exec 関数は、システムのコマンドを実行し、戻ってはきません; 戻って欲しい場合には、execではなく system 関数を使ってください。 コマンドが存在せず、しかも システムのコマンドシェル経由でなく 直接コマンドを実行しようとした場合にのみこの関数は失敗して偽を返します。

system の代わりに exec を使うというよくある間違いを防ぐために、 exec が無効コンテキストで呼び出されて、引き続く文が die, warn, exit 以外の場合、Perl は警告を出します(-w がセットされている場合 -- でもいつもセットしてますよね?)。 もし 本当に exec の後に他の文を書きたい場合、以下のどちらかの スタイルを使うことで警告を回避できます:

    exec ('foo')   or print STDERR "couldn't exec foo: $!";
    { exec ('foo') }; print STDERR "couldn't exec foo: $!";

LIST に複数の引数がある場合か、LIST が複数の値を持つ 配列の場合には、LIST の引数を使って、execvp(3) を呼び出します。 1 つのスカラ引数のみまたは要素が一つの配列の場合には、その引数から シェルのメタ文字をチェックし、もし、メタ文字があれば、 引数全体をシステムのコマンドシェル(これはUnix では /bin/sh -c ですが、システムによって異なります)に渡して解析させます。 シェルのメタ文字がなかった場合、引数は単語に分解されて直接 execvp に 渡されます; この方がより効率的です。 例:

    exec '/bin/echo', 'Your arguments are: ', @ARGV;
    exec "sort $outfile | uniq";

第一引数に指定するものを本当に実行したいが、実行する プログラムに対して別の名前を教えたい場合には、LISTの前に、 「間接オブジェクト」(コンマなし) として、実際に 実行したいプログラムを指定することができます。 (これによって、LIST に単一のスカラしかなくても、複数 値のリストであるように、LIST の解釈を行ないます。) 例:

    $shell = '/bin/csh';
    exec $shell '-sh';    # pretend it's a login shell

あるいは、より直接的に、

    exec {'/bin/csh'} '-sh';  # pretend it's a login shell

引数がシステムシェルで実行されるとき、結果はシェルの奇癖と能力によって 変わります。 詳細については "`STRING`" in perlop を参照してください。

execsystem で間接オブジェクトを使うのもより安全です。 この使い方(system() でも同様にうまく動きます)は、たとえ引数が一つだけの 場合も、複数の値を持つリストとして引数を解釈することを強制します。 この方法で、シェルによるワイルドカード展開や、空白による単語の分割から 守られます。

    @args = ( "echo surprise" );

    exec @args;               # subject to shell escapes
                                # if @args == 1
    exec { $args[0] } @args;  # safe even with one-arg list

間接オブジェクトなしの一つ目のバージョンでは、echo プログラムが実行され、 "surprise" が引数として渡されます。 二つ目のバージョンでは違います; "echo surprise" という名前の プログラムを実行しようとして、見つからないので、失敗したことを示すために $? に非 0 がセットされます。

v5.6.0 から、Perl は exec の前に出力用に開かれている全てのファイルを フラッシュしようとしますが、これに対応していないプラットフォームもあります (perlport を参照してください)。 安全のためには、出力が重複するのを避けるために、全てのオープンしている ハンドルに対して $| (English モジュールでは $AUTOFLUSH) を設定するか、 IO::Handle モジュールの autoflush() メソッドをを呼ぶ必要が あるかもしれません。

execEND ブロックや、オブジェクトの DESTROY メソッドを 起動しないことに注意してください。

移植性の問題: "exec" in perlport

exists EXPR

ハッシュ要素を示す表現が与えられ、指定された要素が、ハッシュに存在すれば、 たとえ対応する値が未定義でも真を返します。

    print "Exists\n"    if exists $hash{$key};
    print "Defined\n"   if defined $hash{$key};
    print "True\n"      if $hash{$key};

exists は配列の要素に対しても呼び出せますが、その振る舞いははるかに 不明確で、配列に対する "delete" の使用と強く結びついています。 配列の値に対して exists を呼び出すのは非推奨であり、将来のバージョンの Perl では削除されるかもしれないことを 注意してください

    print "Exists\n"    if exists $array[$index];
    print "Defined\n"   if defined $array[$index];
    print "True\n"      if $array[$index];

ハッシュまたは配列要素は、定義されているときにのみ真となり、 存在しているときにのみ定義されますが、逆は必ずしも真ではありません。

引数としてサブルーチンの名前が指定された場合、 指定されたサブルーチンが宣言されていれば(たとえ未定義でも) 真を返します。 exists や defined のために言及されているサブルーチン名は 宣言としてのカウントに入りません。 存在しないサブルーチンでも呼び出し可能かもしれないことに注意してください: パッケージが AUTOLOAD メソッドを持っていて、最初に呼び出された時に 存在を作り出すかもしれません; perlsub を参照してください。

    print "Exists\n"  if exists &subroutine;
    print "Defined\n" if defined &subroutine;

最終的な操作がハッシュや配列の key による検索またはサブルーチン名である限りは、 EXPR には任意の複雑な式を置くことができます:

    if (exists $ref->{A}->{B}->{$key})  { }
    if (exists $hash{A}{B}{$key})       { }

    if (exists $ref->{A}->{B}->[$ix])   { }
    if (exists $hash{A}{B}[$ix])        { }

    if (exists &{$ref->{A}{B}{$key}})   { }

最も深くネストした配列やハッシュの要素は、その存在をテストしただけでは 存在するようにはなりませんが、途中のものは存在するようになります。 従って $ref->{"A"}$ref->{"A"}->{"B"} は上記の $key の 存在をテストしたことによって存在するようになります。 これは、矢印演算子が使われるところでは、以下のようなものを含むどこででも 起こります。

    undef $ref;
    if (exists $ref->{"Some key"})    { }
    print $ref;  # prints HASH(0x80d3d5c)

一目見ただけでは -- あるいは二目見ても -- 驚かされる、左辺値コンテキストでの 自動有効化は将来のリリースでは修正されるでしょう。

exists() の引数としてサブルーチン名でなくサブルーチン呼び出しを使うと、 エラーになります。

    exists &sub;    # OK
    exists &sub();  # Error
exit EXPR
exit

EXPR を評価し、即座にその値を持って終了します。 例:

    $ans = <STDIN>;
    exit 0 if $ans =~ /^[Xx]/;

die も参照してください。 EXPR が省略された場合には、ステータスを 0 として終了します。 EXPR の値として広く利用可能なのは 0 が成功で 1 が エラーということだけです; その他の値は、 Perl が実行される環境によって異なる 解釈がされる可能性があります。 例えば、sendmail 到着メールフィルタから 69 (EX_UNAVAILABLE) で終了すると メーラーはアイテムを配達せずに差し戻しますが、 これはいつでも真ではありません。

誰かが発生したエラーをトラップしようと考えている可能性がある場合は、 サブルーチンの中断に exit を使わないでください。 代わりに eval でトラップできる die を使ってください。

exit() 関数は常に直ちに終了するわけではありません。 まず、定義されている END ルーチンを呼び出しますが、 END ルーチン自身は exit を止められません。 同様に、呼び出す必要のあるオブジェクトデストラクタは すべて、実際の終了前に呼び出されます。 END ルーチンとデストラクタは $? を修正することで終了コードを 変更できます。 これが問題になる場合は、END やデストラクタが実行されることを 防ぐために POSIX::_exit($status) を呼び出してください。 詳しくは perlmod を参照してください。

移植性の問題: "exit" in perlport

exp EXPR
exp

e (自然対数の底) の EXPR 乗を返します。 EXPR を省略した場合には、exp($_) を返します。

fc EXPR
fc

EXPR の畳み込み版を返します。 これは、ダブルクォート文字列における、\F エスケープを 実装する内部関数です。

畳み込みは大文字小文字の違いを消した形式に文字列をマッピングする処理です; 畳み込み形式で二つの文字列を比較するのは二つの文字列が大文字小文字に 関わらず等しいかどうかを比較する効率的な方法です。

おおよそ、自分自身で以下のように書いていたとしても

    lc($this) eq lc($that)    # Wrong!
        # or
    uc($this) eq uc($that)    # Also wrong!
        # or
    $this =~ /^\Q$that\E\z/i  # Right!

今では以下のように書けます

    fc($this) eq fc($that)

そして正しい結果を得られます。

Perl は完全な形式の畳み込みのみを実装していますが、 "casefold()" in Unicode::UCD"prop_invmap()" in Unicode::UCD を使って 単純なたたみ込みにアクセスできます。 畳み込みに関するさらなる情報については、 http://www.unicode.org/versions/latest/ で利用可能な Unicode 標準、特に 3.13 Default Case Operations, 4.2 Case-Normative, 5.18 Case Mappings および、http://www.unicode.org/charts/case/ で 利用可能なケース表を参照してください。

EXPR が省略されると、$_ を使います。

この関数は、ロケールのようなさまざまなプラグマの影響下では、 "lc" と同様に振る舞います。

Unicode 標準はさらに二つの畳み込み形式、一つはツルキ語、もう一つは決して 一つの文字が複数の文字にマッピングされないもの、を定義していますが、 これらは Perl コアでは提供されません; しかし、CPAN モジュール Unicode::Casing が実装を提供しています。

このキーワードは "fc" 機能が有効のときか、CORE:: が 前置されたときにのみ利用可能です; feature を参照してください。 または、現在のスコープに use v5.16 またはそれ以上を含めてください。

fcntl FILEHANDLE,FUNCTION,SCALAR

fcntl(2) 関数を実装します。 正しい定数定義を得るために、まず

    use Fcntl;

と書くことが必要でしょう。 引数の処理と返り値については、下記の ioctl と同様に動作します。 例えば:

    use Fcntl;
    fcntl($filehandle, F_GETFL, $packed_return_buffer)
        or die "can't fcntl F_GETFL: $!";

fcntl からの返り値のチェックに defined を使う必要はありません。 ioctl と違って、fnctl はシステムコールの結果が 0 だった場合は "0 だが真"を返します。 この文字列は真偽値コンテキストでは真となり、 数値コンテキストでは 0 になります。 これはまた、不適切な数値変換に関する通常の -w 警告を回避します。

fcntl(2) が実装されていないマシンでは、fcntlは例外を 引き起こすことに注意してください。 システムでどの関数が利用可能かについては Fcntl モジュールや fcntl(2) man ページを参照してください。

これは REMOTE というファイルハンドルをシステムレベルで 非ブロックモードにセットする例です。 ただし、 $| を自分で管理しなければなりません。

    use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);

    $flags = fcntl(REMOTE, F_GETFL, 0)
                or die "Can't get flags for the socket: $!\n";

    $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
                or die "Can't set flags for the socket: $!\n";

移植性の問題: "fcntl" in perlport

__FILE__

これが書いてあるファイルの名前を返す特殊トークン。

fileno FILEHANDLE

ファイルハンドルに対するファイル記述子を返します; ファイルハンドルが オープンしていない場合は未定義値を返します。 OS レベルで実際のファイル記述子がない(open の第 3 引数にリファレンスを 指定してファイルハンドルがメモリオブジェクトと結びつけられたときに 起こります)場合、-1 が返されます。

これは主に select や低レベル POSIX tty 操作に対する、ビットマップを 構成するときに便利です。 FILEHANDLE が式であれば、 その値が間接ファイルハンドル(普通は名前)として使われます。

これを、二つのハンドルが同じ識別子を参照しているかどうかを見つけるのに 使えます:

    if (fileno(THIS) == fileno(THAT)) {
        print "THIS and THAT are dups\n";
    }
flock FILEHANDLE,OPERATION

FILEHANDLE に対して flock(2)、またはそのエミュレーションを呼び出します。 成功時には真を、失敗時には偽を返します。 flock(2), fcntl(2) ロック, lockf(3) のいずれかを実装していない マシンで使うと、致命的エラーが発生します。 flock は Perl の移植性のあるファイルロックインターフェースです; しかしレコードではなく、ファイル全体のみをロックします。

明白ではないものの、伝統的な flock の動作としては、ロックが得られるまで 無限に待ち続けるものと、単に勧告的に ロックするものの二つがあります。 このような自由裁量のロックはより柔軟ですが、保障されるものはより少ないです。 これは、flock を使わないプログラムが flock でロックされたファイルを 書き換えるかもしれないことを意味します。 詳細については、perlport、システム固有のドキュメント、システム固有の ローカルの man ページを参照してください。 移植性のあるプログラムを書く場合は、伝統的な振る舞いを仮定するのが ベストです。 (しかし移植性のないプログラムを書く場合は、自身のシステムの性癖(しばしば 「仕様」と呼ばれます)に合わせて書くことも完全に自由です。 盲目的に移植性に固執することで、あなたの作業を仕上げるのを邪魔するべきでは ありません。)

OPERATION は LOCK_SH, LOCK_EX, LOCK_UN のいずれかで、LOCK_NB と 組み合わされることもあります。 これらの定数は伝統的には 1, 2, 8, 4 の値を持ちますが、Fcntl モジュールから シンボル名を独立してインポートするか、:flock タグを使うグループとして、 シンボル名をを使うことができます。 LOCK_SH は共有ロックを要求し、LOCK_EX は排他ロックを要求し、LOCK_UN は 前回要求したロックを開放します。 LOCK_NB と LOCK_SH か LOCK_EX がビット単位の論理和されると、flock は ロックを取得するまで待つのではなく、すぐに返ります; ロックが取得できたかどうかは返り値を調べます。

不一致の可能性を避けるために、Perl はファイルをロック、アンロックする前に FILEHANDLE をフラッシュします。

lockf(3) で作成されたエミュレーションは共有ロックを提供せず、 FILEHANDLE が書き込みモードで開いていることを必要とすることに 注意してください。 これは lockf(3) が実装している動作です。 しかし、全てではないにしてもほとんどのシステムでは fcntl(2) を使って lockf(3) を実装しているので、異なった動作で多くの人々を混乱させることは ないはずです。

flock(3) の fcntl(2) エミュレーションは、 LOCK_SH を使うためには FILEHANDLE を読み込みで開いている必要があり、LOCK_EX を使うためには 書き込みで開いている必要があることに注意してください。

ネットワーク越しにはロックできない flock もあることに注意してください; このためには、よりシステム依存な fcntl を使う必要があります。 Perl にシステムの flock(2) 関数を無視させ、自身の fcntl(2) ベースの エミュレーションを使う場合は、新しい Perl を設定およびビルドするときに Configure プログラムに -Ud_flock オプションを渡してください。

BSD システムでのメールボックスへの追加処理の例を示します。

    # import LOCK_* and SEEK_END constants
    use Fcntl qw(:flock SEEK_END);

    sub lock {
        my ($fh) = @_;
        flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";

        # and, in case someone appended while we were waiting...
        seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
    }

    sub unlock {
        my ($fh) = @_;
        flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
    }

    open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
        or die "Can't open mailbox: $!";

    lock($mbox);
    print $mbox $msg,"\n\n";
    unlock($mbox);

真の flock(2) に対応しているシステムではロックは fork() を通して 継承されるのに対して、より不安定な fcntl(2) に頼らなければならない場合、 サーバを書くのは本当により難しくなります。

その他の flock() の例としては DB_File も参照してください。

移植性の問題: "flock" in perlport

fork

同じプログラムの同じ地点から開始する新しいプロセスを作成するために システムコール fork(2) を行ないます。 親プロセスには、チャイルドプロセスの pid を、 チャイルドプロセスに 0 を返しますが、 fork に失敗したときには、undefを返します。 ファイル記述子(および記述子に関連するロック)は共有され、 その他の全てはコピーされます。 fork() に対応するほとんどのシステムでは、 これを極めて効率的にするために多大な努力が払われてきました (例えば、データページへの copy-on-write テクノロジーなどです); これはここ 20 年にわたるマルチタスクに関する主要なパラダイムとなっています。

v5.6.0 から、Perl は子プロセスを fork する前に出力用にオープンしている全ての ファイルをフラッシュしようとしますが、これに対応していないプラットフォームも あります(perlport を参照してください)。 安全のためには、出力が重複するのを避けるために、 全てのオープンしているハンドルに対して $| (English モジュールでは $AUTOFLUSH) を設定するか、 IO::Handle モジュールの autoflush()メソッドをを呼ぶ必要が あるかもしれません。

チャイルドプロセスの終了を待たずに、fork を繰り返せば、 ゾンビをためこむことになります。 $SIG{CHLD}"IGNORE" を指定することでこれを回避できるシステムもあります。 fork と消滅しかけている子プロセスを回収するための更なる例については perlipc も参照してください。

fork した子プロセスが STDIN や STDOUT といったシステムファイル記述子を 継承する場合、(CGI スクリプトやリモートシェルといった バックグラウンドジョブのような)リモートサーバは考え通りに 動かないであろうことに注意してください。 このような場合ではこれらを /dev/null として再オープンするべきです。

Windows のような fork() が利用不能なシステムでは、Perl は fork() を Perl インタプリタでエミュレートします。 エミュレーションは Perl プログラムのレベルではできるだけ "Unix" fork() と 互換性があるように設計されています。 しかしコードが移植性があると考えられるように制限があります。 さらなる詳細については perlfork を参照してください。

移植性の問題: "fork" in perlport

format

write 関数で使うピクチャーフォーマットを宣言します。 例えば:

    format Something =
        Test: @<<<<<<<< @||||| @>>>>>
              $str,     $%,    '$' . int($num)
    .

    $str = "widget";
    $num = $cost/$quantity;
    $~ = 'Something';
    write;

詳細と例については perlform を参照してください。

formline PICTURE,LIST

これは、format が使用する内部関数ですが、直接呼び出すこともできます。 これは、PICTURE の内容にしたがって、LIST の値を整形し (perlform を 参照してください)、結果をフォーマット出力アキュムレータ$^A (English モジュールでは $ACCUMULATOR) に納めます。 最終的に、write が実行されると、$^A の中身が、 何らかのファイルハンドルに書き出されます。 また、自分で $^A を読んで、$^A の内容を "" に戻してもかまいません。 format は通常、1 行ごとに formline を行ないますが、 formline 関数自身は、PICTURE の中にいくつの改行が入っているかは、 関係がありません。 これは、~~~トークンは PICTURE 全体を一行として扱うことを意味します。 従って、1 レコードフォーマットを実装するためには フォーマットコンパイラのような複数 formline を使う必要があります。

ダブルクォートで PICTURE を囲む場合には、@ という文字が 配列名の始まりと解釈されますので、注意してください。 formline は常に真を返します。 その他の例については perlform を参照してください。

出力を捕捉するために write の代わりにこれを使おうとした場合、 スカラにファイルハンドルを開いて (open $fh, ">", \$output)、 代わりにここに出力する方が簡単であることに気付くでしょう。

getc FILEHANDLE
getc

FILEHANDLE につながれている入力ファイルから、次の一文字を返します; ファイルの最後、またはエラーが発生した場合は、未定義値を返します (後者の場合は $! がセットされます)。 FILEHANDLE が省略された場合には、STDIN から読み込みを行ないます。 これは特に効率的ではありません。 しかし、これはユーザーがリターンキーを押すのを待つことなく 一文字を読み込む用途には使えません。 そのような場合には、以下のようなものを試して見てください:

    if ($BSD_STYLE) {
        system "stty cbreak </dev/tty >/dev/tty 2>&1";
    }
    else {
        system "stty", '-icanon', 'eol', "\001";
    }

    $key = getc(STDIN);

    if ($BSD_STYLE) {
        system "stty -cbreak </dev/tty >/dev/tty 2>&1";
    }
    else {
        system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
    }
    print "\n";

$BSD_STYLE をセットするべきかどうかを決定する方法については 読者への宿題として残しておきます。

POSIX::getattr 関数は POSIX 準拠を主張するシステムでこれを より移植性のある形で行います。 お近くの CPAN サイトから Term::ReadKey モジュールも参照してください; CPAN に関する詳細は "CPAN" in perlmodlib にあります。

getlogin

これは同じ名前の C ライブラリ関数を実装していて、 多くのシステムでは、もしあれば、/etc/utmp から現在のログイン名を返します。 もし空文字列が返ってきた場合は、getpwuid() を使ってください。

    $login = getlogin || getpwuid($<) || "Kilroy";

getlogin を認証に使ってはいけません: これは getpwuid のように 安全ではありません。

移植性の問題: "getlogin" in perlport

getpeername SOCKET

SOCKET コネクションの向こう側のパックされた aockaddr アドレスを返します。

    use Socket;
    $hersockaddr    = getpeername(SOCK);
    ($port, $iaddr) = sockaddr_in($hersockaddr);
    $herhostname    = gethostbyaddr($iaddr, AF_INET);
    $herstraddr     = inet_ntoa($iaddr);
getpgrp PID

指定された PID の現在のプロセスグループを返します。 PID に 0 を与えるとカレントプロセスの指定となります。 getpgrp(2) を実装していないマシンで実行した場合には、例外が発生します。 PID を省略するとカレントプロセスのプロセスグループを返します。 POSIX 版の getpgrp は PID 引数を受け付けないので、 PID==0 のみが完全に移植性があります。

移植性の問題: "getpgrp" in perlport

getppid

親プロセスのプロセス id を返します。

Linux ユーザーへの注意: v5.8.1 から v5.16.0 の間 Perl は LinuxThreads という非 POSIX なスレッド文法を使っているマイナーな Linux システム (および Debian GNU/kFreeBSD システム) に対応していました。 このエミュレーションは削除されました; 詳しくは $$ の文書を参照してください。

移植性の問題: "getppid" in perlport

getpriority WHICH,WHO

プロセス、プロセスグループ、ユーザに対する現在の優先度を返します。 (getpriority(2) を参照してください。) getpriority(2) を実装していない マシンで実行した場合には、致命的例外が発生します。

移植性の問題: "getpriority" in perlport

getpwnam NAME
getgrnam NAME
gethostbyname NAME
getnetbyname NAME
getprotobyname NAME
getpwuid UID
getgrgid GID
getservbyname NAME,PROTO
gethostbyaddr ADDR,ADDRTYPE
getnetbyaddr ADDR,ADDRTYPE
getprotobynumber NUMBER
getservbyport PORT,PROTO
getpwent
getgrent
gethostent
getnetent
getprotoent
getservent
setpwent
setgrent
sethostent STAYOPEN
setnetent STAYOPEN
setprotoent STAYOPEN
setservent STAYOPEN
endpwent
endgrent
endhostent
endnetent
endprotoent
endservent

これらのルーチンは、システムの C ライブラリの同名の関数と同じです。 リストコンテキストでは、さまざまな get ルーチンからの返り値は、次のようになります:

    ($name,$passwd,$uid,$gid,
       $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
    ($name,$passwd,$gid,$members) = getgr*
    ($name,$aliases,$addrtype,$length,@addrs) = gethost*
    ($name,$aliases,$addrtype,$net) = getnet*
    ($name,$aliases,$proto) = getproto*
    ($name,$aliases,$port,$proto) = getserv*

(エントリが存在しなければ、空リストが返されます。)

$gcos フィールドの正確な意味はさまざまですが、通常は(ログイン名ではなく) ユーザーの実際の名前とユーザーに付随する情報を含みます。 但し、多くのシステムではユーザーがこの情報を変更できるので、この情報は 信頼できず、従って $gcos は汚染されます(perlsec を参照してください)。 ユーザーの暗号化されたパスワードとログインシェルである $passwd と $shell も、同様の理由で汚染されます。

スカラコンテキストでは、*nam、*byname といった NAME で検索するもの以外は、 name を返し、NAME で検索するものは、何か別のものを返します。 (エントリが存在しなければ、未定義値が返ります。) 例えば:

    $uid   = getpwnam($name);
    $name  = getpwuid($num);
    $name  = getpwent();
    $gid   = getgrnam($name);
    $name  = getgrgid($num);
    $name  = getgrent();
    #etc.

getpw*() では、$quota, $comment, $expire フィールドは、 多くのシステムでは対応していないので特別な処理がされます。 $quota が非対応の場合、空のスカラになります。 対応している場合、通常はディスククォータの値が入ります。 $comment フィールドが非対応の場合、空のスカラになります。 対応している場合、通常はユーザーに関する管理上のコメントが入ります。 $quota フィールドはパスワードの寿命を示す $change や $age である システムもあります。 $comment フィールドは $class であるシステムもあります。 $expire フィールドがある場合は、アカウントやパスワードが時間切れになる 期間が入ります。 動作させるシステムでのこれらのフィールドの有効性と正確な意味については、 getpwnam(3) のドキュメントと pwd.h ファイルを参照してください。 $quota と $comment フィールドが何を意味しているかと、$expire フィールドが あるかどうかは、Config モジュールを使って、d_pwquota, d_pwage, d_pwchange, d_pwcomment, d_pwexpire の値を調べることによって Perl 自身で調べることも出来ます。 シャドウパスワードは、通常の C ライブラリルーチンを権限がある状態で 呼び出すことでシャドウ版が取得できるか、System V にあるような (Solaris と Linux を含みます) shadow(3) 関数があるといった、 直感的な方法で実装されている場合にのみ対応されます。 独占的なシャドウパスワード機能を実装しているシステムでは、 それに対応されることはないでしょう。

getgr*() によって返る値 $members は、グループのメンバの ログイン名をスペースで区切ったものです。

gethost*() 関数では、C で h_errno 変数がサポートされていれば、 関数呼出が失敗したときに、$? を通して、その値が返されます。 成功時に返される @addrs 値は、対応するシステムコールが返す、 生のアドレスのリストです。 インターネットドメインでは、個々のアドレスは、4 バイト長です; 以下のようにして unpack することができます:

    ($a,$b,$c,$d) = unpack('W4',$addr[0]);

Socket ライブラリを使うともう少し簡単になります。

    use Socket;
    $iaddr = inet_aton("127.1"); # or whatever address
    $name  = gethostbyaddr($iaddr, AF_INET);

    # or going the other way
    $straddr = inet_ntoa($iaddr);

逆方向に、ホスト名から IP アドレスを解決するには以下のように書けます:

    use Socket;
    $packed_ip = gethostbyname("www.perl.org");
    if (defined $packed_ip) {
        $ip_address = inet_ntoa($packed_ip);
    }

gethostbyname() はスカラコンテキストで呼び出すようにして、返り値が 定義されているかを必ずチェックしてください。

getprotobynumber 関数は、一つの引数しか取らないにも関わらず、リスト 演算子の優先順位を持ちます; 従って注意してください:

    getprotobynumber $number eq 'icmp'   # WRONG
    getprotobynumber($number eq 'icmp')  # actually means this
    getprotobynumber($number) eq 'icmp'  # better this way

返り値のリストの何番目がどの要素かを覚えるのに疲れたなら、 名前ベースのインターフェースが標準モジュールで提供されています: File::stat, Net::hostent, Net::netent, Net::protoent, Net::servent, Time::gmtime, Time::localtime, User::grent です。 これらは通常の組み込みを上書きし、 それぞれのフィールドに適切な名前をつけたオブジェクトを返します。 例えば:

   use File::stat;
   use User::pwent;
   $is_his = (stat($filename)->uid == pwent($whoever)->uid);

同じメソッド(uid)を呼び出しているように見えますが、違います; なぜなら File::stat オブジェクトは User::pwent オブジェクトとは 異なるからです。

移植性の問題: "getpwnam" in perlport から "endservent" in perlport

getsockname SOCKET

SOCKET 接続のこちら側の pack された sockaddr アドレスを返します; 複数の異なる IP から接続されるためにアドレスがわからない場合に使います。

    use Socket;
    $mysockaddr = getsockname(SOCK);
    ($port, $myaddr) = sockaddr_in($mysockaddr);
    printf "Connect to %s [%s]\n",
       scalar gethostbyaddr($myaddr, AF_INET),
       inet_ntoa($myaddr);
getsockopt SOCKET,LEVEL,OPTNAME

与えられた LEVEL で SOCKET に関連付けられた OPTNAME と言う名前のオプションを 問い合わせます。 オプションはソケットの種類に依存しした複数のプロトコルレベルに存在することも ありますが、少なくとも最上位ソケットレベル SOL_SOCKET (Socket モジュールで 定義されています)は存在します。 その他のレベルのオプションを問い合わせるには、そのオプションを制御する 適切なプロトコルのプロトコル番号を指定します。 例えば、オプションが TCP プロトコルで解釈されるべきであることを示すためには、 LEVEL は getprotobyname で得られる TCP のプロトコル番号を設定します。

この関数は、要求されたソケットオプションの pack された文字列表現か、 あるいはエラーの場合は undef を返し、エラーの理由は $! にあります。 pack された文字列の中身は LEVEL と OPTNAME に依存します; 詳細については getsockopt(2) を確認してください。 一般的な場合はオプションが整数の場合で、この場合結果は unpacki (あるいは I)フォーマットでデコードできる pack された整数です。

あるソケットで Nagle のアルゴリズム有効かどうかを調べる例です:

    use Socket qw(:all);

    defined(my $tcp = getprotobyname("tcp"))
        or die "Could not determine the protocol number for tcp";
    # my $tcp = IPPROTO_TCP; # Alternative
    my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
        or die "getsockopt TCP_NODELAY: $!";
    my $nodelay = unpack("I", $packed);
    print "Nagle's algorithm is turned ",
           $nodelay ? "off\n" : "on\n";

移植性の問題: "getsockopt" in perlport

glob EXPR
glob

リストコンテキストでは、 EXPR の値を、標準 Unix シェル /bin/csh が行なうように ファイル名の展開を行なった結果のリスト(空かもしれません)を返します。 スカラコンテキストでは、glob はこのようなファイル名展開を繰り返し、 リストがなくなったら undef を返します。 これは、<*.c> 演算子を実装する内部関数ですが、 直接使用することもできます。 EXPR が省略されると、$_ が使われます。 <*.c>演算子については "I/O Operators" in perlop でより詳細に議論しています。

glob は引数を空白で分割して、それぞれを分割されたパターンとして扱います。 従って、glob("*.c *.h").c または .h 拡張子を持つ全てのファイルに マッチングします。 式 glob(".* *") はカレントワーキングディレクトリの全てのファイルに マッチングします。 空白を含んでいるかも知れないファイル名をグロブしたい場合、それを守るために 空白入りファイル名の周りに追加のクォートを使う必要があります。 例えば、e の後に空白、その後に f というファイル名をグロブするには 以下のどちらかを使います:

    @spacies = <"*e f*">;
    @spacies = glob '"*e f*"';
    @spacies = glob q("*e f*");

変数を通す必要があった場合、以下のようにできました:

    @spacies = glob "'*${var}e f*'";
    @spacies = glob qq("*${var}e f*");

空でない中かっこが glob で使われている唯一のワイルドカード文字列の 場合、ファイル名とはマッチングせず、可能性のある文字列が返されます。 例えば、これは 9 個の文字列を生成し、それぞれは果物と色の組み合わせに なります:

    @many =  glob "{apple,tomato,cherry}={green,yellow,red}";

v5.6.0 から、この演算子は標準の File::Glob 拡張を使って 実装されています。 空白をパターンのセパレータとして扱わない bsd_glob を含めた 詳細は File::Glob を参照してください。

移植性の問題: "glob" in perlport

gmtime EXPR
gmtime

"localtime" と同様に働きますが、返り値はグリニッジ標準時に ローカライズされています。

注意: リストコンテキストで呼び出した時、gmtime が返す末尾の値である $isdst は常に 0 です。 GMT には夏時間はありません。

移植性の問題: "gmtime" in perlport

goto LABEL
goto EXPR
goto &NAME

goto-LABEL の形式は、LABEL というラベルの付いた文を 探して、そこへ実行を移すものです。 sort で与えられたブロックやサブルーチンから外へ出ることはできません。 これ以外は、サブルーチンの外を含む、動的スコープ内の ほとんどすべての場所へ行くために使用できますが、普通は、 lastdie といった別の構造を使った方が良いでしょう。 Perl の作者はこの形式の goto を使う必要を感じたことは、 1 度もありません (Perl では; C は別のお話です)。 (違いは、C にはループ制御と結びついた名前つきのループがないことです。 Perl にはあり、これが他の言語でのほとんどの構造的な goto の使用法を 置き換えます。)

goto-EXPR の形式はラベル名を予測し、このスコープは動的に解決されます。 これにより FORTRAN のような算術 goto が可能になりますが、 保守性を重視するならお勧めしません。

    goto ("FOO", "BAR", "GLARCH")[$i];

この例で示したように、goto-EXPR は「関数のように見える」ルールから 除外されます。 これに引き続くかっこの組は引数の区切りとは(必ずしも)なりません。 goto("NE")."XT"goto NEXT と等価です。 また、ほとんどの名前付き演算子と異なり、これは代入と同じ優先順位を持ちます。

構造の中に飛び込むために goto-LABELgoto-EXPR を使うことは 非推奨で、警告が発生します。 それでも、サブルーチンや foreach ループのような、初期化が必要な 構造の中に入るために使うことは出来ません。 また、最適化してなくなってしまった構造の中へ入るために使うことも出来ません。

goto-&NAME の形式は、その他の goto の形式とはかなり 異なったものです。 実際、これは普通の感覚でいうところのどこかへ行くものでは全くなく、 他の goto が持つ不名誉を持っていません。 現在のサブルーチンを終了し (local() による変更は失われます)、 直ちに現在の @_ の値を使って指定された名前のサブルーチンを呼び出します。 これは、AUTOLOAD サブルーチンが別のサブルーチンをロードして、 その別のサブルーチンが最初に呼ばれたようにするために使われます (ただし、現在のサブルーチンで @_ を修正した場合には、 その別のサブルーチンに伝えられます)。 goto のあとは、caller でさえも、現在のサブルーチンが 最初に呼び出されたと言うことができません。

NAME はサブルーチンの名前である必要はありません; コードリファレンスを 含むスカラ値や、コードリファレンスと評価されるブロックでも構いません。

grep BLOCK LIST
grep EXPR,LIST

これは grep(1) とその親類と同じようなものですが、同じではありません。 特に、正規表現の使用に制限されません。

LIST の個々の要素に対して、BLOCK か EXPR を評価し ($_ は、ローカルに個々の要素が設定されます) 、 その要素のうち、評価した式が真となったものからなるリスト値が返されます。 スカラコンテキストでは、式が真となった回数を返します。

    @foo = grep(!/^#/, @bar);    # weed out comments

あるいは等価な例として:

    @foo = grep {!/^#/} @bar;    # weed out comments

$_ は、LIST の値へのエイリアスですので、LIST の要素を 変更するために使うことができます。 これは、便利でサポートされていますが、 LIST の要素が変数でないと、おかしな結果になります。 同様に、grep は元のリストへのエイリアスを返します; for ループの インデックス変数がリスト要素のエイリアスであるのと同様です。 つまり、grep で返されたリストの要素を (foreach, map, または他の grep で)修正すると 元のリストの要素が変更されます。 これはきれいなコードを書くときには普通は回避されます。

(廃止予定の my $_ 構文で宣言されることによって) $_grep が現れる スコープ内でレキシカルな場合は、ローカルではリスト要素への エイリアスであることに加えて、$_ はブロック内でレキシカルで ありつづけます; つまり、外側からは見えず、起こりうる副作用を回避します。

BLOCK や EXPR の結果をリストの形にしたい場合は "map" を参照してください。

hex EXPR
hex

EXPR を 16 進数の文字列と解釈して、対応する値を返します。 (0, 0x, 0b で始まる文字列の変換には、"oct" を 参照してください。) EXPR が省略されると、$_ を使います。

    print hex '0xAf'; # prints '175'
    print hex 'aF';   # same

16 進文字列は整数のみを表現します。 整数オーバーフローを起こすような文字列は警告を引き起こします。 oct() とは違って、先頭の空白は除去されません。 何かを 16 進で表現したい場合は、"printf", "sprintf", "unpack" を 参照してください。

import LIST

組み込みの import 関数というものはありません。 これは単に、別のモジュールに名前をエクスポートしたいモジュールが 定義した(または継承した)、通常のメソッド(サブルーチン)です。 use 関数はパッケージを使う時に import メソッドを呼び出します。 "use", perlmod, Exporter も参照してください。

index STR,SUBSTR,POSITION
index STR,SUBSTR

index 関数は ある文字列をもうひとつの文字列から検索しますが、 完全正規表現パターンマッチのワイルドカード的な振る舞いはしません。 STR の中の POSITION の位置以降で、最初に SUBSTR が見つかった位置を返します。 POSITION が省略された場合には、STR の最初から探し始めます。 POSITION が文字列の先頭より前、あるいは末尾より後ろを指定した場合は、 それぞれ先頭と末尾を指定されたものとして扱われます。 POSITION と返り値のベースは、0 です。 SURSTR が見つからなかった場合には、index は -1 が返されます。

int EXPR
int

EXPR の整数部を返します。 EXPR が省略されると、$_ を使います。 この関数を丸めのために使うべきではありません: 第一の理由として 0 の 方向への切捨てを行うから、第二の理由として浮動小数点数の機械表現は時々直感に 反した結果を生み出すからです。 たとえば、int(-6.725/0.025) は正しい結果である -269 ではなく -268 を 返します: これは実際には -268.99999999999994315658 というような値に なっているからです。 通常、sprintf, printf, POSIX::floor, POSIX::ceil の方が int() より便利です。

ioctl FILEHANDLE,FUNCTION,SCALAR

ioctl(2) 関数を実装します。 正しい関数の定義を得るために、おそらく最初に

    require "sys/ioctl.ph";  # probably in
                             # $Config{archlib}/sys/ioctl.ph

としなくてはならないでしょう。 sys/ioctl.ph がないか、間違った定義をしている場合には、 <sys/ioctl.h>のような C のヘッダファイルをもとに、 自分で作らなければなりません。 (Perl の配布キットに入っている h2ph という Perl スクリプトが これを手助けしてくれるでしょうが、これは自明ではありません。) FOUNCTION に応じて SCALAR が読み書きされます; SCALAR の文字列値へのポインタが、実際の ioctl コールの 3 番目の引数として渡されます。 (SCALAR が文字列値を持っておらず、数値を持っている場合には、 文字列値へのポインタの代わりに、その値が渡されます。 このことを保証するためには、使用する前に SCALAR に0 を足してください。) ioctl で使われる構造体の値を操作するには、 pack 関数と unpack 関数が必要となるでしょう。

ioctl (と fcntl) の返り値は、以下のようになります:

    OS が返した値:      Perl が返す値:
        -1               未定義値
         0               「0 だが真」の文字列
    その他                  その値そのもの

つまり Perl は、成功時に「真」、失敗時に「偽」を返す ことになり、OS が実際に返した値も、以下のように簡単に知ることができます。

    $retval = ioctl(...) || -1;
    printf "System returned %d\n", $retval;

特別な文字列 "0 だが真" は、不適切な数値変換に関する -w 警告を回避します。

移植性の問題: "ioctl" in perlport

join EXPR,LIST

LIST の個別の文字列を、EXPR の値で区切って 1 つの文字列につなげ、その文字列を返します。 例:

    $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);

split と違って、join は最初の引数にパターンは取れないことに 注意してください。 "split" と比較してください。

keys HASH
keys ARRAY
keys EXPR

リストコンテキストで呼び出されると、指定したハッシュのすべてのキー、あるいは Perl 5.12 以降でのみ、配列のインデックスからなるリストを 返します。 5.12 より前の Perl は配列引数を使おうとすると文法エラーを出力します。 スカラコンテキストでは、キーやインデックスの数を返します。

ハッシュ要素は見かけ上、ランダムな順序で返されます。 実際のランダムな順序はハッシュに固有です; 二つのハッシュに全く同じ一連の 操作を行っても、ハッシュによって異なった順序になります。 ハッシュへの挿入によって順序が変わることがあります; 削除も同様ですが、 each または keys によって返されたもっとも最近のキーは順序を 変えることなく削除できます。 ハッシュが変更されない限り、keys, values, each が繰り返し同じ順序で 返すことに依存してもかまいません。 なぜハッシュの順序がランダム化されているかの詳細については "Algorithmic Complexity Attacks" in perlsec を参照してください。 ここで保証したことを除いて、Perl のハッシュアルゴリズムとハッシュ横断順序の 正確な詳細は Perl のリリースによって変更される可能性があります。

副作用として、HASH や ARRAY の反復子を初期化します ("each" を参照してください)。 特に、無効コンテキストで keys() を呼び出すと オーバーヘッドなしで反復子を初期化します。

環境変数を表示する別の例です:

    @keys = keys %ENV;
    @values = values %ENV;
    while (@keys) {
        print pop(@keys), '=', pop(@values), "\n";
    }

key でソートしてもいいでしょう:

    foreach $key (sort(keys %ENV)) {
        print $key, '=', $ENV{$key}, "\n";
    }

返される値はハッシュにある元のキーのコピーなので、 これを変更しても元のハッシュには影響を与えません。 "values" と比較してください。

ハッシュを値でソートするためには、sort 関数を使う必要があります。 以下ではハッシュの値を数値の降順でソートしています:

    foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
        printf "%4d %s\n", $hash{$key}, $key;
    }

左辺値として使うことで、keys を使うことで与えられたハッシュに割り当てられた ハッシュ表の大きさを増やすことができます。 これによって、ハッシュが大きくなっていくなっていくときの 効率の測定ができます。 (これは大きい値を $#array に代入することで配列を予め拡張することに 似ています。) 以下のようにすると:

    keys %hash = 200;

%hash は少なくとも 200 の大きさの表が割り当てられます -- 実際には 2 のべき乗に切り上げられるので、256 が割り当てられます。 この表はたとえ %hash = () としても残るので、 もし %hash がスコープにいるうちにこの領域を開放したい場合は undef %hash を使います。 この方法で keys を使うことで、表の大きさを小さくすることはできません (間違えてそのようなことをしても何も起きないので気にすることはありません)。 左辺値コンテキストでの keys @array は文法エラーとなります。

Perl 5.14 から、keys はスカラの EXPR を取ることができるようになりました; これは bless されていないハッシュや配列へのリファレンスでなければなりません。 引数は自動的にデリファレンスされます。 keys のこの動作は高度に実験的であると考えられています。 正確な振る舞いは将来のバージョンの Perl で変わるかも知れません。

    for (keys $hashref) { ... }
    for (keys $obj->get_arrayref) { ... }

あなたのコードを以前のバージョンの Perl で実行したユーザーが不思議な 文法エラーで混乱することを避けるために、コードが最近のバージョンの Perl で のみ 動作することを示すためにファイルの先頭に以下のようなことを 書いてください:

    use 5.012;  # so keys/values/each work on arrays
    use 5.014;  # so keys/values/each work on scalars (experimental)

each, values, sort も参照してください。

kill SIGNAL, LIST
kill SIGNAL

プロセスのリストにシグナルを送ります。 シグナル送信に成功したプロセスの数を返します (実際に kill に成功したプロセスと同じとは限りません)。

    $cnt = kill 'HUP', $child1, $child2;
    kill 'KILL', @goners;

SIGNAL はシグナル名(文字列)かシグナル番号のどちらかです。 支部なる名は SIG 接頭辞で始まることがあるので、FOOSIGFOO は同じ シグナルを意味します。 移植性から文字列形式の SIGNAL が推奨されます; 同じシグナルが異なった オペレーティングシステムでは異なった番号になることがあるからです。

現在のプラットフォームが対応しているシグナル名の一覧は、Config モジュールによって提供される $Config{sig_name} にあります。 さらなる詳細については Config を参照してください。

負のシグナル名は負のシグナル番号と同じで、 プロセスではなくプロセスグループに対して kill を行ないます。 たとえば、kill '-KILL', $pgrpkill -9, $pgrp は指定された プロセスグループ全体に SIGKILL を送ります。 すなわち、通常は、負のシグナルは用いず、正のシグナルを使うことになります。

SIGNAL が数値 0 か文字列 ZERO (または SIGZZERO の場合、プロセスに シグナルは送られませんが、kill は、シグナルを送ることが 可能 かどうかを 調べます (これは、簡単に言うと、プロセスが同じユーザーに所有されているか、 自分がスーパーユーザーであることを意味します)。 これは子プロセスが(ゾンビとしてだけでも)まだ生きていて、 UID が 変わっていないことを調べる時に有用です。 この構成の移植性に関する注意については perlport を参照してください。

PROCESS 番号が 0 あるいは負数の場合の kill の振る舞いは オペレーティングシステムに依存します。 例えば、POSIX 準拠のシステムでは、0 は現在のプロセスグループにシグナルを送り、 -1 は全てのプロセスにシグナルを送り、それ以外の負数の PROCESS 番号は 負数のシグナル番号として動作し、指定されたプロセスグループ全体を kill します。

SIGNAL と PROCESS の両方が負数の場合、結果は未定義です。 将来のバージョンでは警告が出るかも知れません。

詳細は "Signals" in perlipc を参照してください。

Windows のような fork() が利用不能なシステムでは、Perl は fork() を インタプリタレベルでエミュレートします。 エミュレーションは kill に関連して、コードが Windows で実行されて しかしコードが移植性があると考えられるように制限があります。

さらなる詳細については perlfork を参照してください。

処理する LIST がない場合、シグナルは送られず、返り値は 0 です。 しかし、この形式は時々使われます; 実行するために汚染チェックを 引き起こすからです。 しかし "Laundering and Detecting Tainted Data" in perlsec を参照してください。

移植性の問題: "kill" in perlport

last LABEL
last EXPR
last

last コマンドは、(ループ内で使った) C の break 文と 同じようなもので、LABEL で指定されるループを即座に抜けます。 LABEL が省略されると、コマンドは一番内側のループを参照します。 Perl 5.18.0 から利用可能な last EXPR 形式では、実行時に計算される ラベル名を使えます; それ以外は last LABEL と同一です。 continue ブロックがあっても実行されません:

    LINE: while (<STDIN>) {
        last LINE if /^$/;  # exit when done with header
        #...
    }

lasteval {}, sub {}, do {} といった 値を返すブロックを終了するのには使えませんし、 grep() や map() 操作を終了するのに使うべきではありません。

ブロック自身は一回だけ実行されるループと文法的に同一であることに 注意してください。 従って、last でそのようなブロックを途中で抜け出すことができます。

last, next, redo がどのように働くかについては "continue" も参照してください。

ほとんどの名前付き演算子と異なり、これは代入と同じ優先順位を持ちます。 また、関数のように見えるものの規則からも免れるので、last ("foo")."bar" と すると "bar" は last への引数の一部となります。

lc EXPR
lc

EXPR を小文字に変換したものを返します。 これは、ダブルクォート文字列における、 \L エスケープを実装する内部関数です。

EXPR が省略されると、$_ を使います。

返り値として得られるものは色々な要素に依存します:

use bytes が有効の場合

結果は ASCII の意味論に従います。 A-Z のみが変換され、それぞれ a-z になります。

それ以外の場合で、use locale が有効の(そして use locale 'not_characters' が有効でない)場合

符号位置 < 256 に対しては現在の LC_CTYPE ロケールに従います; そして 残りの符号位置に付いては Unicode の意味論を使います (これは UTF8 フラグも 設定されている場合にのみ起こります)。 perllocale を参照してください。

これの欠点は、255/266 の境界をまたぐ大文字小文字の変換は 未定義であることです。 例えば、Unicode での LATIN CAPITAL LETTER SHARP S (U+1E9E) の小文字は (ASCII プラットフォームでは) U+00DF です。 しかし use locale が有効なら、U+1E9E の小文字は自分自身です; なぜなら 0xDF は現在のロケールでは LATIN SMALL LETTER SHARP S ではなく、Perl は 例えこのロケールに文字が存在するかどうかを知る方法がなく、まして どの符号位置かを知る方法がないからです。 Perl は 255/256 境界をまたぐ全ての(多くはありません)実体については 入力文字を変更せずに返します。

その他の場合で、EXPR に UTF8 フラグがセットされている場合

大文字小文字変換には Unicode の意味論が使われます。

それ以外の場合で、use feature 'unicode_strings'use locale ':not_characters' が有効の場合

大文字小文字変換には Unicode の意味論が使われます。

それ以外の場合

大文字小文字変換には ASCII の意味論が使われます。 ASCII の範囲外の文字の「小文字」はその文字自身です。

lcfirst EXPR
lcfirst

最初の文字だけを小文字にした、EXPR を返します。 これは、ダブルクォート文字列における、\l エスケープを 実装する内部関数です。

EXPR が省略されると、$_ を使います。

この関数は、ロケールのようなさまざまなプラグマの影響下では、 "lc" と同様に振る舞います。

length EXPR
length

EXPR の値の 文字 の長さを返します。 EXPR が省略されたときには、$_ の長さを返します。 EXPR が未定義値の場合、undef を返します。

この関数は配列やハッシュ全体に対してどれだけの要素を含んでいるかを 調べるためには使えません。 そのような用途には、それぞれ scalar @arrayscalar keys %hash を 利用してください。

全ての Perl の文字操作と同様、length() は通常物理的なバイトではなく 論理文字を扱います。 UTF-8 でエンコードされた文字列が何バイトかを知るには、 length(Encode::encode_utf8(EXPR)) を使ってください (先に use Encode する必要があります)。 Encodeperlunicode を参照してください。

__LINE__

現在の行番号にコンパイルされる特殊トークン。

OLDFILE にリンクされた、新しいファイル NEWFILE を作ります。 成功時には真を、さもなければ偽を返します。

移植性の問題: "link" in perlport

listen SOCKET,QUEUESIZE

listen(2) システムコールと同じことをします。 成功時には真を、さもなければ偽を返します。 "Sockets: Client/Server Communication" in perlipc の例を参照してください。

local EXPR

あなたはが本当に望んでいるのは my の方でしょう; local はほとんどの 人々が「ローカル」と考えるものと違うからです。 詳細は "Private Variables via my()" in perlsub を参照してください。

"local" はリストアップされた変数を、囲っているブロック、 ファイル、eval の中で、ローカルなものにします。 複数の値を指定する場合は、リストはかっこでくくらなければなりません。 tie した配列とハッシュに関する事項を含む詳細については "Temporary Values via local()" in perlsub を参照してください。

delete local EXPR 構文は、配列/ハッシュの要素の削除を現在の ブロックにローカル化するためにも使われていました。 "Localized deletion of elements of composite types" in perlsub を 参照してください。

localtime EXPR
localtime

time 関数が返す時刻を、ローカルなタイムゾーンで測った時刻として、 9 要素の配列に変換します。 普通は、以下のようにして使います:

    #  0    1    2     3     4    5     6     7     8
    ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
                                                localtime(time);

すべてのリスト要素は数値で、C の `struct tm' 構造体から 直接持ってきます。 $sec, $min, $hour は指定された時刻の秒、分、時です。

$mday は月の何日目か、$mon は月の値です; 月の値は 0..11 で、0 が 1 月、11 が 12 月です。 これにより、リストから月の名前を得るのが簡単になります:

    my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
    print "$abbr[$mon] $mday";
    # $mon=9, $mday=18 gives "Oct 18"

$year は 1900 年からの年数を持ちます。 4 桁の年を得るには以下のようにします:

    $year += 1900;

西暦の下 2 桁(2001 年では "01")がほしい場合は以下のようにします:

    $year = sprintf("%02d", $year % 100);

$wday は曜日で、0 が日曜日、3 が木曜日です。 $yday はその年の何日目かで、0..364 の値を取ります (うるう年は 0..365 です。)

$isdst は指定された時刻が夏時間の場合は真、そうでなければ偽です。

EXPR が省略されると、localtime() は(time(3) によって返される) 現在時刻を使います。

スカラコンテキストでは、localtime() は ctime(3) の値を返します:

    $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"

このスカラ値の形式はロケール依存 ではなく、Perl の組み込みの値です。 ローカル時刻ではなく GMT がほしい場合は "gmtime" 組み込み関数を 使ってください。 また、(秒、分、時などの形から、time() が返す値である 1970 年 1 月 1 日の真夜中からの秒数に変換する) Time::Local モジュール 及び POSIX モジュールで提供される strftime(3) と mktime(3) 関数も 参照してください。

似たような、しかしロケール依存の日付文字列がほしい場合は、 ロケール環境変数を適切に設定して(perllocale を参照してください)、 以下の例を試してください:

    use POSIX qw(strftime);
    $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
    # or for GMT formatted appropriately for your locale:
    $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;

曜日と月の短い表現である %a%b は、3 文字とは限らないことに 注意してください。

Time::gmtime モジュールと Time::localtime モジュールは、それぞれ gmtime() 関数と localtime() 関数に、名前でアクセスする機構を提供する 便利なモジュールです。

包括的な日付と時刻の表現については、CPAN の DateTime モジュールを 参照してください。

移植性の問題: "localtime" in perlport

lock THING

この関数は THING が含む共有変数またはリファレンスされたオブジェクトに、 スコープから出るまでアドバイサリロックを掛けます.

返される値は、引数がスカラならそのスカラ自身、引数がハッシュ、配列、 サブルーチンならリファレンスです。

lock() は「弱いキーワード」です: もしユーザーが(呼び出し前に) この名前で関数を定義すると、定義された関数の方が呼び出されます。 use threads::shared の影響下でない場合は、これは何もしません。 threads::shared を参照してください。

log EXPR
log

EXPR の (e を底とする) 自然対数を返します。 EXPR が省略されると、$_ の対数を返します。 底の異なる対数を求めるためには、基礎代数を利用してください: ある数の N を底とする対数は、その数の自然対数を N の自然対数で割ったものです。 例えば:

    sub log10 {
        my $n = shift;
        return log($n)/log(10);
    }

逆操作については "exp" を参照してください。

lstat FILEHANDLE
lstat EXPR
lstat DIRHANDLE
lstat

(特別なファイルハンドルである _ の設定を含めて) stat 関数と同じことをしますが、シンボリックリンクが 指しているファイルではなく、シンボリックリンク自体の stat をとります。 シンボリックリンクがシステムに実装されていないと、通常の stat が行なわれます。 さらにより詳細な情報については、stat の文書を参照してください。

EXPR が省略されると、$_ の stat をとります。

移植性の問題: "lstat" in perlport

m//

マッチ演算子です。 "Regexp Quote-Like Operators" in perlop を参照してください。

map BLOCK LIST
map EXPR,LIST

LIST の個々の要素に対して、BLOCK か EXPR を評価し ($_ は、ローカルに個々の要素が設定されます) 、 それぞれの評価結果からなるリスト値が返されます。 スカラコンテキストでは、生成された要素の数を返します。 BLOCK や EXPR をリストコンテキストで評価しますので、LIST の 個々の要素によって作られる、返り値であるリストの要素数は、 0 個の場合もあれば、複数の場合もあります。

    @chars = map(chr, @numbers);

は、数のリストを対応する文字に変換します。

    my @squares = map { $_ * $_ } @numbers;

これは数値のリストを、その 2 乗に変換します。

    my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;

のように、返された要素の数が入力要素の数と異なる場合もあります。 要素を省略するには、空リスト () を返します。 これは以下のように書くことでも達成できて

    my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;

この方が目的がよりはっきりします。

map は常にリストを返し、要素がキー/値の組になるようなハッシュに 代入できます。 さらなる詳細については perldata を参照してください。

    %hash = map { get_a_key_for($_) => $_ } @array;

は以下のものをちょっと変わった書き方で書いたものです。

    %hash = ();
    foreach (@array) {
        $hash{get_a_key_for($_)} = $_;
    }

$_ は、LIST の値へのエイリアスですので、LIST の要素を 変更するために使うことができます。 これは、便利でサポートされていますが、 LIST の要素が変数でないと、おかしな結果になります。 この目的には通常の foreach ループを使うことで、ほとんどの場合は より明確になります。 BLOCK や EXPR が真になる元のリストの要素からなる配列については、 "grep" も参照してください。

(廃止予定の my $_ 構文で宣言されることによって) $_map が現れる スコープ内でレキシカルな場合は、ローカルではリスト要素への エイリアスであることに加えて、$_ はブロック内でレキシカルでありつづけます; つまり、外側からは見えず、起こりうる副作用を回避します。

{ はハッシュリファレンスとブロックの両方の開始文字なので、 map { ... は map BLOCK LIST の場合と map EXPR, LIST の場合があります。 Perl は終了文字の } を先読みしないので、{ の直後の文字を見て どちらとして扱うかを推測します。 通常この推測は正しいですが、もし間違った場合は、} まで読み込んで カンマが足りない(または多い)ことがわかるまで、何かがおかしいことに 気付きません。 } の近くで文法エラーが出ますが、Perl を助けるために単項の + を 使うというように、{ の近くの何かを変更する必要があります。

    %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
    %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
    %hash = map { ("\L$_" => 1) } @array # this also works
    %hash = map {  lc($_) => 1  } @array # as does this.
    %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!

    %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)

または +{ を使って無名ハッシュコンストラクタを強制します:

    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
                                           # comma at end

こうするとそれぞれ 1 要素だけの無名ハッシュのリストを得られます。

mkdir FILENAME,MASK
mkdir FILENAME
mkdir

FILENAME で指定したディレクトリを、MASK で指定した許可モード(を umask で修正したもの) で作成します。 成功時には真を返します; さもなければ偽を返して $! (errno) を設定します。 MASK を省略すると、0777 とみなし、 FILENAME を省略すると、$_ を使います。

一般的に、制限された MASK を使ってユーザーがより寛容にする方法を 与えないより、寛容な MASK でディレクトリを作り、ユーザーが自身の umask で 修正するようにした方がよいです。 例外は、(例えばメールファイルのような)プライベートに保つべきファイルや ディレクトリを書く場合です。 perlfunc(1) の umask で、MASK の選択に関して詳細に議論しています。

POSIX 1003.1-1996 によれば、FILENAME には末尾に任意の数のスラッシュを つけることができます。 このようには動かない OS やファイルシステムもあるので、Perl はみんなが 幸せになれるように、自動的に末尾のスラッシュを削除します。

ディレクトリ構造を再帰的に作成するには、File::Path モジュールの makepath 関数を参照してください。

msgctl ID,CMD,ARG

System V IPC 関数 msgctl を呼び出します。 正しい定数定義を得るために、まず

    use IPC::SysV;

と書くことが必要でしょう。 CMD が IPC_STAT であれば、ARG は返される msqid_ds 構造体を 納める変数でなければなりません。 ioctl と同じように、エラー時には未定義値、 ゼロのときは "0 but true"、それ以外なら、その値そのものを返します。 "SysV IPC" in perlipc および、IPC::SysV, IPC::Semaphore の文書も 参照してください。

移植性の問題: "msgctl" in perlport

msgget KEY,FLAGS

System V IPC 関数 msgget を呼び出します。 メッセージキューの ID か、エラー時には undef を返します。 "SysV IPC" in perlipc よよび、IPC::SysV, IPC::Msg の文書も 参照してください。

移植性の問題: "msgget" in perlport

msgrcv ID,VAR,SIZE,TYPE,FLAGS

System V IPC 関数 msgrcv を呼び出し、メッセージキュー ID から、 変数 VAR に最大メッセージ長 SIZE のメッセージを受信します。 メッセージが受信された時、ネイティブな long 整数のメッセージタイプが VAR の先頭となり、実際のメッセージが続きます。 このパッキングは unpack("l! a*") で展開できます。 変数は汚染されます。 成功時には真を、エラー時には偽を返します。 "SysV IPC" in perlipc および、IPC::SysV, IPC::SysV::Msg の文書も 参照してください。

移植性の問題: "msgrcv" in perlport

msgsnd ID,MSG,FLAGS

System V IPC 関数 msgsnd を呼び出し、メッセージキュー ID に メッセージ MSG を送信します。 MSG の先頭は、ネイティブなlong 整数のメッセージタイプでなければならず、 メッセージの長さ、メッセージ本体と続きます。 これは、pack("l! a*", $type, $message) として生成できます。 成功時には真を、エラー時には偽を返します。 IPC::SysVIPC::SysV::Msg の文書も参照してください。

移植性の問題: "msgsnd" in perlport

my EXPR
my TYPE EXPR
my EXPR : ATTRS
my TYPE EXPR : ATTRS

my はリストアップされた変数を、囲っているブロック、ファイル、 eval の中でローカルな (レキシカルな) ものにします。 複数の値を指定する場合は、リストはかっこでくくらなければなりません。

TYPE と ATTRS の正確な文法とインターフェースは今でも進化しています。 現在のところ、TYPE は fields プラグマの使用と結び付けられていて、 属性は attributes プラグマか、Perl 5.8.0 からは Attribute::Handlers モジュールと結び付けられています。 詳しくは"Private Variables via my()" in perlsub, fields, attributes, Attribute::Handlers を参照してください。

next LABEL
next EXPR
next

next コマンドは、C での continue 文のようなもので、 ループの次の繰り返しを開始します:

    LINE: while (<STDIN>) {
        next LINE if /^#/;  # discard comments
        #...
    }

continue ブロックが存在すれば、たとえ捨てられる行に あっても、それが実行されます。 LABEL が省略されると、コマンドは一番内側のループを参照します。 Perl 5.18.0 から利用可能な next EXPR 形式では、実行時に計算される ラベル名が使えます; それ以外は next LABEL と同一です。

nexteval {}, sub {}, do {} のように値を返すブロックから 抜けるのには使えません; また、grep() や map() 操作から抜けるのに 使うべきではありません。

ブロック自身は一回だけ実行されるループと文法的に同一であることに 注意してください。 従って、next はそのようなブロックから早く抜けるのに使えます。

last, next, redo がどのように働くかについては "continue" も参照してください。

ほとんどの名前付き演算子と異なり、これは代入と同じ優先順位を持ちます。 また、関数のように見えるものの規則からも免れるので、next ("foo")."bar" と すると "bar" は next への引数の一部となります。

no MODULE VERSION LIST
no MODULE VERSION
no MODULE LIST
no MODULE
no VERSION

use 関数を参照してください; no は、その逆を行なうものです。

oct EXPR
oct

EXPR を 8 進数文字列と解釈して、対応する値を返します。 (EXPR が 0x で始まるときには、16 進数文字列と解釈します。 EXPR が 0bで始まるときは、2 進数文字列と解釈します。 どの場合でも、先頭の空白は無視されます。) 以下の例は、標準的な Perl の記法での 10 進数、2 進数、8 進数、16 進数を扱います:

    $val = oct($val) if $val =~ /^0/;

EXPR が省略されると、$_ を使います。 (8 進数を扱う)その他の方法としては sprintf() または printf()があります。

    $dec_perms = (stat("filename"))[2] & 07777;
    $oct_perm_str = sprintf "%o", $perms;

oct() 関数は例えば、 644 といった文字列をファイルモードに変換する時に よく使います。 Perl は必要に応じて自動的に文字列を数値に変換しますが、 この自動変換は十進数を仮定します。

先頭の空白や、末尾の(小数点のような)非数字は警告なしに無視されます (oct は非負整数のみを扱えます; 負の整数や小数は扱えません)。

open FILEHANDLE,EXPR
open FILEHANDLE,MODE,EXPR
open FILEHANDLE,MODE,EXPR,LIST
open FILEHANDLE,MODE,REFERENCE
open FILEHANDLE

EXPR で与えられたファイル名のファイルを開き、FILEHANDLE と結び付けます。

読み込みのためにファイルを開くための簡単な例は以下のもので:

    open(my $fh, "<", "input.txt") 
        or die "cannot open < input.txt: $!";

書き込み用は以下のものです:

    open(my $fh, ">", "output.txt") 
        or die "cannot open > output.txt: $!";

(以下は総合的な open() のリファレンスです: より親切な説明については perlopentut を参照してください。)

FILEHANDLE が未定義のスカラ変数(または配列かハッシュの要素)の場合、 新しいファイルハンドルが自動有効化され、その変数は新しく割り当てられた 無名ファイルハンドルへのリファレンスが代入されます。 さもなければ、もし FILEHANDLE が式なら、その値を求めている実際の ファイルハンドルの名前として使います。 (これはシンボリックリファレンスとして扱われるので、 use strict "refs" の影響を 受けません。)

EXPR が省略された場合、FILEHANDLE と同じ名前のグローバル(パッケージ) スカラ変数にファイル名が入っています。 (レキシカル変数 -- mystate で宣言されたもの -- はこの用途には 使えないことに注意してください; 従って、mystate を使っている場合は、 open を呼び出すときに EXPR を指定してください。)

3 (またはそれ以上)の引数が指定された場合、2 番目の引数の(オプションの エンコーディングを含む)開く時のモードは、3 番目のファイル名と分離されます。 MODE が < か空の場合、ファイルは入力用に開かれます。 MODE が > の場合、ファイルは出力用に開かれ、既にファイルが ある場合は切り詰められ(上書きされ)、ない場合は新しく作られます。 MODE が >> の場合、ファイルは追加用に開かれ、やはり必要なら 作成されます。

ファイルに読み込みアクセスと書き込みアクセスの両方をしたいことを示すために、 >< の前に + を付けることができます: 従って、+< ほとんど常に 読み書き更新のために使われます -- +> モードはまずファイルを上書きします。 普通はこれらの読み書きモードをテキストファイルの更新のためには使えません; なぜなら可変長のレコードで構成されているからです。 よりよい手法については perlrun-i オプションを参照してください。 ファイルは 0666 をプロセスの umask 値で修正したパーミッションで 作成されます。

これらの様々な前置詞は fopen(3) の r, r+, w, w+, a, a+ のモードに対応します。

1 引数 と 2 引数の形式ではモードとファイル名は(この順番で) 結合されます(空白によって分割されているかもしれません)。 この形式で、モードが '<' の場合はモードを省略できます (が、 するべきではありません)。 ファイル引数が既知のリテラルの場合、2 引数形式の open は常に安全です。

3 引数以上の形式で MODE が |- の場合、ファイル名は出力がパイプされるコマンドとして 解釈され、MODE が -| の場合、ファイル名は出力がこちらに パイプされるコマンドとして解釈されます。 2 引数(と 1 引数) の形式ではハイフン(-)をコマンドの代わりに 使えます。 これに関するさらなる例については "Using open() for IPC" in perlipc を 参照してください。 (open を入出力 両用 にパイプすることは出来ませんが 代替案としては IPC::Open2, IPC::Open3, "Bidirectional Communication with Another Process" in perlipc を 参照してください。)

パイプでの三つ以上の引数の形式では、LIST (コマンド名の後の追加の引数) が 指定されると、プラットフォームが対応していれば、LIST は起動される コマンドへの引数となります。 パイプモードではない open での三つ以上の引数の意味はまだ未定義ですが、 実験的な「層」は追加の LIST 引数の意味を与えます。

2 引数(と 1 引数)で <-- を open すると STDIN が オープンされ、>- を open すると STDOUT がオープンされます。

open の 3 引数形式では、どのように入出力が処理されるかに影響を与える I/O 層(「ディシプリン」とも呼ばれます)を指定できます (そして普通はそうするべきです) (詳細については openPerlIO を参照してください)。 例えば:

  open(my $fh, "<:encoding(UTF-8)", "filename")
    || die "can't open UTF-8 encoded filename: $!";

は、Unicode 文字を含む UTF8 エンコードされたファイルを開きます; perluniintro を参照してください。 3 引数形式で層を指定すると、${^OPEN} (perlvar を参照してください; 通常はopen プラグマか -CioD オプションでセットされます) に保存されたデフォルト層は無視されることに注意してください。 これらの層は、名前なしでコロンを指定した場合にも無視されます。 この場合 OS のデフォルトの層 (Unix では :raw、Windows では :crlf) が 使われます。

open は、成功時にはゼロ以外を返し、失敗時には未定義値を返します。 パイプに関る open のときには、返り値はサブプロセスの pid となります。

テキストファイルとバイナリファイルを区別するシステムで Perl を実行している 場合、これを扱うための小技のために "binmode" をチェックするべきです。 動作させているシステムで binmode が必要か不要化を区別する鍵は、テキスト ファイルの形式です。 Unix, Mac OS, Plan 9 といった、行の境界を 1 文字で表現し、それが C では "\n" でエンコードされる場合、binmode は不要です。 それ以外では必要です。

ファイルを開く時、開くのに失敗した時に通常の処理を続けるのは 普通は悪い考えですので、open はしばしば die と結び付けられて 使われます。 望むものが die でない場合(例えば、CGI スクリプト のように きれいにフォーマットされたエラーメッセージを作りたい場合 (但しこの問題を助けるモジュールがあります))でも、 ファイルを開いた時の返り値を常にチェックするべきです。

特別な場合として、3 引数の形で読み書きモードで 3 番目の引数が undef の場合:

    open(my $tmp, "+>", undef) or die ...

無名一時ファイルとしてファイルハンドルを開きます。 また +< も対称性のために動作しますが、 一時ファイルにはまず何かを書き込みたいはずです。 読み込みを行うためには seek() が必要です。

Perl はデフォルトで PerlIO を使ってビルドされています; (Configure -Uuseperlio して Perl をビルドするなどして)これを 変更していない限り、以下のようにして、Perl スカラを直接ファイルハンドルで 開くことができます:

    open($fh, ">", \$variable) || ..

STDOUTSTDERR を「オンメモリの」ファイルとして 再び開きたい場合は、先にそれを閉じます:

    close STDOUT;
    open(STDOUT, ">", \$variable)
        or die "Can't open STDOUT: $!";

一般的な例:

    $ARTICLE = 100;
    open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
    while (<ARTICLE>) {...

    open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
    # if the open fails, output is discarded

    open(my $dbase, "+<", "dbase.mine")      # open for update
        or die "Can't open 'dbase.mine' for update: $!";

    open(my $dbase, "+<dbase.mine")          # ditto
        or die "Can't open 'dbase.mine' for update: $!";

    open(ARTICLE, "-|", "caesar <$article")  # decrypt article
        or die "Can't start caesar: $!";

    open(ARTICLE, "caesar <$article |")      # ditto
        or die "Can't start caesar: $!";

    open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
        or die "Can't start sort: $!";

    # in-memory files
    open(MEMORY, ">", \$var)
        or die "Can't open memory file: $!";
    print MEMORY "foo!\n";              # output will appear in $var

    # process argument list of files along with any includes

    foreach $file (@ARGV) {
        process($file, "fh00");
    }

    sub process {
        my($filename, $input) = @_;
        $input++;    # this is a string increment
        unless (open($input, "<", $filename)) {
            print STDERR "Can't open $filename: $!\n";
            return;
        }

        local $_;
        while (<$input>) {    # note use of indirection
            if (/^#include "(.*)"/) {
                process($1, $input);
                next;
            }
            #...          # whatever
        }
    }

PerlIO に関する詳しい情報については perliol を参照してください。

Bourne シェルの慣例にしたがって、EXPR の先頭に >& を付けると、EXPR の残りの文字列をファイルハンドル名 (数字であれば、ファイル記述子) と解釈して、それを (dup(2) によって) 複製してオープンします。 & は、>, >>, <, +>, +>>, +<というモード指定に付けることができます。 指定するモード指定は、もとのファイルハンドルのモードと 合っていないといけません。 (ファイルハンドルの複製は既に存在する IO バッファの内容に含めません。) 3 引数形式を使う場合は、数値を渡すか、ファイルハンドルの名前を渡すか、 通常の「グロブへのリファレンス」を渡します。

STDOUTSTDERR 保存し、リダイレクトし、元に戻すスクリプトを示します:

    #!/usr/bin/perl
    open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
    open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";

    open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
    open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";

    select STDERR; $| = 1;  # make unbuffered
    select STDOUT; $| = 1;  # make unbuffered

    print STDOUT "stdout 1\n";  # this works for
    print STDERR "stderr 1\n";  # subprocesses too

    open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
    open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";

    print STDOUT "stdout 2\n";
    print STDERR "stderr 2\n";

X をファイル記述子の番号かファイルハンドルとして、 '<&=X' と指定すると、Perl はそのファイル記述子に対する C の fdopen と同じことを行ないます(そして dup(2) は呼び出しません); これはファイル記述子をより節約します。 例えば:

    # open for input, reusing the fileno of $fd
    open(FILEHANDLE, "<&=$fd")

または

    open(FILEHANDLE, "<&=", $fd)

または

    # open for append, using the fileno of OLDFH
    open(FH, ">>&=", OLDFH)

または

    open(FH, ">>&=OLDFH")

ファイルハンドルを倹約することは、(倹約できること以外に)何かが ファイル記述子に依存している場合、例えば flock() を使った ファイルロックといった場合に有用です。 open(A, ">>&B") とすると、ファイルハンドル A は B と同じ ファイル記述子にはならないので、flock(A) と flock(B) は別々になります。 しかし open(A, ">>&=B") ではファイルハンドルは基礎となシステムの 同じファイル記述子を共有します。

5.8.0 より前の Perl の場合、= 機能の実装は 標準 C ライブラリの fdopen() を使っています。 多くの Unix システムでは、fdopen() はファイル記述子がある値 (典型的には 255)を超えた場合に失敗することが知られています。 5.8.0 以降の Perl では、(ほとんどの場合) PerlIO がデフォルトです。

Perl が PerlIO つきでビルドされているかどうかを確認するには、 perl -V として useperlio= の行を見ます。 useperliodefine なら PerlIO を使っています; そうでなければ使っていません。

1 引数 または 2 引数の形の open() で (-||- というふうに) - というコマンドにパイプを開くと、暗黙の fork が行なわれるので、 open は 2 回返ります; 親プロセスには子プロセスの pid が返され、子プロセスには (定義された) 0 が 返されます。 open が成功したかどうかを調べるには、defined($pid) または // を 使います。

例えば、以下の二つ

    $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";

または

    $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";

を使って、後で以下のようにします。

    if ($child_pid) {
        # am the parent:
        # either write TO_KID or else read FROM_KID
        ...
       waitpid $child_pid, 0;
    } else {
        # am the child; use STDIN/STDOUT normally
        ...
        exit;
    } 

親プロセスでは、このファイルハンドルは 通常通りに動作しますが、行なわれる入出力は、 チャイルドプロセスの STDIN/STDOUT にパイプされます。 チャイルドプロセス側では、そのファイルハンドルは オープンされず、入出力は新しい STDOUT か STDIN に対して行なわれます。 これは、setuid で実行して、シェルコマンドのメタ文字を 検索させたくないような場合に、パイプコマンドの起動の仕方を 制御したいとき、普通のパイプの open と同じように使います。

以下の組み合わせは、だいたい同じものです:

    open(FOO, "|tr '[a-z]' '[A-Z]'");
    open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
    open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
    open(FOO, "|-", "tr", '[a-z]', '[A-Z]');

    open(FOO, "cat -n '$file'|");
    open(FOO, "-|", "cat -n '$file'");
    open(FOO, "-|") || exec "cat", "-n", $file;
    open(FOO, "-|", "cat", "-n", $file);

それぞれのブロックの末尾二つの例ではパイプを「リスト形式」にしていますが、 これはまだ全てのプラットフォームで対応しているわけではなりません。 よい経験則としては、もし実行しているプラットフォームで本当の fork() が あれば(言い換えると、プラットフォームが Linux や MacOS X を含む Unix なら) リスト形式が使えます。 パイプのリスト形式を使うことで、コマンドへのリテラルな引数を、 シェルのメタ文字をシェルが解釈するリスクなしに渡すことができます。 しかし、これは以下のように意図的にシェルメタ文字を含むコマンドをパイプとして 開くことを妨げます:

    open(FOO, "|cat -n | expand -4 | lpr")
        // die "Can't open pipeline to lpr: $!";

これに関する更なる例については "Safe Pipe Opens" in perlipc を 参照してください。

v5.6.0 から、Perl は書き込み用に開いている全てのファイルに対して fork を行う前にフラッシュしようとしますが、これに対応していない プラットフォームもあります(perlport を参照してください)。 安全のために、$| (English モジュールでは $AUTOFLUSH) をセットするか、 全ての開いているハンドルに対して IO::Handleautoflush() メソッドを 呼び出す必要があるかもしれません。

ファイルに対する close-on-exec フラグをサポートしているシステムでは、 フラグは $^F の値で決定される、新しくオープンされたファイル記述子に対して セットされます。 "$^F" in perlvar を参照してください。

パイプのファイルハンドルを close することで、 親プロセスは、チャイルドプロセスの終了を待ち、それから $?${^CHILD_ERROR_NATIVE} にステータス値を返します。

1 引数 と 2 引数の形の open() に渡されたファイル名は、 はじめと終わりの空白が取り除かれ、 通常のリダイレクト文字列を受け付けます。 この機能は "magic open" として知られていますが、 普通いい効果をもたらします。 ユーザーは "rsh cat file |" といったファイル名を指定できますし、 特定のファイル名を必要に応じて変更できます。

    $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
    open(FH, $filename) or die "Can't open $filename: $!";

妙な文字が含まれているようなファイル名をオープンするには、 3 引数の形を使います。

    open(FOO, "<", $file)
        || die "can't open < $file: $!";

あるいは、次のようにして、最初と最後の空白を保護します:

    $file =~ s#^(\s)#./$1#;
    open(FOO, "< $file\0")
        || die "open failed: $!";

(これは奇妙なファイルシステムでは動作しないかもしれません)。 open() の magic3 引数 形式を誠実に選択するべきです。

    open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";

とするとユーザーは "rsh cat file |" という形の引数を指定できますが、 末尾にスペースがついてしまったファイル名では動作しません; 一方:

    open(IN, "<", $ARGV[0])
        || die "can't open < $ARGV[0]: $!";

はまったく逆の制限があります。

もし「本当の」C 言語の open (システムの open(2) を参照してください)が 必要なら、このような副作用のない sysopen 関数を使うべきです (ただし、C の fopen() に割り付けられる Perl の open() とは かすかに違うファイルモードを持ちます)。 これはファイル名を解釈から守るもう一つの方法です。 例えば:

    use IO::Handle;
    sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
        or die "sysopen $path: $!";
    $oldfh = select(HANDLE); $| = 1; select($oldfh);
    print HANDLE "stuff $$\n";
    seek(HANDLE, 0, 0);
    print "File contains: ", <HANDLE>;

IO::Handle パッケージ(または IO::FileIO::Socket といった サブパッケージ)のコンストラクタを使うことで、 これらへのリファレンスを保持している変数のスコープを持ち、それから 参照カウントが 0 になると自動的に (しかし暗黙に) 閉じる 無名ファイルハンドルを作成できます:

    use IO::File;
    #...
    sub read_myfile_munged {
        my $ALL = shift;
        # or just leave it undef to autoviv
        my $handle = IO::File->new;
        open($handle, "<", "myfile") or die "myfile: $!";
        $first = <$handle>
            or return ();     # Automatically closed here.
        mung($first) or die "mung failed";  # Or here.
        return (first, <$handle>) if $ALL;  # Or here.
        return $first;                      # Or here.
    }

警告: 先の例には、自動的に閉じると、handle の参照カウントが 0 になったことが適切に検出できなくて失敗が報告されるというバグがあります。 常に ハンドルを自分自身で閉じて、返り値を調べてください。

    close($handle) 
        || warn "close failed: $!";

読み書きを混ぜる場合の詳細については "seek" を参照してください。

移植性の問題: "open" in perlport

opendir DIRHANDLE,EXPR

readdirtelldirseekdirrewinddirclosedir で 処理するために、EXPR で指定された名前のディレクトリをオープンします。 成功時には真を返します。 DIRHANDLE は間接ディレクトリハンドルとして使える値(普通は実際のディレクトリ ハンドルの名前)となる式でも構いません。 DIRHANDLE が未定義のスカラ値(または配列かハッシュの要素)の場合、その変数は 新しい無名ディレクトリハンドルへのリファレンスが代入されます; つまり、 自動有効化されます。 DIRHANDLE は、FILEHANDLE とは別に名前空間を持っています。

readdir の例を参照してください。

ord EXPR
ord

EXPR の最初の文字の数値としての値を返します。 EXPR が空文字列の場合は、0 を返します。 EXPR が省略されると、$_ を使います。 (バイトではなく 文字 であることに注意してください。)

逆のことをするには "chr" を参照してください。 Unicode については perlunicode を参照してください。

our EXPR
our TYPE EXPR
our EXPR : ATTRS
our TYPE EXPR : ATTRS

our は単純名を、現在のレキシカルスコープ内で使うために、現在のパッケージの 同じ名前のパッケージ変数へのレキシカルな別名を作ります。

ourmystate と同じスコープルールを持ちますが、 our は別名を宣言するだけである一方、mystate は変数名を 宣言し、現在のスコープ内にその名前のための領域を割り当てます。

つまり、use strict 'vars' が有効の場合は、our を使うことで、 パッケージ変数をパッケージ名で修飾することなく使うことができますが、 our 宣言のレキシカルスコープ内だけということです。 この意味では、ouruse vars とは異なります; これは影響するパッケージの中で のみ 非修飾名を使え、スコープを超えることは できません。

複数の値を指定する場合は、リストはかっこでくくらなければなりません。

    our $foo;
    our($bar, $baz);

our 宣言はレキシカルスコープ全体に対して(たとえパッケージ境界を 越えていても)見える、パッケージ変数への別名を宣言します。 この変数が入るパッケージは宣言した時点で定義され、 使用した時点ではありません。 これにより、以下のような振る舞いになります:

    package Foo;
    our $bar;      # declares $Foo::bar for rest of lexical scope
    $bar = 20;

    package Bar;
    print $bar;    # prints 20, as it refers to $Foo::bar

同じレキシカルスコープでも、パッケージが異なっていれば、同じ名前で複数の our 宣言ができます。 同じパッケージになっていると、警告が出力されるようになっていれば 複数の my 宣言がある場合と同じように警告が出力されます。 新しい変数を名前に割り当てることになる 2 回目の my 宣言と違って、 同じパッケージの同じスコープで 2 回 our 宣言するのは単に冗長です。

    use warnings;
    package Foo;
    our $bar;      # declares $Foo::bar for rest of lexical scope
    $bar = 20;

    package Bar;
    our $bar = 30; # declares $Bar::bar for rest of lexical scope
    print $bar;    # prints 30

    our $bar;      # emits warning but has no other effect
    print $bar;    # still prints 30

our 宣言には、それと結び付けられる属性のリストを持つこともあります。

TYPE と ATTRS の正確な文法とインターフェースは今でも進化しています。 現在のところ、TYPE は fields プラグマの使用と結び付けられていて、 属性は attributes プラグマか、Perl 5.8.0 からは Attribute::Handlers モジュールと結び付けられています。 詳しくは"Private Variables via my()" in perlsub, fields, attributes, Attribute::Handlers を参照してください。

pack TEMPLATE,LIST

LIST の値を TEMPLATE で与えられたルールを用いて文字列に変換します。 結果の文字列は変換した値を連結したものです。 典型的には、それぞれの変換された値はマシンレベルの表現のように見えます。 例えば、32-bit マシンでは、整数は 4 バイトで表現されるので、 Perl では 4 文字の文字列で表現されます。

この関数の説明については perlpacktut を参照してください。

TEMPLATE は、以下のような値の型と順番を指定する文字を並べたものです:

    a  任意のバイナリデータを含む文字列、ヌル文字で埋める。
    A  テキスト (ASCII) 文字列、スペース文字で埋める。
    Z  ヌル文字終端 (ASCIZ) 文字列、ヌル文字で埋める。

    b  ビット列 (バイトごとに昇ビット順、vec() と同じ)。
    B  ビット列 (バイトごとに降ビット順)。
    h  16 進数文字列 (低位ニブルが先)。
    H  16 進数文字列 (高位ニブルが先)。

    c  signed char (8 ビット) 値。
    C  unsigned char (オクテット) 値。
    W  unsigned char 値 (255 より大きいかもしれません)。

    s  signed short (16 ビット) 値。
    S  unsigned short 値。

    l  signed long (32 ビット) 値。
    L  unsigned long 値。

    q  符号付き 64 ビット整数。
    Q  符号なし 64 ビット整数。
      (64 ビット整数は、システムが 64 ビット整数に対応していて、かつ Perl が
       64 ビット整数対応としてコンパイルされている場合にのみ使用可能です。
           それ以外の場合は例外が発生します。)

    i  signed int 値。
    I  unsigned int 値。
       (ここでの 'integer' は 「最低」 32 bits 幅です。正確なサイズは
        ローカルの C コンパイラの'int'のサイズに依存します。)

    n  "network" 順序 (ビッグエンディアン) の unsigned short (16 ビット)。
    N  "network" 順序 (ビッグエンディアン) の unsigned long (32 ビット)。
    v  "VAX" 順序 (リトルエンディアン) の unsigned short (16 ビット)。
    V  "VAX" 順序 (リトルエンディアン) の unsigned long (32 ビット)。

    j  Perl 内部符号付き整数 (IV)。
    J  Perl 内部符号なし整数 (UV)。

    f  機種依存の単精度浮動小数点数。
    d  機種依存の倍精度浮動小数点数。

    F  ネイティブフォーマットの Perl 内部浮動小数点数 (NV)
    D  ネイティブフォーマットの長い倍精度浮動小数点数(long double)。
      (long double は、システムが long double に対応していて、かつ Perl が
       long double 対応としてコンパイルされている場合にのみ使用可能です。
           それ以外の場合は例外が発生します。)

    p  ヌル文字で終端する文字列へのポインタ。
    P  構造体 (固定長文字列) へのポインタ。

    u  uuencode 文字列。
    U  Unicode 文字番号。文字モードでは文字に、バイトモードなら UTF-8 に
       (EBCDIC システムでは UTF-EBCDIC に)エンコードされます。

    w  A BER 圧縮変数(ASN.1 BER ではありません; 詳細については perlpacktut を
       参照してください)。このバイト列はできるだけ少ない桁数で表現された
       128 を基とした符号なし整数で、最上位ビットから順に並びます。
       最後のバイト以外の各バイトのビット 8 (上位ビット) がセットされます。

    x  ヌル文字 (つまり ASCII NUL, "\000", chr(0))
    X  1 文字後退。
    @  一番内側の () の組の開始位置から数えて、絶対位置までヌル文字で
       埋めるか切り詰める。
    .  値で指定した絶対位置までヌル文字で埋めるか切り詰める。
    (  () の組の開始。

以下に示す一つまたは複数の修飾子を、TEMPLATE の文字のいくつかにオプションで 付けることができます(表の 2 列目は、その修飾子が有効な文字です):

    !   sSlLiI     固定の(16/32 ビット)サイズではなく、ネイティブな
                   (short, long, int)サイズを強制する。

        xX         x と X をアライメントコマンドとして振舞わせる。

        nNvV       整数を符号なしではなく符号付きとして扱わせる。

        @.         pack された内部表現のバイトオフセットとして位置を指定する。
                   効率的ですが危険です。

    >   sSiIlLqQ   これらの型のバイト順をビッグエンディアンに強制します。
        jJfFdDpP   (「大きい端」が構造に触れています。)

    <   sSiIlLqQ   これらの型のバイト順をリトルエンディアンに強制します。
        jJfFdDpP   (「小さい端」が構造に触れています。)

>< の修飾子は ()-グループでも使えます; この場合はそのグループと全ての副グループ内の全ての要素を特定のバイト順に 強制します。

以下の条件が適用されます:

例:

    $foo = pack("WWWW",65,66,67,68);
    # foo eq "ABCD"
    $foo = pack("W4",65,66,67,68);
    # same thing
    $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
    # same thing with Unicode circled letters.
    $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
    # same thing with Unicode circled letters.  You don't get the
    # UTF-8 bytes because the U at the start of the format caused
    # a switch to U0-mode, so the UTF-8 bytes get joined into
    # characters
    $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
    # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
    # This is the UTF-8 encoding of the string in the
    # previous example

    $foo = pack("ccxxcc",65,66,67,68);
    # foo eq "AB\0\0CD"

    # NOTE: The examples above featuring "W" and "c" are true
    # only on ASCII and ASCII-derived systems such as ISO Latin 1
    # and UTF-8.  On EBCDIC systems, the first example would be
    #      $foo = pack("WWWW",193,194,195,196);

    $foo = pack("s2",1,2);
    # "\001\000\002\000" on little-endian
    # "\000\001\000\002" on big-endian

    $foo = pack("a4","abcd","x","y","z");
    # "abcd"

    $foo = pack("aaaa","abcd","x","y","z");
    # "axyz"

    $foo = pack("a14","abcdefg");
    # "abcdefg\0\0\0\0\0\0\0"

    $foo = pack("i9pl", gmtime);
    # a real struct tm (on my system anyway)

    $utmp_template = "Z8 Z8 Z16 L";
    $utmp = pack($utmp_template, @utmp1);
    # a struct utmp (BSDish)

    @utmp2 = unpack($utmp_template, $utmp);
    # "@utmp1" eq "@utmp2"

    sub bintodec {
        unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
    }

    $foo = pack('sx2l', 12, 34);
    # short 12, two zero bytes padding, long 34
    $bar = pack('s@4l', 12, 34);
    # short 12, zero fill to position 4, long 34
    # $foo eq $bar
    $baz = pack('s.l', 12, 4, 34);
    # short 12, zero fill to position 4, long 34

    $foo = pack('nN', 42, 4711);
    # pack big-endian 16- and 32-bit unsigned integers
    $foo = pack('S>L>', 42, 4711);
    # exactly the same
    $foo = pack('s<l<', -42, 4711);
    # pack little-endian 16- and 32-bit signed integers
    $foo = pack('(sl)<', -42, 4711);
    # exactly the same

一般には、pack で使用したものと同じテンプレートが、 unpack() 関数でも使用できます。

package NAMESPACE
package NAMESPACE VERSION
package NAMESPACE BLOCK
package NAMESPACE VERSION BLOCK

BLOCK や残りのコンパイル単位を与えられた名前空間として宣言します。 パッケージ宣言のスコープは BLOCK か、BLOCK がないばあいは宣言自身から 現在のスコープの末尾 (閉じたブロック、ファイル、eval) です。 つまり、BLOCK なしの形式は、my, state, our 演算子と同様に 現在のスコープの末尾にまで作用します。 このスコープ内の、全ての完全修飾されていない動的識別子は、他の package 宣言によって上書きされるか、 STDOUT, ARGV, ENV や句読点変数のように main:: に 割り当てられる特殊変数でない限り、指定された 名前空間になります。

package 文は動的変数にのみ影響します(local で使ったものも 含みます)が、my, state, our のいずれかで作成された レキシカルなスコープの変数には 影響しません。 典型的にはこれは requireuse 演算子でインクルードされるファイルの 最初に宣言されます。 パッケージを複数の場所で切り替えることができます; なぜならこれは単にコンパイラがこのブロックの残りに対してどの シンボルテーブルを使うかにのみ影響するからです。 他のパッケージの識別子は、$SomePack::varThatPack::INPUT_HANDLE のように、識別子にパッケージ名と コロン二つをつけることで参照できます。 パッケージ名が省略された場合、main パッケージが仮定されます。 つまり、$::sail$main::sail と等価です(ほとんどは Perl 4 からの、 古いコードでは $main'sail もまだ見られます)。

VERSION が指定されると、package は与えられた名前空間の $VERSION 変数に、 指定された VERSION の version オブジェクトをセットします。 VERSION は version で定義されている「厳密な」形式のバージョン番号で なければなりません: 指数のない正の 10 進数 (整数か 10 進小数) か、 さもなければ先頭に 'v' の文字が付いて、少なくとも三つの部分から 構成されるドット付き 10 進v-文字列です。 $VERSION はパッケージ毎に 1 回だけセットするべきです。

パッケージ、モジュール、クラスに関するさらなる情報については "Packages" in perlmod を参照してください。 その他のスコープに関する話題については perlsub を参照してください。

__PACKAGE__

これが書いてあるパッケージの名前を返す特殊トークン。

pipe READHANDLE,WRITEHANDLE

対応するシステムコールと同じように、 接続されたパイプのペアをオープンします。 パイプでプロセスをループにするときには、よほど気を付けないと、 デッドロックが起こり得ます。 さらに、Perl のパイプでは、IO のバッファリングを使いますから、 アプリケーションによっては、コマンドごとに WRITEHANDLE を フラッシュするように、$| を設定することが必要になるかもしれません。

成功時には真を返します。

これらに関する例については、IPC::Open2, IPC::Open3, "Bidirectional Communication with Another Process" in perlipc を 参照してください。

ファイルに対する close-on-exec フラグをサポートしているシステムでは、 新しくオープンされたファイル記述子のうち、 fileno が現在の $^F の値(デフォルトでは STDERR の 2) よりも大きい ものに対してフラグがセットされます。 "$^F" in perlvar を参照してください。

pop ARRAY
pop EXPR
pop

配列の最後の値をポップして返し、配列の大きさを 1 だけ小さくします。

指定された配列に要素がなければ未定義値が返されますが、 しかしこれは他の場合にも起こり得ます。 ARRAY が省略されると、shift と同様に、メインプログラムでは @ARGV が 使われますが、サブルーチンでは @_ が使われます。

Perl 5.14 から、pop はスカラの EXPR を取ることができるようになりました; これは bless されていない配列へのリファレンスでなければなりません。 引数は自動的にデリファレンスされます。 pop のこの動作は高度に実験的であると考えられています。 正確な振る舞いは将来のバージョンの Perl で変わるかも知れません。

あなたのコードを以前のバージョンの Perl で実行したユーザーが不思議な 文法エラーで混乱することを避けるために、コードが最近のバージョンの Perl で のみ 動作することを示すためにファイルの先頭に以下のようなことを 書いてください:

    use 5.014;  # so push/pop/etc work on scalars (experimental)
pos SCALAR
pos

対象の変数に対して、前回の m//g が終了した場所の オフセットを返します(変数が指定されなかった場合は $_ が使われます)。 0 は有効なマッチオフセットであることに注意してください。 undef は検索位置がリセットされることを意味します (通常はマッチ失敗が 原因ですが、このスカラ値にまだマッチングが行われていないためかもしれません)。

pos は正規表現エンジンがオフセットを保存するために使う場所を直接 アクセスするので、pos への代入はオフセットを変更し、そのような変更は 正規表現における \G ゼロ幅アサートにも影響を与えます。 これらの効果の両方は次のマッチングのために行われるので、 (?{pos() = 5})s//pos() = 5/e のように現在のマッチング中の pos の位置には影響を与えません。

pos を設定すると、 "Repeated Patterns Matching a Zero-length Substring" in perlre に 記述されている、長さ 0 でマッチング フラグもリセットされます。

m//gc マッチに失敗してもオフセットはリセットしないので、 pos からの返り値はどちらの場合も変更されません。 perlreperlop を参照してください。

print

文字列か文字列のリストを出力します。 成功時には真を返します。 FILEHANDLE は、ファイルハンドル名またはそのリファレンスが 入っているスカラ変数名でもよいので、一段階の間接指定が行なえます。 (注: FILEHANDLE に変数を使い、次のトークンが「項」のときには、 間に + を置くか、引数の前後を括弧で括らなければ、 誤って解釈されることがあります。) FILEHANDLE を省略した場合には、最後に選択された ("select" 参照) 出力 チャネルに出力します。 LIST を省略すると、$_ が現在選択されている出力ハンドルに出力されます。 $_ の内容を表示するために FILEHANDLE のみを使用するには、 $fh のような間接ファイルハンドルではなく、FH のような実際の ファイルハンドルを使わなければなりません。 デフォルトの出力チャネルを STDOUT 以外にするには、select 演算子を 使ってください。

$, の値が(もしあれば)各 LIST 要素の間に出力されます。 LIST 全体が出力された後、(もしあれば) $\ の現在の値が出力されます。 print の引数は LIST なので、LIST の中のものは、すべてリストコンテキストで 評価されます; print に渡した、リストを返すサブルーチンも含みます。 また、すべての引数を括弧で括るのでなければ、print というキーワードの 次に開き括弧を書いてはいけません; すべての引数を括弧で括ってください (あるいは "print" と引数の間に + を書きますが、これはあまり よくありません)。

もし FILESHANDLE を配列、ハッシュあるいは一般的には裸の単語のハンドルや 普通のスカラ変数よりも複雑な表現を使っている場合、代わりにその値を返す ブロックを使う必要があります; この場合 LIST は省略できません:

    print { $files[$i] } "stuff\n";
    print { $OK ? STDOUT : STDERR } "stuff\n";

閉じたパイプやソケットに print すると SIGPIPE シグナルが生成されます。 さらなるシグナル操作については perlipc を参照してください。

printf FILEHANDLE FORMAT, LIST
printf FILEHANDLE
printf FORMAT, LIST
printf

$\(出力レコードセパレータ)を追加しないことを除けば、 print FILEHANDLE sprintf(FORMAT, LIST) と等価です。 FORMAT と LIST は実際には単一のリストとしてパースされます。 リストの最初の要素は、printf フォーマットと解釈されます。 これは、printf(@_) はフォーマットとして $_[0] を使うということです。 フォーマット引数の説明については sprintf を 参照してください。 (use locale ':not_characters' を含む) use locale が効力をもっていて、 POSIX::setlocale() が呼び出されていれば、 小数点に使われる文字は LC_NUMERIC ロケール設定の影響を受けます。 perllocalePOSIX を参照してください。

歴史的な理由により、リストを省略すると、フォーマットとして $_ が使われます; リストなしで FILEHANDLE を使用するには、 $fh のような間接ファイルハンドルではなく、FH のような実際の ファイルハンドルを使わなければなりません。 しかし、これがあなたが求めていることをすることはまれです; $_ がフォーマッティングコードの場合、空文字列に置き換えられ、警告が有効なら 警告が出力されます。 $_ の内容を表示したい場合は、単に print を使ってください。

単純な print を使うべきところで printf を使ってしまう 罠にかからないようにしてください。 print はより効率的で、間違いが起こりにくいです。

prototype FUNCTION

関数のプロトタイプを文字列として返します(関数にプロトタイプがない場合は undef を返します)。 FUNCTION はプロトタイプを得たい関数の名前、またはリファレンスです。

FUNCTION が CORE:: で始まっている場合、残りは Perl ビルドインの名前として 扱われます。 このビルドインの引数が(system のように)プロトタイプとして適切に 記述できない場合、prototype() は undef を返します; なぜならビルドインは実際に Perl 関数のように振舞わないからです。 それ以外では、等価なプロトタイプを表現した文字列が返されます。

push ARRAY,LIST
push EXPR,LIST

ARRAY をスタックとして扱い、LIST 内の値を ARRAY の終わりに追加します。 ARRAY の大きさは、LIST の長さ分だけ大きくなります。 これは、

    for $value (LIST) {
        $ARRAY[++$#ARRAY] = $value;
    }

とするのと同じ効果がありますが、より効率的です。 push の処理終了後の配列の要素数を返します。

Perl 5.14 から、push はスカラの EXPR を取ることができるようになりました; これは bless されていない配列へのリファレンスでなければなりません。 引数は自動的にデリファレンスされます。 push のこの動作は高度に実験的であると考えられています。 正確な振る舞いは将来のバージョンの Perl で変わるかも知れません。

あなたのコードを以前のバージョンの Perl で実行したユーザーが不思議な 文法エラーで混乱することを避けるために、コードが最近のバージョンの Perl で のみ 動作することを示すためにファイルの先頭に以下のようなことを 書いてください:

    use 5.014;  # so push/pop/etc work on scalars (experimental)
q/STRING/
qq/STRING/
qw/STRING/
qx/STRING/

汎用のクォートです。 "Quote-Like Operators" in perlop を参照してください。

qr/STRING/

正規表現風のクォートです。 "Regexp Quote-Like Operators" in perlop を参照してください。

quotemeta EXPR
quotemeta

EXPR の中のすべての ASCII 非英数字キャラクタをバックスラッシュで エスケープしたものを返します。 (つまり、/[A-Za-z_0-9]/ にマッチしない全ての ASCII 文字の前には ロケールに関わらずバックスラッシュが前置されます。) これは、ダブルクォート文字列での \Q エスケープを実装するための 内部関数です。 (非 ASCII 符号位置での振る舞いについては以下を参照してください。)

EXPR が省略されると、$_ を使います。

クォートメタ (と \Q ... \E) は、文字列を正規表現に展開するのに 便利です; なぜなら、デフォルトでは展開された変数は小さな正規表現として 扱われるからです。 例えば:

    my $sentence = 'The quick brown fox jumped over the lazy dog';
    my $substring = 'quick.*?fox';
    $sentence =~ s{$substring}{big bad wolf};

とすると、$sentence'The big bad wolf jumped over...' になります。

一方:

    my $sentence = 'The quick brown fox jumped over the lazy dog';
    my $substring = 'quick.*?fox';
    $sentence =~ s{\Q$substring\E}{big bad wolf};

あるいは:

    my $sentence = 'The quick brown fox jumped over the lazy dog';
    my $substring = 'quick.*?fox';
    my $quoted_substring = quotemeta($substring);
    $sentence =~ s{$quoted_substring}{big bad wolf};

とすると、両方ともそのままです。 普通は、ユーザーからのリテラルな文字列入力を受け付ける場合は、 必ず quotemeta() か \Q を使わなければなりません。

Perl v5.14 では、全ての非 ASCII 文字は非 UTF-8 エンコードされた 文字列ではクォートされませんが、UTF-8 文字列ではクォートされます。

Perl v5.16 から、Perl は非 ASCII 文字をクォートするのに Unicode で 定義された戦略を採用しました; ASCII 文字のクォートは変わりません。

また、use feature 'unicode_strings' の範囲外で非 UTF-8 文字列を クォートするのも変わりません; 上位の Latin1 の範囲の全ての文字を クォートします。 これは Unicode を使わない古いプログラムに対して完全な後方互換性を 提供します。 (unicode_stringsuse v5.12 またはそれ以上のスコープでは 自動的に有効になることに注意してください。)

use locale スコープの内側では、全ての非 ASCII Latin1 符号位置は 文字列が UTF-8 でエンコードされているかどうかに関わらずクォートされます。 上述のように、ロケールは ASCII の範囲の文字のクォートに影響を与えません。 これは "|" のような文字が単語文字として考えられるロケールから守ります。

さもなければ、Perl は Unicode からの本版を使って非 ASCII 文字をクォートします (http://www.unicode.org/reports/tr31/ 参照)。 クォートされる符号位置は以下のどれかの Unicode を特性を持つものだけです: Pattern_Syntax, Pattern_White_Space, White_Space, Default_Ignorable_Code_Point, or General_Category=Control。

これらの特性の中で、重要な二つは Pattern_Syntax と Pattern_White_Space です。 これらはまさに正規表現中パターン中のどの文字をクォートするべきかを 決定するという目的のために Unicode によって設定されています。 識別子になる文字はこれらの特性はありません。

Perl は、正規表現メタ文字として既に定義されている (\ | ( ) [ { ^ $ * + ? .) ものに追加するときは、 Pattern_Syntax 特性を持つものだけを使うことを約束します。 Perl はまた、(現在の所ほとんどは /x よって影響される)正規表現中で空白と 考えられる文字に追加するときは、Pattern_White_Space 特性を 持つものであることを約束します。

Unicode はこれら二つの特性を持つ符号位置の集合が決して変わらないことを 約束しているので、v5.16 でクォートされないものは将来の Perl リリースでも クォートする必要はありません。 (Pattern_Syntax にマッチングする全ての符号位置が実際に割り当てられている 文字を持っているわけではありません; したがって拡張する余地がありますが、 割り当てられているかどうかに関わらずクォートされます。 Perl はもちろん割り当てられていない符号位置を実際のメタ文字として使うことは ありません。)

その他の 3 特性を持つ文字のクォートは正規表現の可読性を向上させるために 行われ、実際には正規表現の目的でクォートする必要があるからではありません (White_Space 特性を持つ文字は表示上は Pattern_White_Space 特性を持つ文字と おそらく区別が付かないでしょう; そして残りの 二つの特性は非表示文字を含んでいます).

rand EXPR
rand

0 以上 EXPR の値未満の小数の乱数値を返します。 (EXPR は正の数である必要があります。) EXPR が省略されると、1 が使われます。 現在のところ、EXPR に値 0 をセットすると 1 として特別扱いされます (これは Perl 5.8.0 以前には文書化されておらず、将来のバージョンの perl では 変更される可能性があります)。 srand が既に呼ばれている場合以外は、自動的に srand 関数を 呼び出します。 srand も参照してください。

ランダムな小数ではなく、ランダムな整数がほしい場合は、rand() から 返された値に int() を適用してください。 例えば:

    int(rand(10))

これは 0 から 9 の値をランダムに返します。

(注: もし、rand 関数が、常に大きい値ばかりや、小さい数ばかりを 返すようなら、お使いになっている Perl が、 良くない RANDBITS を使ってコンパイルされている可能性があります。)

rand() は暗号学的に安全ではありません。 セキュリティ的に重要な状況でこれに頼るべきではありません。 これを書いている時点で、いくつかのサードパーティ CPAN モジュールが 作者によって暗号学的に安全であることを目的とした乱数生成器を 提供しています: Data::Entropy, Crypt::Random, Math::Random::Secure, Math::TrulyRandom などです。

read FILEHANDLE,SCALAR,LENGTH,OFFSET
read FILEHANDLE,SCALAR,LENGTH

指定した FILEHANDLE から、変数 SCALAR に LENGTH 文字 の データを読み込みます。 実際に読み込まれた文字数、 ファイル終端の場合は 0、エラーの場合は undef のいずれかを返します (後者の場合、$! もセットされます)。 SCALAR は伸び縮みするので、 読み込み後は、実際に読み込んだ最後の文字がスカラの最後の文字になります。

OFFSET を指定すると、文字列の先頭以外の場所から、読み込みを行なうことが できます。 OFFSET に負の値を指定すると、文字列の最後から逆向きに何文字目かで 位置を指定します。 OFFSET が正の値で、SCALAR の長さよりも大きかった場合、文字列は 読み込みの結果が追加される前に、必要なサイズまで "\0" のバイトで パッディングされます。

この関数は、Perl か システムの fread(3) ライブラリ関数を使って実装しています。 本当の read(2) システムコールを利用するには、 sysread を参照してください。

文字 に関する注意: ファイルハンドルの状態によって、(8 ビットの) バイトか 文字が読み込まれます。 デフォルトでは全てのファイルハンドルはバイトを処理しますが、 例えばファイルハンドルが :utf8 I/O 層("open", open プラグマ、 open を参照してください) で開かれた場合、I/O はバイトではなく、 UTF8 エンコードされた Unicode 文字を操作します。 :encoding プラグマも同様です: この場合、ほとんど大体全ての文字が読み込めます。

readdir DIRHANDLE

opendir でオープンしたディレクトリで、 次のディレクトリエントリを返します。 リストコンテキストで用いると、 そのディレクトリの残りのエントリを、すべて返します。 エントリが残っていない場合には、スカラコンテキストでは未定義値を、 リストコンテキストでは空リストを返します。

readdir の返り値をファイルテストに使おうと計画しているなら、 頭にディレクトリをつける必要があります。 さもなければ、ここでは chdir はしないので、 間違ったファイルをテストしてしまうことになるでしょう。

    opendir(my $dh, $some_dir) || die "can't opendir $some_dir: $!";
    @dots = grep { /^\./ && -f "$some_dir/$_" } readdir($dh);
    closedir $dh;

Perl 5.12 から裸の readdirwhile で使うことができ、 この場合繰り返し毎に $_ にセットされます。

    opendir(my $dh, $some_dir) || die;
    while(readdir $dh) {
        print "$some_dir/$_\n";
    }
    closedir $dh;

あなたのコードを以前のバージョンの Perl で実行したユーザーが不思議な 失敗で混乱することを避けるために、コードが最近のバージョンの Perl で のみ 動作することを示すためにファイルの先頭に以下のようなことを 書いてください:

    use 5.012; # so readdir assigns to $_ in a lone while test
readline EXPR
readline

型グロブが EXPR (EXPR がない場合は *ARGV) に含まれている ファイルハンドルから読み込みます。 スカラコンテキストでは、呼び出し毎に一行読み込んで返します; ファイルの 最後まで読み込んだら、以後の呼び出しでは undef を返します。 リストコンテキストでは、ファイルの最後まで読み込んで、行のリストを返します。 ここでの「行」とは、$/ または $INPUT_RECORD_SEPARATOR で 定義されることに注意してください。 "$/" in perlvar を参照してください。

$/undef を設定した場合は、readline はスカラコンテキスト (つまりファイル吸い込みモード)となり、 空のファイルを読み込んだ場合は、最初は '' を返し、 それ以降は undef を返します。

これは <EXPR> 演算子を実装している内部関数ですが、 直接使うこともできます。 <EXPR> 演算子についてのさらなる詳細については "I/O Operators" in perlop で議論されています。

    $line = <STDIN>;
    $line = readline(*STDIN);    # same thing

readline が OS のシステムエラーになると、$! に対応するエラーメッセージが セットされます。 tty やソケットといった、信頼できないファイルハンドルから読み込む時には $! をチェックするのが助けになります。 以下の例は演算子の形の readline を使っており、結果が 未定義の場合は die します。

    while ( ! eof($fh) ) {
        defined( $_ = <$fh> ) or die "readline failed: $!";
        ...
    }

readline のエラーは ARGV ファイルハンドルの方法では扱えないことに 注意してください。 この場合、eofARGV を異なった方法で扱うので、 @ARGV のそれぞれの要素を自分でオープンする必要があります。

    foreach my $arg (@ARGV) {
        open(my $fh, $arg) or warn "Can't open $arg: $!";

        while ( ! eof($fh) ) {
            defined( $_ = <$fh> )
                or die "readline failed for $arg: $!";
            ...
        }
    }

シンボリックリンクが実装されていれば、 シンボリックリンクの値を返します。 実装されていないときには、例外が発生します。 何らかのシステムエラーが検出されると、未定義値を返し、 $! (errno) を設定します。 EXPR が省略されると、$_ を使います。

移植性の問題: "readlink" in perlport

readpipe EXPR
readpipe

EXPR がシステムコマンドとして実行されます。 コマンドの標準出力の内容が返されます。 スカラコンテキストでは、単一の(内部的に複数行の)文字列を返します。 リストコンテキストでは、行のリストを返します (但し、行は $/ または $INPUT_RECORD_SEPARATOR で定義されます)。 これは qx/EXPR/ 演算子を実装する内部関数ですが、 直接使うことも出来ます。 qx/EXPR/ 演算子は "I/O Operators" in perlop でより詳細に 述べられています。 EXPR が省略されると、$_ を使います。

recv SOCKET,SCALAR,LENGTH,FLAGS

ソケット上のメッセージを受信します。 指定されたファイルハンドル SOCKET から、変数 SCALAR に LENGTH 文字のデータを読み込もうとします。 SCALAR は、実際に読まれた長さによって、大きくなったり、 小さくなったりします。 同名のシステムコールと同じフラグが指定できます。 SOCKET のプロトコルが対応していれば、送信側のアドレスを返します。 エラー発生時には、未定義値を返します。 実際には、C のrecvfrom(2) を呼びます。 例については "UDP: Message Passing" in perlipc を参照してください。

文字 に関する注意: ソケットの状態によって、(8 ビットの) バイトか 文字を受信します。 デフォルトでは全てのソケットはバイトを処理しますが、 例えばソケットが binmode() で :encoding(utf8) I/O 層(open プラグマ、 open を参照してください) を使うように指定された場合、I/O はバイトではなく、 UTF8 エンコードされた Unicode 文字を操作します。 :encoding プラグマも同様です: この場合、ほとんど大体全ての文字が読み込めます。

redo LABEL
redo EXPR
redo

redo コマンドは、条件を再評価しないで、ループブロックの始めからもう一度 実行を開始します。 continue ブロックがあっても、実行されません。 LABEL が省略されると、コマンドは一番内側のループを参照します。 Perl 5.18.0 から利用可能な redo EXPR 形式では、実行時に計算されるラベル名が 使えます; それ以外は redo LABEL と同一です。 このコマンドは通常、自分への入力を欺くために使用します:

    # a simpleminded Pascal comment stripper
    # (warning: assumes no { or } in strings)
    LINE: while (<STDIN>) {
        while (s|({.*}.*){.*}|$1 |) {}
        s|{.*}| |;
        if (s|{.*| |) {
            $front = $_;
            while (<STDIN>) {
                if (/}/) {  # end of comment?
                    s|^|$front\{|;
                    redo LINE;
                }
            }
        }
        print;
    }

redoeval {}, sub {}, do {} のように値を返す ブロックを繰り返すのには使えません; また、grep() や map() 操作から抜けるのに 使うべきではありません。

ブロック自身は一回だけ実行されるループと文法的に同一であることに 注意してください。 従って、ブロックの中で redo を使うことで効果的に ループ構造に変換します。

last, next, redo がどのように働くかについては "continue" も参照してください。

ほとんどの名前付き演算子と異なり、これは代入と同じ優先順位を持ちます。 また、関数のように見えるものの規則からも免れるので、redo ("foo")."bar" と すると "bar" は redo への引数の一部となります。

ref EXPR
ref

EXPR がリファレンスであれば、空でない文字列を返し、さもなくば、 空文字列を返します。 EXPR が指定されなければ、$_ が使われます。 返される値は、リファレンスが参照するものの型に依存します。 組み込みの型には、以下のものがあります。

    SCALAR
    ARRAY
    HASH
    CODE
    REF
    GLOB
    LVALUE
    FORMAT
    IO
    VSTRING
    Regexp

参照されるオブジェクトが、何らかのパッケージに bless されたものであれば、これらの代わりに、 そのパッケージ名が返されます。 ref は、typeof 演算子のように考えることができます。

    if (ref($r) eq "HASH") {
        print "r is a reference to a hash.\n";
    }
    unless (ref($r)) {
        print "r is not a reference at all.\n";
    }

返り値 LVALUE は、変数ではない左辺値へのリファレンスを示します。 これは、pos()substr() のようの関数呼び出しのリファレンスから 得られます。 VSTRING は、リファレンスが version string を 指している場合に返されます。

Regexp という結果は、引数が qr// からの結果である 正規表現であることを意味します。

perlref も参照してください。

rename OLDNAME,NEWNAME

ファイルの名前を変更します; NEWNAME というファイルが既に存在した場合、 上書きされるかもしれません。 成功時には真を、さもなければ偽を返します。

この関数の振る舞いはシステムの実装に大きく依存して異なります。 例えば、普通はファイルシステムにまたがってパス名を付け替えることはできません; システムの mv がこれを補完している場合でもそうです。 その他の制限には、ディレクトリ、オープンしているファイル、既に存在している ファイルに対して使えるか、といったことを含みます。 詳しくは、perlport および rename(2) man ページあるいは同様の システムドキュメントを参照してください。

プラットフォームに依存しない move 関数については File::Copy モジュールを 参照してください。

移植性の問題: "rename" in perlport

require VERSION
require EXPR
require

VERSION で指定される Perl のバージョンを要求するか、 EXPR (省略時には $_) によって指定されるいくつかの動作を要求します。

VERSION は 5.006 のような数値($] と比較されます)か、v5.6.1 の形 ($^V (またの名を $PERL_VERSION) と比較されます)で指定します。 VERSION が Perl の現在のバージョンより大きいと、例外が発生します。 "use" と似ていますが、これはコンパイル時にチェックされます。

VERSION に v5.6.1 の形のリテラルを指定することは一般的には避けるべきです; なぜなら、この文法に対応していない Perl の初期のバージョンでは 誤解させるようなエラーメッセージが出るからです。 代わりに等価な数値表現を使うべきです。

    require v5.6.1;     # 実行時バージョンチェック
    require 5.6.1;      # 同様
    require 5.006_001;  # 同様; 後方互換性のためには望ましい

それ以外の場合には、require は、既に読み込まれていないときに読み込む ライブラリファイルを要求するものとなります。 そのファイルは、基本的には eval の一種である、do-FILE によって 読み込まれますが、起動したスクリプトのレキシカル変数は読み込まれたコードから 見えないという欠点があります。 意味的には、次のようなサブルーチンと同じようなものです:

    sub require {
       my ($filename) = @_;
       if (exists $INC{$filename}) {
           return 1 if $INC{$filename};
           die "Compilation failed in require";
       }
       my ($realfilename,$result);
       ITER: {
           foreach $prefix (@INC) {
               $realfilename = "$prefix/$filename";
               if (-f $realfilename) {
                   $INC{$filename} = $realfilename;
                   $result = do $realfilename;
                   last ITER;
               }
           }
           die "Can't find $filename in \@INC";
       }
       if ($@) {
           $INC{$filename} = undef;
           die $@;
       } elsif (!$result) {
           delete $INC{$filename};
           die "$filename did not return true value";
       } else {
           return $result;
       }
    }

ファイルは、同じ名前で 2 回読み込まれることはないことに注意してください。

初期化コードの実行がうまくいったことを示すために、 ファイルは真を返さなければなりませんから、 真を返すようになっている自信がある場合を除いては、 ファイルの最後に 1; と書くのが習慣です。 実行文を追加するような場合に備えて、1; と書いておいた方が 良いでしょう。

EXPR が裸の単語であるときには、標準モジュールのロードを 簡単にするように、require は拡張子が ".pm" であり、 "::" を "/" に変えたものがファイル名であると仮定します。 この形式のモジュールロードは、 名前空間を変更してしまう危険はありません。

言い換えると、以下のようにすると:

        require Foo::Bar;     # a splendid bareword

require 関数は @INC 配列で指定されたディレクトリにある "Foo/Bar.pm" ファイルを探します。

しかし、以下のようにすると:

        $class = 'Foo::Bar';
        require $class;       # $class is not a bareword
    #or
        require "Foo::Bar";   # not a bareword because of the ""

require 関数は @INC 配列の "Foo::Bar" ファイルを探し、 おそらくそこに "Foo::Bar" がないと文句をいうことになるでしょう。 このような場合には、以下のようにします:

        eval "require $class";

引数が裸の単語の場合、require がどのようにファイルを探すかを 理解してください; 水面下でちょっとした追加の機能があります。 require が拡張子 ".pm" のファイルを探す前に、まず拡張子 ".pmc" を 持つファイルを探します。 このファイルが見つかると、このファイルが拡張子 ".pm" の代わりに 読み込まれます。

@INC 配列に直接 Perl コードを入れることで、インポート機能にフックを 挿入できます。 3 種類のフックがあります: サブルーチンリファレンス、配列リファレンス、 bless されたオブジェクトです。

サブルーチンへのリファレンスは一番単純な場合です。 インクルード機能が @INC を走査してサブルーチンに出会った場合、この サブルーチンは二つの引数と共に呼び出されます; 一つ目は自身へのリファレンス、二つ目はインクルードされるファイル名 ("Foo/Bar.pm" など)です。 サブルーチンは何も返さないか、以下の順で最大三つの値のリストを 返します。

  1. ファイルが読み込まれるファイルハンドル。

  2. サブルーチンへのリファレンス。 (一つ前のアイテムである)ファイルハンドルがない場合、 サブルーチンは呼び出し毎に一行のソースコードを生成し、その行を $_ に 書き込んで 1 を返し、それから最終的にファイル終端で 0 を返すものと 想定されます。 ファイルハンドルがある場合、サブルーチンは単純なソースフィルタとして 振舞うように呼び出され、行は $_ から読み込まれます。 再び、有効な行ごとに 1 を返し、全ての行を返した後では 0 を返します。

  3. サブルーチンのための状態(オプション)。 状態は $_[1] として渡されます。 サブルーチンへのリファレンス自身は $_[0] として渡されます。

空リスト、undef、または上記の最初の三つの値のどれとも一致しないものが 返されると、require は @INC の残りの要素を見ます。 このファイルハンドルは実際のファイルハンドル(厳密には型グロブ、型グロブへの リファレンス、bless されているかに関わらず)でなければなりません; tie されたファイルハンドルは無視され、返り値の処理はそこで停止します。

フックが配列のリファレンスの場合、その最初の要素はサブルーチンへの リファレンスでなければなりません。 このサブルーチンは上述のように呼び出されますが、その最初の引数は 配列のリファレンスです。 これによって、間接的にサブルーチンに引数を渡すことが出来ます。

言い換えると、以下のように書いたり:

    push @INC, \&my_sub;
    sub my_sub {
        my ($coderef, $filename) = @_;  # $coderef is \&my_sub
        ...
    }

または以下のように書けます:

    push @INC, [ \&my_sub, $x, $y, ... ];
    sub my_sub {
        my ($arrayref, $filename) = @_;
        # Retrieve $x, $y, ...
        my @parameters = @$arrayref[1..$#$arrayref];
        ...
    }

フックがオブジェクトの場合、INC メソッドを提供している必要があります; それが、最初の引数をオブジェクト自身として上述のように呼び出されます。 (修飾されていない INC は常にパッケージ main に強制されるため、 サブルーチン名は完全修飾する必要があることに注意してください。) 以下は典型的なコードレイアウトです:

    # In Foo.pm
    package Foo;
    sub new { ... }
    sub Foo::INC {
        my ($self, $filename) = @_;
        ...
    }

    # In the main program
    push @INC, Foo->new(...);

これらのフックは、読み込まれるファイルに対応する %INC エントリを セットすることも許可します。 "%INC" in perlvar を参照してください。

より強力な import 機能については、このドキュメントの "use" の項と、perlmod を参照してください。

reset EXPR
reset

通常、ループの最後に、変数をクリアし、?? 検索を再び 動作するようにリセットするため、continue ブロックで使われます。 EXPR は、文字を並べたもの (範囲を指定するのに、ハイフンが使えます) と 解釈されます。 名前がその文字のいずれかで始まる変数や配列は、 最初の状態にリセットされます。 EXPR を省略すると、1 回検索 (?PATTERN?) を再びマッチするように リセットできます。 カレントパッケージの変数もしくは検索だけがリセットされます。 常に 1 を返します。 例:

    reset 'X';      # reset all X variables
    reset 'a-z';    # reset lower case variables
    reset;          # just reset ?one-time? searches

reset "A-Z" とすると、@ARGV, @INC 配列や %ENV ハッシュも なくなってしまいますから、止めた方が良いでしょう。 パッケージ変数だけがリセットされます; レキシカル変数は、影響を受けませんが、スコープから外れれば、 自動的に綺麗になりますので、これからは、こちらを使うようにした方が よいでしょう。 "my" を参照してください。

return EXPR
return

サブルーチン, eval, do FILE から EXPR で与えられた値をもって、 リターンします。 EXPR の評価は、返り値がどのように使われるかによってリスト、スカラ、 無効コンテキストになります; またコンテキストは実行毎に変わります (wantarray を参照してください)。 EXPR が指定されなかった場合は、リストコンテキストでは空リストを、 スカラコンテキストでは未定義値を返します; そして(もちろん) 無効コンテキストでは何も返しません。

(サブルーチン, eval, do FILE に明示的に return が なければ、最後に評価された値で、自動的にリターンします。)

ほとんどの名前付き演算子と異なり、関数のように見えるものの規則からも 免れるので、return ("foo")."bar" とすると "bar" は return への引数の 一部となります。

reverse LIST

リストコンテキストでは、LIST を構成するよ要素を逆順に並べた リスト値を返します。 スカラコンテキストでは、LIST の要素を連結して、 全ての文字を逆順にした文字列を返します。

    print join(", ", reverse "world", "Hello"); # Hello, world

    print scalar reverse "dlrow ,", "olleH";    # Hello, world

スカラコンテキストで引数なしで使うと、reverse() は $_ を逆順にします。

    $_ = "dlrow ,olleH";
    print reverse;                         # No output, list context
    print scalar reverse;                  # Hello, world

(@a = reverse @a のように) 反転した配列を自分自身に代入すると、 存在しない要素は可能なら(つまりマジカルでない配列や EXISTSDELETE メソッドがある tie された配列) いつでも保存されることに注意してください。

この演算子はハッシュの逆順にするのにも便利ですが、いくつかの弱点があります。 元のハッシュで値が重複していると、それらのうち一つだけが 逆順になったハッシュのキーとして表現されます。 また、これは一つのハッシュをほどいて完全に新しいハッシュを作るので、 DBM ファイルからのような大きなハッシュでは少し時間がかかります。

    %by_name = reverse %by_address;  # Invert the hash
rewinddir DIRHANDLE

DIRHANDLE に対する readdir ルーチンの現在位置を ディレクトリの最初に設定します。

移植性の問題: "rewinddir" in perlport

rindex STR,SUBSTR,POSITION
rindex STR,SUBSTR

STR 中で 最後に 見つかった SUBSTR の位置を返すことを除いて、 index() と同じように動作します。 POSITION を指定すると、その位置から始まるか、その位置より前の、 最後の位置を返します。

rmdir FILENAME
rmdir

FILENAME で指定したディレクトリが空であれば、 そのディレクトリを削除します。 成功時には真を返します; さもなければ偽を返して $! (errno) を設定します。 FILENAME を省略した場合には、$_ を使用します。

ディレクトリツリーを再帰的に削除したい (Unix での rm -rf) 場合、 File::Path モジュールの rmtree 関数を参照してください。

s///

置換演算子。 "Regexp Quote-Like Operators" in perlop を参照してください。

say FILEHANDLE LIST
say FILEHANDLE
say LIST
say

print と同様ですが、暗黙に改行が追加されます。 say LIST は単に { local $\ = "\n"; print LIST } の省略形です。 $_ の内容を表示するために LIST なしで FILEHANDLE を使用するには、 $fh のような間接ファイルハンドルではなく、FH のような実際の ファイルハンドルを使わなければなりません。

このキーワードは、"say" 機能が有効か、CORE:: が前置された場合にのみ 利用可能です; feature を参照してください。 または、現在のスコープに use v5.10 以降を含めてください。

scalar EXPR

EXPR を強制的にスカラコンテキストで解釈されるようにして、 EXPR の値を返します。

    @counts = ( scalar @a, scalar @b, scalar @c );

式を強制的にリストコンテキストで解釈させるようにする演算子はありません; 理論的には不要だからです。 それでも、もしそうしたいのなら、@{[ (some expression) ]} という構造を 使えます; しかし、普通は単に (some expression) とすれば十分です。

scalar は単項演算子なので、EXPR として括弧でくくったリストを使った場合、 これはスカラカンマ表現として振舞い、最後以外の全ては無効コンテキストとして 扱われ、最後の要素をスカラコンテキストとして扱った結果が返されます。 これがあなたの望むものであることはめったにないでしょう。

以下の一つの文は:

    print uc(scalar(&foo,$bar)),$baz;

以下の二つの文と等価です。

    &foo;
    print(uc($bar),$baz);

単項演算子とカンマ演算子に関する詳細については perlop を参照してください。

seek FILEHANDLE,POSITION,WHENCE

stdio ライブラリの fseek 関数のように、FILEHANDLE の ファイルポインタを任意の位置に設定します。 FILEHANDLE は、実際のファイルハンドル名を与える式でもかまいません。 WHENCE の値が、0 ならば、新しい位置を バイト単位で POSITION の位置へ 設定します; 1 ならば、現在位置から バイト数で POSITION 加えた位置へ 設定します; 2 ならば、EOF からPOSITION だけ加えた位置へ、新しい位置を 設定します。 この値には、Fcntl モジュールで使われている SEEK_SETSEEK_CURSEEK_END (ファイルの先頭、現在位置、ファイルの最後)という定数を 使うこともできます。 成功時には、1 を、失敗時には 0 を返します。

バイト単位 に関する注意: ファイルハンドルが (例えば :encoding(utf8) 層を 使って)文字を操作するように設定されていたとしても、tell() は文字の オフセットではなくバイトのオフセットを返すことに注意してください (なぜならこれを実装すると seek() と tell() が遅くなってしまうからです)。

sysreadsyswrite のためにファイルの位置を指定したい場合は、 seek は使えません; なぜならバッファリングのためにファイルの読み込み位置は 動作は予測不能で移植性のないものになってしまいます。 代わりに sysseek を使ってください。

ANSI C の規則と困難により、システムによっては読み込みと書き込みを 切り替える度にシークしなければならない場合があります。 その他のことの中で、これは stdio の clearerr(3) を呼び出す効果があります。 WHENCE の 1 (SEEK_CUR) が、ファイル位置を変えないので有用です:

    seek(TEST,0,1);

これはアプリケーションで tail -f をエミュレートするのにも有用です。 一度読み込み時に EOF に到達すると、しばらくスリープし、 (おそらく) ダミーの seek() をすることでリセットする必要があります。 seek は現在の位置を変更しませんが、ハンドルの EOF 状態を クリアします ので、次の <FILE> で Perl は再び何かを 読み込もうとします。(そのはずです。)

これが動かない場合(特に意地の悪い I/O 実装もあります)、 以下のようなことをする必要があります:

    for (;;) {
        for ($curpos = tell(FILE); $_ = <FILE>;
             $curpos = tell(FILE)) {
            # search for some stuff and put it into files
        }
        sleep($for_a_while);
        seek(FILE, $curpos, 0);
    }
seekdir DIRHANDLE,POS

DIRHANDLE での readdir ルーチンの現在位置を設定します。 POS は、telldir が返す値でなければなりません。 seekdir は同名のシステムライブラリルーチンと同じく、 ディレクトリ縮小時の問題が考えられます。

select FILEHANDLE
select

その時点で、選択されていたファイルハンドルを返します。 FILEHANDLE を指定した場合には、その値を出力のデフォルトファイルハンドルに 設定します。 これには、2 つの効果があります: まず、ファイルハンドルを指定しないで writeprint を行なった場合のデフォルトが、この FILEHANDLE に なります。 もう一つは、出力関連の変数への参照は、この出力チャネルを 参照するようになります。

例えば、複数の出力チャネルに対して、ページ先頭フォーマットを 設定するには:

    select(REPORT1);
    $^ = 'report1_top';
    select(REPORT2);
    $^ = 'report2_top';

FILEHANDLE は、実際のファイルハンドル名を示す式でもかまいません。 つまり、以下のようなものです:

    $oldfh = select(STDERR); $| = 1; select($oldfh);

ファイルハンドルはメソッドを持ったオブジェクトであると考えることを好む プログラマもいるかもしれません; そのような場合のための最後の例は 以下のようなものです:

    use IO::Handle;
    STDERR->autoflush(1);

移植性の問題: "select" in perlport

select RBITS,WBITS,EBITS,TIMEOUT

これは、select(2) システムコールを、指定したビットマスクで呼び出します; ビットマスクは、filenovec を使って、以下のようにして 作成できます:

    $rin = $win = $ein = '';
    vec($rin, fileno(STDIN),  1) = 1;
    vec($win, fileno(STDOUT), 1) = 1;
    $ein = $rin | $win;

複数のファイルハンドルに select を行ないたいのであれば、 以下のようにします:

    sub fhbits {
        my @fhlist = @_;
        my $bits = "";
        for my $fh (@fhlist) {
            vec($bits, fileno($fh), 1) = 1;
        }
        return $bits;
    }
    $rin = fhbits(*STDIN, *TTY, *MYSOCK);

通常は、

    ($nfound,$timeleft) =
      select($rout=$rin, $wout=$win, $eout=$ein, $timeout);

のように使い、いずれかの準備が整うまでブロックするには、 以下のようにします。

    $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);

ほとんどのシステムではわざわざ意味のある値を $timeleft に返さないので、 select() をスカラコンテキストで呼び出すと、単に $nfound を返します。

どのビットマスクにも undef を設定することができます。 TIMEOUT を指定するときは、秒数で指定し、小数でかまいません。 注: すべての実装で、$timeleft が返せるものではありません。 その場合、$timeleft には、常に指定した TIMEOUT と同じ値が返されます。

250 ミリ秒の sleep と同じ効果が、以下のようにして得られます。

    select(undef, undef, undef, 0.25);

select がシグナル (例えば、SIGALRM) の後に再起動するかどうかは 実装依存であることに注意してください。 select の移植性に関する注意については perlport も参照してください。

エラー時は、select は select(2) のように振舞います: -1 を返し、$! をセットします。

Unix の中には、実際に利用可能なデータがないために引き続く read が ブロックされる場合でも、select(2) が、ソケットファイル記述子が 「読み込み準備中」であると報告するものもあります。 これは、ソケットに対して常に O_NONBLOCK フラグを使うことで回避できます。 さらなる詳細については select(2) と fcntl(2) を参照してください。

標準の IO::Select モジュールは select へのよりユーザーフレンドリーな インターフェースを提供します; 主な理由はビットマスクの仕事を してくれることです。

警告: バッファ付き I/O (read や <FH>) と select を 混ぜて使ってはいけません(例外: POSIX で認められている形で使い、 POSIX システムでだけ動かす場合を除きます)。 代わりに sysread を使わなければなりません。

移植性の問題: "select" in perlport

semctl ID,SEMNUM,CMD,ARG

System V IPC 関数 semctl(2) を呼び出します。 正しい定数定義を得るために、まず

    use IPC::SysV;

と書くことが必要でしょう。 CMD が、IPC_STAT か GETALL のときには、ARG は、返される semid_ds 構造体か、セマフォ値の配列を納める変数でなければなりません。 ioctl と同じように、エラー時には未定義値、 ゼロのときは "0 だが真"、それ以外なら、その値そのものを返します。 ARG はネイティブな short int のベクターから成っていなければなりません; これは pack("s!",(0)x$nsem) で作成できます。 "SysV IPC" in perlipc, IPC::SysV, IPC::Semaphore も参照してください。

移植性の問題: "semctl" in perlport

semget KEY,NSEMS,FLAGS

System V IPC 関数 semget(2) を呼び出します。 セマフォ ID か、エラー時には未定義値を返します。 "SysV IPC" in perlipc, IPC::SysV, IPC::SysV::Semaphore も 参照してください。

移植性の問題: "semget" in perlport

semop KEY,OPSTRING

シグナルを送信や、待ち合わせなどのセマフォ操作を行なうために、 System V IPC 関数 semop(2) を呼び出します。 OPSTRING は、semop 構造体の pack された配列でなければなりません。 semop 構造体は、それぞれ、 pack("s!3", $semnum, $semop, $semflag) のように作ることができます。 セマフォ操作の数は、OPSTRING の長さからわかります。 成功時には真を、エラー時には偽を返します。 以下の例は、セマフォ ID $semid のセマフォ $semnum で 待ち合わせを行ないます。

    $semop = pack("s!3", $semnum, -1, 0);
    die "Semaphore trouble: $!\n" unless semop($semid, $semop);

セマフォにシグナルを送るには、-11 に変更してください。 "SysV IPC" in perlipc, IPC::SysV, IPC::SysV::Semaphore も 参照してください。

移植性の問題: "semop" in perlport

send SOCKET,MSG,FLAGS,TO
send SOCKET,MSG,FLAGS

ソケットにメッセージを送ります。 スカラ MSG を ファイルハンドル SOCKET に送ろうとします。 同名のシステムコールと同じフラグが指定できます。 接続していないソケットには、send to に接続先を指定しなければならず、 この場合、sendto(2) を実行します。 送信した文字数か、エラー時には、未定義値を返します。 システムコール sendmsg(2) は現在実装されていません。 例については "UDP: Message Passing" in perlipc を参照してください。

文字 に関する注意: ソケットの状態によって、(8 ビットの) バイトか 文字を送信します。 デフォルトでは全てのソケットはバイトを処理しますが、 例えばソケットが binmode() で :encoding(utf8) I/O 層("open"open プラグマ、open を参照してください) を使うように指定された場合、 I/O はバイトではなく、UTF-8 エンコードされた Unicode 文字を操作します。 :encoding プラグマも同様です: この場合、ほとんど大体全ての文字が書き込めます。

setpgrp PID,PGRP

指定した PID (0 を指定するとカレントプロセス) に 対するプロセスグループを設定します。 POSIX setpgrp(2) または BSD setpgrp(2) が実装されていないマシンでは、 例外が発生します。 引数が省略された場合は、0,0が使われます。 BSD 4.2 版の setpgrp は引数を取ることができないので、 setpgrp(0,0) のみが移植性があることに注意してください。 POSIX::setsid() も参照してください。

移植性の問題: "setpgrp" in perlport

setpriority WHICH,WHO,PRIORITY

プロセス、プロセスグループ、ユーザに対する優先順位を設定します。 (setpriority(2) を参照してください。) setpriority(2) が実装されていないマシンでは、 例外が発生します。

移植性の問題: "setpriority" in perlport

setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL

要求したソケットオプションを設定します。 エラー時には、undef を返します。 LEVEL と OPNAME には Socket モジュールが提供する整数定数を使います。 LEVEL の値は getprotobyname から得ることもできます。 OPTVAL は pack された文字列か整数です。 整数の OPTVAL は pack("i", OPTVAL) の省略表現です。

ソケットに対する Nagle のアルゴリズムを無効にする例です:

    use Socket qw(IPPROTO_TCP TCP_NODELAY);
    setsockopt($socket, IPPROTO_TCP, TCP_NODELAY, 1);

移植性の問題: "setsockopt" in perlport

shift ARRAY
shift EXPR
shift

配列の最初の値を取り出して、その値を返し、配列を一つ 短くして、すべての要素を前へずらします。 配列に要素がなければ、未定義値を返します。 ARRAY を省略すると、 サブルーチンやフォーマットのレキシカルスコープでは @_ を、 サブルーチンの外側で、eval STRING, BEGIN {}, INIT {}, CHECK {}, UNITCHECK {}, END {} で作成されたレキシカルスコープでは @ARGV が用いられます。

Perl 5.14 から、shift はスカラの EXPR を取ることができるようになりました; これは bless されていない配列へのリファレンスでなければなりません。 引数は自動的にデリファレンスされます。 shift のこの動作は高度に実験的であると考えられています。 正確な振る舞いは将来のバージョンの Perl で変わるかも知れません。

あなたのコードを以前のバージョンの Perl で実行したユーザーが不思議な 文法エラーで混乱することを避けるために、コードが最近のバージョンの Perl で のみ 動作することを示すためにファイルの先頭に以下のようなことを 書いてください:

    use 5.014;  # so push/pop/etc work on scalars (experimental)

unshiftpushpop も参照してください。 shiftunshift は、poppush が配列の右端で行なうことを、左端で行ないます。

shmctl ID,CMD,ARG

System V IPC 関数 shmctl を呼び出します。 正しい定数定義を得るために、まず

    use IPC::SysV;

と書くことが必要でしょう。 CMD が、IPC_STAT ならば、ARG は、返される shmid_ds 構造体を 納める変数でなければなりません。 ioctl と同様です: エラー時には undef; ゼロのときは "0 だが真"; それ以外なら、その値そのものを返します。 "SysV IPC" in perlipcIPC::SysV も参照してください。

移植性の問題: "shmctl" in perlport

shmget KEY,SIZE,FLAGS

System V IPC 関数 shmget を呼び出します。 共有メモリのセグメント ID か、エラー時には undef を返します。 "SysV IPC" in perlipcIPC::SysV も参照してください。

移植性の問題: "shmget" in perlport

shmread ID,VAR,POS,SIZE
shmwrite ID,STRING,POS,SIZE

System V 共有メモリセグメント ID に対し、アタッチして、 コピーを行ない、デタッチするという形で、位置 POS から、 サイズ SIZE だけ、読み込みか書き込みを行ないます。 読み込み時には、VAR は読み込んだデータを納める 変数でなければなりません。 書き込み時には、STRING が長すぎても、SIZE バイトだけが使われます; STRING が 短すぎる場合には、SIZE バイトを埋めるために、ヌル文字が書き込まれます。 成功時には真を、エラー時には偽を返します。 shmread() は変数を汚染します。 "SysV IPC" in perlipc および IPC::SysV と、 CPAN の IPC::Shareable も参照してください。

移植性の問題: "shmread" in perlport"shmwrite" in perlport

shutdown SOCKET,HOW

同名のシステムコールと同じように解釈される HOW によって、 指定された方法でソケット接続のシャットダウンを行ないます。

    shutdown(SOCKET, 0);    # I/we have stopped reading data
    shutdown(SOCKET, 1);    # I/we have stopped writing data
    shutdown(SOCKET, 2);    # I/we have stopped using this socket

これは、こちらがソケットを書き終わったが読み終わっていない、 またはその逆を相手側に伝えたいときに便利です。 これはその他のプロセスでフォークしたファイル記述子のコピーも 無効にするので、よりしつこい閉じ方です。

成功時には 1 を返します; エラーの場合、最初の引数が有効なファイルハンドルでない場合は undef を 返し、その他のエラーの場合は 0 を返して$! をセットします。

sin EXPR
sin

(ラジアンで示した) EXPR の正弦を返します。 EXPR が省略されたときには、$_ の正弦を返します。

逆正弦を求めるためには、Math::Trig::asin 関数を使うか、 以下の関係を使ってください:

    sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
sleep EXPR
sleep

スクリプトを(整数の) EXPR で指定した秒数 (省略時には、永久に) スリープさせます。 実際にスリープした秒数を返します。

そのプロセスが SIGALRMのようなシグナルを受信すると、 割り込みがかかります。

    eval {
        local $SIG{ALARM} = sub { die "Alarm!\n" };
        sleep;
    };
    die $@ unless $@ eq "Alarm!\n";

sleep は、alarm を使って実装されることが多いので、alarmsleep は、混ぜて使用することはおそらくできません。

古いシステムでは、どのように秒を数えるかによって、要求した秒数に完全に 満たないうちに、スリープから抜ける場合があります。 最近のシステムでは、常に完全にスリープします。 しかし、負荷の高いマルチタスクシステムでは 正しくスケジューリングされないがために より長い時間スリープすることがあります。

1 秒より精度の高いスリープを行なうには、 Time::HiRes モジュール(CPAN から、また Perl 5.8 からは 標準配布されています) が usleep() を提供します。 Perl の 4 引数版 select() を最初の 3 引数を未定義にして使うか、 setitimer(2) をサポートしているシステムでは、Perl の syscall インタフェースを使ってアクセスすることもできます。 詳しくは perlfaq8 を参照してください。

POSIX モジュールの pause 関数も参照してください。

socket SOCKET,DOMAIN,TYPE,PROTOCOL

指定した種類のソケットをオープンし、ファイルハンドル SOCKET にアタッチします。 DOMAIN, TYPE, PROTOCOL は、同名のシステムコールと同じように指定します。 適切な定義を import するために、まず、use Socket と するとよいでしょう。 "Sockets: Client/Server Communication" in perlipc の例を参照してください。

ファイルに対する close-on-exec フラグをサポートしているシステムでは、 フラグは $^F の値で決定される、新しくオープンされたファイル記述子に対して セットされます。 "$^F" in perlvar を参照してください。

socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL

指定した DOMAIN に、指定した TYPE で名前の無いソケットのペアを生成します。 DOMAIN, TYPE, PROTOCOL は、同名のシステムコールと同じように指定します。 実装されていない場合には、例外が発生します。 成功時には真を返します。

ファイルに対する close-on-exec フラグをサポートしているシステムでは、 フラグは $^F の値で決定される、新しくオープンされたファイル記述子に対して セットされます。 "$^F" in perlvar を参照してください。

pipesocketpair を使って定義しているシステムもあります; pipe(Rdr, Wtr) は本質的には以下のようになります:

    use Socket;
    socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
    shutdown(Rdr, 1);        # no more writing for reader
    shutdown(Wtr, 0);        # no more reading for writer

socketpair の使用例については perlipc を参照してください。 Perl 5.8 以降では、システムがソケットを実装しているが socketpair を 実装していない場合、localhost に対して IP ソケットを使うことで socketpair をエミュレートします。

移植性の問題: "socketpair" in perlport

sort SUBNAME LIST
sort BLOCK LIST
sort LIST

リストコンテキストでは、LIST をソートし、ソートされたリスト値を返します。 スカラコンテキストでは、sort() の振る舞いは未定義です。

SUBNAME や BLOCK を省略すると、標準の文字列比較の順番でソートが 行なわれます。 SUBNAME を指定すると、それは、リストの要素をどのような順番に並べるかに 応じて、負、ゼロ、正の整数を返すサブルーチンの名前であると解釈されます。 (このようなルーチンには、<=> 演算子や cmp 演算子が、 たいへん便利です。) SUBNAME は、スカラ変数名(添字なし)でもよく、 その場合には、その値が使用する実際のサブルーチンの 名前(またはそのリファレンス)と解釈されます。 SUBNAME の代わりに、無名のインライン ソートルーチンとして、BLOCK を書くことができます。

サブルーチンのプロトタイプが ($$)の場合、比較する要素は通常の サブルーチンと同じように @_ の中にリファレンスとして渡されます。 これはプロトタイプなしのサブルーチンより遅いです; この場合は比較のため サブルーチンに渡される二つの要素は、パッケージのグローバル変数 $a と $b で 渡されます(次の例を参照してください)。 後者の場合、レキシカルに $a と $b を宣言するのは普通とても逆効果になります。

サブルーチンが XSUB の場合、比較される要素は、普通に引数を XSUB に渡す形で、 スタックにプッシュされます。 $a と $b は設定されません。

$a や $b はリファレンスによって渡されるので、変更するべきではありません。

また、ソートブロックやサブルーチンから perlsyn で説明されている ループ制御子や goto を使って抜けてはいけません。

use locale が有効(そして use locale 'not_characters' が有効でない)の 場合、sort LIST は LIST を現在の比較ロケールに従ってソートします。 perllocale を参照してください。

sort() は元のリストへのエイリアスを返します; for ループのインデックス変数が リスト要素へのエイリアスと同様です。 つまり、sort() で返されるリストの要素を(例えば、foreachmapgrep で)変更すると、実際に元のリストの要素が変更されます。 これはきれいなコードを書くときには普通は回避されます。

Perl 5.6 以前ではソートの実装にクイックソートアルゴリズムを使っていました。 このアルゴリズムは安定していないので、2 乗の時間が掛かる 可能性があります。 (安定した ソートは、比較した時に同じ要素の入力順が保存されます。 クイックソートの実行時間は、長さ N の全ての配列の平均では O(NlogN) ですが、入力によっては O(N**2) という 2 乗の 振る舞いを することがあります。) 5.7 では、クイックソートによる実装は、最悪の場合の振る舞いも O(NlogN) である、安定したマージソートアルゴリズムに置き換えられました。 しかし、入力とプラットフォームによっては、ベンチマークはクイックソートの 方が速くなります。 5.8 ではソートを限定的に制御できる sort プラグマがあります。 この、アルゴリズムの直接的な制御方法は将来の perl では引き継がれないかも しれませんが、実装に依存しない形で入力や出力を性格付ける機能は おそらくあります。 the sort pragma を参照してください。

例:

    # sort lexically
    @articles = sort @files;

    # same thing, but with explicit sort routine
    @articles = sort {$a cmp $b} @files;

    # now case-insensitively
    @articles = sort {fc($a) cmp fc($b)} @files;

    # same thing in reversed order
    @articles = sort {$b cmp $a} @files;

    # sort numerically ascending
    @articles = sort {$a <=> $b} @files;

    # sort numerically descending
    @articles = sort {$b <=> $a} @files;

    # this sorts the %age hash by value instead of key
    # using an in-line function
    @eldest = sort { $age{$b} <=> $age{$a} } keys %age;

    # sort using explicit subroutine name
    sub byage {
        $age{$a} <=> $age{$b};  # presuming numeric
    }
    @sortedclass = sort byage @class;

    sub backwards { $b cmp $a }
    @harry  = qw(dog cat x Cain Abel);
    @george = qw(gone chased yz Punished Axed);
    print sort @harry;
        # prints AbelCaincatdogx
    print sort backwards @harry;
        # prints xdogcatCainAbel
    print sort @george, 'to', @harry;
        # prints AbelAxedCainPunishedcatchaseddoggonetoxyz

    # inefficiently sort by descending numeric compare using
    # the first integer after the first = sign, or the
    # whole record case-insensitively otherwise

    my @new = sort {
        ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
                            ||
                    fc($a)  cmp  fc($b)
    } @old;

    # same thing, but much more efficiently;
    # we'll build auxiliary indices instead
    # for speed
    my @nums = @caps = ();
    for (@old) {
        push @nums, ( /=(\d+)/ ? $1 : undef );
        push @caps, fc($_);
    }

    my @new = @old[ sort {
                           $nums[$b] <=> $nums[$a]
                                    ||
                           $caps[$a] cmp $caps[$b]
                         } 0..$#old
                  ];

    # same thing, but without any temps
    @new = map { $_->[0] }
           sort { $b->[1] <=> $a->[1]
                           ||
                  $a->[2] cmp $b->[2]
           } map { [$_, /=(\d+)/, fc($_)] } @old;

    # using a prototype allows you to use any comparison subroutine
    # as a sort subroutine (including other package's subroutines)
    package other;
    sub backwards ($$) { $_[1] cmp $_[0]; }  # $a and $b are
                                             # not set here    
    package main;
    @new = sort other::backwards @old;

    # guarantee stability, regardless of algorithm
    use sort 'stable';
    @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;

    # force use of mergesort (not portable outside Perl 5.8)
    use sort '_mergesort';  # note discouraging _
    @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;

警告: 関数からかえされたリストをソートするときには文法上の注意が必要です。 関数呼び出し find_records(@key) から返されたリストをソートしたい場合、 以下のように出来ます:

    @contact = sort { $a cmp $b } find_records @key;
    @contact = sort +find_records(@key);
    @contact = sort &find_records(@key);
    @contact = sort(find_records(@key));

一方、配列 @key を比較ルーチン find_records() でソートしたい場合は、 以下のように出来ます:

    @contact = sort { find_records() } @key;
    @contact = sort find_records(@key);
    @contact = sort(find_records @key);
    @contact = sort(find_records (@key));

use strict している場合、$a と $b をレキシカルとして 宣言しては いけません。 これはパッケージグローバルです。 つまり、main パッケージで以下のように書いた場合:

    @articles = sort {$b <=> $a} @files;

$a$b$main::a$main::b (または $::a$::b) を 意味しますが、FooPack パッケージ内の場合、これは以下と同じになります:

    @articles = sort {$FooPack::b <=> $FooPack::a} @files;

比較関数は一貫した振る舞いをすることが求められます。 一貫しない結果を返す(例えば、あるときは $x[1]$x[2] より 小さいと返し、またあるときは逆を返す)場合、結果は未定義です。

<=> はどちらかのオペランドが NaN (not-a-number) のときに undef を返すので、 $a <=> $b といった比較関数でソートする場合はリストに NaN が 含まれないように注意してください。 以下の例は 入力リストから NaN を取り除くために NaN != NaN という性質を 利用しています。

    @result = sort { $a <=> $b } grep { $_ == $_ } @input;
splice ARRAY or EXPR,OFFSET,LENGTH,LIST
splice ARRAY or EXPR,OFFSET,LENGTH
splice ARRAY or EXPR,OFFSET
splice ARRAY or EXPR

ARRAY から OFFSET、LENGTH で指定される要素を取り除き、 LIST があれば、それを代わりに挿入します。 リストコンテキストでは、配列から取り除かれた要素を返します。 スカラコンテキストでは、取り除かれた最後の要素を返します; 要素が 取り除かれなかった場合は undef を返します。 配列は、必要に応じて、大きくなったり、小さくなったりします。 OFFSET が負の数の場合は、配列の最後からの距離を示します。 LENGTH が省略されると、OFFSET 以降のすべての要素を取り除きます。 LENGTH が負の数の場合は、OFFSET から前方へ、配列の最後から -LENGTH 要素を 除いて取り除きます。 OFFSET と LENGTH の両方が省略されると、全ての要素を取り除きます。 OFFSET が配列の最後より後ろの場合、Perl は警告を出し、配列の最後に対して 処理します。

以下は、($#a >= $i と仮定すると) それぞれ、等価です。

    push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
    pop(@a)             splice(@a,-1)
    shift(@a)           splice(@a,0,1)
    unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
    $a[$i] = $y         splice(@a,$i,1,$y)

次の例では、配列の前に、それぞれの配列の大きさが渡されるものとしています:

    sub aeq {  # compare two list values
        my(@a) = splice(@_,0,shift);
        my(@b) = splice(@_,0,shift);
        return 0 unless @a == @b;  # same len?
        while (@a) {
            return 0 if pop(@a) ne pop(@b);
        }
        return 1;
    }
    if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }

Perl 5.14 から、splice はスカラの EXPR を取ることができるようになりました; これは bless されていない配列へのリファレンスでなければなりません。 引数は自動的にデリファレンスされます。 splice のこの動作は高度に実験的であると考えられています。 正確な振る舞いは将来のバージョンの Perl で変わるかも知れません。

あなたのコードを以前のバージョンの Perl で実行したユーザーが不思議な 文法エラーで混乱することを避けるために、コードが最近のバージョンの Perl で のみ 動作することを示すためにファイルの先頭に以下のようなことを 書いてください:

    use 5.014;  # so push/pop/etc work on scalars (experimental)
split /PATTERN/,EXPR,LIMIT
split /PATTERN/,EXPR
split /PATTERN/
split

文字列 EXPR を文字列のリストに分割して、リストコンテキストではそのリストを 返し、スカラコンテキストではリストの大きさを返します。

PATTERN のみが与えられた場合、EXPR のデフォルトは $_ です。

EXPR の中で PATTERN にマッチングするものは何でも EXPR を("fields" と 呼ばれる)セパレータを 含まない 部分文字列に分割するための セパレータとなります。 セパレータは一文字より長くてもよく、全く文字がなくてもよい(空文字列は ゼロ幅マッチングです)ということに注意してください。

PATTERN は定数である必要はありません; 実行時に変更されるパターンを 指定するために式を使えます。

PATTERN が空文字列にマッチングする場合、EXPR はマッチング位置 (文字の間)で分割されます。 例えば、以下のものは:

    print join(':', split('b', 'abc')), "\n";

'abc' の 'b' をセパレータとして使って出力 'a:c' を生成します。 しかし、これは:

    print join(':', split('', 'abc')), "\n";

空文字列マッチングをセパレータとして使って出力 'a:b:c' を生成します; 従って、 空文字列は EXPR を構成する文字のリストに分割するために使われます。

split の特殊な場合として、 マッチング演算子 文法で与えられた 空パターン (//) は特に空文字列にマッチングし、最後に成功した マッチングという普通の解釈と異なります。

PATTERN が /^/ の場合、複数行修飾子 (/^/m) が使われたかのように扱われます; そうでなければほとんど 使えないからです。

もう一つの特別な場合として、split は PATTERN が省略されるか 単一のスペース文字からなる リテラル文字列 (つまり例えば / / ではなく ' '"\x20") の場合、コマンドラインツール awk のデフォルトの振る舞いをエミュレートします。 この場合、EXPR の先頭の空白は分割を行う前に削除され、PATTERN は /\s+/ であったかのように扱われます; 特に、これは (単に単一の スペース文字ではなく) あらゆる 連続した空白がセパレータとして 使われるということです。 しかし、この特別の扱いは文字列 " " の代わりにパターン / / を 指定することで回避でき、それによってセパレータとして単一の スペース文字のみが使われます。 以前の Perl ではこの特別な場合は split のパターン引数として単に " " を 使った場合に制限されていましたが、Perl 5.18.0 以降では、この特別な場合は 単純な文字列 " " に評価される任意の式によって引き起こされます。

省略されると、PATTERN のデフォルトは単一のスペース " " になり、 先に記述した awk エミュレーションを起動します。

LIMIT が指定された正数の場合、EXPR が分割されるフィールドの最大数を 表現します; 言い換えると、 LIMIT は EXPR が分割される数より一つ大きい 数です。 従って、LIMIT の値 1 は EXPR が最大 0 回分割されるということで、 最大で一つのフィールドを生成します (言い換えると、EXPR 全体の値です)。 例えば:

    print join(':', split(//, 'abc', 1)), "\n";

これは 'abc' を出力し、次のものは:

    print join(':', split(//, 'abc', 2)), "\n";

'a:bc' を出力し、以下のものそれぞれは:

    print join(':', split(//, 'abc', 3)), "\n";
    print join(':', split(//, 'abc', 4)), "\n";

'a:b:c' を出力します。

LIMIT が負数なら、非常に大きい数であるかのように扱われます; できるだけ多くの フィールドが生成されます。

LIMIT が省略されると(あるいは等価な 0 なら)、普通は負数が指定されたかのように 動作しますが、末尾の空フィールドは取り除かれるという例外があります (先頭の空フィールドは常に保存されます); もし全てのフィールドが空なら、 全てのフィールドが末尾として扱われます(そしてこの場合取り除かれます)。 従って、以下のようにすると:

    print join(':', split(',', 'a,b,c,,,')), "\n";

出力 'a:b:c' を生成しますが、以下のようにすると:

    print join(':', split(',', 'a,b,c,,,', -1)), "\n";

出力 'a:b:c:::' を生成します。

時間に厳しいアプリケーションでは、必要でないフィールドの分割を避けるのは 価値があります。 従って、リストに代入される場合に、LIMIT が省略される(または 0)と、 LIMIT は リストにある変数の数より一つ大きい数のように扱われます; 次の場合、LIMIT は暗黙に 3 になります:

    ($login, $passwd) = split(/:/);

LIMIT の指定に関わらず、空文字列に評価される EXPR を分割すると常に 0 個の フィールドを生成することに注意してください。

EXPR の先頭で正数幅でマッチングしたときには先頭に空のフィールドが 生成されます。 例えば:

    print join(':', split(/ /, ' abc')), "\n";

これは出力 ':abc' を生成します。 しかし、EXPR の先頭でのゼロ幅マッチングは決して空フィールドを生成しないので:

    print join(':', split(//, ' abc'));

これは(': :a:b:c' ではなく)出力 ' :a:b:c' を生成します。

一方、末尾の空のフィールドは、マッチングの長さに関わらず、EXPR の末尾で マッチングしたときに生成されます(もちろん非 0 の LIMIT が明示的に 指定されていない場合です; このようなフィールドは前の例のように 取り除かれます)。 従って:

    print join(':', split(//, ' abc', -1)), "\n";

これは出力 ' :a:b:c:' を生成します。

PATTERN が 捕捉グループ を 含んでいる場合、それぞれのセパレータについて、 (後方参照 のようにグループが指定された) グループによって捕捉されたそれぞれの部分文字列について追加のフィールドが 生成されます; どのグループもマッチングしなかった場合、部分文字列の代わりに undef 値を捕捉します。 また、このような追加のフィールドはセパレータがあるとき(つまり、分割が 行われるとき)はいつでも生成され、このような追加のフィールドは LIMIT に関してはカウント されない ことに注意してください。 リストコンテキストで評価される以下のような式を考えます (それぞれの返されるリストは関連づけられたコメントで提供されます):

    split(/-|,/, "1-10,20", 3)
    # ('1', '10', '20')

    split(/(-|,)/, "1-10,20", 3)
    # ('1', '-', '10', ',', '20')

    split(/-|(,)/, "1-10,20", 3)
    # ('1', undef, '10', ',', '20')

    split(/(-)|,/, "1-10,20", 3)
    # ('1', '-', '10', undef, '20')

    split(/(-)|(,)/, "1-10,20", 3)
    # ('1', '-', undef, '10', undef, ',', '20')
sprintf FORMAT, LIST

普通の C 言語の printf 記法のフォーマットで、整形された文字列を返します。 一般的な原則の説明については以下の説明と、システムの sprintf(3) または printf(3) の説明を参照してください。

例えば:

        # Format number with up to 8 leading zeroes
        $result = sprintf("%08d", $number);

        # Round number to 3 digits after decimal point
        $rounded = sprintf("%.3f", $number);

Perl は sprintf フォーマット処理を自力で行います: これは C の sprintf(3) 関数をエミュレートしますが、 C の関数は使いません(浮動小数点を除きますが、それでも標準の 記述子のみが利用できます)。 従って、ローカルな非標準の sprintf 拡張機能は Perl では使えません。

printf と違って、 sprintf の最初の引数に配列を渡しても あなたが多分望むとおりには動作しません。 配列はスカラコンテキストで渡されるので、配列の 0 番目の要素ではなく、 配列の要素数をフォーマットとして扱います; これはほとんど役に立ちません。

Perl の sprintf は以下の一般に知られている変換に対応しています:

   %%    パーセントマーク
   %c    与えられた番号の文字
   %s    文字列
   %d    符号付き 10 進数
   %u    符号なし 10 進数
   %o    符号なし 8 進数
   %x    符号なし 16 進数
   %e    科学的表記の浮動小数点数
   %f    固定 10 進数表記の浮動小数点数
   %g    %e か %f の表記の浮動小数点数

さらに、Perl では以下のよく使われている変換に対応しています:

   %X    %x と同様だが大文字を使う
   %E    %e と同様だが大文字の "E" を使う
   %G    %g と同様だが(適切なら)大文字の "E" を使う
   %b    符号なし 2 進数
   %B    %b と同様だが、# フラグで大文字の "B" を使う
   %p    ポインタ (Perl の値のアドレスを 16 進数で出力する)
   %n    特殊: 出力文字数を引数リストの次の変数に「格納」する

最後に、過去との互換性(これは「過去」だと考えています)のために、 Perl は以下の不要ではあるけれども広く使われている変換に対応しています。

   %i    %d の同義語
   %D    %ld の同義語
   %U    %lu の同義語
   %O    %lo の同義語
   %F    %f の同義語

%e, %E, %g, %G において、指数部が 100 未満の場合の 指数部の科学的な表記法はシステム依存であることに注意してください: 3 桁かもしれませんし、それ以下かもしれません(必要に応じて 0 で パッディングされます)。 言い換えると、 1.23 掛ける 10 の 99 乗は "1.23e99" かもしれませんし "1.23e099" かもしれません。

% とフォーマット文字の間に、フォーマットの解釈を制御するための、 いくつかの追加の属性を指定できます。 順番に、以下のものがあります:

フォーマットパラメータインデックス

2$ のような明示的なフォーマットパラメータインデックス。 デフォルトでは sprintf はリストの次の使われていない引数を フォーマットしますが、これによって異なった順番の引数を使えるようにします:

  printf '%2$d %1$d', 12, 34;      # prints "34 12"
  printf '%3$d %d %1$d', 1, 2, 3;  # prints "3 1 1"
フラグ

以下のうちの一つまたは複数指定できます:

   space   非負数の前に空白をつける
   +       非負数の前にプラス記号をつける
   -       フィールド内で左詰めする
   0       右詰めに空白ではなくゼロを使う
   #       8 進数では確実に先頭に "0" をつける;
           非 0 の 16 進数では "0x" か "0X" をつける;
           非 0 の 2 進数では "0b" か "0B" をつける

例えば:

  printf '<% d>',  12;   # prints "< 12>"
  printf '<%+d>',  12;   # prints "<+12>"
  printf '<%6s>',  12;   # prints "<    12>"
  printf '<%-6s>', 12;   # prints "<12    >"
  printf '<%06s>', 12;   # prints "<000012>"
  printf '<%#o>',  12;   # prints "<014>"
  printf '<%#x>',  12;   # prints "<0xc>"
  printf '<%#X>',  12;   # prints "<0XC>"
  printf '<%#b>',  12;   # prints "<0b1100>"
  printf '<%#B>',  12;   # prints "<0B1100>"

空白とプラス記号がフラグとして同時に与えられると、プラス記号は正の数に 前置するために使われます。

  printf '<%+ d>', 12;   # prints "<+12>"
  printf '<% +d>', 12;   # prints "<+12>"

%o 変換に # フラグと精度が与えられると、先頭の "0" が必要な場合は 精度に 1 が加えられます。

  printf '<%#.5o>', 012;      # prints "<00012>"
  printf '<%#.5o>', 012345;   # prints "<012345>"
  printf '<%#.0o>', 0;        # prints "<0>"
ベクタフラグ

このフラグは Perl に、与えられた文字列を、文字毎に一つの整数のベクタとして 解釈させます。 Perl は各数値をフォーマットし、それから結果の文字列をセパレータ (デフォルトでは .)で連結します。 これは任意の文字列の文字を順序付きの値として表示するのに便利です:

  printf "%vd", "AB\x{100}";           # prints "65.66.256"
  printf "version is v%vd\n", $^V;     # Perl's version

アスタリスク *v の前に置くと、数値を分けるために使われる文字列を 上書きします:

  printf "address is %*vX\n", ":", $addr;   # IPv6 address
  printf "bits are %0*v8b\n", " ", $bits;   # random bitstring

また、*2$v のように、連結する文字列として使う引数の番号を明示的に 指定できます; 例えば:

  printf '%*4$vX %*4$vX %*4$vX',       # 3 IPv6 addresses
          @addr[1..3], ":";
(最小)幅

引数は、普通は値を表示するのに必要なちょうどの幅でフォーマットされます。 ここに数値を置くか、(* で)次の引数か(*2$ で)明示的に指定した引数で 幅を上書きできます。

 printf "<%s>", "a";       # prints "<a>"
 printf "<%6s>", "a";      # prints "<     a>"
 printf "<%*s>", 6, "a";   # prints "<     a>"
 printf '<%*2$s>', "a", 6; # prints "<     a>"
 printf "<%2s>", "long";   # prints "<long>" (does not truncate)

* を通して得られたフィールドの値が負数の場合、- フラグと 同様の効果 (左詰め) があります。

精度あるいは最大幅

. の後に数値を指定することで、(数値変換の場合)精度や(文字列変換の場合) 最大幅を指定できます。 小数点数フォーマットの場合、gG を除いて、表示する小数点以下の 桁数を指定します(デフォルトは 6 です)。 例えば:

  # these examples are subject to system-specific variation
  printf '<%f>', 1;    # prints "<1.000000>"
  printf '<%.1f>', 1;  # prints "<1.0>"
  printf '<%.0f>', 1;  # prints "<1>"
  printf '<%e>', 10;   # prints "<1.000000e+01>"
  printf '<%.1e>', 10; # prints "<1.0e+01>"

"g" と "G" の場合、これは表示する数値の数を指定します; これには小数点の前の数値と後の数値を含みます; 例えば:

  # These examples are subject to system-specific variation.
  printf '<%g>', 1;        # prints "<1>"
  printf '<%.10g>', 1;     # prints "<1>"
  printf '<%g>', 100;      # prints "<100>"
  printf '<%.1g>', 100;    # prints "<1e+02>"
  printf '<%.2g>', 100.01; # prints "<1e+02>"
  printf '<%.5g>', 100.01; # prints "<100.01>"
  printf '<%.4g>', 100.01; # prints "<100>"

整数変換の場合、精度を指定すると、数値自体の出力はこの幅に 0 で パッディングするべきであることを暗に示すことになり、0 フラグは 無視されます:

  printf '<%.6d>', 1;      # prints "<000001>"
  printf '<%+.6d>', 1;     # prints "<+000001>"
  printf '<%-10.6d>', 1;   # prints "<000001    >"
  printf '<%10.6d>', 1;    # prints "<    000001>"
  printf '<%010.6d>', 1;   # prints "<    000001>"
  printf '<%+10.6d>', 1;   # prints "<   +000001>"

  printf '<%.6x>', 1;      # prints "<000001>"
  printf '<%#.6x>', 1;     # prints "<0x000001>"
  printf '<%-10.6x>', 1;   # prints "<000001    >"
  printf '<%10.6x>', 1;    # prints "<    000001>"
  printf '<%010.6x>', 1;   # prints "<    000001>"
  printf '<%#10.6x>', 1;   # prints "<  0x000001>"

文字列変換の場合、精度を指定すると、指定された幅に収まるように文字列を 切り詰めます:

  printf '<%.5s>', "truncated";   # prints "<trunc>"
  printf '<%10.5s>', "truncated"; # prints "<     trunc>"

.* を使って精度を次の引数から取ることも出来ます:

  printf '<%.6x>', 1;       # prints "<000001>"
  printf '<%.*x>', 6, 1;    # prints "<000001>"

* によって得られた精度が負数の場合、精度が指定されなかった場合と 同じ効果となります。

  printf '<%.*s>',  7, "string";   # prints "<string>"
  printf '<%.*s>',  3, "string";   # prints "<str>"
  printf '<%.*s>',  0, "string";   # prints "<>"
  printf '<%.*s>', -1, "string";   # prints "<string>"

  printf '<%.*d>',  1, 0;   # prints "<0>"
  printf '<%.*d>',  0, 0;   # prints "<>"
  printf '<%.*d>', -1, 0;   # prints "<0>"

現在のところ精度を指定した数値から得ることはできませんが、 将来は 例えば .*2$ のようにして可能にしようとしています:

  printf '<%.*2$x>', 1, 6;   # INVALID, but in future will print
                             # "<000001>"
サイズ

数値変換では、l, h, V, q, L, ll を使って解釈する数値の 大きさを指定できます。 整数変換 (d u o x X b i D U O) では、数値は通常プラットフォームの デフォルトの整数のサイズ (通常は 32 ビットか 64 ビット) を仮定しますが、 これを Perl がビルドされたコンパイラが対応している標準 C の型の一つで 上書きできます:

   hh          Perl 5.14 以降で整数を C の "char" または "unsigned char"
               型として解釈する
   h           整数を C の "char" または "unsigned char" 型として解釈する
   j           Perl 5.14 以降 C99 コンパイラのみで整数を C の "intmax_t"
               型として解釈する (移植性なし)
   l           整数を C の "long" または "unsigned long" と解釈する
   h           整数を C の "short" または "unsigned short" と解釈する
   q, L or ll  整数を C の "long long", "unsigned long long",
               "quads"(典型的には 64 ビット整数) のどれかと解釈する
   t           Perl 5.14 以降で整数を C の "ptrdiff_t" 型として解釈する
   z           Perl 5.14 以降で整数を C の "size_t" 型として解釈する

5.14 から、プラットフォームがこれらに対応していないときでも例外が 発生しなくなりました。 しかし、もし警告が有効になっているなら、 非対応変換フラグに関して printf 警告クラスの警告が発生します。 例外の方がお好みなら、以下のようにします:

    use warnings FATAL => "printf";

プログラムの実行開始前にバージョン依存について知りたいなら、先頭に 以下のようなものを書きます:

    use 5.014;  # for hh/j/t/z/ printf modifiers

Perl が 64 ビット整数に対応しているかどうかは Config を使って 調べられます:

    use Config;
    if ($Config{use64bitint} eq "define"
        || $Config{longsize} >= 8) {
        print "Nice quads!\n";
    }

浮動小数点数変換 (e f g E F G) では、普通はプラットフォームのデフォルトの 不動小数点数のサイズ (double か long double) を仮定します。 Perl が long double に対応しているかどうかは Config を使って 調べられます:

    use Config;
    print "long doubles\n" if $Config{d_longdbl} eq "define";

Perl が "long double" をデフォルトの浮動小数点数として扱っているかどうかは Config を使って調べられます:

    use Config;
    if ($Config{uselongdouble} eq "define") {
        print "long doubles by default\n";
    }

long double と double が同じ場合もあります:

        use Config;
        ($Config{doublesize} == $Config{longdblsize}) &&
                print "doubles are long doubles\n";

サイズ指定子 V は Perl のコードには何の影響もありませんが、これは XS コードとの互換性のために対応しています。 これは「Perl 整数 (または浮動小数点数) として標準的なサイズを使う」ことを 意味し、これはデフォルトです。

引数の順序

通常、sprintf() は各フォーマット指定について、使われていない次の引数を フォーマットする値として使います。 追加の引数を要求するためにフォーマット指定 * を使うと、 これらはフォーマットする値の のフォーマット指定に現れる順番に 引数リストから消費されます。 引数の位置が明示的なインデックスを使って指定された場合、 (明示的に指定したインデックスが次の引数の場合でも) これは通常の引数の順番に影響を与えません。

それで:

    printf "<%*.*s>", $a, $b, $c;

とすると $a を幅に、$b を精度に、$c をフォーマットの値に 使います; 一方:

  printf '<%*1$.*s>', $a, $b;

とすると $a を幅と精度に、$b をフォーマットの値に使います。

以下にさらなる例を示します; 明示的にインデックスを使う場合、$ は エスケープする必要があることに注意してください:

  printf "%2\$d %d\n",    12, 34;      # will print "34 12\n"
  printf "%2\$d %d %d\n", 12, 34;      # will print "34 12 34\n"
  printf "%3\$d %d %d\n", 12, 34, 56;  # will print "56 12 34\n"
  printf "%2\$*3\$d %d\n", 12, 34, 3;  # will print " 34 12\n"

(use locale 'not_characters' を含む)use locale が有効で、 POSIX::setlocale() が呼び出されている場合、フォーマットされた浮動小数点数の 小数点として使われる文字は LC_NUMERIC ロケールの影響を受けます。 perllocalePOSIX を参照してください。

sqrt EXPR
sqrt

EXPR の正の平方根を返します。 EXPR が省略されると、$_ を使います。 Math::Complex モジュールを使わない場合は、負の数の引数は扱えません。

    use Math::Complex;
    print sqrt(-4);    # prints 2i
srand EXPR
srand

rand 演算子のためのシード値を設定して返します。

この関数のポイントは、プログラムを実行するごとに rand 関数が 異なる乱数列を生成できるように rand 関数の「種」を設定することです。 srand を引数付きで呼び出すと、これを種として使います; さもなければ (だいたい)ランダムに種を選びます。 どちらの場合でも、Perl 5.14 からは種を返します。 特定の時期の Perl でのみ 動作することを知らせるには以下のようにします:

    use 5.014;  # so srand returns the seed

srand() が明示的に呼び出されなかった場合、最初に rand 演算子を使った 時点で暗黙に引数なしで呼び出されます。 しかし、最近の Perl でプログラムが srand を呼び出したいであろう状況が いくつかあります。 一つはテストやデバッグのために予測可能な結果を生成するためです。 この場合、srand($seed) ($seed は毎回同じ値を使う) を使います。 もう一つの場合としては、子プロセスが親や他の子プロセスと同じ種の値を 共有することを避けるために、fork() の後に srand() を 呼び出したいかもしれません。

srand() (引数なし)をプロセス中で複数回呼び出しては いけません。 乱数生成器の内部状態はどのような種によって提供されるものよりも 高いエントロピーを持っているので、srand() を再び呼び出すと ランダム性が 失われます

srand のほとんどの実装では整数を取り、小数を暗黙に切り捨てます。 これは、srand(42) は普通 srand(42.1) と同じ結果になることを 意味します。 安全のために、srand には常に整数を渡しましょう。

返された種の典型的な利用法は、実行毎のテストを利用可能な時間内に完全に 行うには組み合わせが多すぎるテストプログラム用です。 毎回ランダムなサブセットをテストし、もし失敗したら、その実行で使った 種をログに出力することで、後で同じ結果を再現するために使えます。

rand() は暗号学的に安全ではありません。 セキュリティ的に重要な状況でこれに頼るべきではありません。 これを書いている時点で、いくつかのサードパーティ CPAN モジュールが 作者によって暗号学的に安全であることを目的とした乱数生成器を 提供しています: Data::Entropy, Crypt::Random, Math::Random::Secure, Math::TrulyRandom などです。

stat FILEHANDLE
stat EXPR
stat DIRHANDLE
stat

FILEHANDLE か DIRHANDLE を通じてオープンされているファイルか、 EXPR で指定されるファイルの情報を与える、13 要素のリストを返します。 EXPR が省略されると、 $_ が用いられます (_ ではありません!)。 stat に失敗した場合には、空リストを返します。 普通は、以下のようにして使います:

    ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
       $atime,$mtime,$ctime,$blksize,$blocks)
           = stat($filename);

全てのファイルシステムで全てのフィールドに対応しているわけではありません。 フィールドの意味は以下の通りです。

  0 dev      ファイルシステムのデバイス番号
  1 ino      inode 番号
  2 mode     ファイルモード (タイプとパーミッション)
  3 nlink    ファイルへの(ハード)リンクの数
  4 uid      ファイル所有者のユーザー ID の数値
  5 gid      ファイル所有者のグループ ID の数値
  6 rdev     デバイス識別子(特殊ファイルのみ)
  7 size     ファイルサイズ(バイト単位)
  8 atime    紀元から、最後にアクセスされた時刻までの秒数
  9 mtime    紀元から、最後に修正(modify)された時刻までの秒数
 10 ctime    紀元から、inode 変更(change)された時刻までの秒数 (*)
 11 blksize  ファイルとの相互作用のために適した I/O バイト数
             (ファイルごとに異なるかもしれない)
 12 blocks   ディスクに割り当てたシステム依存のブロック(常にでは
             ありませんがたいていはそれぞれ 512 バイト)の数

(紀元は GMT で 1970/01/01 00:00:00。)

(*) 全てのフィールドが全てのファイルシステムタイプで対応しているわけでは ありません。 明らかに、ctime のフィールドは移植性がありません。 特に、これから「作成時刻」を想定することは出来ません; 詳細については "Files and Filesystems" in perlport を参照してください。

下線だけの _ という特別なファイルハンドルを stat に渡すと、 実際には stat を行なわず、stat 構造体に残っている 前回の stat やファイルテストの情報が返されます。 例:

    if (-x $file && (($d) = stat(_)) && $d < 0) {
        print "$file is executable NFS file\n";
    }

(これは、NFS のもとでデバイス番号が負になるマシンで のみ動作します。)

モードにはファイルタイプとその権限の両方が含まれているので、 本当の権限を見たい場合は、(s)printf で "%" を使うことで ファイルタイプをマスクするべきです。

    $mode = (stat($filename))[2];
    printf "Permissions are %04o\n", $mode & 07777;

スカラコンテキストでは、stat は成功か失敗を表す真偽値を返し、 成功した場合は、特別なファイルハンドル _ に結び付けられた 情報をセットします。

File::stat モジュールは、便利な名前によるアクセス機構を提供します。

    use File::stat;
    $sb = stat($filename);
    printf "File is %s, size is %s, perm %04o, mtime %s\n",
           $filename, $sb->size, $sb->mode & 07777,
           scalar localtime $sb->mtime;

モード定数 (S_IF*) と関数 (S_IS*) を Fcntl モジュールから インポートできます。

    use Fcntl ':mode';

    $mode = (stat($filename))[2];

    $user_rwx      = ($mode & S_IRWXU) >> 6;
    $group_read    = ($mode & S_IRGRP) >> 3;
    $other_execute =  $mode & S_IXOTH;

    printf "Permissions are %04o\n", S_IMODE($mode), "\n";

    $is_setuid     =  $mode & S_ISUID;
    $is_directory  =  S_ISDIR($mode);

最後の二つは -u-d 演算子を使っても書けます。 一般に利用可能な S_IF* 定数は以下のものです。

    # Permissions: read, write, execute, for user, group, others.

    S_IRWXU S_IRUSR S_IWUSR S_IXUSR
    S_IRWXG S_IRGRP S_IWGRP S_IXGRP
    S_IRWXO S_IROTH S_IWOTH S_IXOTH

    # Setuid/Setgid/Stickiness/SaveText.
    # Note that the exact meaning of these is system-dependent.

    S_ISUID S_ISGID S_ISVTX S_ISTXT

    # File types.  Not all are necessarily available on
    # your system.

    S_IFREG S_IFDIR S_IFLNK S_IFBLK S_IFCHR
    S_IFIFO S_IFSOCK S_IFWHT S_ENFMT

    # The following are compatibility aliases for S_IRUSR,
    # S_IWUSR, and S_IXUSR.

    S_IREAD S_IWRITE S_IEXEC

一般に利用可能な S_IF* 関数は以下のものです。

    S_IMODE($mode)    the part of $mode containing the permission
                      bits and the setuid/setgid/sticky bits

    S_IFMT($mode)     the part of $mode containing the file type
                      which can be bit-anded with (for example)
                      S_IFREG or with the following functions

    # The operators -f, -d, -l, -b, -c, -p, and -S.

    S_ISREG($mode) S_ISDIR($mode) S_ISLNK($mode)
    S_ISBLK($mode) S_ISCHR($mode) S_ISFIFO($mode) S_ISSOCK($mode)

    # No direct -X operator counterpart, but for the first one
    # the -g operator is often equivalent.  The ENFMT stands for
    # record flocking enforcement, a platform-dependent feature.

    S_ISENFMT($mode) S_ISWHT($mode)

S_* 定数に関する詳細についてはネイティブの chmod(2) と stat(2) の ドキュメントを参照してください。 リンクの先にあるファイルではなく、シンボリックリンクそのものの情報を 得たい場合は、lstat 関数を使ってください。

移植性の問題: "stat" in perlport

state EXPR
state TYPE EXPR
state EXPR : ATTRS
state TYPE EXPR : ATTRS

state はちょうど my と同様に、レキシカルなスコープの変数を宣言します。 しかし、レキシカル変数がブロックに入る毎に再初期化されるのと異なり、 この変数は決して再初期化されません。 詳しくは "Persistent Private Variables" in perlsub を参照してください。

state 変数は、キーワードが CORE::state として書かれていない限り、 feature 'state' プラグマが有効の場合のみ有効です。 feature も参照してください。

study SCALAR
study

次に変更される前に、何回も文字列に対するパターンマッチを行なう アプリケーションで、そのような文字列 SCALAR(省略時には $_) を予め 学習しておきます。 これは、検索のために、どのようなパターンを何回使うかによって、また、 検索される文字列内の文字頻度の分布によって、時間を節約することに なるかもしれませんし、逆に浪費することになるかもしれません; 予習をした場合と しない場合の実行時間を比較して、どちらが速いか調べることが必要でしょう。 短い固定文字列 (複雑なパターンの固定部分を含みます) をたくさん検索する ループで、もっとも効果があるでしょう。 (この study の仕組みは、まず、検索される文字列内のすべての文字の リンクされたリストが作られ、たとえば、すべての 'k' がどこにあるかが わかるようになります。 各々の検索文字列から、C プログラムや英語のテキストから作られた頻度の 統計情報に基づいて、もっとも珍しい文字が選ばれます。 この「珍しい」文字を含む場所だけが調べられるのです。)

たとえば、特定のパターンを含む行の前にインデックスを 付けるエントリを入れる例を示します。

    while (<>) {
        study;
        print ".IX foo\n"    if /\bfoo\b/;
        print ".IX bar\n"    if /\bbar\b/;
        print ".IX blurfl\n" if /\bblurfl\b/;
        # ...
        print;
    }

fo よりも珍しいので、/\bfoo\b/ を探すとき、$_f を 含む場所だけが探されます。 一般に、病的な場合を除いて、かなりの結果が得られます。 唯一の問題は、節約できる時間が、最初にリンクリストを作る 時間よりも多いかどうかです、

実行時まで、探そうとする文字列がわからないときには、 ループ全体を文字列として組み立てて、eval すれば、 いつも、すべてのパターンを再コンパイルするという事態は避けられます。 ファイル全体を一つのレコードとして入力するために、 $/ を未定義にすれば、かなり速くなり、 多くの場合 fgrep(1) のような専用のプログラムより速くなります。 以下の例は、ファイルのリスト (@files) から単語のリスト (@words) を 探して、マッチするものがあったファイル名を出力します。

    $search = 'while (<>) { study;';
    foreach $word (@words) {
        $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
    }
    $search .= "}";
    @ARGV = @files;
    undef $/;
    eval $search;        # this screams
    $/ = "\n";        # put back to normal input delimiter
    foreach $file (sort keys(%seen)) {
        print $file, "\n";
    }
sub NAME BLOCK
sub NAME (PROTO) BLOCK
sub NAME : ATTRS BLOCK
sub NAME (PROTO) : ATTRS BLOCK

これはサブルーチン定義であり、本質的には 実際の関数ではありません。 BLOCK なしの場合、これは単に前方宣言です。 NAME なしの場合は、無名関数定義であり、値(作成したブロックの コードリファレンス)を返します: 単にクロージャの CODE リファレンスが 作成されます。

サブルーチンとリファレンスに関する詳細については、perlsubperlref を参照してください; 属性に関する更なる情報については attributesAttribute::Handlers を参照してください。

__SUB__

現在のサブルーチンのリファレンスを返す特殊トークン; サブルーチンの外側では undef

(/(?{...})/ のような) 正規表現コードブロックの中の __SUB__ の振る舞いは 変更される予定です。

このトークンは use v5.16 または "current_sub" 機能でのみ利用可能です。 feature を参照してください。

substr EXPR,OFFSET,LENGTH,REPLACEMENT
substr EXPR,OFFSET,LENGTH
substr EXPR,OFFSET

EXPR から、部分文字列を取り出して返します。 最初の文字がオフセット 0 となります。 OFFSET に負の値を設定すると、EXPR の終わりからのオフセットとなります。 LENGTH を省略すると、EXPR の最後まですべてが返されます。 LENGTH が負の値だと、文字列の最後から指定された数だけ文字を取り除きます。

    my $s = "The black cat climbed the green tree";
    my $color  = substr $s, 4, 5;      # black
    my $middle = substr $s, 4, -11;    # black cat climbed the
    my $end    = substr $s, 14;        # climbed the green tree
    my $tail   = substr $s, -4;        # tree
    my $z      = substr $s, -4, 2;     # tr

substr() を左辺値として使用することも可能で、その場合には、 EXPR が自身左辺値でなければなりません。 LENGTH より短いものを代入したときには、 EXPR は短くなり、LENGTH より長いものを代入したときには、 EXPR はそれに合わせて伸びることになります。 EXPR の長さを一定に保つためには、sprintf を使って、 代入する値の長さを調整することが、必要になるかもしれません。

OFFSET と LENGTH として文字列の外側を含むような部分文字列が指定されると、 文字列の内側の部分だけが返されます。 部分文字列が文字列の両端の外側の場合、substr() は未定義値を返し、 警告が出力されます。 左辺値として使った場合、文字列の完全に外側を部分文字列として指定すると 例外が発生します。 以下は境界条件の振る舞いを示す例です:

    my $name = 'fred';
    substr($name, 4) = 'dy';         # $name is now 'freddy'
    my $null = substr $name, 6, 2;   # returns "" (no warning)
    my $oops = substr $name, 7;      # returns undef, with warning
    substr($name, 7) = 'gap';        # raises an exception

substr() を左辺値として使う代わりの方法は、置き換える文字列を 4 番目の 引数として指定することです。 これにより、EXPR の一部を置き換え、置き換える前が何であったかを返す、 ということを(splice() と同様) 1 動作で行えます。

    my $s = "The black cat climbed the green tree";
    my $z = substr $s, 14, 7, "jumped from";    # climbed
    # $s is now "The black cat jumped from the green tree"

3 引数の substr() によって返された左辺値は「魔法の弾丸」のように振舞うことに 注意してください; これが代入される毎に、元の文字列のどの部分が変更されたかが 思い出されます; 例えば:

    $x = '1234';
    for (substr($x,1,2)) {
        $_ = 'a';   print $x,"\n";    # prints 1a4
        $_ = 'xyz'; print $x,"\n";    # prints 1xyz4
        $x = '56789';
        $_ = 'pq';  print $x,"\n";    # prints 5pq9
    }

負数のオフセットの場合、ターゲット文字列が修正されたときに文字列の末尾からの 位置を覚えます:

    $x = '1234';
    for (substr($x, -3, 2)) {
        $_ = 'a';   print $x,"\n";    # prints 1a4, as above
        $x = 'abcdefg';
        print $_,"\n";                # prints f
    }

バージョン 5.10 より前の Perl では、複数回左辺値を使った場合の結果は 未定義でした。 5.16 より前では、負のオフセットの結果は未定義です。

NEWFILE として、OLDFILE へのシンボリックリンクを生成します。 成功時には 1 を返し、失敗時には 0 を返します。 シンボリックリンクをサポートしていないシステムでは、 例外が発生します。 これをチェックするには、eval を使用します:

    $symlink_exists = eval { symlink("",""); 1 };

移植性の問題: "symlink" in perlport

syscall NUMBER, LIST

LIST の最初の要素で指定するシステムコールを、残りの要素をその システムコールの引数として呼び出します。 実装されていない場合には、例外が発生します。 引数は、以下のように解釈されます: 引数が数字であれば、int として 引数を渡します。 そうでなければ、文字列値へのポインタが渡されます。 文字列に結果を受け取るときには、その結果を受け取るのに十分なくらいに、 文字列を予め伸ばしておく必要があります。 文字列リテラル(あるいはその他の読み込み専用の文字列)を syscall の 引数として使うことはできません; Perl は全ての文字列ポインタは書き込まれると 仮定しなければならないからです。 整数引数が、リテラルでなく、数値コンテキストで評価されたことの ないものであれば、数値として解釈されるように、 0 を足しておく必要があるかもしれません。 以下は syswrite 関数(あるいはその逆)をエミュレートします。

    require 'syscall.ph';        # may need to run h2ph
    $s = "hi there\n";
    syscall(&SYS_write, fileno(STDOUT), $s, length $s);

Perl は、システムコールに最大 14 個の引数しか渡せませんが、 (普通は)実用上問題はないでしょう。

syscall は、呼び出したシステムコールが返した値を返します。 システムコールが失敗すると、syscall-1 を返し、 $!(errno) を設定します。 システムコールが正常に -1 を返す 場合がある ことに注意してください。 このようなシステムコールを正しく扱うには、 $!=0 をシステムコールの前に実行し、それから syscall-1 を返した時には $! の値を調べてください。

syscall(&SYS_pipe) には問題があり、 作ったパイプの、読み出し側のファイル番号を返しますが、 もう一方のファイル番号を得る方法がありません。 この問題を避けるためには、代わりに pipe を使ってください。

移植性の問題: "syscall" in perlport

sysopen FILEHANDLE,FILENAME,MODE
sysopen FILEHANDLE,FILENAME,MODE,PERMS

FILENAME で与えられたファイル名のファイルをオープンし、 FILEHANDLE と結び付けます。 FILEHANDLE が式の場合、その値は実際の求めているファイルハンドルの名前として 扱われます; 未定義のスカラは適切に自動有効化されます。 この関数呼び出しはシステムの open(2) 関数を FILENAME, MODE, PERMS の 引数で呼び出すことを基礎としています。

MODE パラメータに指定できるフラグビットと値はシステム依存です; これは標準モジュール Fcntl 経由で利用可能です。 どのようなフラグビットと値が利用可能であるかについては、 OS の open(2) システムコールに関する文書を参照してください。 | 演算子を使って複数のフラグを結合することができます。

もっともよく使われる値は、ファイルを読み込み専用で開く O_RDONLY、 ファイルを書き込み専用で開く O_WRONLY、 ファイルを読み書き両用で開く O_RDWR です。

歴史的な理由により、Perl が対応しているほとんどのシステムで使える値が あります:0 は読み込み専用、1 は書き込み専用、2 は読み書き両用を意味します。 OS/390 と Macintosh では動作 しない ことが分かっています; 新しく書くコードではこれらは使わないほうがよいでしょう。

FILENAME という名前のファイルが存在せず、(典型的には MODE が O_CREAT フラグを含んでいたために) open 呼び出しがそれを作った場合、 PERMS の値は新しく作られたファイルの権限を指定します。 sysopen の PERMS 引数を省略した場合、Perl は 8 進数 0666 を使います。 これらの権限は 8 進数である必要があり、プロセスの現在の umask で 修正されます。

多くのシステムではファイルを排他モードで開くために O_EXCL が 利用可能です。 これはロック ではありません: 排他性というのは既にファイルが 存在していた場合、sysopen() が失敗することを意味します。 O_EXCL はネットワークファイルシステムでは動作せず、 またO_CREAT フラグも有効でない限りは効果がありません。 O_CREAT|O_EXCL をセットすると、これがシンボリックリンクだった場合は ファイルを開くことを妨げます。 これはファイルパス中のシンボリックリンクは守りません。

既に存在しているファイルを切り詰めたい場合もあるかもしれません。 これは O_TRUNC フラグを使うことで行えます。 O_RDONLYO_TRUNC を同時に指定したときの振る舞いは未定義です。

めったなことでは sysopen の引数に 0644 を指定するべきではないでしょう: ユーザーがより寛大な umask を指定する選択肢を奪うからです。 省略した方がいいです。 これに関するさらなる情報については perlfunc(1) の umask を 参照してください。

sysopen は C の fdopen() ライブラリ関数に依存していることに注意してください。 多くの Unix システムでは、fdopen() はファイル記述子がある値(例えば 255)を超えると 失敗することが知られています。 これより多くのファイル記述子が必要な場合は、 Perl を sfio ライブラリを使って再ビルドするか、 POSIX::open() 関数を使うことを健闘してください。

ファイル操作に関するより親切な説明については perlopentut を参照してください。

移植性の問題: "sysopen" in perlport

sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
sysread FILEHANDLE,SCALAR,LENGTH

read(2) を用いて、指定した FILEHANDLE から、変数 SCALAR へ、LENGTH バイトの データの読み込みを試みます。 これは、バッファ付き IO ルーチンを通りませんから、他の入力関数, print, write, seek, tell, eof と混ぜて使うと、入力がおかしくなるかも しれません; perlio 層や stdio 層は普通データをバッファリングするからです。 ファイルの最後では 0が、エラー時には undef が、 それ以外では実際に読み込まれたデータの長さが返されます (後者の場合は $! も セットされます)。 実際に読み込んだ最後のバイトが read した後の最後のバイトになるので、 SCALAR は伸び縮みします。

OFFSET を指定すると、文字列の先頭以外の場所から、読み込みを行なうことが できます。 OFFSET に負の値を指定すると、文字列の最後から逆向きに何文字目かで 位置を指定します。 OFFSET が正の値で、SCALAR の長さよりも大きかった場合、文字列は 読み込みの結果が追加される前に、必要なサイズまで "\0" のバイトで パッディングされます。

syseof() 関数はありませんが、問題ありません; どちらにしろ eof() は (tty のような)デバイスファイルに対してはうまく動作しないからです。 sysread() を使って、 返り値が 0 かどうかで最後まで読んだかを 判断してください。

ファイルハンドルが :utf8 であるとマークが付けられると、バイトではなく Unicode 文字が読み込まれます (sysread() の LENGTH, OFFSET および返り値は Unicode 文字になります)。 :encoding(...) 層は暗黙のうちに :utf8 層が導入されます。 "binmode", "open", open プラグマ, open を参照してください。

sysseek FILEHANDLE,POSITION,WHENCE

FILEHANDLE のシステム位置をバイト単位で lseek(2) を使って設定します。 FILEHANDLE は、実際のファイルハンドル名を与える式でもかまいません。 WHENCE の値が、0 ならば、新しい位置を POSITION の位置へ設定します; 1 ならば、現在位置から POSITION 加えた位置へ設定します; 2 ならば、 EOF から POSITION だけ(普通は負の数です)加えた位置へ、新しい位置を 設定します。

バイト単位 に関する注意: 文字単位で扱うようにファイルハンドルが 設定されている場合(:encoding(utf8) I/O 層を使っている場合など)でも、 tell() は文字のオフセットではなくバイトのオフセットを返します (なぜならこれを実装すると sysseek() が受け入れられないほど 遅くなるからです)。

sysseek() は普通のバッファ付き IO をバイパスしますので、 sysread 以外の (例えば <> や read() の)読み込み、 print, write, seek, tell, eof と混ぜて使うと 混乱を引き起こします。

WHENCE には、Fcntl モジュールで使われている SEEK_SET, SEEK_CUR, SEEK_END (ファイルの先頭、現在位置、ファイルの最後)という定数を 使うこともできます。 定数の使用は 0, 1, 2 に依存するよりも移植性があります。 例えば "systell" 関数を定義するには:

    use Fcntl 'SEEK_CUR';
    sub systell { sysseek($_[0], 0, SEEK_CUR) }

新しい位置を返します; 失敗したときは未定義値を返します。 位置がゼロの場合は、"0 but true" の文字列として返されます; 従って sysseek は成功時に真を返し、失敗時に偽を返しますが、簡単に新しい位置を 判定できます。

system LIST
system PROGRAM LIST

exec LIST とほとんど同じですが、まず fork を行ない、 親プロセスではチャイルドプロセスが終了するのを wait します。 exec の項で述べたように、引数の処理は、引数の数によって異なることに 注意してください。 LIST に複数の引数がある場合、または LIST が複数の要素からなる配列の場合、 リストの最初の要素で与えられるプログラムを、リストの残りの要素を引数として 起動します。 スカラの引数が一つだけの場合、引数はシェルのメタ文字をチェックされ、もし あればパースのために引数全体がシステムコマンドシェル (これは Unix プラットフォームでは /bin/sh -c ですが、他のプラットフォームでは 異なります)に渡されます。 シェルのメタ文字がなかった場合、引数は単語に分解されて直接 execvp に 渡されます; この方がより効率的です。

v5.6.0 から、Perl は書き込み用に開いている全てのファイルに対して fork を行う前にフラッシュしようとしますが、これに対応していない プラットフォームもあります(perlport を参照してください)。 安全のために、$| (English モジュールでは $AUTOFLUSH) をセットするか、 全ての開いているハンドルに対して IO::Handleautoflush() メソッドを 呼び出す必要があるかもしれません。

返り値は、wait が返すプログラムの exit 状態です。 実際の exit 値を得るには 右に 8 ビットシフトしてください(後述)。 "exec" も参照してください。 これはコマンドからの出力を捕らえるために使うものではありません; そのような用途には、"`STRING`" in perlop に記述されている 逆クォートや qx// を使用してください。 -1 の返り値はプログラムを開始させることに失敗したか、wait(2) システムコールがエラーを出したことを示します (理由は $! を調べてください)。

もし system (及び Perl のその他の多くの部分) でエラー時に die したいなら、autodie プラグマを見てみてください。

exec と同様に、system でも system PROGRAM LIST の文法を 使うことで、プログラムに対してその名前を嘘をつくことができます。 再び、"exec" を参照してください。

SIGINTSIGQUITsystem の実行中は無視されるので、 これらのシグナルを受信して終了させることを想定したプログラムの場合、 返り値を利用するように変更する必要があります。

    @args = ("command", "arg1", "arg2");
    system(@args) == 0
        or die "system @args failed: $?"

system の失敗を手動で検査したいなら、 以下のように $? を調べることで、全ての失敗の可能性を チェックできます:

    if ($? == -1) {
        print "failed to execute: $!\n";
    }
    elsif ($? & 127) {
        printf "child died with signal %d, %s coredump\n",
            ($? & 127),  ($? & 128) ? 'with' : 'without';
    }
    else {
        printf "child exited with value %d\n", $? >> 8;
    }

または、POSIX モジュールの W*() 呼び出しを使って ${^CHILD_ERROR_NATIVE} の値を調べることもできます。

system の引数がシェルによって間接的に実行された場合、 結果と返り値はシェルの癖によって変更されることがあります。 詳細については "`STRING`" in perlop"exec" を参照してください。

systemforkwait を行うので、SIGCHLD ハンドラの影響を 受けます。 詳しくは perlipc を参照してください。

移植性の問題: "system" in perlport

syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
syswrite FILEHANDLE,SCALAR,LENGTH
syswrite FILEHANDLE,SCALAR

write(2) を使って、指定した FILEHANDLEへ、変数 SCALAR から、LENGTH バイトの データの書き込みを試みます。 LENGTH が指定されなかった場合、 SCALAR 全体を書き込みます。 これは、バッファ付き IO ルーチンを通りませんから、他の入力関数 (sysread() 以外), print, write, seek, tell, eof と 混ぜて使うと、出力がおかしくなるかもしれません; perlio 層と stdio 層は普通 データをバッファリングするからです。 実際に読み込まれたデータの長さか、エラー時には undef が返されます (この場合エラー変数 $! もセットされます)。 LENGTH が OFFSET 以降の SCALAR の利用可能なデータより大きかった場合、 利用可能なデータのみが書き込まれます。

OFFSET を指定すると、SCALAR の先頭以外の場所から、 データを取り出して、書き込みを行なうことができます。 OFFSET に負の値を指定すると、文字列の最後から逆向きに数えて 何バイト目から書き込むかを示します。 SCALAR の長さが 0 の場合、OFFSET は 0 のみ使用できます。

警告: ファイルハンドルが :utf8 であるとマークが付けられると、 バイトではなく UTF-8 エンコードされた Unicode 文字が読み込まれ、 syswrite() の LENGTH, OFFSET および返り値は (UTF8 エンコードされた Unicode) 文字単位になります。 :encoding(...) 層は暗黙のうちに :utf8 層が導入されます。 または、もしハンドルにエンコーディングが記録されていない状態で 255 を超える符号位置の文字を書き込もうとすると、例外が発生します。 "binmode", "open", open プラグマ, open を参照してください。

tell FILEHANDLE
tell

FILEHANDLE の現在の位置を バイト数で 返します; エラーの場合は -1 を 返します。 FILEHANDLE は、実際のファイルハンドル名を示す式でもかまいません。 FILEHANDLE が省略された場合には、 最後に読み込みを行なったファイルについて調べます。

バイト単位 に関する注意: ファイルハンドルが (例えば :encoding(utf8) 層を使って) 文字を操作するように設定されていたとしても、tell() は文字の オフセットではなくバイトのオフセットを返すことに注意してください (なぜならこれは seek() と tell() が遅くなってしまうからです)。

STDIN のような標準ストリームに対する tell() の返り値は OS に依存します: -1 やその他の値が返ってくるかもしれません。 パイプ、FIFO、ソケットに対して tell() を使うと、普通は -1 が返ります。

systell 関数はありません。 代わりに sysseek(FH, 0, 1) を使ってください。

sysread(), syswrite(), sysseek() で操作されたファイルハンドルに tell() (またはその他のバッファリング I/O 操作) を使わないでください。 これらの関数はバッファリングを無視しますが、tell() は違います。

telldir DIRHANDLE

DIRHANDLE 上の readdir ルーチンに対する現在位置を返します。 値は、そのディレクトリで特定の位置をアクセスするため、 seekdir に渡すことができます。 telldir は同名のシステムライブラリルーチンと同じく、 ディレクトリ縮小時の問題が考えられます。

tie VARIABLE,CLASSNAME,LIST

この関数は、変数を、その変数の実装を行なうクラスと結び付けます。 VARIABLE は、魔法をかける変数の名前です。 CLASSNAME は、正しい型のオブジェクトを実装するクラスの名前です。 他に引数があれば、そのクラスの適切なコンストラクタメソッドに渡されます (つまり TIESCALAR, TIEHANDLE, TIEARRAY, TIEHASH)。 通常、これらは、C の dbm_open などの関数に渡す引数となります。 コンストラクタで返されるオブジェクトはまた tie 関数でも返されます; これは CLASSNAME の他のメソッドにアクセスしたいときに便利です。

DBM ファイルのような大きなオブジェクトでは、keysvalues のような 関数は、大きなリストを返す可能性があります。 そのような場合では、each 関数を使って繰り返しを行なった方が よいかもしれません。 例:

    # print out history file offsets
    use NDBM_File;
    tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
    while (($key,$val) = each %HIST) {
        print $key, ' = ', unpack('L',$val), "\n";
    }
    untie(%HIST);

ハッシュを実装するクラスでは、次のようなメソッドを用意します:

    TIEHASH classname, LIST
    FETCH this, key
    STORE this, key, value
    DELETE this, key
    CLEAR this
    EXISTS this, key
    FIRSTKEY this
    NEXTKEY this, lastkey
    SCALAR this
    DESTROY this
    UNTIE this

通常の配列を実装するクラスでは、次のようなメソッドを用意します:

    TIEARRAY classname, LIST
    FETCH this, key
    STORE this, key, value
    FETCHSIZE this
    STORESIZE this, count
    CLEAR this
    PUSH this, LIST
    POP this
    SHIFT this
    UNSHIFT this, LIST
    SPLICE this, offset, length, LIST
    EXTEND this, count
    DELETE this, key
    EXISTS this, key
    DESTROY this
    UNTIE this

ファイルハンドルを実装するクラスでは、次のようなメソッドを用意します:

    TIEHANDLE classname, LIST
    READ this, scalar, length, offset
    READLINE this
    GETC this
    WRITE this, scalar, length, offset
    PRINT this, LIST
    PRINTF this, format, LIST
    BINMODE this
    EOF this
    FILENO this
    SEEK this, position, whence
    TELL this
    OPEN this, mode, LIST
    CLOSE this
    DESTROY this
    UNTIE this

スカラ変数を実装するクラスでは、次のようなメソッドを用意します:

    TIESCALAR classname, LIST
    FETCH this,
    STORE this, value
    DESTROY this
    UNTIE this

上記の全てのメソッドを実装する必要はありません。 perltie, Tie::Hash, Tie::Array, Tie::Scalar, Tie::Handle を参照してください。

dbmopen と違い、tie 関数はモジュールを use したり require したりしません; 自分で明示的に行う必要があります。 tie の興味深い実装については DB_FileConfig モジュールを 参照してください。

更なる詳細については perltie"tied VARIABLE" を参照してください。

tied VARIABLE

VARIABLE の基となるオブジェクトへのリファレンスを返します (変数をパッケージに結びつけるために tie 呼び出しをしたときの 返り値と同じものです)。 VARIABLE がパッケージと結び付けられていない場合は未定義値を返します。

time

gmtimelocaltime への入力形式に合っている、 システムが紀元と考える時点からの連続秒数を返します。 ほとんどのシステムでは紀元は UTC 1970 年 1 月 1 日 00:00:00 です; 特徴的な例外としては、古い Mac OS ではローカルタイムゾーンの 1904 年 1 月 1 日 00:00:00 を紀元として使います。

1 秒よりも細かい時間を計測するためには、Perl 5.8 以降(それ以前では CPANから)の Time::HiRes モジュールを使うか、 gettimeofday(2) があるなら、Perl の syscall インターフェースを 使ってください。 詳しくは perlfaq8 を参照してください。

日付と時刻の処理は、多くの関連するモジュールが CPAN にあります。 包括的な日付と時刻の表現については、CPAN の DateTime モジュールを 参照してください。

times

現プロセス及び終了したその子プロセスに対する、ユーザ時間とシステム時間を 秒で示した、4 要素のリスト値を返します。

    ($user,$system,$cuser,$csystem) = times;

スカラコンテキストでは、times$user を返します。

子プロセスに対する times は、終了した子プロセスのみ含められます。

移植性の問題: "times" in perlport

tr///

文字変換演算子です。 y/// と同じです。 "Quote and Quote-like Operators" in perlop を参照してください。

truncate FILEHANDLE,LENGTH
truncate EXPR,LENGTH

FILEHANDLE 上にオープンされたファイルか、EXPR で名前を表わしたファイルを、 指定した長さに切り詰めます。 システム上に truncate が実装されていなければ、例外が発生します。 成功すれば真を、エラー時には undef を返します。

LENGTH がファイルの長さより大きい場合の振る舞いは未定義です。

FILEHANDLE のファイルの位置は変わりません。 ファイルに書き込む前に seek を 呼び出したいかもしれません。

移植性の問題: "truncate" in perlport

uc EXPR
uc

EXPR を大文字に変換したものを返します。 これは、ダブルクォート文字列における、\U エスケープを 実装する内部関数です。 先頭文字の タイトル文字マッピングは試みません。 このためには "ucfirst" を参照してください。

EXPR が省略されると、$_ を使います。

この関数は、ロケールのようなさまざまなプラグマの影響下では、 "lc" と同様に振る舞います。

ucfirst EXPR
ucfirst

最初の文字だけを大文字にした、EXPR を返します (Unicode では titlecase)。 これは、ダブルクォート文字列における、\u エスケープを 実装する内部関数です。

EXPR が省略されると、$_ を使います。

この関数は、ロケールのようなさまざまなプラグマの影響下では、 "lc" と同様に振る舞います。

umask EXPR
umask

現在のプロセスの umask を EXPR に設定し、以前の値を返します。 EXPR が省略されると、単にその時点の umask の値を返します。

Unix パーミッション rwxr-x--- は 3 ビットの三つの組、 または 3 桁の 8 進数として表現されます: 0750 (先頭の 0 は 8 進数を意味し、実際の値ではありません)。 umask の値は無効にするパーミッションビットのこのような数値表現です。 mkdirsysopen で渡されたパーミッション(または「モード」)の値は umask で修正され、たとえ sysopen0777 のパーミッションで ファイルを作るように指定しても、umask が 0022 なら、 結果としてファイルは 0755 のパーミッションで作成されます。 umask0027 (グループは書き込めない; その他は読み込み、書き込み、 実行できない) のとき、sysopen0666 を渡すと、 ファイルはモード 0640 (なぜなら 0666 &~ 0270640)で作成されます。

以下は助言です: 作成モードとして、(sysopen による)通常ファイルでは 0666 を、(mkdir による)ディレクトリでは 0777 を指定しましょう。 これにより、ユーザーに選択の自由を与えます: もしファイルを守りたいなら、 プロセスの umask として 022, 027, あるいは特に非社交的な 077 を選択できます。 プログラムがユーザーより適切なポリシー選択ができることは稀です。 例外は、プライベートに保つべきファイル(メール、ウェブブラウザのクッキー、 .rhosts ファイルなど)を書く場合です。

umask(2) が実装されていないシステムで、自分自身 へのアクセスを 制限しようとした(つまり (EXPR & 0700) > 0)場合、例外が発生します。 umask(2) が実装されていないシステムで、自分自身へのアクセスは 制限しようとしなかった場合、undef を返します。

umask は通常 8 進数で与えられる数値であることを忘れないでください; 8 進数の 文字列 ではありません。 文字列しかない場合、 "oct" も参照してください。

移植性の問題: "umask" in perlport

undef EXPR
undef

左辺値である EXPR の値を未定義にします。 スカラ値、(@ を使った)配列、(% を使った)ハッシュ、(& を使った) サブルーチン、(* を使った)型グロブだけに使用します。 特殊変数や DBM リスト値に undef $hash{$key} などとしても おそらく期待通りの結果にはなりませんから、しないでください; "delete" を参照してください。 常に未定義値を返します。 EXPR は省略することができ、その場合には何も未定義にされませんが 未定義値は返されますので、それをたとえば、 サブルーチンの返り値、変数への割り当て、引数などとして使うことができます。 例:

    undef $foo;
    undef $bar{'blurfl'};      # Compare to: delete $bar{'blurfl'};
    undef @ary;
    undef %hash;
    undef &mysub;
    undef *xyz;       # destroys $xyz, @xyz, %xyz, &xyz, etc.
    return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it;
    select undef, undef, undef, 0.25;
    ($a, $b, undef, $c) = &foo;       # Ignore third value returned

これはリスト演算子ではなく、単項演算子であることに注意してください。

LIST に含まれるファイルを削除します。 成功時は削除に成功したファイルの数を返します。 失敗時は偽を返して $! (error) をセットします:

    my $unlinked = unlink 'a', 'b', 'c';
    unlink @goners;
    unlink glob "*.bak";

エラーの場合、unlink はどのファイルが削除できなかったかを知らせません。 どのファイルが削除できなかったかを知りたい場合は、一つずつ削除してください:

     foreach my $file ( @goners ) {
         unlink $file or warn "Could not unlink $file: $!";
     }

注: スーパーユーザ権限で、Perl に -U を付けて実行した場合でなければ、 unlink はディレクトリを削除しようとすることはありません。 この条件にあう場合にも、ディレクトリの削除は、 ファイルシステムに多大な損害を与える可能性があります。 最後に、unlink をディレクトリに使うのはほとんどの OS では 対応していません。 代わりに rmdir を使ってください。

LIST が省略されると、unlink$_ を使います。

unpack TEMPLATE,EXPR
unpack TEMPLATE

unpackpack の逆を行ないます: 構造体を表わす文字列をとり、 リスト値に展開し、その配列値を返します。 (スカラコンテキストでは、単に最初の値を返します。)

EXPR が省略されると、$_ の文字列を unpack します。 この関数の説明については perlpacktut を参照してください。

文字列は TEMPLATE で示された固まりに分割されます。 それぞれの固まりは別々に値に変換されます。 典型的には、文字列は pack の結果あるいはある種の C の構造体の 文字列表現の文字列です。

TEMPLATE は、pack 関数と同じフォーマットを使います。 部分文字列を取り出すうサブルーチンの例を示します:

    sub substr {
        my($what,$where,$howmuch) = @_;
        unpack("x$where a$howmuch", $what);
    }

これもそうです。

    sub ordinal { unpack("W",$_[0]); } # same as ord()

pack() で利用可能なフィールドの他に、 フィールドの前に %<数値> というものを付けて、 項目自身の代わりに、その項目の <数値>-ビットのチェックサムを 計算させることができます。 デフォルトは、16-ビットチェックサムです。 チェックサムは展開された値の数値としての値の合計 (文字列フィールドの場合は ord($char) の合計; ビットフィールドの場合は 0 と 1 の合計) が用いられます。

たとえば、以下のコードは System V の sum プログラムと同じ値を計算します。

    $checksum = do {
        local $/;  # slurp!
        unpack("%32W*",<>) % 65535;
    };

以下は、効率的にビットベクターの設定されているビットを 数えるものです。

    $setbits = unpack("%32b*", $selectmask);

pP は注意深く使うべきです。 Perl は unpack() に渡された値が有効なメモリ位置を指しているかどうかを 確認する方法がないので、有効かどうかわからないポインタ値を渡すと 悲惨な結果を引き起こすかもしれません。

多くの pack コードがある場合や、フィールドやグループの繰り返し回数が 入力文字列の残りより大きい場合、結果は未定義です: 繰り返し回数が減らされる場合もありますし、unpack() が空文字列や 0 を 返すこともありますし、例外が発生します。 もし入力文字列が TEMPLATE で表現されているものより大きい場合、 入力文字列の残りは無視されます。

さらなる例と注意に関しては "pack" を参照してください。

unshift ARRAY,LIST
unshift EXPR,LIST

shift の逆操作を行ないます。 見方を変えれば、push の逆操作とも考えられます。 LIST を ARRAY の先頭に入れて、新しくできた配列の要素の数を返します。

    unshift(@ARGV, '-e') unless $ARGV[0] =~ /^-/;

LIST は、はらばらにではなく、一度に登録されるので、順番はそのままです。 逆順に登録するには、reverse を使ってください。

Perl 5.14 から、unshift はスカラの EXPR を取ることができるようになりました; これは bless されていない配列へのリファレンスでなければなりません。 引数は自動的にデリファレンスされます。 unshift のこの動作は高度に実験的であると考えられています。 正確な振る舞いは将来のバージョンの Perl で変わるかも知れません。

あなたのコードを以前のバージョンの Perl で実行したユーザーが不思議な 文法エラーで混乱することを避けるために、コードが最近のバージョンの Perl で のみ 動作することを示すためにファイルの先頭に以下のようなことを 書いてください:

    use 5.014;  # so push/pop/etc work on scalars (experimental)
untie VARIABLE

変数とパッケージの間の結合を解きます。 (tie を参照してください。) 結合されていない場合は何も起きません。

use Module VERSION LIST
use Module VERSION
use Module LIST
use Module
use VERSION

指定したモジュールから、現在のパッケージにさまざまな内容をインポートします; 多くは、パッケージのサブルーチン名や、変数名に別名を付けることで、 実現されています。 これは、以下は等価ですが:

    BEGIN { require Module; Module->import( LIST ); }

Module が 裸の単語でなければならない ことを除けば、です。 インポートは、if を使って条件付きで行うことができます。

特に use VERSION の形式では、 VERSION は 5.006 のような正の 10 進小数 ($] と比較されます)か、v5.6.1 の形 ($^V (またの名を $PERL_VERSION) と比較されます) のv-文字列で指定します。 VERSION が Perl の現在のバージョンより大きいと、例外が発生します; Perl はファイルの残りを読み込みません。 "require" と似ていますが、これは実行時にチェックされます。 対称的に、no VERSION は指定されたバージョンより古いバージョンの Perl で 動作させたいことを意味します。

VERSION に v5.6.1 の形のリテラルを指定することは一般的には避けるべきです; なぜなら、この文法に対応していない Perl の初期のバージョン (つまり、 5.6.0 以前) では誤解させるようなエラーメッセージが出るからです。 代わりに等価な数値表現を使うべきです。

    use v5.6.1;     # compile time version check
    use 5.6.1;      # ditto
    use 5.006_001;  # ditto; preferred for backwards compatibility

これは古いバージョンの Perl で動かなくなったライブラリモジュールを use する前に、現在の Perl のバージョンを調べたい場合に有用です。 (我々は必要な場合以外にそのようなことがないように努力していますが。)

use VERSION は、feature プラグマで定義されたように、指定された バージョンで利用可能な全ての機能を有効にし、指定されたバージョンの機能の 束にない機能を無効にします。 feature を参照してください。 同様に、指定された Perl のバージョンが 5.12.0 以上の場合、 制限は use strict と同様にレキシカルに有効になります。 明示的に use strictno strict を使うと、例え先に 指定されていたとしても、use VERSION を上書きします。 どちらの場合も、feature.pmstrict.pm ファイルは実際には 読み込まれません。

BEGIN によって、requireimport は、コンパイル時に 実行されることになります。 require は、モジュールがまだメモリにロードされていなければ、ロードします。 import は、組込みの関数ではありません; さまざまな機能を現在のパッケージに インポートするように Module パッケージに伝えるために呼ばれる、 通常の静的メソッドです。 モジュール側では、import メソッドをどのようにでも実装することが できますが、多くのモジュールでは、Exporter モジュールで定義された、 Exporter クラスからの継承によって、import メソッドを行なうように しています。 Exporterモジュールを参照してください。 importメソッドが見つからなかった場合、AUTOLOAD メソッドがあったとしても 呼び出しはスキップされます。

パッケージの import メソッドを呼び出したくない場合(例えば、名前空間を 変更したくない場合など)は、明示的に空リストを指定してください:

    use Module ();

これは以下と完全に等価です:

    BEGIN { require Module }

Module と LIST の間に VERSION 引数がある場合、use は Module クラスの VERSION メソッドを、与えられたバージョンを引数として呼び出します。 デフォルトの VERSION メソッドは、 UNIVERSAL クラスから継承したもので、 与えられたバージョンが 変数 $Module::VERSION の値より大きい場合に 警告を出します。

繰り返すと、LIST を省略する(import が引数なしで呼び出される)ことと 明示的に空の LIST () を指定する (import は呼び出されない)ことは 違います。 VERSION の後ろにカンマが不要なことに注意してください!

これは、広く公開されているインタフェースですので、 プラグマ (コンパイラディレクティブ) も、この方法で実装されています。 現在実装されているプラグマには、以下のものがあります:

    use constant;
    use diagnostics;
    use integer;
    use sigtrap  qw(SEGV BUS);
    use strict   qw(subs vars refs);
    use subs     qw(afunc blurfl);
    use warnings qw(all);
    use sort     qw(stable _quicksort _mergesort);

通常のモジュールが、現在のパッケージにシンボルをインポートする (これは、ファイルの終わりまで有効です) のに対して、 これらの擬似モジュールの一部(strictinteger など)は、 現在のブロックスコープにインポートを行ないます。

use はコンパイル時に有効なので、コードがコンパイルされる際の通常の 流れ制御には従いません。 特に、条件文のうち成立しない側の中に use を書いても、 処理を妨げられません。 モジュールやプラグマを条件付きでのみ読み込みたい場合、 if プラグマを使って実現できます:

    use if $] < 5.008, "utf8";
    use if WANT_WARNINGS, warnings => qw(all);

これに対して、no 宣言という、use によってインポートされたものを、 インポートされていないことにするものがあります; つまり、import の代わりに unimport Module LIST を呼び出します。 これは VERSION、省略された LIST、空の LIST、unimport メソッドが見つからない 場合などの観点では、import と同様に振る舞います。

    no integer;
    no strict 'refs';
    no warnings;

nono VERSION 形式を使うときには注意を払うべきです。 これは引数で指定されたバージョンよりも前の Perl で実行されたときに アサートされることを意味する だけ で、use VERSION によって 有効にされた副作用をなかったことにするもの ではありません

標準モジュールやプラグマの一覧は、perlmodlib を参照してください。 コマンドラインから use 機能を指定するための -M-m の コマンドラインオプションについては perlrun を参照してください。

utime LIST

ファイルのアクセス時刻と修正(modification) 時刻を変更します。 LIST の最初の二つの要素に、数値で表わしたアクセス時刻と修正時刻を 順に指定します。 変更に成功したファイルの数を返します。 各ファイルの inode 変更(change)時刻には、その時点の時刻が設定されます。 例えば、このコードはファイルが 既に存在して いて、ユーザーが 実行しているプログラムに従っているなら、 Unix の touch(1) コマンドと同じ効果があります。

    #!/usr/bin/perl
    $atime = $mtime = time;
    utime $atime, $mtime, @ARGV;

Perl 5.8.0 から、リストの最初の二つの要素が undef である場合、 C ライブラリの utime(2) システムコールを、秒の引数を null として 呼び出します。 ほとんどのシステムでは、これによってファイルのアクセス時刻と修正時刻を 現在の時刻にセットし(つまり、上記の例と等価です)、 書き込み権限があれば他のユーザーのファイルに対しても動作します。

    for $file (@ARGV) {
        utime(undef, undef, $file) 
            || warn "couldn't touch $file: $!";
    } 

NFS では、これはローカルマシンの時刻ではなく、NFS サーバーの時刻が 使われます。 時刻同期に問題がある場合、NFS サーバーとローカルマシンで違う時刻に なっている場合があります。 実際のところ、Unix の touch(1) コマンドは普通、最初の例ではなく、 この形を使います。

最初の二つの要素のうち、一つだけに undef を渡すと、その要素は 0 を 渡すのと等価となり、上述の、両方に undef を渡した時と同じ 効果ではありません。 この場合は、未初期化の警告が出ます。

futimes(2) に対応しているシステムでは、ファイルハンドルを引数として 渡せます。 futimes(2) に対応していないシステムでは、ファイルハンドルを渡すと 例外が発生します。 ファイルハンドルを認識させるためには、グロブまたはリファレンスとして 渡されなければなりません; 裸の単語はファイル名として扱われます。

移植性の問題: "utime" in perlport

values HASH
values ARRAY
values EXPR

リストコンテキストでは、指定したハッシュのすべての値を返します。 Perl 5.12 以降でのみ、配列の全ての値からなるリストも 返します; このリリースの前では、配列要素に使おうとすると文法エラーが 発生します。 スカラコンテキストでは、値の数を返します。

ハッシュ要素は見かけ上、ランダムな順序で返されます。 実際のランダムな順序はハッシュに固有です; 二つのハッシュに全く同じ一連の 操作を行っても、ハッシュによって異なった順序になります。 ハッシュへの挿入によって順序が変わることがあります; 削除も同様ですが、 each または keys によって返されたもっとも最近のキーは順序を 変えることなく削除できます。 ハッシュが変更されない限り、keys, values, each が繰り返し同じ順序で 返すことに依存してもかまいません。 なぜハッシュの順序がランダム化されているかの詳細については "Algorithmic Complexity Attacks" in perlsec を参照してください。 ここで保証したことを除いて、Perl のハッシュアルゴリズムとハッシュ横断順序の 正確な詳細は Perl のリリースによって変更される可能性があります。

副作用として、values() を呼び出すと HASH や ARRAY の内部反復子を リセットします; /each を参照してください。 (特に、values() を無効コンテキストで呼び出すとその他のオーバーヘッドなしで 反復子をリセットします。 反復子をリセットするということを除けば、 リストコンテキストでの values @array は単なる @array と同じです。 この目的のためには無効コンテキストで keys @array を使うことを お勧めしますが、values @array を取り出すにはそのままにするよりも より多くの文書が必要だと判断しました。)

値はコピーされないので、返されたリストを変更すると ハッシュの中身が変更されることに注意してください。

    for (values %hash)      { s/foo/bar/g }  # modifies %hash values
    for (@hash{keys %hash}) { s/foo/bar/g }  # same

Perl 5.14 から、values はスカラの EXPR を取ることができるようになりました; これは bless されていないハッシュや配列へのリファレンスでなければなりません。 引数は自動的にデリファレンスされます。 values のこの動作は高度に実験的であると考えられています。 正確な振る舞いは将来のバージョンの Perl で変わるかも知れません。

    for (values $hashref) { ... }
    for (values $obj->get_arrayref) { ... }

あなたのコードを以前のバージョンの Perl で実行したユーザーが不思議な 文法エラーで混乱することを避けるために、コードが最近のバージョンの Perl で のみ 動作することを示すためにファイルの先頭に以下のようなことを 書いてください:

    use 5.012;  # so keys/values/each work on arrays
    use 5.014;  # so keys/values/each work on scalars (experimental)

keys, each, sort も参照してください。

vec EXPR,OFFSET,BITS

文字列 EXPR を BITS 幅の要素からなるビットベクターとして扱い、 OFFSET で指定された要素を符号なし整数として返します。 従って、 BITS はビットベクターの中の各要素について予約されるビット数です。 BIT は、1 から 32 まで(プラットホームが 対応していれば 64 まで) の 2 のべき乗でなければなりません。

BITS が 8 の場合、「要素」は入力文字列の各バイトと一致します。

BITS が 16 以上の場合、入力のバイト列は BITS/8 のサイズの固まりに グループ化され、各グループは pack()/unpack() のビッグエンディアン フォーマット n/N を用いて(BITS==64 の類似として)数値に変換されます。 詳細は "pack" を参照してください。

BITS が 4 以下の場合、文字列はバイトに分解され、バイトの各ビットは 8/BITS 個のグループに分割されます。 ビットはリトルエンディアン風に、0x01, 0x02, 0x04, 0x08, 0x10, 0x20, 0x40, 0x80 の順になります。 例えば、入力バイト chr(0x36) を二つのグループに分割すると、 (0x6, 0x3) になります; 4 つに分割すると (0x2, 0x1, 0x3, 0x0) に なります。

左辺値として、代入の対象にすることもできます; この場合、式を正しく 先行させるために以下のように括弧が必要です:

    vec($image, $max_x * $x + $y, 8) = 3;

選択された要素が文字列の外側だった場合、値 0 が返されます。 文字列の最後よりも後ろの要素に書き込もうとした場合、 Perl はまず文字列を必要な分だけ 0 のバイトで拡張します。 文字列の先頭より前に書き込もうとした(つまり OFFSET が負の数だった) 場合はエラーとなります。

文字列がなぜか内部で UTF-8 でエンコードされている場合(したがって UTF8 フラグが セットされている場合)、これは vec では無視され、たとえ値が 256 未満の 文字だけであったとしても、概念的な 文字列ではなく内部バイト文字列で操作されます。

vec で作られた文字列は、論理演算子 |&^ で 扱うこともできます。 これらの演算子は、両方の被演算子に文字列を使うと、 ビットベクター演算を行ないます。 "Bitwise String Operators" in perlop を参照してください。

次のコードは 'PerlPerlPerl' という ASCII 文字列を作成します。 コメントは各行の実行後の文字列を示します。 このコードはビッグエンディアンでもリトルエンディアンでも同じように 動作することに注意してください。

    my $foo = '';
    vec($foo,  0, 32) = 0x5065726C; # 'Perl'

    # $foo eq "Perl" eq "\x50\x65\x72\x6C", 32 bits
    print vec($foo, 0, 8);  # prints 80 == 0x50 == ord('P')

    vec($foo,  2, 16) = 0x5065; # 'PerlPe'
    vec($foo,  3, 16) = 0x726C; # 'PerlPerl'
    vec($foo,  8,  8) = 0x50;   # 'PerlPerlP'
    vec($foo,  9,  8) = 0x65;   # 'PerlPerlPe'
    vec($foo, 20,  4) = 2;      # 'PerlPerlPe'   . "\x02"
    vec($foo, 21,  4) = 7;      # 'PerlPerlPer'
                                   # 'r' is "\x72"
    vec($foo, 45,  2) = 3;      # 'PerlPerlPer'  . "\x0c"
    vec($foo, 93,  1) = 1;      # 'PerlPerlPer'  . "\x2c"
    vec($foo, 94,  1) = 1;      # 'PerlPerlPerl'
                                   # 'l' is "\x6c"

ビットベクターを、0 と 1 の文字列や配列に変換するには、 以下のようにします。

    $bits = unpack("b*", $vector);
    @bits = split(//, unpack("b*", $vector));

ビット長が分かっていれば、* の代わりにその長さを使うことができます。

これはビットが実際にどのような位置に入るかを図示する例です。

  #!/usr/bin/perl -wl

  print <<'EOT';
                                    0         1         2         3
                     unpack("V",$_) 01234567890123456789012345678901
  ------------------------------------------------------------------
  EOT

  for $w (0..3) {
      $width = 2**$w;
      for ($shift=0; $shift < $width; ++$shift) {
          for ($off=0; $off < 32/$width; ++$off) {
              $str = pack("B*", "0"x32);
              $bits = (1<<$shift);
              vec($str, $off, $width) = $bits;
              $res = unpack("b*",$str);
              $val = unpack("V", $str);
              write;
          }
      }
  }

  format STDOUT =
  vec($_,@#,@#) = @<< == @######### @>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  $off, $width, $bits, $val, $res
  .
  __END__

実行するマシンのアーキテクチャに関わらず、 上記の例は以下の表を出力します。

                                    0         1         2         3
                     unpack("V",$_) 01234567890123456789012345678901
  ------------------------------------------------------------------
  vec($_, 0, 1) = 1   ==          1 10000000000000000000000000000000
  vec($_, 1, 1) = 1   ==          2 01000000000000000000000000000000
  vec($_, 2, 1) = 1   ==          4 00100000000000000000000000000000
  vec($_, 3, 1) = 1   ==          8 00010000000000000000000000000000
  vec($_, 4, 1) = 1   ==         16 00001000000000000000000000000000
  vec($_, 5, 1) = 1   ==         32 00000100000000000000000000000000
  vec($_, 6, 1) = 1   ==         64 00000010000000000000000000000000
  vec($_, 7, 1) = 1   ==        128 00000001000000000000000000000000
  vec($_, 8, 1) = 1   ==        256 00000000100000000000000000000000
  vec($_, 9, 1) = 1   ==        512 00000000010000000000000000000000
  vec($_,10, 1) = 1   ==       1024 00000000001000000000000000000000
  vec($_,11, 1) = 1   ==       2048 00000000000100000000000000000000
  vec($_,12, 1) = 1   ==       4096 00000000000010000000000000000000
  vec($_,13, 1) = 1   ==       8192 00000000000001000000000000000000
  vec($_,14, 1) = 1   ==      16384 00000000000000100000000000000000
  vec($_,15, 1) = 1   ==      32768 00000000000000010000000000000000
  vec($_,16, 1) = 1   ==      65536 00000000000000001000000000000000
  vec($_,17, 1) = 1   ==     131072 00000000000000000100000000000000
  vec($_,18, 1) = 1   ==     262144 00000000000000000010000000000000
  vec($_,19, 1) = 1   ==     524288 00000000000000000001000000000000
  vec($_,20, 1) = 1   ==    1048576 00000000000000000000100000000000
  vec($_,21, 1) = 1   ==    2097152 00000000000000000000010000000000
  vec($_,22, 1) = 1   ==    4194304 00000000000000000000001000000000
  vec($_,23, 1) = 1   ==    8388608 00000000000000000000000100000000
  vec($_,24, 1) = 1   ==   16777216 00000000000000000000000010000000
  vec($_,25, 1) = 1   ==   33554432 00000000000000000000000001000000
  vec($_,26, 1) = 1   ==   67108864 00000000000000000000000000100000
  vec($_,27, 1) = 1   ==  134217728 00000000000000000000000000010000
  vec($_,28, 1) = 1   ==  268435456 00000000000000000000000000001000
  vec($_,29, 1) = 1   ==  536870912 00000000000000000000000000000100
  vec($_,30, 1) = 1   == 1073741824 00000000000000000000000000000010
  vec($_,31, 1) = 1   == 2147483648 00000000000000000000000000000001
  vec($_, 0, 2) = 1   ==          1 10000000000000000000000000000000
  vec($_, 1, 2) = 1   ==          4 00100000000000000000000000000000
  vec($_, 2, 2) = 1   ==         16 00001000000000000000000000000000
  vec($_, 3, 2) = 1   ==         64 00000010000000000000000000000000
  vec($_, 4, 2) = 1   ==        256 00000000100000000000000000000000
  vec($_, 5, 2) = 1   ==       1024 00000000001000000000000000000000
  vec($_, 6, 2) = 1   ==       4096 00000000000010000000000000000000
  vec($_, 7, 2) = 1   ==      16384 00000000000000100000000000000000
  vec($_, 8, 2) = 1   ==      65536 00000000000000001000000000000000
  vec($_, 9, 2) = 1   ==     262144 00000000000000000010000000000000
  vec($_,10, 2) = 1   ==    1048576 00000000000000000000100000000000
  vec($_,11, 2) = 1   ==    4194304 00000000000000000000001000000000
  vec($_,12, 2) = 1   ==   16777216 00000000000000000000000010000000
  vec($_,13, 2) = 1   ==   67108864 00000000000000000000000000100000
  vec($_,14, 2) = 1   ==  268435456 00000000000000000000000000001000
  vec($_,15, 2) = 1   == 1073741824 00000000000000000000000000000010
  vec($_, 0, 2) = 2   ==          2 01000000000000000000000000000000
  vec($_, 1, 2) = 2   ==          8 00010000000000000000000000000000
  vec($_, 2, 2) = 2   ==         32 00000100000000000000000000000000
  vec($_, 3, 2) = 2   ==        128 00000001000000000000000000000000
  vec($_, 4, 2) = 2   ==        512 00000000010000000000000000000000
  vec($_, 5, 2) = 2   ==       2048 00000000000100000000000000000000
  vec($_, 6, 2) = 2   ==       8192 00000000000001000000000000000000
  vec($_, 7, 2) = 2   ==      32768 00000000000000010000000000000000
  vec($_, 8, 2) = 2   ==     131072 00000000000000000100000000000000
  vec($_, 9, 2) = 2   ==     524288 00000000000000000001000000000000
  vec($_,10, 2) = 2   ==    2097152 00000000000000000000010000000000
  vec($_,11, 2) = 2   ==    8388608 00000000000000000000000100000000
  vec($_,12, 2) = 2   ==   33554432 00000000000000000000000001000000
  vec($_,13, 2) = 2   ==  134217728 00000000000000000000000000010000
  vec($_,14, 2) = 2   ==  536870912 00000000000000000000000000000100
  vec($_,15, 2) = 2   == 2147483648 00000000000000000000000000000001
  vec($_, 0, 4) = 1   ==          1 10000000000000000000000000000000
  vec($_, 1, 4) = 1   ==         16 00001000000000000000000000000000
  vec($_, 2, 4) = 1   ==        256 00000000100000000000000000000000
  vec($_, 3, 4) = 1   ==       4096 00000000000010000000000000000000
  vec($_, 4, 4) = 1   ==      65536 00000000000000001000000000000000
  vec($_, 5, 4) = 1   ==    1048576 00000000000000000000100000000000
  vec($_, 6, 4) = 1   ==   16777216 00000000000000000000000010000000
  vec($_, 7, 4) = 1   ==  268435456 00000000000000000000000000001000
  vec($_, 0, 4) = 2   ==          2 01000000000000000000000000000000
  vec($_, 1, 4) = 2   ==         32 00000100000000000000000000000000
  vec($_, 2, 4) = 2   ==        512 00000000010000000000000000000000
  vec($_, 3, 4) = 2   ==       8192 00000000000001000000000000000000
  vec($_, 4, 4) = 2   ==     131072 00000000000000000100000000000000
  vec($_, 5, 4) = 2   ==    2097152 00000000000000000000010000000000
  vec($_, 6, 4) = 2   ==   33554432 00000000000000000000000001000000
  vec($_, 7, 4) = 2   ==  536870912 00000000000000000000000000000100
  vec($_, 0, 4) = 4   ==          4 00100000000000000000000000000000
  vec($_, 1, 4) = 4   ==         64 00000010000000000000000000000000
  vec($_, 2, 4) = 4   ==       1024 00000000001000000000000000000000
  vec($_, 3, 4) = 4   ==      16384 00000000000000100000000000000000
  vec($_, 4, 4) = 4   ==     262144 00000000000000000010000000000000
  vec($_, 5, 4) = 4   ==    4194304 00000000000000000000001000000000
  vec($_, 6, 4) = 4   ==   67108864 00000000000000000000000000100000
  vec($_, 7, 4) = 4   == 1073741824 00000000000000000000000000000010
  vec($_, 0, 4) = 8   ==          8 00010000000000000000000000000000
  vec($_, 1, 4) = 8   ==        128 00000001000000000000000000000000
  vec($_, 2, 4) = 8   ==       2048 00000000000100000000000000000000
  vec($_, 3, 4) = 8   ==      32768 00000000000000010000000000000000
  vec($_, 4, 4) = 8   ==     524288 00000000000000000001000000000000
  vec($_, 5, 4) = 8   ==    8388608 00000000000000000000000100000000
  vec($_, 6, 4) = 8   ==  134217728 00000000000000000000000000010000
  vec($_, 7, 4) = 8   == 2147483648 00000000000000000000000000000001
  vec($_, 0, 8) = 1   ==          1 10000000000000000000000000000000
  vec($_, 1, 8) = 1   ==        256 00000000100000000000000000000000
  vec($_, 2, 8) = 1   ==      65536 00000000000000001000000000000000
  vec($_, 3, 8) = 1   ==   16777216 00000000000000000000000010000000
  vec($_, 0, 8) = 2   ==          2 01000000000000000000000000000000
  vec($_, 1, 8) = 2   ==        512 00000000010000000000000000000000
  vec($_, 2, 8) = 2   ==     131072 00000000000000000100000000000000
  vec($_, 3, 8) = 2   ==   33554432 00000000000000000000000001000000
  vec($_, 0, 8) = 4   ==          4 00100000000000000000000000000000
  vec($_, 1, 8) = 4   ==       1024 00000000001000000000000000000000
  vec($_, 2, 8) = 4   ==     262144 00000000000000000010000000000000
  vec($_, 3, 8) = 4   ==   67108864 00000000000000000000000000100000
  vec($_, 0, 8) = 8   ==          8 00010000000000000000000000000000
  vec($_, 1, 8) = 8   ==       2048 00000000000100000000000000000000
  vec($_, 2, 8) = 8   ==     524288 00000000000000000001000000000000
  vec($_, 3, 8) = 8   ==  134217728 00000000000000000000000000010000
  vec($_, 0, 8) = 16  ==         16 00001000000000000000000000000000
  vec($_, 1, 8) = 16  ==       4096 00000000000010000000000000000000
  vec($_, 2, 8) = 16  ==    1048576 00000000000000000000100000000000
  vec($_, 3, 8) = 16  ==  268435456 00000000000000000000000000001000
  vec($_, 0, 8) = 32  ==         32 00000100000000000000000000000000
  vec($_, 1, 8) = 32  ==       8192 00000000000001000000000000000000
  vec($_, 2, 8) = 32  ==    2097152 00000000000000000000010000000000
  vec($_, 3, 8) = 32  ==  536870912 00000000000000000000000000000100
  vec($_, 0, 8) = 64  ==         64 00000010000000000000000000000000
  vec($_, 1, 8) = 64  ==      16384 00000000000000100000000000000000
  vec($_, 2, 8) = 64  ==    4194304 00000000000000000000001000000000
  vec($_, 3, 8) = 64  == 1073741824 00000000000000000000000000000010
  vec($_, 0, 8) = 128 ==        128 00000001000000000000000000000000
  vec($_, 1, 8) = 128 ==      32768 00000000000000010000000000000000
  vec($_, 2, 8) = 128 ==    8388608 00000000000000000000000100000000
  vec($_, 3, 8) = 128 == 2147483648 00000000000000000000000000000001
wait

wait(2) と同様に振る舞います: チャイルドプロセスが終了するのを待ち、消滅した プロセスの pid を返します; チャイルドプロセスが存在しないときには、-1 を 返します。 ステータスは $?${^CHILD_ERROR_NATIVE} に返されます。 perlipc に書いているように、返り値が -1 の場合は子プロセスが 自動的に刈り取られたことを意味するかもしれないことに注意してください。

wait を $SIG{CHLD} のハンドラで使うと、誤って qx() や system() に 適用されるかも知れません。 詳しくは perlipc を参照してください。

移植性の問題: "wait" in perlport

waitpid PID,FLAGS

特定のチャイルドプロセスが終了するのを待ち、消滅したプロセスの pid を 返します; 指定したチャイルドプロセスが存在しないときには、-1 を返します。 値 0 がプロセスがまだ実行中であることを示すシステムもあります。 ステータスは $?${^CHILD_ERROR_NATIVE} に返されます。 以下のようにすると

    use POSIX ":sys_wait_h";
    #...
    do {
        $kid = waitpid(-1, WNOHANG);
    } while $kid > 0;

ブロックが起こらないようにして、全ての待機中ゾンビプロセスを wait します。 ブロックなしの wait は、システムコール wait_pid(2) か、 システムコール wait4(2) をサポートしているマシンで利用可能です。 しかしながら、特定の pid を 0 の FLAGS での wait はどこでも 実装されています。 (exit したプロセスのステータス値を覚えておいて、Perl がシステムコールを エミュレートしますが、Perl スクリプトには取り入れられていません。)

システムによっては、返り値が -1 の場合は子プロセスが自動的に 刈り取られたことを意味するかもしれないことに注意してください。 詳細やその他の例については perlipc を参照してください。

移植性の問題: "waitpid" in perlport

wantarray

現在実行中のサブルーチンか eval() ブロックのコンテキストが、リスト値を 要求するものであれば、真を返します。 スカラを要求するコンテキストであれば、偽を返します。 何も値を要求しない(無効コンテキスト)場合は未定義値を返します。

    return unless defined wantarray; # don't bother doing more
    my @a = complex_calculation();
    return wantarray ? @a : "@a";

ファイルのトップレベル、BEGIN, UNITCHECK, CHECK, INIT, END ブロック内、DESTROY メソッド内では wantarray() の結果は未定義です。

この関数は wantlist() という名前にするべきでした。

warn LIST

LIST の値を STDERR に出力します。 LIST の最後の要素が改行で終わっていない場合、die が行うのと同様の ファイル/行番号のテキストが追加されます。

出力が空かつ、(典型的には以前の eval によって) $@ に既に値が入っている 場合、$@"\t...caught" を追加した値が用いられます。 これはほとんどそのままにするときに便利ですが、 die と全体的に似ているわけではありません。

$@ が空の場合は、"Warning: Something's wrong" という文字列が 使われます。

$SIG{__WARN__} ハンドラが設定されている場合は何のメッセージも 表示されません。 メッセージをどう扱うか(例えば die に変換するか)はハンドラの 責任ということです。 従ってほとんどのハンドラは、扱おうと準備していない警告を表示するために、 ハンドラの中で warn を再び呼び出します。 __WARN__ フックはハンドラ内では呼び出されないので、これは十分安全で、 無限ループを引き起こすことはないということに注意してください。

この振る舞いは $SIG{__DIE__} ハンドラ(エラーテキストは削除しませんが、 代わりに die をもう一度呼び出すことで変更できます)とは 少し違うことに気付くことでしょう。

__WARN__ ハンドラを使うと、(いわゆる必須のものを含む)全ての 警告を黙らせる強力な手段となります。 例:

    # wipe out *all* compile-time warnings
    BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
    my $foo = 10;
    my $foo = 20;          # no warning about duplicate my $foo,
                           # but hey, you asked for it!
    # no compile-time or run-time warnings before here
    $DOWARN = 1;

    # run-time warnings enabled after here
    warn "\$foo is alive and $foo!";     # does show up

%SIG エントリのセットに関する詳細とさらなる例に関しては perlvar を参照してください。 carp() 関数と cluck() 関数を用いた警告の方法に関しては Carp モジュールを参照してください。

write FILEHANDLE
write EXPR
write

指定された FILEHANDLE に対して、そのファイルに対応させた フォーマットを使って、(複数行の場合もある) 整形された レコードを書き出します。 デフォルトでは、ファイルに対応するフォーマットは、ファイルハンドルと 同じ名前のものですが、その時点の出力チャネル (select 関数の項を 参照してください) のフォーマットは、その名前を明示的に変数 $~ に 代入することで、変更が可能です。

ページの先頭の処理は、自動的に行なわれます: 現在のページに整形された レコードを出力するだけのスペースがない場合には、改ページを行なってページを 進め、新しいページヘッダを整形するため、ページ先頭フォーマットが使われ、 その後でレコードが書かれます。 デフォルトでは、ページ先頭フォーマットは、ファイルハンドルの名前に "_TOP" をつなげたものです。 これは自動有効化されたファイルハンドルで問題になる可能性がありますが、 ファイルハンドルが選択されている間に、 変数 $^ に名前を設定すれば、動的にフォーマットを 変更することができます。 そのページの残り行数は、変数 $- に入っており、この変数を 0 に 設定することで、強制的に改ページを行なうことができます。

FILEHANDLE を指定しないと、出力はその時点のデフォルト出力チャネルに対して 行なわれます; これは、スクリプトの開始時点では STDOUT ですが、 select() 演算子で変更することができます。 FILEHANDLE が EXPR ならば、式が評価され、その結果の文字列が 実行時に FILEHANDLE の名前として見られます。 フォーマットについて、さらには、perlform を参照してください。

write は read の反対のことをするもの ではありません。 残念ながら。

y///

文字変換演算子です。 tr/// と同じです。 "Quote and Quote-like Operators" in perlop を参照してください。

Non-function Keywords by Cross-reference

perldata

__DATA__
__END__

これらのキーワードは "Special Literals" in perldata で文書化されています。

perlmod

BEGIN
CHECK
END
INIT
UNITCHECK

これらのコンパイルフェーズキーワードは "BEGIN, UNITCHECK, CHECK, INIT and END" in perlmod で文書化されています。

perlobj

DESTROY

このメソッドキーワードは "Destructors" in perlobj で文書化されています。

perlop

and
cmp
eq
ge
gt
if
le
lt
ne
not
or
x
xor

これらの演算子は perlop で文書化されています。

perlsub

AUTOLOAD

このキーワードは "Autoloading" in perlsub で文書化されています。

perlsyn

else
elseif
elsif
for
foreach
unless
until
while

これらのフロー制御キーワードは "Compound Statements" in perlsyn で 文書化されています。

default
given
when

これらの実験的な switch 機能に関連するフロー制御キーワードは "Switch Statements" in perlsyn で文書化されています。